qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //  SVQC Monster Properties
   3 // =========================
   4
   5
   6 void monster_item_spawn()
   7 {
   8         if(self.monster_loot)
   9                 self.monster_loot();
  10
  11         self.gravity = 1;
  12         self.reset = SUB_Remove;
  13         self.noalign = TRUE;
  14         self.velocity = randomvec() * 175 + '0 0 325';
  15         self.classname = "droppedweapon"; // hax
  16         self.item_spawnshieldtime = time + 0.7;
  17
  18         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  19 }
  20
  21 void monster_dropitem()
  22 {
  23         if(!self.candrop || !self.monster_loot)
  24                 return;
  25
  26         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  27         entity e = spawn();
  28
  29         setorigin(e, org);
  30
  31         e.monster_loot = self.monster_loot;
  32
  33         other = e;
  34         MUTATOR_CALLHOOK(MonsterDropItem);
  35         e = other;
  36
  37         if(e)
  38         {
  39                 e.think = monster_item_spawn;
  40                 e.nextthink = time + 0.3;
  41         }
  42 }
  43
  44 float Monster_SkillModifier()
  45 {
  46         float t = 1;
  47
  48         t *= (self.monster_skill * 0.5);
  49
  50         return t;
  51 }
  52
  53 float monster_isvalidtarget (entity targ, entity ent)
  54 {
  55         if(!targ || !ent)
  56                 return FALSE; // someone doesn't exist
  57
  58         if(targ == ent)
  59                 return FALSE; // don't attack ourselves
  60
  61         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  62
  63         if(trace_ent != targ)
  64                 return FALSE;
  65
  66         if(targ.vehicle_flags & VHF_ISVEHICLE)
  67         if not((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED)
  68                 return FALSE; // melee attacks are useless against vehicles
  69
  70         if(time < game_starttime)
  71                 return FALSE; // monsters do nothing before the match has started
  72
  73         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  74                 return FALSE; // enemy is too far away
  75
  76         if(targ.takedamage == DAMAGE_NO)
  77                 return FALSE; // enemy can't be damaged
  78
  79         if(targ.items & IT_INVISIBILITY)
  80                 return FALSE; // enemy is invisible
  81
  82         if(substring(targ.classname, 0, 10) == "onslaught_")
  83                 return FALSE; // don't attack onslaught targets
  84
  85         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  86                 return FALSE; // enemy is a spectator
  87
  88         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  89         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  90                 return FALSE; // enemy/self is dead
  91
  92         if(ent.monster_owner == targ)
  93                 return FALSE; // don't attack our master
  94
  95         if(targ.monster_owner == ent)
  96                 return FALSE; // don't attack our pet
  97
  98         if not(targ.vehicle_flags & VHF_ISVEHICLE)
  99         if(targ.flags & FL_NOTARGET)
 100                 return FALSE; // enemy can't be targeted
 101
 102         if not(autocvar_g_monsters_typefrag)
 103         if(targ.BUTTON_CHAT)
 104                 return FALSE; // no typefragging!
 105
 106         if(SAME_TEAM(targ, ent))
 107                 return FALSE; // enemy is on our team
 108
 109         if (targ.frozen == 1 || (targ.frozen == 2 && ent.monsterid != MON_SPIDER))
 110                 return FALSE; // ignore frozen
 111
 112         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 113         if(ent.enemy != targ)
 114         {
 115                 float dot;
 116
 117                 makevectors (ent.angles);
 118                 dot = normalize (targ.origin - ent.origin) * v_forward;
 119
 120                 if(dot <= 0.3)
 121                         return FALSE;
 122         }
 123
 124         return TRUE;
 125 }
 126
 127 entity FindTarget (entity ent)
 128 {
 129         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 130
 131         entity head, closest_target = world;
 132         head = findradius(ent.origin, ent.target_range);
 133
 134         while(head) // find the closest acceptable target to pass to
 135         {
 136                 if(head.monster_attack)
 137                 if(monster_isvalidtarget(head, ent))
 138                 {
 139                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 140                         vector head_center = CENTER_OR_VIEWOFS(head);
 141                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 142
 143                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 144                         if(closest_target)
 145                         {
 146                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 147                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 148                                         { closest_target = head; }
 149                         }
 150                         else { closest_target = head; }
 151                 }
 152
 153                 head = head.chain;
 154         }
 155
 156         return closest_target;
 157 }
 158
 159 void MonsterTouch ()
 160 {
 161         if(other == world)
 162                 return;
 163
 164         if(self.enemy != other)
 165         if not(other.flags & FL_MONSTER)
 166         if(monster_isvalidtarget(other, self))
 167                 self.enemy = other;
 168 }
 169
 170 string get_monster_model_datafilename(string m, float sk, string fil)
 171 {
 172         if(m)
 173                 m = strcat(m, "_");
 174         else
 175                 m = "models/monsters/*_";
 176         if(sk >= 0)
 177                 m = strcat(m, ftos(sk));
 178         else
 179                 m = strcat(m, "*");
 180         return strcat(m, ".", fil);
 181 }
 182
 183 void PrecacheMonsterSounds(string f)
 184 {
 185         float fh;
 186         string s;
 187         fh = fopen(f, FILE_READ);
 188         if(fh < 0)
 189                 return;
 190         while((s = fgets(fh)))
 191         {
 192                 if(tokenize_console(s) != 3)
 193                 {
 194                         dprint("Invalid sound info line: ", s, "\n");
 195                         continue;
 196                 }
 197                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 198         }
 199         fclose(fh);
 200 }
 201
 202 void precache_monstersounds()
 203 {
 204         string m = (get_monsterinfo(self.monsterid)).model;
 205         float globhandle, n, i;
 206         string f;
 207
 208         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 209         if (globhandle < 0)
 210                 return;
 211         n = search_getsize(globhandle);
 212         for (i = 0; i < n; ++i)
 213         {
 214                 //print(search_getfilename(globhandle, i), "\n");
 215                 f = search_getfilename(globhandle, i);
 216                 PrecacheMonsterSounds(f);
 217         }
 218         search_end(globhandle);
 219 }
 220
 221 void ClearMonsterSounds()
 222 {
 223 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 224         ALLMONSTERSOUNDS
 225 #undef _MSOUND
 226 }
 227
 228 .string GetMonsterSoundSampleField(string type)
 229 {
 230         GetMonsterSoundSampleField_notFound = 0;
 231         switch(type)
 232         {
 233 #define _MSOUND(m) case #m: return monstersound_##m;
 234                 ALLMONSTERSOUNDS
 235 #undef _MSOUND
 236         }
 237         GetMonsterSoundSampleField_notFound = 1;
 238         return string_null;
 239 }
 240
 241 float LoadMonsterSounds(string f, float first)
 242 {
 243         float fh;
 244         string s;
 245         var .string field;
 246         fh = fopen(f, FILE_READ);
 247         if(fh < 0)
 248         {
 249                 dprint("Monster sound file not found: ", f, "\n");
 250                 return 0;
 251         }
 252         while((s = fgets(fh)))
 253         {
 254                 if(tokenize_console(s) != 3)
 255                         continue;
 256                 field = GetMonsterSoundSampleField(argv(0));
 257                 if(GetMonsterSoundSampleField_notFound)
 258                         continue;
 259                 if(self.field)
 260                         strunzone(self.field);
 261                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 262         }
 263         fclose(fh);
 264         return 1;
 265 }
 266
 267 .float skin_for_monstersound;
 268 void UpdateMonsterSounds()
 269 {
 270         entity mon = get_monsterinfo(self.monsterid);
 271
 272         if(self.skin == self.skin_for_monstersound)
 273                 return;
 274         self.skin_for_monstersound = self.skin;
 275         ClearMonsterSounds();
 276         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 277         if(!autocvar_g_debug_defaultsounds)
 278         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 279                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 280 }
 281
 282 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 283 {
 284         if(delaytoo && time < self.msound_delay)
 285                 return; // too early
 286         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 287
 288         self.msound_delay = time + sound_delay;
 289 }
 290
 291 void monster_makevectors(entity e)
 292 {
 293         vector v;
 294
 295         v = e.origin + (e.mins + e.maxs) * 0.5;
 296         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 297         self.v_angle_x = -self.v_angle_x;
 298
 299         makevectors(self.v_angle);
 300 }
 301
 302 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 303 {
 304         if (self.health <= 0)
 305                 return FALSE; // attacking while dead?!
 306
 307         if(dostop)
 308         {
 309                 self.velocity_x = 0;
 310                 self.velocity_y = 0;
 311                 self.state = MONSTER_STATE_ATTACK_MELEE;
 312         }
 313
 314         self.frame = anim;
 315
 316         if(anim_finished != 0)
 317                 self.attack_finished_single = time + anim_finished;
 318
 319         monster_makevectors(targ);
 320
 321         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 322
 323         if(trace_ent.takedamage)
 324                 Damage(trace_ent, self, self, damg * Monster_SkillModifier(), deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 325
 326         return TRUE;
 327 }
 328
 329 void Monster_CheckMinibossFlag ()
 330 {
 331         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 332                 return;
 333
 334         float chance = random() * 100;
 335
 336         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 337         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 338         {
 339                 self.health += autocvar_g_monsters_miniboss_healthboost;
 340                 self.effects |= EF_RED;
 341                 if not(self.weapon)
 342                         self.weapon = WEP_NEX;
 343         }
 344 }
 345
 346 float Monster_CanRespawn(entity ent)
 347 {
 348         other = ent;
 349         if(ent.deadflag == DEAD_DEAD) // don't call when monster isn't dead
 350         if(MUTATOR_CALLHOOK(MonsterRespawn))
 351                 return TRUE; // enabled by a mutator
 352
 353         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 354                 return FALSE;
 355
 356         if not(autocvar_g_monsters_respawn)
 357                 return FALSE;
 358
 359         return TRUE;
 360 }
 361
 362 void Monster_Fade ()
 363 {
 364         if(Monster_CanRespawn(self))
 365         {
 366                 self.monster_respawned = TRUE;
 367                 self.think = self.monster_spawnfunc;
 368                 self.nextthink = time + self.respawntime;
 369                 self.ltime = 0;
 370                 self.deadflag = DEAD_RESPAWNING;
 371                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 372                 {
 373                         self.pos1 = self.origin;
 374                         self.pos2 = self.angles;
 375                 }
 376                 self.event_damage = func_null;
 377                 self.takedamage = DAMAGE_NO;
 378                 setorigin(self, self.pos1);
 379                 self.angles = self.pos2;
 380                 self.health = self.max_health;
 381                 setmodel(self, "null");
 382         }
 383         else
 384                 SUB_SetFade(self, time + 3, 1);
 385 }
 386
 387 float Monster_CanJump (vector vel)
 388 {
 389         if(self.state)
 390                 return FALSE; // already attacking
 391         if not(self.flags & FL_ONGROUND)
 392                 return FALSE; // not on the ground
 393         if(self.health <= 0)
 394                 return FALSE; // called when dead?
 395         if(time < self.attack_finished_single)
 396                 return FALSE; // still attacking
 397
 398         vector old = self.velocity;
 399
 400         self.velocity = vel;
 401         tracetoss(self, self);
 402         self.velocity = old;
 403         if (trace_ent != self.enemy)
 404                 return FALSE;
 405
 406         return TRUE;
 407 }
 408
 409 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 410 {
 411         if(!Monster_CanJump(vel))
 412                 return FALSE;
 413
 414         self.frame = anm;
 415         self.state = MONSTER_STATE_ATTACK_LEAP;
 416         self.touch = touchfunc;
 417         self.origin_z += 1;
 418         self.velocity = vel;
 419         self.flags &= ~FL_ONGROUND;
 420
 421         self.attack_finished_single = time + anim_finished;
 422
 423         return TRUE;
 424 }
 425
 426 void monster_checkattack(entity e, entity targ)
 427 {
 428         if(e == world)
 429                 return;
 430         if(targ == world)
 431                 return;
 432
 433         if not(e.monster_attackfunc)
 434                 return;
 435
 436         if(time < e.attack_finished_single)
 437                 return;
 438
 439         if(vlen(targ.origin - e.origin) <= e.attack_range)
 440         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 441         {
 442                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 443                 return;
 444         }
 445
 446         if(vlen(targ.origin - e.origin) > e.attack_range)
 447         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 448         {
 449                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 450                 return;
 451         }
 452 }
 453
 454 void monster_use ()
 455 {
 456         if not(self.enemy)
 457         if(self.health > 0)
 458         if(monster_isvalidtarget(activator, self))
 459                 self.enemy = activator;
 460 }
 461
 462 .float last_trace;
 463 .float last_enemycheck; // for checking enemy
 464 vector monster_pickmovetarget(entity targ)
 465 {
 466         // enemy is always preferred target
 467         if(self.enemy)
 468         {
 469                 makevectors(self.angles);
 470                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 471                 self.last_trace = time + 1.2;
 472                 return self.enemy.origin;
 473         }
 474
 475         switch(self.monster_moveflags)
 476         {
 477                 case MONSTER_MOVE_OWNER:
 478                 {
 479                         self.monster_movestate = MONSTER_MOVE_OWNER;
 480                         self.last_trace = time + 0.3;
 481                         return (self.monster_owner) ? self.monster_owner.origin : self.origin;
 482                 }
 483                 case MONSTER_MOVE_SPAWNLOC:
 484                 {
 485                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 486                         self.last_trace = time + 2;
 487                         return self.pos1;
 488                 }
 489                 case MONSTER_MOVE_NOMOVE:
 490                 {
 491                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 492                         self.last_trace = time + 2;
 493                         return self.origin;
 494                 }
 495                 default:
 496                 case MONSTER_MOVE_WANDER:
 497                 {
 498                         vector pos;
 499                         self.monster_movestate = MONSTER_MOVE_WANDER;
 500                         self.last_trace = time + 2;
 501
 502                         self.angles_y = rint(random() * 500);
 503                         makevectors(self.angles);
 504                         pos = self.origin + v_forward * 600;
 505
 506                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 507                         if(self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 508                         {
 509                                 pos_z = random() * 200;
 510                                 if(random() >= 0.5)
 511                                         pos_z *= -1;
 512                         }
 513
 514                         if(targ)
 515                         {
 516                                 self.last_trace = time + 0.5;
 517                                 pos = targ.origin;
 518                         }
 519
 520                         return pos;
 521                 }
 522         }
 523 }
 524
 525 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 526 {
 527         fixedmakevectors(self.angles);
 528
 529         if(self.target2)
 530                 self.goalentity = find(world, targetname, self.target2);
 531
 532         entity targ;
 533
 534         if(self.frozen)
 535         {
 536                 self.revive_progress = bound(0, self.revive_progress + self.ticrate * self.revive_speed, 1);
 537                 self.health = max(1, self.max_health * self.revive_progress);
 538
 539                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 540
 541                 movelib_beak_simple(stopspeed);
 542
 543                 self.frame = manim_idle;
 544
 545                 self.enemy = world;
 546                 self.nextthink = time + self.ticrate;
 547
 548                 if(self.revive_progress >= 1)
 549                         Unfreeze(self); // wait for next think before attacking
 550
 551                 return; // no moving while frozen
 552         }
 553
 554         if(self.flags & FL_SWIM)
 555         {
 556                 if(self.waterlevel < WATERLEVEL_WETFEET)
 557                 {
 558                         if(time >= self.last_trace)
 559                         {
 560                                 self.fish_wasdrowning = TRUE;
 561                                 self.last_trace = time + 0.4;
 562
 563                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 564                                 self.angles = '90 90 0';
 565                                 if(random() < 0.5)
 566                                 {
 567                                         self.velocity_y += random() * 50;
 568                                         self.velocity_x -= random() * 50;
 569                                 }
 570                                 else
 571                                 {
 572                                         self.velocity_y -= random() * 50;
 573                                         self.velocity_x += random() * 50;
 574                                 }
 575                                 self.velocity_z += random() * 150;
 576                         }
 577
 578
 579                         self.movetype = MOVETYPE_BOUNCE;
 580                         //self.velocity_z = -200;
 581
 582                         return;
 583                 }
 584                 else if(self.fish_wasdrowning)
 585                 {
 586                         self.fish_wasdrowning = FALSE;
 587                         self.angles_x = 0;
 588                         self.movetype = MOVETYPE_WALK;
 589                 }
 590         }
 591
 592         targ = self.goalentity;
 593
 594         monster_target = targ;
 595         monster_speed_run = runspeed;
 596         monster_speed_walk = walkspeed;
 597
 598         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 599         {
 600                 runspeed = walkspeed = 0;
 601                 if(time >= self.spawn_time)
 602                         self.frame = manim_idle;
 603                 movelib_beak_simple(stopspeed);
 604                 return;
 605         }
 606
 607         targ = monster_target;
 608         runspeed = monster_speed_run;
 609         walkspeed = monster_speed_walk;
 610
 611         if(teamplay)
 612         if(autocvar_g_monsters_teams)
 613         if(DIFF_TEAM(self.monster_owner, self))
 614                 self.monster_owner = world;
 615
 616         if(self.enemy && self.enemy.health < 1)
 617                 self.enemy = world; // enough!
 618
 619         if(time >= self.last_enemycheck)
 620         {
 621                 if not(monster_isvalidtarget(self.enemy, self))
 622                         self.enemy = world;
 623
 624                 if not(self.enemy)
 625                 {
 626                         self.enemy = FindTarget(self);
 627                         if(self.enemy)
 628                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 629                 }
 630
 631                 self.last_enemycheck = time + 0.5;
 632         }
 633
 634         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 635                 self.state = 0;
 636
 637         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 638         if(time >= self.last_trace || self.enemy) // update enemy instantly
 639                 self.moveto = monster_pickmovetarget(targ);
 640
 641         if not(self.enemy)
 642                 MonsterSound(monstersound_idle, 5, TRUE, CH_VOICE);
 643
 644         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 645                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 646
 647         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 648         {
 649                 self.state = 0;
 650                 self.touch = MonsterTouch;
 651         }
 652
 653         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 654
 655         float turny = 0;
 656         vector real_angle = vectoangles(self.steerto) - self.angles;
 657
 658         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 659                 turny = 20;
 660
 661         if(self.flags & FL_SWIM)
 662                 turny = vlen(self.angles - self.moveto);
 663
 664         if(turny)
 665         {
 666                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 667                 self.angles_y += turny;
 668         }
 669
 670         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 671                 self.moveto = self.origin;
 672
 673         if(self.enemy && self.enemy.vehicle)
 674                 runspeed = 0;
 675
 676         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 677                 v_forward = normalize(self.moveto - self.origin);
 678         else
 679                 self.moveto_z = self.origin_z;
 680
 681         if(vlen(self.origin - self.moveto) > 64)
 682         {
 683                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 684                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 685                 else
 686                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 687
 688                 if(time > self.pain_finished)
 689                 if(time > self.attack_finished_single)
 690                 if(vlen(self.velocity) > 10)
 691                         self.frame = ((self.enemy) ? manim_run : manim_walk);
 692                 else
 693                         self.frame = manim_idle;
 694         }
 695         else
 696         {
 697                 entity e = find(world, targetname, self.target2);
 698                 if(e.target2)
 699                         self.target2 = e.target2;
 700                 else if(e.target)
 701                         self.target2 = e.target;
 702
 703                 movelib_beak_simple(stopspeed);
 704                 if(time > self.attack_finished_single)
 705                 if(time > self.pain_finished)
 706                 if (vlen(self.velocity) <= 30)
 707                         self.frame = manim_idle;
 708         }
 709
 710         monster_checkattack(self, self.enemy);
 711 }
 712
 713 void monster_remove(entity mon)
 714 {
 715         if not(mon)
 716                 return; // nothing to remove
 717
 718         pointparticles(particleeffectnum("item_pickup"), mon.origin, '0 0 0', 1);
 719
 720         if(mon.weaponentity)
 721                 remove(mon.weaponentity);
 722
 723         if(mon.iceblock)
 724                 remove(mon.iceblock);
 725
 726         WaypointSprite_Kill(mon.sprite);
 727
 728         remove(mon);
 729 }
 730
 731 void monster_dead_think()
 732 {
 733         self.nextthink = time + self.ticrate;
 734
 735         CSQCMODEL_AUTOUPDATE();
 736
 737         if(self.ltime != 0)
 738         if(time >= self.ltime)
 739         {
 740                 Monster_Fade();
 741                 return;
 742         }
 743 }
 744
 745 void monsters_setstatus()
 746 {
 747         self.stat_monsters_total = monsters_total;
 748         self.stat_monsters_killed = monsters_killed;
 749 }
 750
 751 void Monster_Appear()
 752 {
 753         self.enemy = activator;
 754         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 755         self.monster_spawnfunc();
 756 }
 757
 758 float Monster_CheckAppearFlags(entity ent)
 759 {
 760         if not(ent.spawnflags & MONSTERFLAG_APPEAR)
 761                 return FALSE;
 762
 763         ent.think = func_null;
 764         ent.nextthink = 0;
 765         ent.use = Monster_Appear;
 766         ent.flags = FL_MONSTER; // set so this monster can get butchered
 767
 768         return TRUE;
 769 }
 770
 771 void monsters_reset()
 772 {
 773         setorigin(self, self.pos1);
 774         self.angles = self.pos2;
 775
 776         Unfreeze(self); // remove any icy remains
 777
 778         self.health = self.max_health;
 779         self.velocity = '0 0 0';
 780         self.enemy = world;
 781         self.goalentity = world;
 782         self.attack_finished_single = 0;
 783         self.moveto = self.origin;
 784 }
 785
 786 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 787 {
 788         self.health -= damage;
 789
 790         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 791
 792         if(self.health <= -100) // 100 health until gone?
 793         {
 794                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 795
 796                 if(IS_CLIENT(self.realowner))
 797                 if not(self.monster_respawned)
 798                         self.realowner.monstercount -= 1;
 799
 800                 self.think = SUB_Remove;
 801                 self.nextthink = time + 0.1;
 802         }
 803 }
 804
 805 void monster_die(entity attacker, float gibbed)
 806 {
 807         self.think = monster_dead_think;
 808         self.nextthink = time;
 809         self.ltime = time + 5;
 810
 811         if ( self.frozen )
 812         {
 813                 Unfreeze(self); // remove any icy remains
 814                 self.health = 0; // reset by Unfreeze
 815         }
 816
 817         monster_dropitem();
 818
 819         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 820
 821         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned)
 822                 monsters_killed += 1;
 823
 824         if(IS_PLAYER(attacker))
 825         if( autocvar_g_monsters_score_spawned ||
 826                         ( !(self.spawnflags & MONSTERFLAG_SPAWNED) && !self.monster_respawned) )
 827                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
 828
 829         if(!Monster_CanRespawn(self) || gibbed)
 830         {
 831                 // number of monsters spawned with mobspawn command
 832                 totalspawned -= 1;
 833
 834                 if(IS_CLIENT(self.realowner))
 835                 if not(self.monster_respawned)
 836                         self.realowner.monstercount -= 1;
 837         }
 838
 839         if(self.candrop && self.weapon)
 840                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 841
 842         self.event_damage       = monsters_corpse_damage;
 843         self.solid                      = SOLID_CORPSE;
 844         self.takedamage         = DAMAGE_AIM;
 845         self.deadflag           = DEAD_DEAD;
 846         self.enemy                      = world;
 847         self.movetype           = MOVETYPE_TOSS;
 848         self.moveto                     = self.origin;
 849         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 850         self.reset                      = func_null;
 851         self.state                      = 0;
 852         self.attack_finished_single = 0;
 853
 854         if not(self.flags & FL_FLY)
 855                 self.velocity = '0 0 0';
 856
 857         MON_ACTION(self.monsterid, MR_DEATH);
 858 }
 859
 860 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 861 {
 862
 863         if(self.frozen && deathtype != DEATH_KILL)
 864                 return;
 865
 866         if(time < self.pain_finished && deathtype != DEATH_KILL)
 867                 return;
 868
 869         if(time < self.spawnshieldtime && deathtype != DEATH_KILL)
 870                 return;
 871
 872         vector v;
 873         float take, save;
 874
 875         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, deathtype, damage);
 876         take = v_x;
 877         save = v_y;
 878
 879         self.health -= take;
 880
 881         WaypointSprite_UpdateHealth(self.sprite, self.health);
 882
 883         self.dmg_time = time;
 884
 885         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 886                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 887
 888         self.velocity += force * self.damageforcescale;
 889
 890         if(deathtype != DEATH_DROWN)
 891         {
 892                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 893                 if (take > 50)
 894                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 895                 if (take > 100)
 896                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 897         }
 898
 899         if(self.health <= 0)
 900         {
 901                 if(deathtype == DEATH_KILL)
 902                         self.candrop = FALSE; // killed by mobkill command
 903
 904                 // TODO: fix this?
 905                 activator = attacker;
 906                 other = self.enemy;
 907                 SUB_UseTargets();
 908                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 909
 910                 monster_die(attacker, (self.health <= -100 || deathtype == DEATH_KILL));
 911
 912                 WaypointSprite_Kill(self.sprite);
 913
 914                 frag_attacker = attacker;
 915                 frag_target = self;
 916                 MUTATOR_CALLHOOK(MonsterDies);
 917
 918                 if(self.health <= -100 || deathtype == DEATH_KILL) // check if we're already gibbed
 919                 {
 920                         Violence_GibSplash(self, 1, 0.5, attacker);
 921
 922                         self.think = SUB_Remove;
 923                         self.nextthink = time + 0.1;
 924                 }
 925         }
 926 }
 927
 928 void monster_think()
 929 {
 930         self.think = monster_think;
 931         self.nextthink = self.ticrate;
 932
 933         if(self.ltime)
 934         if(time >= self.ltime)
 935         {
 936                 Damage(self, self, self, self.health + self.max_health, DEATH_KILL, self.origin, self.origin);
 937                 return;
 938         }
 939
 940         MON_ACTION(self.monsterid, MR_THINK);
 941
 942         CSQCMODEL_AUTOUPDATE();
 943 }
 944
 945 void monster_spawn()
 946 {
 947         MON_ACTION(self.monsterid, MR_SETUP);
 948
 949         if not(self.monster_respawned)
 950                 Monster_CheckMinibossFlag();
 951
 952         self.max_health = self.health;
 953         self.pain_finished = self.nextthink;
 954
 955         if(IS_PLAYER(self.monster_owner))
 956                 self.effects |= EF_DIMLIGHT;
 957
 958         if not(self.monster_respawned)
 959         if not(self.skin)
 960                 self.skin = rint(random() * 4);
 961
 962         if not(self.attack_range)
 963                 self.attack_range = autocvar_g_monsters_attack_range;
 964
 965         precache_monstersounds();
 966         UpdateMonsterSounds();
 967
 968         if(teamplay)
 969                 self.monster_attack = TRUE; // we can have monster enemies in team games
 970
 971         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
 972
 973         WaypointSprite_Spawn(M_NAME(self.monsterid), 0, 1024, self, '0 0 1' * (self.maxs_z + 15), world, self.team, self, sprite, TRUE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 974         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 975         WaypointSprite_UpdateHealth(self.sprite, self.health);
 976
 977         self.think = monster_think;
 978         self.nextthink = time + self.ticrate;
 979
 980         MUTATOR_CALLHOOK(MonsterSpawn);
 981
 982         // TODO: fix this mess
 983         if(IS_PLAYER(self.monster_owner))
 984                 self.colormap = self.monster_owner.colormap;
 985         else if(teamplay && self.team)
 986                 self.colormap = 1024 + self.team * 17;
 987         else
 988         {
 989                 if(self.monster_skill <= MONSTER_SKILL_EASY)
 990                         self.colormap = 1027;
 991                 else if(self.monster_skill <= MONSTER_SKILL_MEDIUM)
 992                         self.colormap = 1038;
 993                 else if(self.monster_skill <= MONSTER_SKILL_HARD)
 994                         self.colormap = 1028;
 995                 else
 996                         self.colormap = 1024;
 997         }
 998 }
 999
1000 float monster_initialize(float mon_id, float nodrop)
1001 {
1002         if not(autocvar_g_monsters)
1003                 return FALSE;
1004
1005         entity mon = get_monsterinfo(mon_id);
1006
1007         if not(self.monster_skill)
1008                 self.monster_skill = cvar("g_monsters_skill");
1009
1010         // support for quake style removing monsters based on skill
1011         if(self.monster_skill == MONSTER_SKILL_EASY) if(self.spawnflags & MONSTERSKILL_NOTEASY) { return FALSE; }
1012         if(self.monster_skill == MONSTER_SKILL_MEDIUM) if(self.spawnflags & MONSTERSKILL_NOTMEDIUM) { return FALSE; }
1013         if(self.monster_skill == MONSTER_SKILL_HARD) if(self.spawnflags & MONSTERSKILL_NOTHARD) { return FALSE; }
1014
1015         if(self.team && !teamplay)
1016                 self.team = 0;
1017
1018         if not(self.spawnflags & MONSTERFLAG_SPAWNED) // naturally spawned monster
1019         if not(self.monster_respawned)
1020                 monsters_total += 1;
1021
1022         setmodel(self, mon.model);
1023         setsize(self, mon.mins, mon.maxs);
1024         self.flags                              = FL_MONSTER;
1025         self.takedamage                 = DAMAGE_AIM;
1026         self.bot_attack                 = TRUE;
1027         self.iscreature                 = TRUE;
1028         self.teleportable               = TRUE;
1029         self.damagedbycontents  = TRUE;
1030         self.monsterid                  = mon_id;
1031         self.damageforcescale   = 0;
1032         self.event_damage               = monsters_damage;
1033         self.touch                              = MonsterTouch;
1034         self.use                                = monster_use;
1035         self.solid                              = SOLID_BBOX;
1036         self.movetype                   = MOVETYPE_WALK;
1037         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1038         self.enemy                              = world;
1039         self.velocity                   = '0 0 0';
1040         self.moveto                             = self.origin;
1041         self.pos1                               = self.origin;
1042         self.pos2                               = self.angles;
1043         self.reset                              = monsters_reset;
1044         self.netname                    = mon.netname;
1045         self.monster_name               = M_NAME(mon_id);
1046         self.candrop                    = TRUE;
1047         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1048         self.oldtarget2                 = self.target2;
1049         self.deadflag                   = DEAD_NO;
1050         self.scale                              = 1;
1051         self.noalign                    = nodrop;
1052         self.spawn_time                 = time;
1053         self.gravity                    = 1;
1054         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1055
1056         if(autocvar_g_fullbrightplayers)
1057                 self.effects |= EF_FULLBRIGHT;
1058
1059         if(autocvar_g_nodepthtestplayers)
1060                 self.effects |= EF_NODEPTHTEST;
1061
1062         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1063                 self.flags |= FL_SWIM;
1064
1065         if(mon.spawnflags & MONSTER_TYPE_FLY)
1066         {
1067                 self.flags |= FL_FLY;
1068                 self.movetype = MOVETYPE_FLY;
1069         }
1070
1071         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1072                 self.scale = 1.3;
1073
1074         if not(self.ticrate)
1075                 self.ticrate = autocvar_g_monsters_think_delay;
1076
1077         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1078
1079         if not(self.m_armor_blockpercent)
1080                 self.m_armor_blockpercent = 0.5;
1081
1082         if not(self.target_range)
1083                 self.target_range = autocvar_g_monsters_target_range;
1084
1085         if not(self.respawntime)
1086                 self.respawntime = autocvar_g_monsters_respawn_delay;
1087
1088         if not(self.monster_moveflags)
1089                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1090
1091         if not(self.noalign)
1092         {
1093                 setorigin(self, self.origin + '0 0 20');
1094                 tracebox(self.origin + '0 0 64', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1095                 setorigin(self, trace_endpos);
1096         }
1097
1098         monster_spawn();
1099
1100         CSQCMODEL_AUTOINIT();
1101
1102         return TRUE;
1103 }