qcsrc/common/monsters/sv_monsters.qc

   1 // =========================
   2 //      SVQC Monster Properties
   3 // =========================
   4
   5
   6 void monster_item_spawn()
   7 {
   8         if(self.monster_loot)
   9                 self.monster_loot();
  10
  11         self.gravity = 1;
  12         self.reset = SUB_Remove;
  13         self.noalign = TRUE;
  14         self.velocity = randomvec() * 175 + '0 0 325';
  15         self.classname = "droppedweapon"; // hax
  16         self.item_spawnshieldtime = time + 0.7;
  17
  18         SUB_SetFade(self, time + autocvar_g_monsters_drop_time, 1);
  19 }
  20
  21 void monster_dropitem()
  22 {
  23         if(!self.candrop || !self.monster_loot)
  24                 return;
  25
  26         vector org = self.origin + ((self.mins + self.maxs) * 0.5);
  27         entity e = spawn();
  28
  29         setorigin(e, org);
  30
  31         e.monster_loot = self.monster_loot;
  32
  33         other = e;
  34         MUTATOR_CALLHOOK(MonsterDropItem);
  35         e = other;
  36
  37         if(e)
  38         {
  39                 e.think = monster_item_spawn;
  40                 e.nextthink = time + 0.3;
  41         }
  42 }
  43
  44 float Monster_SkillModifier()
  45 {
  46         float t = 0.5+self.monster_skill*((1.2-0.3)/10);
  47
  48         return t;
  49 }
  50
  51 float monster_isvalidtarget (entity targ, entity ent)
  52 {
  53         if(!targ || !ent)
  54                 return FALSE; // someone doesn't exist
  55
  56         if(targ == ent)
  57                 return FALSE; // don't attack ourselves
  58
  59         traceline(ent.origin, targ.origin, MOVE_NORMAL, ent);
  60
  61         if(trace_ent != targ)
  62                 return FALSE;
  63
  64         if(targ.vehicle_flags & VHF_ISVEHICLE)
  65         if(!((get_monsterinfo(ent.monsterid)).spawnflags & MON_FLAG_RANGED))
  66                 return FALSE; // melee attacks are useless against vehicles
  67
  68         if(time < game_starttime)
  69                 return FALSE; // monsters do nothing before the match has started
  70
  71         if(vlen(targ.origin - ent.origin) >= ent.target_range)
  72                 return FALSE; // enemy is too far away
  73
  74         if(targ.takedamage == DAMAGE_NO)
  75                 return FALSE; // enemy can't be damaged
  76
  77         if(targ.items & IT_INVISIBILITY)
  78                 return FALSE; // enemy is invisible
  79
  80         if(substring(targ.classname, 0, 10) == "onslaught_")
  81                 return FALSE; // don't attack onslaught targets
  82
  83         if(IS_SPEC(targ) || IS_OBSERVER(targ))
  84                 return FALSE; // enemy is a spectator
  85
  86         if(!(targ.vehicle_flags & VHF_ISVEHICLE))
  87         if(targ.deadflag != DEAD_NO || ent.deadflag != DEAD_NO || targ.health <= 0 || ent.health <= 0)
  88                 return FALSE; // enemy/self is dead
  89
  90         if(ent.monster_owner == targ)
  91                 return FALSE; // don't attack our master
  92
  93         if(targ.monster_owner == ent)
  94                 return FALSE; // don't attack our pet
  95
  96         if(!(targ.vehicle_flags & VHF_ISVEHICLE))
  97         if(targ.flags & FL_NOTARGET)
  98                 return FALSE; // enemy can't be targeted
  99
 100         if(!autocvar_g_monsters_typefrag)
 101         if(targ.BUTTON_CHAT)
 102                 return FALSE; // no typefragging!
 103
 104         if(SAME_TEAM(targ, ent))
 105                 return FALSE; // enemy is on our team
 106
 107         if (targ.freezetag_frozen)
 108                 return FALSE; // ignore frozen
 109
 110         if(autocvar_g_monsters_target_infront || ent.spawnflags & MONSTERFLAG_INFRONT)
 111         if(ent.enemy != targ)
 112         {
 113                 float dot;
 114
 115                 makevectors (ent.angles);
 116                 dot = normalize (targ.origin - ent.origin) * v_forward;
 117
 118                 if(dot <= 0.3)
 119                         return FALSE;
 120         }
 121
 122         return TRUE;
 123 }
 124
 125 entity FindTarget (entity ent)
 126 {
 127         if(MUTATOR_CALLHOOK(MonsterFindTarget)) { return ent.enemy; } // Handled by a mutator
 128
 129         entity head, closest_target = world;
 130         head = findradius(ent.origin, ent.target_range);
 131
 132         while(head) // find the closest acceptable target to pass to
 133         {
 134                 if(head.monster_attack)
 135                 if(monster_isvalidtarget(head, ent))
 136                 {
 137                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
 138                         vector head_center = CENTER_OR_VIEWOFS(head);
 139                         vector ent_center = CENTER_OR_VIEWOFS(ent);
 140
 141                         //if(ctf_CheckPassDirection(head_center, ent_center, ent.v_angle, head.WarpZone_findradius_nearest))
 142                         if(closest_target)
 143                         {
 144                                 vector closest_target_center = CENTER_OR_VIEWOFS(closest_target);
 145                                 if(vlen(ent_center - head_center) < vlen(ent_center - closest_target_center))
 146                                         { closest_target = head; }
 147                         }
 148                         else { closest_target = head; }
 149                 }
 150
 151                 head = head.chain;
 152         }
 153
 154         return closest_target;
 155 }
 156
 157 void MonsterTouch ()
 158 {
 159         if(other == world)
 160                 return;
 161
 162         if(self.enemy != other)
 163         if(!(other.flags & FL_MONSTER))
 164         if(monster_isvalidtarget(other, self))
 165                 self.enemy = other;
 166 }
 167
 168 string get_monster_model_datafilename(string m, float sk, string fil)
 169 {
 170         if(m)
 171                 m = strcat(m, "_");
 172         else
 173                 m = "models/monsters/*_";
 174         if(sk >= 0)
 175                 m = strcat(m, ftos(sk));
 176         else
 177                 m = strcat(m, "*");
 178         return strcat(m, ".", fil);
 179 }
 180
 181 void PrecacheMonsterSounds(string f)
 182 {
 183         float fh;
 184         string s;
 185         fh = fopen(f, FILE_READ);
 186         if(fh < 0)
 187                 return;
 188         while((s = fgets(fh)))
 189         {
 190                 if(tokenize_console(s) != 3)
 191                 {
 192                         dprint("Invalid sound info line: ", s, "\n");
 193                         continue;
 194                 }
 195                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 196         }
 197         fclose(fh);
 198 }
 199
 200 void precache_monstersounds()
 201 {
 202         string m = (get_monsterinfo(self.monsterid)).model;
 203         float globhandle, n, i;
 204         string f;
 205
 206         globhandle = search_begin(strcat(m, "_*.sounds"), TRUE, FALSE);
 207         if (globhandle < 0)
 208                 return;
 209         n = search_getsize(globhandle);
 210         for (i = 0; i < n; ++i)
 211         {
 212                 //print(search_getfilename(globhandle, i), "\n");
 213                 f = search_getfilename(globhandle, i);
 214                 PrecacheMonsterSounds(f);
 215         }
 216         search_end(globhandle);
 217 }
 218
 219 void ClearMonsterSounds()
 220 {
 221 #define _MSOUND(m) if(self.monstersound_##m) { strunzone(self.monstersound_##m); self.monstersound_##m = string_null; }
 222         ALLMONSTERSOUNDS
 223 #undef _MSOUND
 224 }
 225
 226 .string GetMonsterSoundSampleField(string type)
 227 {
 228         GetMonsterSoundSampleField_notFound = 0;
 229         switch(type)
 230         {
 231 #define _MSOUND(m) case #m: return monstersound_##m;
 232                 ALLMONSTERSOUNDS
 233 #undef _MSOUND
 234         }
 235         GetMonsterSoundSampleField_notFound = 1;
 236         return string_null;
 237 }
 238
 239 float LoadMonsterSounds(string f, float first)
 240 {
 241         float fh;
 242         string s;
 243         var .string field;
 244         fh = fopen(f, FILE_READ);
 245         if(fh < 0)
 246         {
 247                 dprint("Monster sound file not found: ", f, "\n");
 248                 return 0;
 249         }
 250         while((s = fgets(fh)))
 251         {
 252                 if(tokenize_console(s) != 3)
 253                         continue;
 254                 field = GetMonsterSoundSampleField(argv(0));
 255                 if(GetMonsterSoundSampleField_notFound)
 256                         continue;
 257                 if(self.field)
 258                         strunzone(self.field);
 259                 self.field = strzone(strcat(argv(1), " ", argv(2)));
 260         }
 261         fclose(fh);
 262         return 1;
 263 }
 264
 265 .float skin_for_monstersound;
 266 void UpdateMonsterSounds()
 267 {
 268         entity mon = get_monsterinfo(self.monsterid);
 269
 270         if(self.skin == self.skin_for_monstersound)
 271                 return;
 272         self.skin_for_monstersound = self.skin;
 273         ClearMonsterSounds();
 274         //LoadMonsterSounds("sound/monsters/default.sounds", 1);
 275         if(!autocvar_g_debug_defaultsounds)
 276         if(!LoadMonsterSounds(get_monster_model_datafilename(mon.model, self.skin, "sounds"), 0))
 277                 LoadMonsterSounds(get_monster_model_datafilename(mon.model, 0, "sounds"), 0);
 278 }
 279
 280 void MonsterSound(.string samplefield, float sound_delay, float delaytoo, float chan)
 281 {
 282         if(delaytoo && time < self.msound_delay)
 283                 return; // too early
 284         GlobalSound(self.samplefield, chan, VOICETYPE_PLAYERSOUND);
 285
 286         self.msound_delay = time + sound_delay;
 287 }
 288
 289 void monster_makevectors(entity e)
 290 {
 291         vector v;
 292
 293         v = e.origin + (e.mins + e.maxs) * 0.5;
 294         self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 295         self.v_angle_x = -self.v_angle_x;
 296
 297         makevectors(self.v_angle);
 298 }
 299
 300 float monster_melee(entity targ, float damg, float anim, float er, float anim_finished, float deathtype, float dostop)
 301 {
 302         if (self.health <= 0)
 303                 return FALSE; // attacking while dead?!
 304
 305         if(dostop)
 306         {
 307                 self.velocity_x = 0;
 308                 self.velocity_y = 0;
 309                 self.state = MONSTER_STATE_ATTACK_MELEE;
 310         }
 311
 312         self.frame = anim;
 313
 314         if(anim_finished != 0)
 315                 self.attack_finished_single = time + anim_finished;
 316
 317         monster_makevectors(targ);
 318
 319         traceline(self.origin + self.view_ofs, self.origin + v_forward * er, 0, self);
 320
 321         if(trace_ent.takedamage)
 322                 Damage(trace_ent, self, self, damg * Monster_SkillModifier(), deathtype, trace_ent.origin, normalize(trace_ent.origin - self.origin));
 323
 324         return TRUE;
 325 }
 326
 327 void Monster_CheckMinibossFlag ()
 328 {
 329         if(MUTATOR_CALLHOOK(MonsterCheckBossFlag))
 330                 return;
 331
 332         float chance = random() * 100;
 333
 334         // g_monsters_miniboss_chance cvar or spawnflags 64 causes a monster to be a miniboss
 335         if ((self.spawnflags & MONSTERFLAG_MINIBOSS) || (chance < autocvar_g_monsters_miniboss_chance))
 336         {
 337                 self.health += autocvar_g_monsters_miniboss_healthboost;
 338                 self.effects |= EF_RED;
 339                 if(!self.weapon)
 340                         self.weapon = WEP_NEX;
 341         }
 342 }
 343
 344 float Monster_CanRespawn(entity ent)
 345 {
 346         other = ent;
 347         if(ent.deadflag == DEAD_DEAD) // don't call when monster isn't dead
 348         if(MUTATOR_CALLHOOK(MonsterRespawn))
 349                 return TRUE; // enabled by a mutator
 350
 351         if(ent.spawnflags & MONSTERFLAG_NORESPAWN)
 352                 return FALSE;
 353
 354         if(!autocvar_g_monsters_respawn)
 355                 return FALSE;
 356
 357         return TRUE;
 358 }
 359
 360 void Monster_Fade ()
 361 {
 362         if(Monster_CanRespawn(self))
 363         {
 364                 self.spawnflags |= MONSTERFLAG_RESPAWNED;
 365                 self.think = self.monster_spawnfunc;
 366                 self.nextthink = time + self.respawntime;
 367                 self.ltime = 0;
 368                 self.deadflag = DEAD_RESPAWNING;
 369                 if(self.spawnflags & MONSTER_RESPAWN_DEATHPOINT)
 370                 {
 371                         self.pos1 = self.origin;
 372                         self.pos2 = self.angles;
 373                 }
 374                 self.event_damage = func_null;
 375                 self.takedamage = DAMAGE_NO;
 376                 setorigin(self, self.pos1);
 377                 self.angles = self.pos2;
 378                 self.health = self.max_health;
 379                 setmodel(self, "null");
 380         }
 381         else
 382         {
 383                 // number of monsters spawned with mobspawn command
 384                 totalspawned -= 1;
 385
 386                 if(IS_CLIENT(self.realowner))
 387                         self.realowner.monstercount -= 1;
 388
 389                 SUB_SetFade(self, time + 3, 1);
 390         }
 391 }
 392
 393 float Monster_CanJump (vector vel)
 394 {
 395         if(self.state)
 396                 return FALSE; // already attacking
 397         if(!(self.flags & FL_ONGROUND))
 398                 return FALSE; // not on the ground
 399         if(self.health <= 0)
 400                 return FALSE; // called when dead?
 401         if(time < self.attack_finished_single)
 402                 return FALSE; // still attacking
 403
 404         vector old = self.velocity;
 405
 406         self.velocity = vel;
 407         tracetoss(self, self);
 408         self.velocity = old;
 409         if (trace_ent != self.enemy)
 410                 return FALSE;
 411
 412         return TRUE;
 413 }
 414
 415 float monster_leap (float anm, void() touchfunc, vector vel, float anim_finished)
 416 {
 417         if(!Monster_CanJump(vel))
 418                 return FALSE;
 419
 420         self.frame = anm;
 421         self.state = MONSTER_STATE_ATTACK_LEAP;
 422         self.touch = touchfunc;
 423         self.origin_z += 1;
 424         self.velocity = vel;
 425         self.flags &= ~FL_ONGROUND;
 426
 427         self.attack_finished_single = time + anim_finished;
 428
 429         return TRUE;
 430 }
 431
 432 void monster_checkattack(entity e, entity targ)
 433 {
 434         if(e == world)
 435                 return;
 436         if(targ == world)
 437                 return;
 438
 439         if(!e.monster_attackfunc)
 440                 return;
 441
 442         if(time < e.attack_finished_single)
 443                 return;
 444
 445         if(vlen(targ.origin - e.origin) <= e.attack_range)
 446         if(e.monster_attackfunc(MONSTER_ATTACK_MELEE))
 447         {
 448                 MonsterSound(monstersound_melee, 0, FALSE, CH_VOICE);
 449                 return;
 450         }
 451
 452         if(vlen(targ.origin - e.origin) > e.attack_range)
 453         if(e.monster_attackfunc(MONSTER_ATTACK_RANGED))
 454         {
 455                 MonsterSound(monstersound_ranged, 0, FALSE, CH_VOICE);
 456                 return;
 457         }
 458 }
 459
 460 void monster_use ()
 461 {
 462         if(!self.enemy)
 463         if(self.health > 0)
 464         if(monster_isvalidtarget(activator, self))
 465                 self.enemy = activator;
 466 }
 467
 468 .float last_trace;
 469 .float last_enemycheck; // for checking enemy
 470 vector monster_pickmovetarget(entity targ)
 471 {
 472         // enemy is always preferred target
 473         if(self.enemy)
 474         {
 475                 makevectors(self.angles);
 476                 self.monster_movestate = MONSTER_MOVE_ENEMY;
 477                 self.last_trace = time + 1.2;
 478                 return self.enemy.origin;
 479         }
 480
 481         switch(self.monster_moveflags)
 482         {
 483                 case MONSTER_MOVE_OWNER:
 484                 {
 485                         self.monster_movestate = MONSTER_MOVE_OWNER;
 486                         self.last_trace = time + 0.3;
 487                         return (self.monster_owner) ? self.monster_owner.origin : self.origin;
 488                 }
 489                 case MONSTER_MOVE_SPAWNLOC:
 490                 {
 491                         self.monster_movestate = MONSTER_MOVE_SPAWNLOC;
 492                         self.last_trace = time + 2;
 493                         return self.pos1;
 494                 }
 495                 case MONSTER_MOVE_NOMOVE:
 496                 {
 497                         self.monster_movestate = MONSTER_MOVE_NOMOVE;
 498                         self.last_trace = time + 2;
 499                         return self.origin;
 500                 }
 501                 default:
 502                 case MONSTER_MOVE_WANDER:
 503                 {
 504                         vector pos;
 505                         self.monster_movestate = MONSTER_MOVE_WANDER;
 506                         self.last_trace = time + 2;
 507
 508                         self.angles_y = rint(random() * 500);
 509                         makevectors(self.angles);
 510                         pos = self.origin + v_forward * 600;
 511
 512                         if(self.flags & FL_FLY || self.flags & FL_SWIM)
 513                         if(self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 514                         {
 515                                 pos_z = random() * 200;
 516                                 if(random() >= 0.5)
 517                                         pos_z *= -1;
 518                         }
 519
 520                         if(targ)
 521                         {
 522                                 self.last_trace = time + 0.5;
 523                                 pos = targ.origin;
 524                         }
 525
 526                         return pos;
 527                 }
 528         }
 529 }
 530
 531 void monster_move(float runspeed, float walkspeed, float stopspeed, float manim_run, float manim_walk, float manim_idle)
 532 {
 533         fixedmakevectors(self.angles);
 534
 535         if(self.target2)
 536                 self.goalentity = find(world, targetname, self.target2);
 537
 538         entity targ;
 539
 540         if(self.flags & FL_SWIM)
 541         {
 542                 if(self.waterlevel < WATERLEVEL_WETFEET)
 543                 {
 544                         if(time >= self.last_trace)
 545                         {
 546                                 self.fish_wasdrowning = TRUE;
 547                                 self.last_trace = time + 0.4;
 548
 549                                 Damage (self, world, world, 2, DEATH_DROWN, self.origin, '0 0 0');
 550                                 self.angles = '90 90 0';
 551                                 if(random() < 0.5)
 552                                 {
 553                                         self.velocity_y += random() * 50;
 554                                         self.velocity_x -= random() * 50;
 555                                 }
 556                                 else
 557                                 {
 558                                         self.velocity_y -= random() * 50;
 559                                         self.velocity_x += random() * 50;
 560                                 }
 561                                 self.velocity_z += random() * 150;
 562                         }
 563
 564
 565                         self.movetype = MOVETYPE_BOUNCE;
 566                         //self.velocity_z = -200;
 567
 568                         return;
 569                 }
 570                 else if(self.fish_wasdrowning)
 571                 {
 572                         self.fish_wasdrowning = FALSE;
 573                         self.angles_x = 0;
 574                         self.movetype = MOVETYPE_WALK;
 575                 }
 576         }
 577
 578         targ = self.goalentity;
 579
 580         monster_target = targ;
 581         monster_speed_run = runspeed;
 582         monster_speed_walk = walkspeed;
 583
 584         if(MUTATOR_CALLHOOK(MonsterMove) || gameover || (round_handler_IsActive() && !round_handler_IsRoundStarted()) || time < game_starttime || (autocvar_g_campaign && !campaign_bots_may_start) || time < self.spawn_time)
 585         {
 586                 runspeed = walkspeed = 0;
 587                 if(time >= self.spawn_time)
 588                         self.frame = manim_idle;
 589                 movelib_beak_simple(stopspeed);
 590                 return;
 591         }
 592
 593         targ = monster_target;
 594         runspeed = bound(0, monster_speed_run * Monster_SkillModifier(), runspeed * 2); // limit maxspeed to prevent craziness
 595         walkspeed = bound(0, monster_speed_walk * Monster_SkillModifier(), walkspeed * 2); // limit maxspeed to prevent craziness
 596
 597         if(time < self.spider_slowness)
 598         {
 599                 runspeed *= 0.5;
 600                 walkspeed *= 0.5;
 601         }
 602
 603         if(teamplay)
 604         if(autocvar_g_monsters_teams)
 605         if(DIFF_TEAM(self.monster_owner, self))
 606                 self.monster_owner = world;
 607
 608         if(self.enemy && self.enemy.health < 1)
 609                 self.enemy = world; // enough!
 610
 611         if(time >= self.last_enemycheck)
 612         {
 613                 if(!monster_isvalidtarget(self.enemy, self))
 614                         self.enemy = world;
 615
 616                 if(!self.enemy)
 617                 {
 618                         self.enemy = FindTarget(self);
 619                         if(self.enemy)
 620                                 MonsterSound(monstersound_sight, 0, FALSE, CH_VOICE);
 621                 }
 622
 623                 self.last_enemycheck = time + 0.5;
 624         }
 625
 626         if(self.state == MONSTER_STATE_ATTACK_MELEE && time >= self.attack_finished_single)
 627                 self.state = 0;
 628
 629         if(self.state != MONSTER_STATE_ATTACK_MELEE) // don't move if set
 630         if(time >= self.last_trace || self.enemy) // update enemy instantly
 631                 self.moveto = monster_pickmovetarget(targ);
 632
 633         if(!self.enemy)
 634                 MonsterSound(monstersound_idle, 7, TRUE, CH_VOICE);
 635
 636         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 637                 self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 638
 639         if(self.state == MONSTER_STATE_ATTACK_LEAP && (self.flags & FL_ONGROUND))
 640         {
 641                 self.state = 0;
 642                 self.touch = MonsterTouch;
 643         }
 644
 645         //self.steerto = steerlib_attract2(self.moveto, 0.5, 500, 0.95);
 646
 647         float turny = 0;
 648         vector real_angle = vectoangles(self.steerto) - self.angles;
 649
 650         if(self.state != MONSTER_STATE_ATTACK_LEAP && self.state != MONSTER_STATE_ATTACK_MELEE)
 651                 turny = 20;
 652
 653         if(self.flags & FL_SWIM)
 654                 turny = vlen(self.angles - self.moveto);
 655
 656         if(turny)
 657         {
 658                 turny = bound(turny * -1, shortangle_f(real_angle_y, self.angles_y), turny);
 659                 self.angles_y += turny;
 660         }
 661
 662         if(self.state == MONSTER_STATE_ATTACK_MELEE)
 663                 self.moveto = self.origin;
 664
 665         if(self.enemy && self.enemy.vehicle)
 666                 runspeed = 0;
 667
 668         if(((self.flags & FL_FLY) || (self.flags & FL_SWIM)) && self.spawnflags & MONSTERFLAG_FLY_VERTICAL)
 669                 v_forward = normalize(self.moveto - self.origin);
 670         else
 671                 self.moveto_z = self.origin_z;
 672
 673         if(vlen(self.origin - self.moveto) > 64)
 674         {
 675                 if(self.flags & FL_FLY || self.flags & FL_SWIM)
 676                         movelib_move_simple(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 677                 else
 678                         movelib_move_simple_gravity(v_forward, ((self.enemy) ? runspeed : walkspeed), 0.6);
 679
 680                 if(time > self.pain_finished)
 681                 if(time > self.attack_finished_single)
 682                 if(vlen(self.velocity) > 10)
 683                         self.frame = ((self.enemy) ? manim_run : manim_walk);
 684                 else
 685                         self.frame = manim_idle;
 686         }
 687         else
 688         {
 689                 entity e = find(world, targetname, self.target2);
 690                 if(e.target2)
 691                         self.target2 = e.target2;
 692                 else if(e.target)
 693                         self.target2 = e.target;
 694
 695                 movelib_beak_simple(stopspeed);
 696                 if(time > self.attack_finished_single)
 697                 if(time > self.pain_finished)
 698                 if (vlen(self.velocity) <= 30)
 699                         self.frame = manim_idle;
 700         }
 701
 702         monster_checkattack(self, self.enemy);
 703 }
 704
 705 void monster_remove(entity mon)
 706 {
 707         if(!mon)
 708                 return; // nothing to remove
 709
 710         pointparticles(particleeffectnum("item_pickup"), mon.origin, '0 0 0', 1);
 711
 712         if(mon.weaponentity)
 713                 remove(mon.weaponentity);
 714
 715         WaypointSprite_Kill(mon.sprite);
 716
 717         remove(mon);
 718 }
 719
 720 void monster_dead_think()
 721 {
 722         self.nextthink = time + self.ticrate;
 723
 724         CSQCMODEL_AUTOUPDATE();
 725
 726         if(self.ltime != 0)
 727         if(time >= self.ltime)
 728         {
 729                 Monster_Fade();
 730                 return;
 731         }
 732 }
 733
 734 void monsters_setstatus()
 735 {
 736         self.stat_monsters_total = monsters_total;
 737         self.stat_monsters_killed = monsters_killed;
 738 }
 739
 740 void Monster_Appear()
 741 {
 742         self.enemy = activator;
 743         self.spawnflags &= ~MONSTERFLAG_APPEAR;
 744         self.monster_spawnfunc();
 745 }
 746
 747 float Monster_CheckAppearFlags(entity ent)
 748 {
 749         if(!(ent.spawnflags & MONSTERFLAG_APPEAR))
 750                 return FALSE;
 751
 752         ent.think = func_null;
 753         ent.nextthink = 0;
 754         ent.use = Monster_Appear;
 755         ent.flags = FL_MONSTER; // set so this monster can get butchered
 756
 757         return TRUE;
 758 }
 759
 760 void monsters_reset()
 761 {
 762         setorigin(self, self.pos1);
 763         self.angles = self.pos2;
 764
 765         self.health = self.max_health;
 766         self.velocity = '0 0 0';
 767         self.enemy = world;
 768         self.goalentity = world;
 769         self.attack_finished_single = 0;
 770         self.moveto = self.origin;
 771 }
 772
 773 void monsters_corpse_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 774 {
 775         self.health -= damage;
 776
 777         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 778
 779         if(self.health <= -100) // 100 health until gone?
 780         {
 781                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 782
 783                 // number of monsters spawned with mobspawn command
 784                 totalspawned -= 1;
 785
 786                 if(IS_CLIENT(self.realowner))
 787                         self.realowner.monstercount -= 1;
 788
 789                 self.think = SUB_Remove;
 790                 self.nextthink = time + 0.1;
 791         }
 792 }
 793
 794 void monster_die(entity attacker, float gibbed)
 795 {
 796         self.think = monster_dead_think;
 797         self.nextthink = time;
 798         self.ltime = time + 5;
 799
 800         monster_dropitem();
 801
 802         MonsterSound(monstersound_death, 0, FALSE, CH_VOICE);
 803
 804         if(!(self.spawnflags & MONSTERFLAG_SPAWNED) && !(self.spawnflags & MONSTERFLAG_RESPAWNED))
 805                 monsters_killed += 1;
 806
 807         if(IS_PLAYER(attacker))
 808         if(autocvar_g_monsters_score_spawned || !((self.spawnflags & MONSTERFLAG_SPAWNED) || (self.spawnflags & MONSTERFLAG_RESPAWNED)))
 809                 PlayerScore_Add(attacker, SP_SCORE, +autocvar_g_monsters_score_kill);
 810
 811         if(gibbed)
 812         {
 813                 // number of monsters spawned with mobspawn command
 814                 totalspawned -= 1;
 815
 816                 if(IS_CLIENT(self.realowner))
 817                         self.realowner.monstercount -= 1;
 818         }
 819
 820         if(self.candrop && self.weapon)
 821                 W_ThrowNewWeapon(self, self.weapon, 0, self.origin, randomvec() * 150 + '0 0 325');
 822
 823         self.event_damage       = monsters_corpse_damage;
 824         self.solid                      = SOLID_CORPSE;
 825         self.takedamage         = DAMAGE_AIM;
 826         self.deadflag           = DEAD_DEAD;
 827         self.enemy                      = world;
 828         self.movetype           = MOVETYPE_TOSS;
 829         self.moveto                     = self.origin;
 830         self.touch                      = MonsterTouch; // reset incase monster was pouncing
 831         self.reset                      = func_null;
 832         self.state                      = 0;
 833         self.attack_finished_single = 0;
 834
 835         if(!(self.flags & FL_FLY))
 836                 self.velocity = '0 0 0';
 837
 838         MON_ACTION(self.monsterid, MR_DEATH);
 839 }
 840
 841 void monsters_damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 842 {
 843         if(time < self.pain_finished && deathtype != DEATH_KILL)
 844                 return;
 845
 846         if(time < self.spawnshieldtime && deathtype != DEATH_KILL)
 847                 return;
 848
 849         vector v;
 850         float take, save;
 851
 852         v = healtharmor_applydamage(self.armorvalue, self.m_armor_blockpercent, deathtype, damage);
 853         take = v_x;
 854         save = v_y;
 855
 856         self.health -= take;
 857
 858         WaypointSprite_UpdateHealth(self.sprite, self.health);
 859
 860         self.dmg_time = time;
 861
 862         if(sound_allowed(MSG_BROADCAST, attacker) && deathtype != DEATH_DROWN)
 863                 spamsound (self, CH_PAIN, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 864
 865         self.velocity += force * self.damageforcescale;
 866
 867         if(deathtype != DEATH_DROWN)
 868         {
 869                 Violence_GibSplash_At(hitloc, force, 2, bound(0, take, 200) / 16, self, attacker);
 870                 if (take > 50)
 871                         Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 872                 if (take > 100)
 873                         Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 874         }
 875
 876         if(self.health <= 0)
 877         {
 878                 if(deathtype == DEATH_KILL)
 879                         self.candrop = FALSE; // killed by mobkill command
 880
 881                 // TODO: fix this?
 882                 activator = attacker;
 883                 other = self.enemy;
 884                 SUB_UseTargets();
 885                 self.target2 = self.oldtarget2; // reset to original target on death, incase we respawn
 886
 887                 monster_die(attacker, (self.health <= -100 || deathtype == DEATH_KILL));
 888
 889                 WaypointSprite_Kill(self.sprite);
 890
 891                 frag_attacker = attacker;
 892                 frag_target = self;
 893                 MUTATOR_CALLHOOK(MonsterDies);
 894
 895                 if(self.health <= -100 || deathtype == DEATH_KILL) // check if we're already gibbed
 896                 {
 897                         Violence_GibSplash(self, 1, 0.5, attacker);
 898
 899                         self.think = SUB_Remove;
 900                         self.nextthink = time + 0.1;
 901                 }
 902         }
 903 }
 904
 905 void monster_setupcolors()
 906 {
 907         if(IS_PLAYER(self.monster_owner))
 908                 self.colormap = self.monster_owner.colormap;
 909         else if(teamplay && self.team)
 910                 self.colormap = 1024 + (self.team - 1) * 17;
 911         else
 912         {
 913                 if(self.monster_skill <= MONSTER_SKILL_EASY)
 914                         self.colormap = 1029;
 915                 else if(self.monster_skill <= MONSTER_SKILL_MEDIUM)
 916                         self.colormap = 1027;
 917                 else if(self.monster_skill <= MONSTER_SKILL_HARD)
 918                         self.colormap = 1038;
 919                 else if(self.monster_skill <= MONSTER_SKILL_INSANE)
 920                         self.colormap = 1028;
 921                 else if(self.monster_skill <= MONSTER_SKILL_NIGHTMARE)
 922                         self.colormap = 1032;
 923                 else
 924                         self.colormap = 1024;
 925         }
 926 }
 927
 928 void monster_think()
 929 {
 930         self.think = monster_think;
 931         self.nextthink = self.ticrate;
 932
 933         if(self.ltime)
 934         if(time >= self.ltime)
 935         {
 936                 Damage(self, self, self, self.health + self.max_health, DEATH_KILL, self.origin, self.origin);
 937                 return;
 938         }
 939
 940         MON_ACTION(self.monsterid, MR_THINK);
 941
 942         CSQCMODEL_AUTOUPDATE();
 943 }
 944
 945 float monster_spawn()
 946 {
 947         MON_ACTION(self.monsterid, MR_SETUP);
 948
 949         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 950         {
 951                 Monster_CheckMinibossFlag();
 952                 self.health *= Monster_SkillModifier();
 953         }
 954
 955         self.max_health = self.health;
 956         self.pain_finished = self.nextthink;
 957
 958         if(IS_PLAYER(self.monster_owner))
 959                 self.effects |= EF_DIMLIGHT;
 960
 961         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
 962         if(!self.skin)
 963                 self.skin = rint(random() * 4);
 964
 965         if(!self.attack_range)
 966                 self.attack_range = autocvar_g_monsters_attack_range;
 967
 968         precache_monstersounds();
 969         UpdateMonsterSounds();
 970
 971         if(teamplay)
 972                 self.monster_attack = TRUE; // we can have monster enemies in team games
 973
 974         MonsterSound(monstersound_spawn, 0, FALSE, CH_VOICE);
 975
 976         WaypointSprite_Spawn(M_NAME(self.monsterid), 0, 1024, self, '0 0 1' * (self.maxs_z + 15), world, self.team, self, sprite, TRUE, RADARICON_DANGER, ((self.team) ? Team_ColorRGB(self.team) : '1 0 0'));
 977         WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 978         WaypointSprite_UpdateHealth(self.sprite, self.health);
 979
 980         self.think = monster_think;
 981         self.nextthink = time + self.ticrate;
 982
 983         if(MUTATOR_CALLHOOK(MonsterSpawn))
 984                 return FALSE;
 985
 986         return TRUE;
 987 }
 988
 989 float monster_initialize(float mon_id, float nodrop)
 990 {
 991         if(!autocvar_g_monsters)
 992                 return FALSE;
 993
 994         entity mon = get_monsterinfo(mon_id);
 995
 996         if(!self.monster_skill)
 997                 self.monster_skill = cvar("g_monsters_skill");
 998
 999         // support for quake style removing monsters based on skill
1000         if(self.monster_skill == MONSTER_SKILL_EASY) if(self.spawnflags & MONSTERSKILL_NOTEASY) { return FALSE; }
1001         if(self.monster_skill == MONSTER_SKILL_MEDIUM) if(self.spawnflags & MONSTERSKILL_NOTMEDIUM) { return FALSE; }
1002         if(self.monster_skill == MONSTER_SKILL_HARD) if(self.spawnflags & MONSTERSKILL_NOTHARD) { return FALSE; }
1003
1004         if(self.team && !teamplay)
1005                 self.team = 0;
1006
1007         if(!(self.spawnflags & MONSTERFLAG_SPAWNED)) // naturally spawned monster
1008         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1009                 monsters_total += 1;
1010
1011         setmodel(self, mon.model);
1012         setsize(self, mon.mins, mon.maxs);
1013         self.flags                              = FL_MONSTER;
1014         self.takedamage                 = DAMAGE_AIM;
1015         self.bot_attack                 = TRUE;
1016         self.iscreature                 = TRUE;
1017         self.teleportable               = TRUE;
1018         self.damagedbycontents  = TRUE;
1019         self.monsterid                  = mon_id;
1020         self.damageforcescale   = 0;
1021         self.event_damage               = monsters_damage;
1022         self.touch                              = MonsterTouch;
1023         self.use                                = monster_use;
1024         self.solid                              = SOLID_BBOX;
1025         self.movetype                   = MOVETYPE_WALK;
1026         self.spawnshieldtime    = time + autocvar_g_monsters_spawnshieldtime;
1027         self.enemy                              = world;
1028         self.velocity                   = '0 0 0';
1029         self.moveto                             = self.origin;
1030         self.pos1                               = self.origin;
1031         self.pos2                               = self.angles;
1032         self.reset                              = monsters_reset;
1033         self.netname                    = mon.netname;
1034         self.monster_name               = M_NAME(mon_id);
1035         self.candrop                    = TRUE;
1036         self.view_ofs                   = '0 0 1' * (self.maxs_z * 0.5);
1037         self.oldtarget2                 = self.target2;
1038         self.deadflag                   = DEAD_NO;
1039         self.scale                              = 1;
1040         self.noalign                    = nodrop;
1041         self.spawn_time                 = time;
1042         self.spider_slowness    = 0;
1043         self.gravity                    = 1;
1044         self.dphitcontentsmask  = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_BOTCLIP | DPCONTENTS_MONSTERCLIP;
1045
1046         if(autocvar_g_fullbrightplayers)
1047                 self.effects |= EF_FULLBRIGHT;
1048
1049         if(autocvar_g_nodepthtestplayers)
1050                 self.effects |= EF_NODEPTHTEST;
1051
1052         if(mon.spawnflags & MONSTER_TYPE_SWIM)
1053                 self.flags |= FL_SWIM;
1054
1055         if(mon.spawnflags & MONSTER_TYPE_FLY)
1056         {
1057                 self.flags |= FL_FLY;
1058                 self.movetype = MOVETYPE_FLY;
1059         }
1060
1061         if(mon.spawnflags & MONSTER_SIZE_BROKEN)
1062                 self.scale = 1.3;
1063
1064         if(!self.ticrate)
1065                 self.ticrate = autocvar_g_monsters_think_delay;
1066
1067         self.ticrate = bound(sys_frametime, self.ticrate, 60);
1068
1069         if(!self.m_armor_blockpercent)
1070                 self.m_armor_blockpercent = 0.5;
1071
1072         if(!self.target_range)
1073                 self.target_range = autocvar_g_monsters_target_range;
1074
1075         if(!self.respawntime)
1076                 self.respawntime = autocvar_g_monsters_respawn_delay;
1077
1078         if(!self.monster_moveflags)
1079                 self.monster_moveflags = MONSTER_MOVE_WANDER;
1080
1081         if(!self.noalign)
1082         {
1083                 setorigin(self, self.origin + '0 0 20');
1084                 tracebox(self.origin + '0 0 64', self.mins, self.maxs, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1085                 setorigin(self, trace_endpos);
1086         }
1087
1088         if(!monster_spawn())
1089                 return FALSE;
1090
1091         if(!(self.spawnflags & MONSTERFLAG_RESPAWNED))
1092                 monster_setupcolors();
1093
1094         CSQCMODEL_AUTOINIT();
1095
1096         return TRUE;
1097 }