qcsrc/common/mutators/base.qh

   1 #ifndef MUTATORS_BASE_H
   2 #define MUTATORS_BASE_H
   3
   4 const int CBC_ORDER_FIRST = 1;
   5 const int CBC_ORDER_LAST = 2;
   6 const int CBC_ORDER_EXCLUSIVE = 3;
   7 const int CBC_ORDER_ANY = 4;
   8
   9 bool CallbackChain_ReturnValue; // read-only field of the current return value
  10
  11 /**
  12  * Callbacks may be added to zero or more callback chains.
  13  */
  14 CLASS(Callback, Object)
  15     /**
  16      * a callback function is like this:
  17      * bool mycallback()
  18      * {
  19      *     do something
  20      *     return false;
  21      * }
  22      */
  23     ATTRIB(Callback, cbc_func, bool(), func_null)
  24     CONSTRUCTOR(Callback, bool() func) {
  25         CONSTRUCT(Callback);
  26         this.cbc_func = func;
  27     }
  28 ENDCLASS(Callback)
  29
  30 /**
  31  * Callback chains contain zero or more callbacks.
  32  */
  33 CLASS(CallbackChain, Object)
  34     CLASS(CallbackNode, Object)
  35         ATTRIB(CallbackNode, cbc, Callback, NULL)
  36         ATTRIB(CallbackNode, cbc_next, CallbackNode, NULL)
  37         ATTRIB(CallbackNode, cbc_order, int, 0)
  38         CONSTRUCTOR(CallbackNode, Callback it, int order) {
  39             CONSTRUCT(CallbackNode);
  40             this.cbc = it;
  41             this.cbc_order = order;
  42         }
  43     ENDCLASS(CallbackNode)
  44
  45     ATTRIB(CallbackChain, cbc_next, CallbackNode, NULL)
  46     ATTRIB(CallbackChain, cbc_order, int, 0)
  47     CONSTRUCTOR(CallbackChain, string _name) {
  48         CONSTRUCT(CallbackChain);
  49         this.netname = _name;
  50     }
  51
  52     bool CallbackChain_Add(CallbackChain this, Callback cb, int order)
  53     {
  54         if (order & CBC_ORDER_FIRST) {
  55             if (order & CBC_ORDER_LAST)
  56                 if (this.cbc_order & CBC_ORDER_ANY)
  57                     return false;
  58             if (this.cbc_order & CBC_ORDER_FIRST)
  59                 return false;
  60         } else if (order & CBC_ORDER_LAST) {
  61             if (this.cbc_order & CBC_ORDER_LAST)
  62                 return false;
  63         }
  64         entity node = NEW(CallbackNode, cb, order);
  65         if (order & CBC_ORDER_FIRST) {
  66             node.cbc_next = this.cbc_next;
  67             this.cbc_next = node;
  68         } else if (order & CBC_ORDER_LAST) {
  69             CallbackNode prev = NULL, it = this.cbc_next;
  70             while (it) { prev = it, it = it.cbc_next; }
  71             if (prev) prev.cbc_next = node;
  72             else this.cbc_next = node;
  73         } else {
  74             // by default we execute last, but before a possible CBC_ORDER_LAST callback
  75             CallbackNode prev = NULL, it = this.cbc_next;
  76             while (it && !(it.cbc_order & CBC_ORDER_LAST)) { prev = it, it = it.cbc_next; }
  77             node.cbc_next = it;
  78             if (prev) prev.cbc_next = node;
  79             else this.cbc_next = node;
  80         }
  81         this.cbc_order |= (order | CBC_ORDER_ANY);
  82         return true;
  83     }
  84     int CallbackChain_Remove(CallbackChain this, Callback cb)
  85     {
  86         int n = 0, order = 0;
  87         for (Callback prev = NULL, it = this.cbc_next; it; prev = it, it = it.cbc_next) {
  88             if (it.cbc == cb) {
  89                 // remove it from the chain
  90                 Callback next = it.cbc_next;
  91                 if (prev) prev.cbc_next = next;
  92                 else this.cbc_next = next;
  93                 ++n;
  94             }
  95             // it is now something we want to keep
  96             order |= (it.cbc_order & CBC_ORDER_ANY);
  97         }
  98         this.cbc_order = order;
  99         return n;
 100     }
 101     bool CallbackChain_Call(CallbackChain this)
 102     {
 103         bool r = false;
 104         for (Callback it = this.cbc_next; it; it = it.cbc_next) {
 105             CallbackChain_ReturnValue = r;
 106             r |= it.cbc.cbc_func();
 107         }
 108         return r; // callbacks return an error status, so 0 is default return value
 109     }
 110 ENDCLASS(CallbackChain)
 111
 112 #define _MUTATOR_HANDLE_NOP(type, id)
 113 #define _MUTATOR_HANDLE_PARAMS(type, id) , type in_##id
 114 #define _MUTATOR_HANDLE_PREPARE(type, id) id = in_##id;
 115 #define _MUTATOR_HANDLE_PUSHTMP(type, id) type tmp_##id = id;
 116 #define _MUTATOR_HANDLE_PUSHOUT(type, id) type out_##id = id;
 117 #define _MUTATOR_HANDLE_POPTMP(type, id) id = tmp_##id;
 118 #define _MUTATOR_HANDLE_POPOUT(type, id) id = out_##id;
 119
 120 void RegisterHooks() {};
 121 void RegisterCallbacks() {};
 122
 123 #define _MUTATOR_HOOKABLE(id, ...) CallbackChain HOOK_##id; bool __Mutator_Send_##id(__VA_ARGS__)
 124 #define MUTATOR_HOOKABLE(id, params) \
 125     _MUTATOR_HOOKABLE(id, int params(_MUTATOR_HANDLE_PARAMS, _MUTATOR_HANDLE_NOP)) { \
 126         params(_MUTATOR_HANDLE_PUSHTMP, _MUTATOR_HANDLE_NOP) \
 127         params(_MUTATOR_HANDLE_PREPARE, _MUTATOR_HANDLE_NOP) \
 128         bool ret = CallbackChain_Call(HOOK_##id); \
 129         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_PUSHOUT) \
 130         params(_MUTATOR_HANDLE_POPTMP,  _MUTATOR_HANDLE_NOP) \
 131         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_POPOUT) \
 132         return ret; \
 133     } \
 134     [[accumulate]] void RegisterHooks() { HOOK_##id = NEW(CallbackChain, #id); }
 135 #ifdef __STDC__
 136     #define MUTATOR_CALLHOOK(id, ...) APPLY(__Mutator_Send_##id, 0 P99_IF_EMPTY(__VA_ARGS__)()(, __VA_ARGS__))
 137 #else
 138     #define MUTATOR_CALLHOOK(id, ...) APPLY(__Mutator_Send_##id, 0, ##__VA_ARGS__)
 139 #endif
 140
 141 enum {
 142     MUTATOR_REMOVING,
 143     MUTATOR_ADDING,
 144     MUTATOR_ROLLING_BACK
 145 };
 146
 147 typedef bool(int) mutatorfunc_t;
 148
 149 CLASS(Mutator, Object)
 150     ATTRIB(Mutator, m_id, int, 0)
 151     ATTRIB(Mutator, m_name, string, string_null)
 152     ATTRIB(Mutator, mutatorfunc, mutatorfunc_t, func_null)
 153     ATTRIB(Mutator, mutatorcheck, bool(), func_null)
 154     CONSTRUCTOR(Mutator, string _name, mutatorfunc_t func) {
 155         CONSTRUCT(Mutator);
 156         this.m_name = _name;
 157         this.mutatorfunc = func;
 158     }
 159 ENDCLASS(Mutator)
 160
 161 REGISTRY(Mutators, BITS(7))
 162 #define Mutators_from(i) _Mutators_from(i, NULL)
 163 Mutator loaded_mutators[Mutators_MAX];
 164 bool Mutator_Add(Mutator mut);
 165 void Mutator_Remove(Mutator mut);
 166 bool mutator_log = false;
 167
 168 #ifndef MENUQC
 169 REGISTER_NET_LINKED(Mutator)
 170
 171 #ifdef SVQC
 172 bool Mutator_SendEntity(entity this, entity to, int sf)
 173 {
 174     int chan = MSG_ENTITY;
 175     WriteHeader(chan, Mutator);
 176     WriteString(chan, this.registered_id);
 177     return true;
 178 }
 179 #endif
 180
 181 #ifdef CSQC
 182 void NET_Mutator_Remove()
 183 {
 184     SELFPARAM();
 185     string s = this.netname;
 186     WITH(bool, mutator_log, true, LAMBDA(
 187         FOREACH(Mutators, it.registered_id == s, LAMBDA(Mutator_Remove(it)));
 188     ));
 189 }
 190 NET_HANDLE(Mutator, bool isNew)
 191 {
 192     string s = this.netname = ReadString();
 193     return = true;
 194     if (isNew)
 195     {
 196         make_pure(this);
 197         this.entremove = NET_Mutator_Remove;
 198         int added = 0;
 199         WITH(bool, mutator_log, true, LAMBDA(
 200             FOREACH(Mutators, it.registered_id == s, LAMBDA(Mutator_Add(it); ++added));
 201         ));
 202         if (added > 1) LOG_WARNINGF("Added more than one mutator for %s\n", s);
 203     }
 204 }
 205 #endif
 206
 207 #endif
 208
 209 bool Mutator_Add(Mutator mut)
 210 {
 211     int j = -1;
 212     for (int i = 0; i < Mutators_MAX; ++i) {
 213         if (loaded_mutators[i] == mut)
 214             return true; // already added
 215         if (!(loaded_mutators[i]))
 216             j = i;
 217     }
 218     if (j < 0) {
 219         backtrace("WARNING: too many mutators, cannot add any more\n");
 220         return false;
 221     }
 222     loaded_mutators[j] = mut;
 223     mutatorfunc_t func = mut.mutatorfunc;
 224     if (!func(MUTATOR_ADDING)) {
 225         // good
 226         if (mutator_log) LOG_TRACEF("Mutator: added %s\n", mut.m_name);
 227 #ifdef SVQC
 228         Net_LinkEntity(mut, false, 0, Mutator_SendEntity);
 229 #endif
 230         return true;
 231     }
 232     backtrace("WARNING: when adding mutator: adding failed, rolling back\n");
 233     if (func(MUTATOR_ROLLING_BACK)) {
 234         // baaaaad
 235         error("WARNING: when adding mutator: rolling back failed");
 236     }
 237     return false;
 238 }
 239
 240 void Mutator_Remove(Mutator mut)
 241 {
 242     int i;
 243     for (i = 0; i < Mutators_MAX; ++i)
 244         if (loaded_mutators[i] == mut)
 245             break;
 246     if (i >= Mutators_MAX) {
 247         backtrace("WARNING: removing not-added mutator\n");
 248         return;
 249     }
 250     loaded_mutators[i] = NULL;
 251     mutatorfunc_t func = mut.mutatorfunc;
 252     if (func(MUTATOR_REMOVING)) {
 253         // baaaaad
 254         error("Mutator_Remove: removing mutator failed");
 255     }
 256     if (mutator_log) LOG_TRACEF("Mutator: removed %s\n", mut.m_name);
 257 #ifdef SVQC
 258     Net_UnlinkEntity(mut);
 259 #endif
 260 }
 261
 262 #define REGISTER_MUTATOR(id, dependence) \
 263     bool MUTATORFUNCTION_##id##_hooks(int mode) { return = false; } \
 264     bool MUTATORFUNCTION_##id(int mode) { \
 265         return = false; \
 266         bool ret = MUTATORFUNCTION_##id##_hooks(mode); if (ret) return ret; \
 267     } \
 268     bool MUTATOR_##id##_check() { return dependence; } \
 269     REGISTER(Mutators, MUTATOR, id, m_id, NEW(Mutator, #id, MUTATORFUNCTION_##id)) \
 270     { this.mutatorcheck = MUTATOR_##id##_check; } \
 271     [[accumulate]] bool MUTATORFUNCTION_##id(int mode)
 272
 273 STATIC_INIT(Mutators) {
 274     RegisterHooks();
 275     RegisterCallbacks();
 276     RegisterMutators();
 277 }
 278
 279 STATIC_INIT_LATE(Mutators) {
 280     FOREACH(Mutators, it.mutatorcheck(), LAMBDA(Mutator_Add(it)));
 281 }
 282
 283 #define MUTATOR_ONADD                   if (mode == MUTATOR_ADDING)
 284 #define MUTATOR_ONREMOVE                if (mode == MUTATOR_REMOVING)
 285 #define MUTATOR_ONROLLBACK_OR_REMOVE    if (mode == MUTATOR_REMOVING || mode == MUTATOR_ROLLING_BACK)
 286 #define MUTATOR_ADD(name)               Mutator_Add(MUTATOR_##name)
 287 #define MUTATOR_REMOVE(name)            Mutator_Remove(MUTATOR_##name)
 288 #define MUTATOR_RETURNVALUE             CallbackChain_ReturnValue
 289
 290 #define _MUTATOR_CALLBACK(name, func) \
 291     Callback CALLBACK_##name; \
 292     bool func(); \
 293     [[accumulate]] void RegisterCallbacks() { CALLBACK_##name = NEW(Callback, func); }
 294
 295 #define MUTATOR_HOOKFUNCTION(...) \
 296     EVAL_MUTATOR_HOOKFUNCTION(OVERLOAD(MUTATOR_HOOKFUNCTION, __VA_ARGS__))
 297 #define EVAL_MUTATOR_HOOKFUNCTION(...) __VA_ARGS__
 298
 299 #define MUTATOR_HOOKFUNCTION_2(mut, cb) \
 300     MUTATOR_HOOKFUNCTION_3(mut, cb, CBC_ORDER_ANY)
 301
 302 #define MUTATOR_HOOKFUNCTION_3(mut, cb, order) \
 303     _MUTATOR_CALLBACK(mut##_##cb, mut##_##cb) \
 304     [[accumulate]] bool MUTATORFUNCTION_##mut##_hooks(int mode) { MUTATOR_HOOK(cb, mut##_##cb, order); } \
 305     bool mut##_##cb() { return = false; } \
 306     [[accumulate]] bool mut##_##cb()
 307
 308 #define MUTATOR_HOOK(cb, func, order) MACRO_BEGIN {                     \
 309     MUTATOR_ONADD {                                                     \
 310         if (!CallbackChain_Add(HOOK_##cb, CALLBACK_##func, order)) {    \
 311             LOG_INFO("HOOK FAILED: ", #cb, ":", #func, "\n");           \
 312             return true;                                                \
 313         }                                                               \
 314     }                                                                   \
 315     MUTATOR_ONROLLBACK_OR_REMOVE {                                      \
 316         CallbackChain_Remove(HOOK_##cb, CALLBACK_##func);               \
 317     }                                                                   \
 318 } MACRO_END
 319
 320 #include "events.qh"
 321
 322 #endif