qcsrc/common/mutators/base.qh

   1 #ifndef MUTATORS_BASE_H
   2 #define MUTATORS_BASE_H
   3
   4 const int CBC_ORDER_FIRST = 1;
   5 const int CBC_ORDER_LAST = 2;
   6 const int CBC_ORDER_EXCLUSIVE = 3;
   7 const int CBC_ORDER_ANY = 4;
   8
   9 bool CallbackChain_ReturnValue; // read-only field of the current return value
  10
  11 /**
  12  * Callbacks may be added to zero or more callback chains.
  13  */
  14 CLASS(Callback, Object)
  15     /**
  16      * a callback function is like this:
  17      * bool mycallback()
  18      * {
  19      *     do something
  20      *     return false;
  21      * }
  22      */
  23     ATTRIB(Callback, cbc_func, bool(), func_null)
  24     CONSTRUCTOR(Callback, bool() func) {
  25         CONSTRUCT(Callback);
  26         this.cbc_func = func;
  27     }
  28 ENDCLASS(Callback)
  29
  30 /**
  31  * Callback chains contain zero or more callbacks.
  32  */
  33 CLASS(CallbackChain, Object)
  34     CLASS(CallbackNode, Object)
  35         ATTRIB(CallbackNode, cbc, Callback, NULL)
  36         ATTRIB(CallbackNode, cbc_next, CallbackNode, NULL)
  37         ATTRIB(CallbackNode, cbc_order, int, 0)
  38         CONSTRUCTOR(CallbackNode, Callback it, int order) {
  39             CONSTRUCT(CallbackNode);
  40             this.cbc = it;
  41             this.cbc_order = order;
  42         }
  43     ENDCLASS(CallbackNode)
  44
  45     ATTRIB(CallbackChain, cbc_next, CallbackNode, NULL)
  46     ATTRIB(CallbackChain, cbc_order, int, 0)
  47     CONSTRUCTOR(CallbackChain, string _name) {
  48         CONSTRUCT(CallbackChain);
  49         this.netname = _name;
  50     }
  51
  52     bool CallbackChain_Add(CallbackChain this, Callback cb, int order)
  53     {
  54         if (order & CBC_ORDER_FIRST) {
  55             if (order & CBC_ORDER_LAST)
  56                 if (this.cbc_order & CBC_ORDER_ANY)
  57                     return false;
  58             if (this.cbc_order & CBC_ORDER_FIRST)
  59                 return false;
  60         } else if (order & CBC_ORDER_LAST) {
  61             if (this.cbc_order & CBC_ORDER_LAST)
  62                 return false;
  63         }
  64         entity node = NEW(CallbackNode, cb, order);
  65         if (order & CBC_ORDER_FIRST) {
  66             node.cbc_next = this.cbc_next;
  67             this.cbc_next = node;
  68         } else if (order & CBC_ORDER_LAST) {
  69             CallbackNode prev = NULL, it = this.cbc_next;
  70             while (it) { prev = it, it = it.cbc_next; }
  71             if (prev) prev.cbc_next = node;
  72             else this.cbc_next = node;
  73         } else {
  74             // by default we execute last, but before a possible CBC_ORDER_LAST callback
  75             CallbackNode prev = NULL, it = this.cbc_next;
  76             while (it && !(it.cbc_order & CBC_ORDER_LAST)) { prev = it, it = it.cbc_next; }
  77             node.cbc_next = it;
  78             if (prev) prev.cbc_next = node;
  79             else this.cbc_next = node;
  80         }
  81         this.cbc_order |= (order | CBC_ORDER_ANY);
  82         return true;
  83     }
  84     int CallbackChain_Remove(CallbackChain this, Callback cb)
  85     {
  86         int n = 0, order = 0;
  87         for (Callback prev = NULL, it = this.cbc_next; it; prev = it, it = it.cbc_next) {
  88             if (it.cbc == cb) {
  89                 // remove it from the chain
  90                 Callback next = it.cbc_next;
  91                 if (prev) prev.cbc_next = next;
  92                 else this.cbc_next = next;
  93                 ++n;
  94             }
  95             // it is now something we want to keep
  96             order |= (it.cbc_order & CBC_ORDER_ANY);
  97         }
  98         this.cbc_order = order;
  99         return n;
 100     }
 101     bool CallbackChain_Call(CallbackChain this)
 102     {
 103         bool r = false;
 104         for (Callback it = this.cbc_next; it; it = it.cbc_next) {
 105             CallbackChain_ReturnValue = r;
 106             r |= it.cbc.cbc_func();
 107         }
 108         return r; // callbacks return an error status, so 0 is default return value
 109     }
 110 ENDCLASS(CallbackChain)
 111
 112 #define _MUTATOR_HANDLE_NOP(type, id)
 113 #define _MUTATOR_HANDLE_PARAMS(type, id) , type in_##id
 114 #define _MUTATOR_HANDLE_PREPARE(type, id) id = in_##id;
 115 #define _MUTATOR_HANDLE_PUSHTMP(type, id) type tmp_##id = id;
 116 #define _MUTATOR_HANDLE_PUSHOUT(type, id) type out_##id = id;
 117 #define _MUTATOR_HANDLE_POPTMP(type, id) id = tmp_##id;
 118 #define _MUTATOR_HANDLE_POPOUT(type, id) id = out_##id;
 119
 120 void RegisterHooks() {};
 121 void RegisterCallbacks() {};
 122
 123 #define _MUTATOR_HOOKABLE(id, ...) CallbackChain HOOK_##id; bool __Mutator_Send_##id(__VA_ARGS__)
 124 #define MUTATOR_HOOKABLE(id, params) \
 125     _MUTATOR_HOOKABLE(id, int params(_MUTATOR_HANDLE_PARAMS, _MUTATOR_HANDLE_NOP)) { \
 126         params(_MUTATOR_HANDLE_PUSHTMP, _MUTATOR_HANDLE_NOP) \
 127         params(_MUTATOR_HANDLE_PREPARE, _MUTATOR_HANDLE_NOP) \
 128         bool ret = CallbackChain_Call(HOOK_##id); \
 129         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_PUSHOUT) \
 130         params(_MUTATOR_HANDLE_POPTMP,  _MUTATOR_HANDLE_NOP) \
 131         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_POPOUT) \
 132         return ret; \
 133     } \
 134     [[accumulate]] void RegisterHooks() { HOOK_##id = NEW(CallbackChain, #id); }
 135 #ifdef __STDC__
 136     #define MUTATOR_CALLHOOK(id, ...) APPLY(__Mutator_Send_##id, 0 P99_IF_EMPTY(__VA_ARGS__)()(, __VA_ARGS__))
 137 #else
 138     #define MUTATOR_CALLHOOK(id, ...) APPLY(__Mutator_Send_##id, 0, ##__VA_ARGS__)
 139 #endif
 140
 141 enum {
 142     MUTATOR_REMOVING,
 143     MUTATOR_ADDING,
 144     MUTATOR_ROLLING_BACK
 145 };
 146
 147 typedef bool(int) mutatorfunc_t;
 148
 149 CLASS(Mutator, Object)
 150     ATTRIB(Mutator, m_id, int, 0)
 151     ATTRIB(Mutator, m_name, string, string_null)
 152     ATTRIB(Mutator, mutatorfunc, mutatorfunc_t, func_null)
 153     ATTRIB(Mutator, mutatorcheck, bool(), func_null)
 154     CONSTRUCTOR(Mutator, string _name, mutatorfunc_t func) {
 155         CONSTRUCT(Mutator);
 156         this.m_name = _name;
 157         this.mutatorfunc = func;
 158     }
 159 ENDCLASS(Mutator)
 160
 161 REGISTRY(Mutators, BITS(7))
 162 #define Mutators_from(i) _Mutators_from(i, NULL)
 163 Mutator loaded_mutators[Mutators_MAX];
 164 bool Mutator_Add(Mutator mut);
 165 void Mutator_Remove(Mutator mut);
 166 bool mutator_log = false;
 167
 168 #ifndef MENUQC
 169 REGISTER_NET_LINKED(Mutator)
 170
 171 #ifdef SVQC
 172 bool Mutator_SendEntity(entity this, entity to, int sf)
 173 {
 174     int chan = MSG_ENTITY;
 175     WriteHeader(chan, Mutator);
 176     WriteString(chan, this.registered_id);
 177     return true;
 178 }
 179 #endif
 180
 181 #ifdef CSQC
 182 void NET_Mutator_Remove(entity this)
 183 {
 184     string s = this.netname;
 185     WITH(bool, mutator_log, true, LAMBDA(
 186         FOREACH(Mutators, it.registered_id == s, LAMBDA(Mutator_Remove(it)));
 187     ));
 188 }
 189 NET_HANDLE(Mutator, bool isNew)
 190 {
 191     string s = this.netname = ReadString();
 192     return = true;
 193     if (isNew)
 194     {
 195         make_pure(this);
 196         this.entremove = NET_Mutator_Remove;
 197         int added = 0;
 198         WITH(bool, mutator_log, true, LAMBDA(
 199             FOREACH(Mutators, it.registered_id == s, LAMBDA(Mutator_Add(it); ++added));
 200         ));
 201         if (added > 1) LOG_WARNINGF("Added more than one mutator for %s\n", s);
 202     }
 203 }
 204 #endif
 205
 206 #endif
 207
 208 bool Mutator_Add(Mutator mut)
 209 {
 210     int j = -1;
 211     for (int i = 0; i < Mutators_MAX; ++i) {
 212         if (loaded_mutators[i] == mut)
 213             return true; // already added
 214         if (!(loaded_mutators[i]))
 215             j = i;
 216     }
 217     if (j < 0) {
 218         backtrace("WARNING: too many mutators, cannot add any more\n");
 219         return false;
 220     }
 221     loaded_mutators[j] = mut;
 222     mutatorfunc_t func = mut.mutatorfunc;
 223     if (!func(MUTATOR_ADDING)) {
 224         // good
 225         if (mutator_log) LOG_TRACEF("Mutator: added %s\n", mut.m_name);
 226 #ifdef SVQC
 227         Net_LinkEntity(mut, false, 0, Mutator_SendEntity);
 228 #endif
 229         return true;
 230     }
 231     backtrace("WARNING: when adding mutator: adding failed, rolling back\n");
 232     if (func(MUTATOR_ROLLING_BACK)) {
 233         // baaaaad
 234         error("WARNING: when adding mutator: rolling back failed");
 235     }
 236     return false;
 237 }
 238
 239 void Mutator_Remove(Mutator mut)
 240 {
 241     int i;
 242     for (i = 0; i < Mutators_MAX; ++i)
 243         if (loaded_mutators[i] == mut)
 244             break;
 245     if (i >= Mutators_MAX) {
 246         backtrace("WARNING: removing not-added mutator\n");
 247         return;
 248     }
 249     loaded_mutators[i] = NULL;
 250     mutatorfunc_t func = mut.mutatorfunc;
 251     if (func(MUTATOR_REMOVING)) {
 252         // baaaaad
 253         error("Mutator_Remove: removing mutator failed");
 254     }
 255     if (mutator_log) LOG_TRACEF("Mutator: removed %s\n", mut.m_name);
 256 #ifdef SVQC
 257     Net_UnlinkEntity(mut);
 258 #endif
 259 }
 260
 261 #define REGISTER_MUTATOR(id, dependence) \
 262     bool MUTATORFUNCTION_##id##_hooks(int mode) { return = false; } \
 263     bool MUTATORFUNCTION_##id(int mode) { \
 264         return = false; \
 265         bool ret = MUTATORFUNCTION_##id##_hooks(mode); if (ret) return ret; \
 266     } \
 267     bool MUTATOR_##id##_check() { return dependence; } \
 268     REGISTER(Mutators, MUTATOR, id, m_id, NEW(Mutator, #id, MUTATORFUNCTION_##id)) \
 269     { this.mutatorcheck = MUTATOR_##id##_check; } \
 270     [[accumulate]] bool MUTATORFUNCTION_##id(int mode)
 271
 272 STATIC_INIT(Mutators) {
 273     RegisterHooks();
 274     RegisterCallbacks();
 275     RegisterMutators();
 276 }
 277
 278 STATIC_INIT_LATE(Mutators) {
 279     FOREACH(Mutators, it.mutatorcheck(), LAMBDA(Mutator_Add(it)));
 280 }
 281
 282 #define MUTATOR_ONADD                   if (mode == MUTATOR_ADDING)
 283 #define MUTATOR_ONREMOVE                if (mode == MUTATOR_REMOVING)
 284 #define MUTATOR_ONROLLBACK_OR_REMOVE    if (mode == MUTATOR_REMOVING || mode == MUTATOR_ROLLING_BACK)
 285 #define MUTATOR_ADD(name)               Mutator_Add(MUTATOR_##name)
 286 #define MUTATOR_REMOVE(name)            Mutator_Remove(MUTATOR_##name)
 287 #define MUTATOR_RETURNVALUE             CallbackChain_ReturnValue
 288
 289 #define _MUTATOR_CALLBACK(name, func) \
 290     Callback CALLBACK_##name; \
 291     bool func(); \
 292     [[accumulate]] void RegisterCallbacks() { CALLBACK_##name = NEW(Callback, func); }
 293
 294 #define MUTATOR_HOOKFUNCTION(...) \
 295     EVAL_MUTATOR_HOOKFUNCTION(OVERLOAD(MUTATOR_HOOKFUNCTION, __VA_ARGS__))
 296 #define EVAL_MUTATOR_HOOKFUNCTION(...) __VA_ARGS__
 297
 298 #define MUTATOR_HOOKFUNCTION_2(mut, cb) \
 299     MUTATOR_HOOKFUNCTION_3(mut, cb, CBC_ORDER_ANY)
 300
 301 #define MUTATOR_HOOKFUNCTION_3(mut, cb, order) \
 302     _MUTATOR_CALLBACK(mut##_##cb, mut##_##cb) \
 303     [[accumulate]] bool MUTATORFUNCTION_##mut##_hooks(int mode) { MUTATOR_HOOK(cb, mut##_##cb, order); } \
 304     bool mut##_##cb() { return = false; } \
 305     [[accumulate]] bool mut##_##cb()
 306
 307 #define MUTATOR_HOOK(cb, func, order) MACRO_BEGIN {                     \
 308     MUTATOR_ONADD {                                                     \
 309         if (!CallbackChain_Add(HOOK_##cb, CALLBACK_##func, order)) {    \
 310             LOG_INFO("HOOK FAILED: ", #cb, ":", #func, "\n");           \
 311             return true;                                                \
 312         }                                                               \
 313     }                                                                   \
 314     MUTATOR_ONROLLBACK_OR_REMOVE {                                      \
 315         CallbackChain_Remove(HOOK_##cb, CALLBACK_##func);               \
 316     }                                                                   \
 317 } MACRO_END
 318
 319 #include "events.qh"
 320
 321 #endif