qcsrc/common/mutators/base.qh

   1 #ifndef MUTATORS_BASE_H
   2 #define MUTATORS_BASE_H
   3
   4 const int CBC_ORDER_FIRST = 1;
   5 const int CBC_ORDER_LAST = 2;
   6 const int CBC_ORDER_EXCLUSIVE = 3;
   7 const int CBC_ORDER_ANY = 4;
   8
   9 bool CallbackChain_ReturnValue; // read-only field of the current return value
  10
  11 /**
  12  * Callbacks may be added to zero or more callback chains.
  13  */
  14 CLASS(Callback, Object)
  15     /**
  16      * a callback function is like this:
  17      * bool mycallback()
  18      * {
  19      *     do something
  20      *     return false;
  21      * }
  22      */
  23     ATTRIB(Callback, cbc_func, bool(), func_null)
  24     CONSTRUCTOR(Callback, bool() func) {
  25         CONSTRUCT(Callback);
  26         this.cbc_func = func;
  27     }
  28 ENDCLASS(Callback)
  29
  30 /**
  31  * Callback chains contain zero or more callbacks.
  32  */
  33 CLASS(CallbackChain, Object)
  34     CLASS(CallbackNode, Object)
  35         ATTRIB(CallbackNode, cbc, Callback, NULL)
  36         ATTRIB(CallbackNode, cbc_next, CallbackNode, NULL)
  37         ATTRIB(CallbackNode, cbc_order, int, 0)
  38         CONSTRUCTOR(CallbackNode, Callback it, int order) {
  39             CONSTRUCT(CallbackNode);
  40             this.cbc = it;
  41             this.cbc_order = order;
  42         }
  43     ENDCLASS(CallbackNode)
  44
  45     ATTRIB(CallbackChain, cbc_next, CallbackNode, NULL)
  46     ATTRIB(CallbackChain, cbc_order, int, 0)
  47     CONSTRUCTOR(CallbackChain, string _name) {
  48         CONSTRUCT(CallbackChain);
  49         this.netname = _name;
  50     }
  51
  52     bool CallbackChain_Add(CallbackChain this, Callback cb, int order)
  53     {
  54         if (order & CBC_ORDER_FIRST) {
  55             if (order & CBC_ORDER_LAST)
  56                 if (this.cbc_order & CBC_ORDER_ANY)
  57                     return false;
  58             if (this.cbc_order & CBC_ORDER_FIRST)
  59                 return false;
  60         } else if (order & CBC_ORDER_LAST) {
  61             if (this.cbc_order & CBC_ORDER_LAST)
  62                 return false;
  63         }
  64         entity node = NEW(CallbackNode, cb, order);
  65         if (order & CBC_ORDER_FIRST) {
  66             node.cbc_next = this.cbc_next;
  67             this.cbc_next = node;
  68         } else if (order & CBC_ORDER_LAST) {
  69             CallbackNode prev = NULL, it = this.cbc_next;
  70             while (it) { prev = it, it = it.cbc_next; }
  71             if (prev) prev.cbc_next = node;
  72             else this.cbc_next = node;
  73         } else {
  74             // by default we execute last, but before a possible CBC_ORDER_LAST callback
  75             CallbackNode prev = NULL, it = this.cbc_next;
  76             while (it && !(it.cbc_order & CBC_ORDER_LAST)) { prev = it, it = it.cbc_next; }
  77             node.cbc_next = it;
  78             if (prev) prev.cbc_next = node;
  79             else this.cbc_next = node;
  80         }
  81         this.cbc_order |= (order | CBC_ORDER_ANY);
  82         return true;
  83     }
  84     int CallbackChain_Remove(CallbackChain this, Callback cb)
  85     {
  86         int n = 0, order = 0;
  87         for (Callback prev = NULL, it = this.cbc_next; it; prev = it, it = it.cbc_next) {
  88             if (it.cbc == cb) {
  89                 // remove it from the chain
  90                 Callback next = it.cbc_next;
  91                 if (prev) prev.cbc_next = next;
  92                 else this.cbc_next = next;
  93                 ++n;
  94             }
  95             // it is now something we want to keep
  96             order |= (it.cbc_order & CBC_ORDER_ANY);
  97         }
  98         this.cbc_order = order;
  99         return n;
 100     }
 101     bool CallbackChain_Call(CallbackChain this)
 102     {
 103         bool r = false;
 104         for (Callback it = this.cbc_next; it; it = it.cbc_next) {
 105             CallbackChain_ReturnValue = r;
 106             r |= it.cbc.cbc_func();
 107         }
 108         return r; // callbacks return an error status, so 0 is default return value
 109     }
 110 ENDCLASS(CallbackChain)
 111
 112 #define _MUTATOR_HANDLE_NOP(type, id)
 113 #define _MUTATOR_HANDLE_PARAMS(type, id) , type in_##id
 114 #define _MUTATOR_HANDLE_PREPARE(type, id) id = in_##id;
 115 #define _MUTATOR_HANDLE_PUSHTMP(type, id) type tmp_##id = id;
 116 #define _MUTATOR_HANDLE_PUSHOUT(type, id) type out_##id = id;
 117 #define _MUTATOR_HANDLE_POPTMP(type, id) id = tmp_##id;
 118 #define _MUTATOR_HANDLE_POPOUT(type, id) id = out_##id;
 119
 120 void RegisterHooks() {};
 121 void RegisterCallbacks() {};
 122
 123 #define _MUTATOR_HOOKABLE(id, ...) CallbackChain HOOK_##id; bool __Mutator_Send_##id(__VA_ARGS__)
 124 #define MUTATOR_HOOKABLE(id, params) \
 125     _MUTATOR_HOOKABLE(id, int params(_MUTATOR_HANDLE_PARAMS, _MUTATOR_HANDLE_NOP)) { \
 126         params(_MUTATOR_HANDLE_PUSHTMP, _MUTATOR_HANDLE_NOP) \
 127         params(_MUTATOR_HANDLE_PREPARE, _MUTATOR_HANDLE_NOP) \
 128         bool ret = CallbackChain_Call(HOOK_##id); \
 129         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_PUSHOUT) \
 130         params(_MUTATOR_HANDLE_POPTMP,  _MUTATOR_HANDLE_NOP) \
 131         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_POPOUT) \
 132         return ret; \
 133     } \
 134     [[accumulate]] void RegisterHooks() { HOOK_##id = NEW(CallbackChain, #id); }
 135 #ifdef __STDC__
 136     #define MUTATOR_CALLHOOK(id, ...) APPLY(__Mutator_Send_##id, 0 P99_IF_EMPTY(__VA_ARGS__)()(, __VA_ARGS__))
 137 #else
 138     #define MUTATOR_CALLHOOK(id, ...) APPLY(__Mutator_Send_##id, 0, ##__VA_ARGS__)
 139 #endif
 140
 141 enum {
 142     MUTATOR_REMOVING,
 143     MUTATOR_ADDING,
 144     MUTATOR_ROLLING_BACK
 145 };
 146
 147 typedef bool(int) mutatorfunc_t;
 148
 149 CLASS(Mutator, Object)
 150     ATTRIB(Mutator, m_id, int, 0)
 151     ATTRIB(Mutator, m_name, string, string_null)
 152     ATTRIB(Mutator, mutatorfunc, mutatorfunc_t, func_null)
 153     ATTRIB(Mutator, mutatorcheck, bool(), func_null)
 154     CONSTRUCTOR(Mutator, string _name, mutatorfunc_t func) {
 155         CONSTRUCT(Mutator);
 156         this.m_name = _name;
 157         this.mutatorfunc = func;
 158     }
 159 ENDCLASS(Mutator)
 160
 161 REGISTRY(Mutators, BITS(7))
 162 #define Mutators_from(i) _Mutators_from(i, NULL)
 163 Mutator loaded_mutators[Mutators_MAX];
 164 bool Mutator_Add(Mutator mut);
 165 void Mutator_Remove(Mutator mut);
 166 bool mutator_log = false;
 167
 168 #ifndef MENUQC
 169 /** server mutators activate corresponding client mutators for all clients */
 170 REGISTER_NET_LINKED(Mutator)
 171
 172 #ifdef SVQC
 173 bool Mutator_SendEntity(entity this, entity to, int sf)
 174 {
 175     int chan = MSG_ENTITY;
 176     WriteHeader(chan, Mutator);
 177     WriteString(chan, this.registered_id);
 178     return true;
 179 }
 180 #endif
 181
 182 #ifdef CSQC
 183 void NET_Mutator_Remove(entity this)
 184 {
 185     string s = this.netname;
 186     WITH(bool, mutator_log, true, LAMBDA(
 187         FOREACH(Mutators, it.registered_id == s, Mutator_Remove(it));
 188     ));
 189 }
 190 NET_HANDLE(Mutator, bool isNew)
 191 {
 192     make_pure(this);
 193     string s = this.netname = ReadString();
 194     return = true;
 195     if (isNew)
 196     {
 197         make_pure(this);
 198         this.entremove = NET_Mutator_Remove;
 199         int added = 0;
 200         WITH(bool, mutator_log, true, LAMBDA(
 201             FOREACH(Mutators, it.registered_id == s, { Mutator_Add(it); ++added; });
 202         ));
 203         if (added > 1) LOG_WARNINGF("Added more than one mutator for %s\n", s);
 204     }
 205 }
 206 #endif
 207
 208 #endif
 209
 210 bool Mutator_Add(Mutator mut)
 211 {
 212     int j = -1;
 213     for (int i = 0; i < Mutators_MAX; ++i) {
 214         if (loaded_mutators[i] == mut)
 215             return true; // already added
 216         if (!(loaded_mutators[i]))
 217             j = i;
 218     }
 219     if (j < 0) {
 220         backtrace("WARNING: too many mutators, cannot add any more\n");
 221         return false;
 222     }
 223     loaded_mutators[j] = mut;
 224     mutatorfunc_t func = mut.mutatorfunc;
 225     if (!func(MUTATOR_ADDING)) {
 226         // good
 227         if (mutator_log) LOG_TRACEF("Mutator: added %s\n", mut.m_name);
 228 #ifdef SVQC
 229         Net_LinkEntity(mut, false, 0, Mutator_SendEntity);
 230 #endif
 231         return true;
 232     }
 233     backtrace("WARNING: when adding mutator: adding failed, rolling back\n");
 234     if (func(MUTATOR_ROLLING_BACK)) {
 235         // baaaaad
 236         error("WARNING: when adding mutator: rolling back failed");
 237     }
 238     return false;
 239 }
 240
 241 void Mutator_Remove(Mutator mut)
 242 {
 243     int i;
 244     for (i = 0; i < Mutators_MAX; ++i)
 245         if (loaded_mutators[i] == mut)
 246             break;
 247     if (i >= Mutators_MAX) {
 248         backtrace("WARNING: removing not-added mutator\n");
 249         return;
 250     }
 251     loaded_mutators[i] = NULL;
 252     mutatorfunc_t func = mut.mutatorfunc;
 253     if (func(MUTATOR_REMOVING)) {
 254         // baaaaad
 255         error("Mutator_Remove: removing mutator failed");
 256     }
 257     if (mutator_log) LOG_TRACEF("Mutator: removed %s\n", mut.m_name);
 258 #ifdef SVQC
 259     Net_UnlinkEntity(mut);
 260 #endif
 261 }
 262
 263 #define REGISTER_MUTATOR(id, dependence) \
 264     bool MUTATORFUNCTION_##id##_hooks(int mode) { return = false; } \
 265     bool MUTATORFUNCTION_##id(int mode) { \
 266         return = false; \
 267         bool ret = MUTATORFUNCTION_##id##_hooks(mode); if (ret) return ret; \
 268     } \
 269     bool MUTATOR_##id##_check() { return dependence; } \
 270     REGISTER(Mutators, MUTATOR, id, m_id, NEW(Mutator, #id, MUTATORFUNCTION_##id)) \
 271     { this.mutatorcheck = MUTATOR_##id##_check; } \
 272     [[accumulate]] bool MUTATORFUNCTION_##id(int mode)
 273
 274 STATIC_INIT(Mutators) {
 275     RegisterHooks();
 276     RegisterCallbacks();
 277     RegisterMutators();
 278 }
 279
 280 STATIC_INIT_LATE(Mutators) {
 281     FOREACH(Mutators, it.mutatorcheck(), Mutator_Add(it));
 282 }
 283
 284 #define MUTATOR_ONADD                   if (mode == MUTATOR_ADDING)
 285 #define MUTATOR_ONREMOVE                if (mode == MUTATOR_REMOVING)
 286 #define MUTATOR_ONROLLBACK_OR_REMOVE    if (mode == MUTATOR_REMOVING || mode == MUTATOR_ROLLING_BACK)
 287 #define MUTATOR_ADD(name)               Mutator_Add(MUTATOR_##name)
 288 #define MUTATOR_REMOVE(name)            Mutator_Remove(MUTATOR_##name)
 289 #define MUTATOR_RETURNVALUE             CallbackChain_ReturnValue
 290
 291 #define _MUTATOR_CALLBACK(name, func) \
 292     Callback CALLBACK_##name; \
 293     bool func(); \
 294     [[accumulate]] void RegisterCallbacks() { CALLBACK_##name = NEW(Callback, func); }
 295
 296 #define MUTATOR_HOOKFUNCTION(...) \
 297     EVAL_MUTATOR_HOOKFUNCTION(OVERLOAD(MUTATOR_HOOKFUNCTION, __VA_ARGS__))
 298 #define EVAL_MUTATOR_HOOKFUNCTION(...) __VA_ARGS__
 299
 300 #define MUTATOR_HOOKFUNCTION_2(mut, cb) \
 301     MUTATOR_HOOKFUNCTION_3(mut, cb, CBC_ORDER_ANY)
 302
 303 #define MUTATOR_HOOKFUNCTION_3(mut, cb, order) \
 304     _MUTATOR_CALLBACK(mut##_##cb, mut##_##cb) \
 305     [[accumulate]] bool MUTATORFUNCTION_##mut##_hooks(int mode) { MUTATOR_HOOK(cb, mut##_##cb, order); } \
 306     bool mut##_##cb() { return = false; } \
 307     [[accumulate]] bool mut##_##cb()
 308
 309 #define MUTATOR_HOOK(cb, func, order) MACRO_BEGIN {                     \
 310     MUTATOR_ONADD {                                                     \
 311         if (!CallbackChain_Add(HOOK_##cb, CALLBACK_##func, order)) {    \
 312             LOG_INFO("HOOK FAILED: ", #cb, ":", #func, "\n");           \
 313             return true;                                                \
 314         }                                                               \
 315     }                                                                   \
 316     MUTATOR_ONROLLBACK_OR_REMOVE {                                      \
 317         CallbackChain_Remove(HOOK_##cb, CALLBACK_##func);               \
 318     }                                                                   \
 319 } MACRO_END
 320
 321 #include "events.qh"
 322
 323 #endif