qcsrc/common/mutators/base.qh

   1 #ifndef MUTATORS_BASE_H
   2 #define MUTATORS_BASE_H
   3
   4 const int CBC_ORDER_FIRST = 1;
   5 const int CBC_ORDER_LAST = 2;
   6 const int CBC_ORDER_EXCLUSIVE = 3;
   7 const int CBC_ORDER_ANY = 4;
   8
   9 bool CallbackChain_ReturnValue; // read-only field of the current return value
  10
  11 /**
  12  * Callbacks may be added to zero or more callback chains.
  13  */
  14 CLASS(Callback, Object)
  15     /**
  16      * a callback function is like this:
  17      * bool mycallback()
  18      * {
  19      *     do something
  20      *     return false;
  21      * }
  22      */
  23     ATTRIB(Callback, cbc_func, bool(), func_null)
  24     CONSTRUCTOR(Callback, bool() func) {
  25         CONSTRUCT(Callback);
  26         this.cbc_func = func;
  27     }
  28 ENDCLASS(Callback)
  29
  30 /**
  31  * Callback chains contain zero or more callbacks.
  32  */
  33 CLASS(CallbackChain, Object)
  34     CLASS(CallbackNode, Object)
  35         ATTRIB(CallbackNode, cbc, Callback, NULL)
  36         ATTRIB(CallbackNode, cbc_next, CallbackNode, NULL)
  37         ATTRIB(CallbackNode, cbc_order, int, 0)
  38         CONSTRUCTOR(CallbackNode, Callback it, int order) {
  39             CONSTRUCT(CallbackNode);
  40             this.cbc = it;
  41             this.cbc_order = order;
  42         }
  43     ENDCLASS(CallbackNode)
  44
  45     ATTRIB(CallbackChain, cbc_next, CallbackNode, NULL)
  46     ATTRIB(CallbackChain, cbc_order, int, 0)
  47     CONSTRUCTOR(CallbackChain, string _name) {
  48         CONSTRUCT(CallbackChain);
  49         this.netname = _name;
  50     }
  51
  52     bool CallbackChain_Add(CallbackChain this, Callback cb, int order)
  53     {
  54         if (order & CBC_ORDER_FIRST) {
  55             if (order & CBC_ORDER_LAST)
  56                 if (this.cbc_order & CBC_ORDER_ANY)
  57                     return false;
  58             if (this.cbc_order & CBC_ORDER_FIRST)
  59                 return false;
  60         } else if (order & CBC_ORDER_LAST) {
  61             if (this.cbc_order & CBC_ORDER_LAST)
  62                 return false;
  63         }
  64         entity node = NEW(CallbackNode, cb, order);
  65         if (order & CBC_ORDER_FIRST) {
  66             node.cbc_next = this.cbc_next;
  67             this.cbc_next = node;
  68         } else if (order & CBC_ORDER_LAST) {
  69             CallbackNode prev = NULL, it = this.cbc_next;
  70             while (it) { prev = it, it = it.cbc_next; }
  71             if (prev) prev.cbc_next = node;
  72             else this.cbc_next = node;
  73         } else {
  74             // by default we execute last, but before a possible CBC_ORDER_LAST callback
  75             CallbackNode prev = NULL, it = this.cbc_next;
  76             while (it && !(it.cbc_order & CBC_ORDER_LAST)) { prev = it, it = it.cbc_next; }
  77             node.cbc_next = it;
  78             if (prev) prev.cbc_next = node;
  79             else this.cbc_next = node;
  80         }
  81         this.cbc_order |= (order | CBC_ORDER_ANY);
  82         return true;
  83     }
  84     int CallbackChain_Remove(CallbackChain this, Callback cb)
  85     {
  86         int n = 0, order = 0;
  87         for (Callback prev = NULL, it = this.cbc_next; it; prev = it, it = it.cbc_next) {
  88             if (it.cbc == cb) {
  89                 // remove it from the chain
  90                 Callback next = it.cbc_next;
  91                 if (prev) prev.cbc_next = next;
  92                 else this.cbc_next = next;
  93                 ++n;
  94             }
  95             // it is now something we want to keep
  96             order |= (it.cbc_order & CBC_ORDER_ANY);
  97         }
  98         this.cbc_order = order;
  99         return n;
 100     }
 101     bool CallbackChain_Call(CallbackChain this)
 102     {
 103         bool r = false;
 104         for (Callback it = this.cbc_next; it; it = it.cbc_next) {
 105             CallbackChain_ReturnValue = r;
 106             r |= it.cbc.cbc_func();
 107         }
 108         return r; // callbacks return an error status, so 0 is default return value
 109     }
 110 ENDCLASS(CallbackChain)
 111
 112 #define _MUTATOR_HANDLE_NOP(type, id)
 113 #define _MUTATOR_HANDLE_PARAMS(type, id) , type in_##id
 114 #define _MUTATOR_HANDLE_PREPARE(type, id) id = in_##id;
 115 #define _MUTATOR_HANDLE_PUSHTMP(type, id) type tmp_##id = id;
 116 #define _MUTATOR_HANDLE_PUSHOUT(type, id) type out_##id = id;
 117 #define _MUTATOR_HANDLE_POPTMP(type, id) id = tmp_##id;
 118 #define _MUTATOR_HANDLE_POPOUT(type, id) id = out_##id;
 119
 120 void RegisterHooks() {};
 121 void RegisterCallbacks() {};
 122
 123 #define _MUTATOR_HOOKABLE(id, ...) CallbackChain HOOK_##id; bool __Mutator_Send_##id(__VA_ARGS__)
 124 #define MUTATOR_HOOKABLE(id, params) \
 125     _MUTATOR_HOOKABLE(id, int params(_MUTATOR_HANDLE_PARAMS, _MUTATOR_HANDLE_NOP)) { \
 126         params(_MUTATOR_HANDLE_PUSHTMP, _MUTATOR_HANDLE_NOP) \
 127         params(_MUTATOR_HANDLE_PREPARE, _MUTATOR_HANDLE_NOP) \
 128         bool ret = CallbackChain_Call(HOOK_##id); \
 129         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_PUSHOUT) \
 130         params(_MUTATOR_HANDLE_POPTMP,  _MUTATOR_HANDLE_NOP) \
 131         params(_MUTATOR_HANDLE_NOP,     _MUTATOR_HANDLE_POPOUT) \
 132         return ret; \
 133     } \
 134     [[accumulate]] void RegisterHooks() { HOOK_##id = NEW(CallbackChain, #id); }
 135 #define MUTATOR_CALLHOOK(id, ...) APPLY(__Mutator_Send_##id, 0, ##__VA_ARGS__)
 136
 137 enum {
 138     MUTATOR_REMOVING,
 139     MUTATOR_ADDING,
 140     MUTATOR_ROLLING_BACK
 141 };
 142
 143 typedef bool(int) mutatorfunc_t;
 144
 145 CLASS(Mutator, Object)
 146     ATTRIB(Mutator, m_id, int, 0)
 147     ATTRIB(Mutator, m_name, string, string_null)
 148     ATTRIB(Mutator, mutatorfunc, mutatorfunc_t, func_null)
 149     ATTRIB(Mutator, mutatorcheck, bool(), func_null)
 150     CONSTRUCTOR(Mutator, string _name, mutatorfunc_t func) {
 151         CONSTRUCT(Mutator);
 152         this.m_name = _name;
 153         this.mutatorfunc = func;
 154     }
 155 ENDCLASS(Mutator)
 156
 157 REGISTRY(Mutators, BITS(7))
 158 #define Mutators_from(i) _Mutators_from(i, NULL)
 159 Mutator loaded_mutators[Mutators_MAX];
 160
 161 bool Mutator_Add(Mutator mut)
 162 {
 163     int j = -1;
 164     for (int i = 0; i < Mutators_MAX; ++i) {
 165         if (loaded_mutators[i] == mut)
 166             return true; // already added
 167         if (!(loaded_mutators[i]))
 168             j = i;
 169     }
 170     if (j < 0) {
 171         backtrace("WARNING: too many mutators, cannot add any more\n");
 172         return false;
 173     }
 174     loaded_mutators[j] = mut;
 175     mutatorfunc_t func = mut.mutatorfunc;
 176     if (!func(MUTATOR_ADDING)) {
 177         // good
 178         return true;
 179     }
 180     backtrace("WARNING: when adding mutator: adding failed, rolling back\n");
 181     if (func(MUTATOR_ROLLING_BACK)) {
 182         // baaaaad
 183         error("WARNING: when adding mutator: rolling back failed");
 184     }
 185     return false;
 186 }
 187
 188 void Mutator_Remove(Mutator mut)
 189 {
 190     int i;
 191     for (i = 0; i < Mutators_MAX; ++i)
 192         if (loaded_mutators[i] == mut)
 193             break;
 194     if (i >= Mutators_MAX) {
 195         backtrace("WARNING: removing not-added mutator\n");
 196         return;
 197     }
 198     loaded_mutators[i] = NULL;
 199     mutatorfunc_t func = mut.mutatorfunc;
 200     if (func(MUTATOR_REMOVING)) {
 201         // baaaaad
 202         error("Mutator_Remove: removing mutator failed");
 203     }
 204 }
 205
 206 #define REGISTER_MUTATOR(id, dependence) \
 207     bool MUTATORFUNCTION_##id##_hooks(int mode) { return = false; } \
 208     bool MUTATORFUNCTION_##id(int mode) { \
 209         return = false; \
 210         bool ret = MUTATORFUNCTION_##id##_hooks(mode); if (ret) return ret; \
 211     } \
 212     bool MUTATOR_##id##_check() { return dependence; } \
 213     REGISTER(RegisterMutators, MUTATOR, Mutators, id, m_id, NEW(Mutator, #id, MUTATORFUNCTION_##id)) \
 214     { this.mutatorcheck = MUTATOR_##id##_check; } \
 215     [[accumulate]] bool MUTATORFUNCTION_##id(int mode)
 216
 217 STATIC_INIT(Mutators) {
 218     RegisterHooks();
 219     RegisterCallbacks();
 220     RegisterMutators();
 221 }
 222
 223 STATIC_INIT_LATE(Mutators) {
 224     FOREACH(Mutators, it.mutatorcheck(), LAMBDA(Mutator_Add(it)));
 225 }
 226
 227 #define MUTATOR_ONADD                   if (mode == MUTATOR_ADDING)
 228 #define MUTATOR_ONREMOVE                if (mode == MUTATOR_REMOVING)
 229 #define MUTATOR_ONROLLBACK_OR_REMOVE    if (mode == MUTATOR_REMOVING || mode == MUTATOR_ROLLING_BACK)
 230 #define MUTATOR_ADD(name)               Mutator_Add(MUTATOR_##name)
 231 #define MUTATOR_REMOVE(name)            Mutator_Remove(MUTATOR_##name)
 232 #define MUTATOR_RETURNVALUE             CallbackChain_ReturnValue
 233
 234 #define _MUTATOR_CALLBACK(name, func) \
 235     Callback CALLBACK_##name; \
 236     bool func(); \
 237     [[accumulate]] void RegisterCallbacks() { CALLBACK_##name = NEW(Callback, func); }
 238
 239 #define MUTATOR_HOOKFUNCTION(...) \
 240     EVAL(OVERLOAD(MUTATOR_HOOKFUNCTION, __VA_ARGS__))
 241
 242 #define MUTATOR_HOOKFUNCTION_2(mut, cb) \
 243     MUTATOR_HOOKFUNCTION_3(mut, cb, CBC_ORDER_ANY)
 244
 245 #define MUTATOR_HOOKFUNCTION_3(mut, cb, order) \
 246     _MUTATOR_CALLBACK(mut##_##cb, mut##_##cb) \
 247     [[accumulate]] bool MUTATORFUNCTION_##mut##_hooks(int mode) { MUTATOR_HOOK(cb, mut##_##cb, order); } \
 248     bool mut##_##cb() { return = false; } \
 249     [[accumulate]] bool mut##_##cb()
 250
 251 #define MUTATOR_HOOK(cb, func, order) do {                              \
 252     MUTATOR_ONADD {                                                     \
 253         if (!CallbackChain_Add(HOOK_##cb, CALLBACK_##func, order)) {    \
 254             LOG_INFO("HOOK FAILED: ", #cb, ":", #func, "\n");           \
 255             return true;                                                \
 256         }                                                               \
 257     }                                                                   \
 258     MUTATOR_ONROLLBACK_OR_REMOVE {                                      \
 259         CallbackChain_Remove(HOOK_##cb, CALLBACK_##func);               \
 260     }                                                                   \
 261 } while (0)
 262
 263 #include "events.qh"
 264
 265 #endif