qcsrc/common/mutators/mutator/buffs/buffs.qc

   1 #ifndef MUTATOR_BUFFS_H
   2 #define MUTATOR_BUFFS_H
   3
   4 #include "../instagib/module.inc"
   5
   6 bool  autocvar_g_buffs_effects;
   7 float autocvar_g_buffs_waypoint_distance;
   8 bool autocvar_g_buffs_randomize;
   9 float autocvar_g_buffs_random_lifetime;
  10 bool autocvar_g_buffs_random_location;
  11 int autocvar_g_buffs_random_location_attempts;
  12 int autocvar_g_buffs_spawn_count;
  13 bool autocvar_g_buffs_replace_powerups;
  14 float autocvar_g_buffs_cooldown_activate;
  15 float autocvar_g_buffs_cooldown_respawn;
  16 float autocvar_g_buffs_resistance_blockpercent;
  17 float autocvar_g_buffs_medic_survive_chance;
  18 float autocvar_g_buffs_medic_survive_health;
  19 float autocvar_g_buffs_medic_rot;
  20 float autocvar_g_buffs_medic_max;
  21 float autocvar_g_buffs_medic_regen;
  22 float autocvar_g_buffs_medic_heal_amount = 15;
  23 float autocvar_g_buffs_medic_heal_delay = 1;
  24 float autocvar_g_buffs_medic_heal_range = 400;
  25 float autocvar_g_buffs_vengeance_damage_multiplier;
  26 float autocvar_g_buffs_bash_force;
  27 float autocvar_g_buffs_bash_force_self;
  28 float autocvar_g_buffs_disability_slowtime;
  29 float autocvar_g_buffs_disability_speed;
  30 float autocvar_g_buffs_disability_rate;
  31 float autocvar_g_buffs_disability_weaponspeed;
  32 float autocvar_g_buffs_speed_speed;
  33 float autocvar_g_buffs_speed_rate;
  34 float autocvar_g_buffs_speed_weaponspeed;
  35 float autocvar_g_buffs_speed_damage_take;
  36 float autocvar_g_buffs_speed_regen;
  37 float autocvar_g_buffs_vampire_damage_steal;
  38 float autocvar_g_buffs_invisible_alpha;
  39 float autocvar_g_buffs_jump_height;
  40 float autocvar_g_buffs_inferno_burntime_factor;
  41 float autocvar_g_buffs_inferno_burntime_min_time;
  42 float autocvar_g_buffs_inferno_burntime_target_damage;
  43 float autocvar_g_buffs_inferno_burntime_target_time;
  44 float autocvar_g_buffs_inferno_damagemultiplier;
  45 float autocvar_g_buffs_swapper_range;
  46 float autocvar_g_buffs_magnet_range_item;
  47 float autocvar_g_buffs_magnet_range_buff = 200;
  48 float autocvar_g_buffs_luck_chance = 0.15;
  49 float autocvar_g_buffs_luck_damagemultiplier = 3;
  50
  51 // ammo
  52 .float buff_ammo_prev_infitems;
  53 .int buff_ammo_prev_clipload;
  54 // invisible
  55 .float buff_invisible_prev_alpha;
  56 // medic
  57 .float buff_medic_healtime;
  58 // disability
  59 .float buff_disability_time;
  60 .float buff_disability_effect_time;
  61 // common buff variables
  62 .float buff_effect_delay;
  63
  64 // buff definitions
  65 .float buff_active;
  66 .float buff_activetime;
  67 .float buff_activetime_updated;
  68 .entity buff_waypoint;
  69 .int oldbuffs; // for updating effects
  70 .entity buff_model; // controls effects (TODO: make csqc)
  71
  72 const vector BUFF_MIN = ('-16 -16 -20');
  73 const vector BUFF_MAX = ('16 16 20');
  74
  75 // client side options
  76 .float cvar_cl_buffs_autoreplace;
  77 #endif
  78
  79 #ifdef IMPLEMENTATION
  80
  81 #include <common/triggers/target/music.qh>
  82 #include <common/gamemodes/all.qh>
  83
  84 .float buff_time = _STAT(BUFF_TIME);
  85 void buffs_DelayedInit(entity this);
  86
  87 REGISTER_MUTATOR(buffs, cvar("g_buffs"))
  88 {
  89         MUTATOR_ONADD
  90         {
  91                 InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
  92         }
  93 }
  94
  95 bool buffs_BuffModel_Customize(entity this)
  96 {
  97         entity player, myowner;
  98         bool same_team;
  99
 100         player = WaypointSprite_getviewentity(other);
 101         myowner = self.owner;
 102         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
 103
 104         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
 105                 return false;
 106
 107         if(MUTATOR_CALLHOOK(BuffModel_Customize, self, player))
 108                 return false;
 109
 110         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
 111         {
 112                 // somewhat hide the model, but keep the glow
 113                 self.effects = 0;
 114                 self.alpha = -1;
 115         }
 116         else
 117         {
 118                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 119                 self.alpha = 1;
 120         }
 121         return true;
 122 }
 123
 124 void buffs_BuffModel_Spawn(entity player)
 125 {
 126         player.buff_model = spawn();
 127         setmodel(player.buff_model, MDL_BUFF);
 128         setsize(player.buff_model, '0 0 -40', '0 0 40');
 129         setattachment(player.buff_model, player, "");
 130         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
 131         player.buff_model.owner = player;
 132         player.buff_model.scale = 0.7;
 133         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
 134         player.buff_model.light_lev = 200;
 135         setcefc(player.buff_model, buffs_BuffModel_Customize);
 136 }
 137
 138 vector buff_GlowColor(entity buff)
 139 {
 140         //if(buff.team) { return Team_ColorRGB(buff.team); }
 141         return buff.m_color;
 142 }
 143
 144 void buff_Effect(entity player, string eff)
 145 {SELFPARAM();
 146         if(!autocvar_g_buffs_effects) { return; }
 147
 148         if(time >= self.buff_effect_delay)
 149         {
 150                 Send_Effect_(eff, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
 151                 self.buff_effect_delay = time + 0.05; // prevent spam
 152         }
 153 }
 154
 155 // buff item
 156 bool buff_Waypoint_visible_for_player(entity this, entity player, entity view)
 157 {
 158         if(!this.owner.buff_active && !this.owner.buff_activetime)
 159                 return false;
 160
 161         if (view.buffs)
 162         {
 163                 return view.cvar_cl_buffs_autoreplace == false || view.buffs != this.owner.buffs;
 164         }
 165
 166         return WaypointSprite_visible_for_player(this, player, view);
 167 }
 168
 169 void buff_Waypoint_Spawn(entity e)
 170 {
 171         entity buff = buff_FirstFromFlags(e.buffs);
 172         entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_Buff);
 173         wp.wp_extra = buff.m_id;
 174         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
 175         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
 176 }
 177
 178 void buff_SetCooldown(entity this, float cd)
 179 {
 180         cd = max(0, cd);
 181
 182         if(!this.buff_waypoint)
 183                 buff_Waypoint_Spawn(this);
 184
 185         WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + cd);
 186         this.buff_activetime = cd;
 187         this.buff_active = !cd;
 188 }
 189
 190 void buff_Respawn(entity this)
 191 {
 192         if(gameover) { return; }
 193
 194         vector oldbufforigin = this.origin;
 195         this.velocity = '0 0 200';
 196
 197         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY,
 198                 ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 199         {
 200                 entity spot = SelectSpawnPoint(this, true);
 201                 setorigin(this, spot.origin);
 202                 this.velocity = ((randomvec() * 100) + '0 0 200');
 203                 this.angles = spot.angles;
 204         }
 205
 206         tracebox(this.origin, this.mins * 1.5, this.maxs * 1.5, this.origin, MOVE_NOMONSTERS, this);
 207
 208         setorigin(this, trace_endpos); // attempt to unstick
 209
 210         this.movetype = MOVETYPE_TOSS;
 211
 212         makevectors(this.angles);
 213         this.angles = '0 0 0';
 214         if(autocvar_g_buffs_random_lifetime > 0)
 215                 this.lifetime = time + autocvar_g_buffs_random_lifetime;
 216
 217         Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((this.mins + this.maxs) * 0.5), '0 0 0', 1);
 218         Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 219
 220         WaypointSprite_Ping(this.buff_waypoint);
 221
 222         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 223 }
 224
 225 void buff_Touch(entity this)
 226 {
 227         if(gameover) { return; }
 228
 229         if(ITEM_TOUCH_NEEDKILL())
 230         {
 231                 buff_Respawn(self);
 232                 return;
 233         }
 234
 235         if((self.team && DIFF_TEAM(other, self))
 236         || (STAT(FROZEN, other))
 237         || (other.vehicle)
 238         || (!self.buff_active)
 239         )
 240         {
 241                 // can't touch this
 242                 return;
 243         }
 244
 245         if(MUTATOR_CALLHOOK(BuffTouch, self, other))
 246                 return;
 247
 248         if(!IS_PLAYER(other))
 249                 return; // incase mutator changed other
 250
 251         if (other.buffs)
 252         {
 253                 if (other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 254                 {
 255                         int buffid = buff_FirstFromFlags(other.buffs).m_id;
 256                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 257                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, buffid);
 258
 259                         other.buffs = 0;
 260                         //sound(other, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 261                 }
 262                 else { return; } // do nothing
 263         }
 264
 265         self.owner = other;
 266         self.buff_active = false;
 267         self.lifetime = 0;
 268         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 269         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, buffid);
 270         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, buffid);
 271
 272         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 273         sound(other, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
 274         other.buffs |= (self.buffs);
 275 }
 276
 277 float buff_Available(entity buff)
 278 {
 279         if (buff == BUFF_Null)
 280                 return false;
 281         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 282                 return false;
 283         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
 284                 return false;
 285         return cvar(strcat("g_buffs_", buff.m_name));
 286 }
 287
 288 .int buff_seencount;
 289
 290 void buff_NewType(entity ent, float cb)
 291 {
 292         RandomSelection_Init();
 293         FOREACH(Buffs, buff_Available(it), LAMBDA(
 294                 it.buff_seencount += 1;
 295                 // if it's already been chosen, give it a lower priority
 296                 RandomSelection_Add(world, it.m_itemid, string_null, 1, max(0.2, 1 / it.buff_seencount));
 297         ));
 298         ent.buffs = RandomSelection_chosen_float;
 299 }
 300
 301 void buff_Think(entity this)
 302 {
 303         if(this.buffs != this.oldbuffs)
 304         {
 305                 entity buff = buff_FirstFromFlags(this.buffs);
 306                 this.color = buff.m_color;
 307                 this.glowmod = buff_GlowColor(buff);
 308                 this.skin = buff.m_skin;
 309
 310                 setmodel(this, MDL_BUFF);
 311
 312                 if(this.buff_waypoint)
 313                 {
 314                         //WaypointSprite_Disown(this.buff_waypoint, 1);
 315                         WaypointSprite_Kill(this.buff_waypoint);
 316                         buff_Waypoint_Spawn(this);
 317                         if(this.buff_activetime)
 318                                 WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + this.buff_activetime - frametime);
 319                 }
 320
 321                 this.oldbuffs = this.buffs;
 322         }
 323
 324         if(!gameover)
 325         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 326         if(!this.buff_activetime_updated)
 327         {
 328                 buff_SetCooldown(this, this.buff_activetime);
 329                 this.buff_activetime_updated = true;
 330         }
 331
 332         if(!this.buff_active && !this.buff_activetime)
 333         if(!this.owner || STAT(FROZEN, this.owner) || IS_DEAD(this.owner) || !this.owner.iscreature || !(this.owner.buffs & this.buffs))
 334         {
 335                 buff_SetCooldown(this, autocvar_g_buffs_cooldown_respawn + frametime);
 336                 this.owner = world;
 337                 if(autocvar_g_buffs_randomize)
 338                         buff_NewType(this, this.buffs);
 339
 340                 if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 341                         buff_Respawn(this);
 342         }
 343
 344         if(this.buff_activetime)
 345         if(!gameover)
 346         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 347         {
 348                 this.buff_activetime = max(0, this.buff_activetime - frametime);
 349
 350                 if(!this.buff_activetime)
 351                 {
 352                         this.buff_active = true;
 353                         sound(this, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
 354                         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 355                 }
 356         }
 357
 358         if(this.buff_active)
 359         {
 360                 if(this.team && !this.buff_waypoint)
 361                         buff_Waypoint_Spawn(this);
 362
 363                 if(this.lifetime)
 364                 if(time >= this.lifetime)
 365                         buff_Respawn(this);
 366         }
 367
 368         this.nextthink = time;
 369         //this.angles_y = time * 110.1;
 370 }
 371
 372 void buff_Waypoint_Reset(entity this)
 373 {
 374         WaypointSprite_Kill(this.buff_waypoint);
 375
 376         if(this.buff_activetime) { buff_Waypoint_Spawn(this); }
 377 }
 378
 379 void buff_Reset(entity this)
 380 {
 381         if(autocvar_g_buffs_randomize)
 382                 buff_NewType(this, this.buffs);
 383         this.owner = world;
 384         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate);
 385         buff_Waypoint_Reset(this);
 386         this.buff_activetime_updated = false;
 387
 388         if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 389                 buff_Respawn(this);
 390 }
 391
 392 float buff_Customize(entity this)
 393 {
 394         entity player = WaypointSprite_getviewentity(other);
 395         if(!this.buff_active || (this.team && DIFF_TEAM(player, this)))
 396         {
 397                 this.alpha = 0.3;
 398                 if(this.effects & EF_FULLBRIGHT) { this.effects &= ~(EF_FULLBRIGHT); }
 399                 this.pflags = 0;
 400         }
 401         else
 402         {
 403                 this.alpha = 1;
 404                 if(!(this.effects & EF_FULLBRIGHT)) { this.effects |= EF_FULLBRIGHT; }
 405                 this.light_lev = 220 + 36 * sin(time);
 406                 this.pflags = PFLAGS_FULLDYNAMIC;
 407         }
 408         return true;
 409 }
 410
 411 void buff_Init(entity this)
 412 {
 413         if(!cvar("g_buffs")) { remove(this); return; }
 414
 415         if(!teamplay && this.team) { this.team = 0; }
 416
 417         entity buff = buff_FirstFromFlags(this.buffs);
 418
 419         if(!this.buffs || buff_Available(buff))
 420                 buff_NewType(this, 0);
 421
 422         this.classname = "item_buff";
 423         this.solid = SOLID_TRIGGER;
 424         this.flags = FL_ITEM;
 425         setthink(this, buff_Think);
 426         settouch(this, buff_Touch);
 427         this.reset = buff_Reset;
 428         this.nextthink = time + 0.1;
 429         this.gravity = 1;
 430         this.movetype = MOVETYPE_TOSS;
 431         this.scale = 1;
 432         this.skin = buff.m_skin;
 433         this.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 434         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 435         setcefc(this, buff_Customize);
 436         //this.gravity = 100;
 437         this.color = buff.m_color;
 438         this.glowmod = buff_GlowColor(this);
 439         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate + game_starttime);
 440         this.buff_active = !this.buff_activetime;
 441         this.pflags = PFLAGS_FULLDYNAMIC;
 442
 443         if(this.spawnflags & 1)
 444                 this.noalign = true;
 445
 446         if(this.noalign)
 447                 this.movetype = MOVETYPE_NONE; // reset by random location
 448
 449         setmodel(this, MDL_BUFF);
 450         setsize(this, BUFF_MIN, BUFF_MAX);
 451
 452         if(cvar("g_buffs_random_location") || (this.spawnflags & 64))
 453                 buff_Respawn(this);
 454 }
 455
 456 void buff_Init_Compat(entity ent, entity replacement)
 457 {
 458         if (ent.spawnflags & 2)
 459                 ent.team = NUM_TEAM_1;
 460         else if (ent.spawnflags & 4)
 461                 ent.team = NUM_TEAM_2;
 462
 463         ent.buffs = replacement.m_itemid;
 464
 465         buff_Init(ent);
 466 }
 467
 468 void buff_SpawnReplacement(entity ent, entity old)
 469 {
 470         setorigin(ent, old.origin);
 471         ent.angles = old.angles;
 472         ent.noalign = (old.noalign || (old.spawnflags & 1));
 473
 474         buff_Init(ent);
 475 }
 476
 477 void buff_Vengeance_DelayedDamage(entity this)
 478 {
 479         if(this.enemy)
 480                 Damage(this.enemy, this.owner, this.owner, this.dmg, DEATH_BUFF.m_id, this.enemy.origin, '0 0 0');
 481
 482         remove(this);
 483         return;
 484 }
 485
 486 // note: only really useful in teamplay
 487 void buff_Medic_Heal(entity this)
 488 {
 489         FOREACH_CLIENT(IS_PLAYER(it) && it != this && vdist(it.origin - this.origin, <=, autocvar_g_buffs_medic_heal_range),
 490         {
 491                 if(SAME_TEAM(it, this))
 492                 if(it.health < autocvar_g_balance_health_regenstable)
 493                 {
 494                         Send_Effect(EFFECT_HEALING, it.origin, '0 0 0', 1);
 495                         it.health = bound(0, it.health + autocvar_g_buffs_medic_heal_amount, autocvar_g_balance_health_regenstable);
 496                 }
 497         });
 498 }
 499
 500 float buff_Inferno_CalculateTime(float x, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 501 {
 502         return offset_y + (intersect_y - offset_y) * logn(((x - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 503 }
 504
 505 // mutator hooks
 506 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_SplitHealthArmor)
 507 {
 508         entity frag_target = M_ARGV(2, entity);
 509         float frag_deathtype = M_ARGV(6, float);
 510         float frag_damage = M_ARGV(7, float);
 511
 512         if(frag_deathtype == DEATH_BUFF.m_id) { return false; }
 513
 514         if(frag_target.buffs & BUFF_RESISTANCE.m_itemid)
 515         {
 516                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 517                 M_ARGV(4, float) = v.x; // take
 518                 M_ARGV(5, float) = v.y; // save
 519         }
 520
 521         return false;
 522 }
 523
 524 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_Calculate)
 525 {
 526         entity frag_attacker = M_ARGV(1, entity);
 527         entity frag_target = M_ARGV(2, entity);
 528         float frag_deathtype = M_ARGV(3, float);
 529         float frag_damage = M_ARGV(4, float);
 530         vector frag_force = M_ARGV(6, vector);
 531
 532         if(frag_deathtype == DEATH_BUFF.m_id) { return false; }
 533
 534         if(frag_target.buffs & BUFF_SPEED.m_itemid)
 535         if(frag_target != frag_attacker)
 536                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 537
 538         if(frag_target.buffs & BUFF_MEDIC.m_itemid)
 539         if((frag_target.health - frag_damage) <= 0)
 540         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 541         if(frag_attacker)
 542         if(random() <= autocvar_g_buffs_medic_survive_chance)
 543                 frag_damage = max(5, frag_target.health - autocvar_g_buffs_medic_survive_health);
 544
 545         if(frag_target.buffs & BUFF_JUMP.m_itemid)
 546         if(frag_deathtype == DEATH_FALL.m_id)
 547                 frag_damage = 0;
 548
 549         if(frag_target.buffs & BUFF_VENGEANCE.m_itemid)
 550         if(frag_attacker)
 551         if(frag_attacker != frag_target)
 552         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 553         {
 554                 entity dmgent = spawn();
 555
 556                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 557                 dmgent.enemy = frag_attacker;
 558                 dmgent.owner = frag_target;
 559                 setthink(dmgent, buff_Vengeance_DelayedDamage);
 560                 dmgent.nextthink = time + 0.1;
 561         }
 562
 563         if(frag_target.buffs & BUFF_BASH.m_itemid)
 564         if(frag_attacker != frag_target)
 565                 frag_force = '0 0 0';
 566
 567         if(frag_attacker.buffs & BUFF_BASH.m_itemid)
 568         if(frag_force)
 569         if(frag_attacker == frag_target)
 570                 frag_force *= autocvar_g_buffs_bash_force_self;
 571         else
 572                 frag_force *= autocvar_g_buffs_bash_force;
 573
 574         if(frag_attacker.buffs & BUFF_DISABILITY.m_itemid)
 575         if(frag_target != frag_attacker)
 576                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 577
 578         if(frag_target.buffs & BUFF_INFERNO.m_itemid)
 579         {
 580                 if(frag_deathtype == DEATH_FIRE.m_id)
 581                         frag_damage = 0;
 582                 if(frag_deathtype == DEATH_LAVA.m_id)
 583                         frag_damage *= 0.5; // TODO: cvarize?
 584         }
 585
 586         if(frag_attacker.buffs & BUFF_LUCK.m_itemid)
 587         if(frag_attacker != frag_target)
 588         if(autocvar_g_buffs_luck_damagemultiplier > 0)
 589         if(random() <= autocvar_g_buffs_luck_chance)
 590                 frag_damage *= autocvar_g_buffs_luck_damagemultiplier;
 591
 592         if(frag_attacker.buffs & BUFF_INFERNO.m_itemid)
 593         if(frag_target != frag_attacker) {
 594                 float btime = buff_Inferno_CalculateTime(
 595                         frag_damage,
 596                         0,
 597                         autocvar_g_buffs_inferno_burntime_min_time,
 598                         autocvar_g_buffs_inferno_burntime_target_damage,
 599                         autocvar_g_buffs_inferno_burntime_target_time,
 600                         autocvar_g_buffs_inferno_burntime_factor
 601                 );
 602                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier), btime, DEATH_BUFF.m_id);
 603         }
 604
 605         // this... is ridiculous (TODO: fix!)
 606         if(frag_attacker.buffs & BUFF_VAMPIRE.m_itemid)
 607         if(!frag_target.vehicle)
 608         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 609         if(!IS_DEAD(frag_target))
 610         if(IS_PLAYER(frag_target) || IS_MONSTER(frag_target))
 611         if(frag_attacker != frag_target)
 612         if(!STAT(FROZEN, frag_target))
 613         if(frag_target.takedamage)
 614         if(DIFF_TEAM(frag_attacker, frag_target))
 615         {
 616                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 617                 if(frag_target.armorvalue)
 618                         frag_attacker.armorvalue = bound(0, frag_attacker.armorvalue + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.armorvalue), g_pickup_armorsmall_max);
 619         }
 620
 621         M_ARGV(4, float) = frag_damage;
 622         M_ARGV(6, vector) = frag_force;
 623
 624         return false;
 625 }
 626
 627 MUTATOR_HOOKFUNCTION(buffs, PlayerSpawn)
 628 {
 629         entity player = M_ARGV(0, entity);
 630
 631         player.buffs = 0;
 632         // reset timers here to prevent them continuing after re-spawn
 633         player.buff_disability_time = 0;
 634         player.buff_disability_effect_time = 0;
 635         return false;
 636 }
 637
 638 .float stat_sv_maxspeed;
 639 .float stat_sv_airspeedlimit_nonqw;
 640 .float stat_sv_jumpvelocity;
 641
 642 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics)
 643 {SELFPARAM();
 644         if(self.buffs & BUFF_SPEED.m_itemid)
 645         {
 646                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 647                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 648         }
 649
 650         if(time < self.buff_disability_time)
 651         {
 652                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 653                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 654         }
 655
 656         if(self.buffs & BUFF_JUMP.m_itemid)
 657         {
 658                 // automatically reset, no need to worry
 659                 self.stat_sv_jumpvelocity = autocvar_g_buffs_jump_height;
 660         }
 661
 662         return false;
 663 }
 664
 665 MUTATOR_HOOKFUNCTION(buffs, PlayerJump)
 666 {SELFPARAM();
 667         if(self.buffs & BUFF_JUMP.m_itemid)
 668                 player_jumpheight = autocvar_g_buffs_jump_height;
 669
 670         return false;
 671 }
 672
 673 MUTATOR_HOOKFUNCTION(buffs, MonsterMove)
 674 {
 675         entity mon = M_ARGV(0, entity);
 676
 677         if(time < mon.buff_disability_time)
 678         {
 679                 M_ARGV(1, float) *= autocvar_g_buffs_disability_speed; // run speed
 680                 M_ARGV(2, float) *= autocvar_g_buffs_disability_speed; // walk speed
 681         }
 682 }
 683
 684 MUTATOR_HOOKFUNCTION(buffs, PlayerDies)
 685 {
 686         entity frag_target = M_ARGV(2, entity);
 687
 688         if(frag_target.buffs)
 689         {
 690                 int buffid = buff_FirstFromFlags(frag_target.buffs).m_id;
 691                 Send_Notification(NOTIF_ALL_EXCEPT, frag_target, MSG_INFO, INFO_ITEM_BUFF_LOST, frag_target.netname, buffid);
 692                 frag_target.buffs = 0;
 693
 694                 if(frag_target.buff_model)
 695                 {
 696                         remove(frag_target.buff_model);
 697                         frag_target.buff_model = world;
 698                 }
 699         }
 700         return false;
 701 }
 702
 703 MUTATOR_HOOKFUNCTION(buffs, PlayerUseKey, CBC_ORDER_FIRST)
 704 {SELFPARAM();
 705         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 706         if(self.buffs)
 707         {
 708                 int buffid = buff_FirstFromFlags(self.buffs).m_id;
 709                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 710                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 711
 712                 self.buffs = 0;
 713                 sound(self, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 714                 return true;
 715         }
 716         return false;
 717 }
 718
 719 MUTATOR_HOOKFUNCTION(buffs, ForbidThrowCurrentWeapon)
 720 {
 721         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 722         entity player = M_ARGV(0, entity);
 723
 724         if(player.buffs & BUFF_SWAPPER.m_itemid)
 725         {
 726                 float best_distance = autocvar_g_buffs_swapper_range;
 727                 entity closest = world;
 728                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 729                         if(!IS_DEAD(it) && !STAT(FROZEN, it) && !it.vehicle)
 730                         if(DIFF_TEAM(it, player))
 731                         {
 732                                 float test = vlen2(player.origin - it.origin);
 733                                 if(test <= best_distance * best_distance)
 734                                 {
 735                                         best_distance = sqrt(test);
 736                                         closest = it;
 737                                 }
 738                         }
 739                 ));
 740
 741                 if(closest)
 742                 {
 743                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 744
 745                         my_org = player.origin;
 746                         my_vel = player.velocity;
 747                         my_ang = player.angles;
 748                         their_org = closest.origin;
 749                         their_vel = closest.velocity;
 750                         their_ang = closest.angles;
 751
 752                         Drop_Special_Items(closest);
 753
 754                         MUTATOR_CALLHOOK(PortalTeleport, player); // initiate flag dropper
 755
 756                         setorigin(player, their_org);
 757                         setorigin(closest, my_org);
 758
 759                         closest.velocity = my_vel;
 760                         closest.angles = my_ang;
 761                         closest.fixangle = true;
 762                         closest.oldorigin = my_org;
 763                         closest.oldvelocity = my_vel;
 764                         player.velocity = their_vel;
 765                         player.angles = their_ang;
 766                         player.fixangle = true;
 767                         player.oldorigin = their_org;
 768                         player.oldvelocity = their_vel;
 769
 770                         // set pusher so player gets the kill if they fall into void
 771                         closest.pusher = player;
 772                         closest.pushltime = time + autocvar_g_maxpushtime;
 773                         closest.istypefrag = PHYS_INPUT_BUTTON_CHAT(closest);
 774
 775                         Send_Effect(EFFECT_ELECTRO_COMBO, their_org, '0 0 0', 1);
 776                         Send_Effect(EFFECT_ELECTRO_COMBO, my_org, '0 0 0', 1);
 777
 778                         sound(player, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 779                         sound(closest, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 780
 781                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 782                         player.buffs = 0;
 783                         return true;
 784                 }
 785         }
 786         return false;
 787 }
 788
 789 bool buffs_RemovePlayer(entity player)
 790 {
 791         if(player.buff_model)
 792         {
 793                 remove(player.buff_model);
 794                 player.buff_model = world;
 795         }
 796
 797         // also reset timers here to prevent them continuing after spectating
 798         player.buff_disability_time = 0;
 799         player.buff_disability_effect_time = 0;
 800
 801         return false;
 802 }
 803 MUTATOR_HOOKFUNCTION(buffs, MakePlayerObserver) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
 804 MUTATOR_HOOKFUNCTION(buffs, ClientDisconnect) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
 805
 806 MUTATOR_HOOKFUNCTION(buffs, CustomizeWaypoint)
 807 {
 808         entity wp = M_ARGV(0, entity);
 809         entity player = M_ARGV(1, entity);
 810
 811         entity e = WaypointSprite_getviewentity(player);
 812
 813         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 814         // but only apply this to real players, not to spectators
 815         if((wp.owner.flags & FL_CLIENT) && (wp.owner.buffs & BUFF_INVISIBLE.m_itemid) && (e == player))
 816         if(DIFF_TEAM(wp.owner, e))
 817                 return true;
 818
 819         return false;
 820 }
 821
 822 MUTATOR_HOOKFUNCTION(buffs, OnEntityPreSpawn, CBC_ORDER_LAST)
 823 {
 824         entity ent = M_ARGV(0, entity);
 825
 826         if(autocvar_g_buffs_replace_powerups)
 827         switch(ent.classname)
 828         {
 829                 case "item_strength":
 830                 case "item_invincible":
 831                 {
 832                         entity e = spawn();
 833                         buff_SpawnReplacement(e, ent);
 834                         return true;
 835                 }
 836         }
 837         return false;
 838 }
 839
 840 MUTATOR_HOOKFUNCTION(buffs, WeaponRateFactor)
 841 {
 842         entity player = M_ARGV(1, entity);
 843
 844         if(player.buffs & BUFF_SPEED.m_itemid)
 845                 M_ARGV(0, float) *= autocvar_g_buffs_speed_rate;
 846
 847         if(time < player.buff_disability_time)
 848                 M_ARGV(0, float) *= autocvar_g_buffs_disability_rate;
 849 }
 850
 851 MUTATOR_HOOKFUNCTION(buffs, WeaponSpeedFactor)
 852 {
 853         entity player = M_ARGV(1, entity);
 854
 855         if(player.buffs & BUFF_SPEED.m_itemid)
 856                 M_ARGV(0, float) *= autocvar_g_buffs_speed_weaponspeed;
 857
 858         if(time < player.buff_disability_time)
 859                 M_ARGV(0, float) *= autocvar_g_buffs_disability_weaponspeed;
 860 }
 861
 862 MUTATOR_HOOKFUNCTION(buffs, PlayerPreThink)
 863 {SELFPARAM();
 864         if(gameover || IS_DEAD(self)) { return false; }
 865
 866         if(time < self.buff_disability_time)
 867         if(time >= self.buff_disability_effect_time)
 868         {
 869                 Send_Effect(EFFECT_SMOKING, self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 870                 self.buff_disability_effect_time = time + 0.5;
 871         }
 872
 873         // handle buff lost status
 874         // 1: notify everyone else
 875         // 2: notify carrier as well
 876         int buff_lost = 0;
 877
 878         if(self.buff_time)
 879         if(time >= self.buff_time)
 880                 buff_lost = 2;
 881
 882         if(STAT(FROZEN, self)) { buff_lost = 1; }
 883
 884         if(buff_lost)
 885         {
 886                 if(self.buffs)
 887                 {
 888                         int buffid = buff_FirstFromFlags(self.buffs).m_id;
 889                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, buffid);
 890                         if(buff_lost >= 2)
 891                         {
 892                                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
 893                                 sound(self, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 894                         }
 895                         self.buffs = 0;
 896                 }
 897         }
 898
 899         if(self.buffs & BUFF_MAGNET.m_itemid)
 900         {
 901                 vector pickup_size;
 902                 FOREACH_ENTITY_FLAGS(flags, FL_ITEM,
 903                 {
 904                         if(it.buffs)
 905                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_buff;
 906                         else
 907                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 908
 909                         if(boxesoverlap(self.absmin - pickup_size, self.absmax + pickup_size, it.absmin, it.absmax))
 910                         {
 911                                 if(gettouch(it))
 912                                 {
 913                                         entity oldother = other;
 914                                         other = self;
 915                                         WITHSELF(it, gettouch(it)(it));
 916                                         other = oldother;
 917                                 }
 918                         }
 919                 });
 920         }
 921
 922         if(self.buffs & BUFF_AMMO.m_itemid)
 923         if(self.clip_size)
 924                 self.clip_load = self.(weapon_load[PS(self).m_switchweapon.m_id]) = self.clip_size;
 925
 926         if((self.buffs & BUFF_INVISIBLE.m_itemid) && (self.oldbuffs & BUFF_INVISIBLE.m_itemid))
 927         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 928                 self.alpha = autocvar_g_buffs_invisible_alpha; // powerups reset alpha, so we must enforce this (TODO)
 929
 930         if(self.buffs & BUFF_MEDIC.m_itemid)
 931         if(time >= self.buff_medic_healtime)
 932         {
 933                 buff_Medic_Heal(self);
 934                 self.buff_medic_healtime = time + autocvar_g_buffs_medic_heal_delay;
 935         }
 936
 937 #define BUFF_ONADD(b) if ( (self.buffs & (b).m_itemid) && !(self.oldbuffs & (b).m_itemid))
 938 #define BUFF_ONREM(b) if (!(self.buffs & (b).m_itemid) &&  (self.oldbuffs & (b).m_itemid))
 939
 940         if(self.buffs != self.oldbuffs)
 941         {
 942                 entity buff = buff_FirstFromFlags(self.buffs);
 943                 float bufftime = buff != BUFF_Null ? buff.m_time(buff) : 0;
 944                 self.buff_time = (bufftime) ? time + bufftime : 0;
 945
 946                 BUFF_ONADD(BUFF_AMMO)
 947                 {
 948                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 949                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 950
 951                         if(self.clip_load)
 952                                 self.buff_ammo_prev_clipload = self.clip_load;
 953                         self.clip_load = self.(weapon_load[PS(self).m_switchweapon.m_id]) = self.clip_size;
 954                 }
 955
 956                 BUFF_ONREM(BUFF_AMMO)
 957                 {
 958                         if(self.buff_ammo_prev_infitems)
 959                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 960                         else
 961                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 962
 963                         if(self.buff_ammo_prev_clipload)
 964                                 self.clip_load = self.buff_ammo_prev_clipload;
 965                 }
 966
 967                 BUFF_ONADD(BUFF_INVISIBLE)
 968                 {
 969                         if(time < self.strength_finished && g_instagib)
 970                                 self.alpha = autocvar_g_instagib_invis_alpha;
 971                         else
 972                                 self.alpha = self.buff_invisible_prev_alpha;
 973                         self.alpha = autocvar_g_buffs_invisible_alpha;
 974                 }
 975
 976                 BUFF_ONREM(BUFF_INVISIBLE)
 977                         self.alpha = self.buff_invisible_prev_alpha;
 978
 979                 self.oldbuffs = self.buffs;
 980                 if(self.buffs)
 981                 {
 982                         if(!self.buff_model)
 983                                 buffs_BuffModel_Spawn(self);
 984
 985                         self.buff_model.color = buff.m_color;
 986                         self.buff_model.glowmod = buff_GlowColor(self.buff_model);
 987                         self.buff_model.skin = buff.m_skin;
 988
 989                         self.effects |= EF_NOSHADOW;
 990                 }
 991                 else
 992                 {
 993                         remove(self.buff_model);
 994                         self.buff_model = world;
 995
 996                         self.effects &= ~(EF_NOSHADOW);
 997                 }
 998         }
 999
1000         if(self.buff_model)
1001         {
1002                 self.buff_model.effects = self.effects;
1003                 self.buff_model.effects |= EF_LOWPRECISION;
1004                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
1005
1006                 self.buff_model.alpha = self.alpha;
1007         }
1008
1009 #undef BUFF_ONADD
1010 #undef BUFF_ONREM
1011         return false;
1012 }
1013
1014 MUTATOR_HOOKFUNCTION(buffs, SpectateCopy)
1015 {
1016         entity spectatee = M_ARGV(0, entity);
1017         entity client = M_ARGV(1, entity);
1018
1019         client.buffs = spectatee.buffs;
1020 }
1021
1022 MUTATOR_HOOKFUNCTION(buffs, VehicleEnter)
1023 {
1024         entity player = M_ARGV(0, entity);
1025         entity veh = M_ARGV(1, entity);
1026
1027         veh.buffs = player.buffs;
1028         player.buffs = 0;
1029         veh.buff_time = max(0, player.buff_time - time);
1030         player.buff_time = 0;
1031 }
1032
1033 MUTATOR_HOOKFUNCTION(buffs, VehicleExit)
1034 {
1035         entity player = M_ARGV(0, entity);
1036         entity veh = M_ARGV(1, entity);
1037
1038         player.buffs = player.oldbuffs = veh.buffs;
1039         veh.buffs = 0;
1040         player.buff_time = time + veh.buff_time;
1041         veh.buff_time = 0;
1042 }
1043
1044 MUTATOR_HOOKFUNCTION(buffs, PlayerRegen)
1045 {SELFPARAM();
1046         if(self.buffs & BUFF_MEDIC.m_itemid)
1047         {
1048                 regen_mod_rot = autocvar_g_buffs_medic_rot;
1049                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
1050                 regen_mod_regen = autocvar_g_buffs_medic_regen;
1051         }
1052
1053         if(self.buffs & BUFF_SPEED.m_itemid)
1054                 regen_mod_regen = autocvar_g_buffs_speed_regen;
1055
1056         return false;
1057 }
1058
1059 REPLICATE(cvar_cl_buffs_autoreplace, bool, "cl_buffs_autoreplace");
1060
1061 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsString)
1062 {
1063         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Buffs");
1064 }
1065
1066 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsPrettyString)
1067 {
1068         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Buffs");
1069 }
1070
1071 void buffs_DelayedInit(entity this)
1072 {
1073         if(autocvar_g_buffs_spawn_count > 0)
1074         if(find(world, classname, "item_buff") == world)
1075         {
1076                 float i;
1077                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
1078                 {
1079                         entity e = spawn();
1080                         e.spawnflags |= 64; // always randomize
1081                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
1082                         buff_Init(e);
1083                 }
1084         }
1085 }
1086 #endif