qcsrc/common/mutators/mutator/buffs/sv_buffs.qc

   1 #include "sv_buffs.qh"
   2
   3 #include <common/triggers/target/music.qh>
   4 #include <common/gamemodes/_mod.qh>
   5
   6 .float buff_time = _STAT(BUFF_TIME);
   7 void buffs_DelayedInit(entity this);
   8
   9 AUTOCVAR(g_buffs, int, -1, "Enable buffs, -1: enabled but no auto location or replacing powerups, 1: enabled and can replace them");
  10
  11 REGISTER_MUTATOR(buffs, autocvar_g_buffs)
  12 {
  13         MUTATOR_ONADD
  14         {
  15                 if(autocvar_g_buffs > 0)
  16                         InitializeEntity(NULL, buffs_DelayedInit, INITPRIO_FINDTARGET);
  17         }
  18 }
  19
  20 bool buffs_BuffModel_Customize(entity this, entity client)
  21 {
  22         entity player, myowner;
  23         bool same_team;
  24
  25         player = WaypointSprite_getviewentity(client);
  26         myowner = this.owner;
  27         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
  28
  29         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
  30                 return false;
  31
  32         if(MUTATOR_CALLHOOK(BuffModel_Customize, this, player))
  33                 return false;
  34
  35         if(player == myowner || (IS_SPEC(client) && client.enemy == myowner))
  36         {
  37                 // somewhat hide the model, but keep the glow
  38                 this.effects = 0;
  39                 this.alpha = -1;
  40         }
  41         else
  42         {
  43                 this.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  44                 this.alpha = 1;
  45         }
  46         return true;
  47 }
  48
  49 void buffs_BuffModel_Spawn(entity player)
  50 {
  51         player.buff_model = spawn();
  52         setmodel(player.buff_model, MDL_BUFF);
  53         setsize(player.buff_model, '0 0 -40', '0 0 40');
  54         setattachment(player.buff_model, player, "");
  55         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
  56         player.buff_model.owner = player;
  57         player.buff_model.scale = 0.7;
  58         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
  59         player.buff_model.light_lev = 200;
  60         setcefc(player.buff_model, buffs_BuffModel_Customize);
  61 }
  62
  63 vector buff_GlowColor(entity buff)
  64 {
  65         //if(buff.team) { return Team_ColorRGB(buff.team); }
  66         return buff.m_color;
  67 }
  68
  69 void buff_Effect(entity player, string eff)
  70 {
  71         if(!autocvar_g_buffs_effects) { return; }
  72
  73         if(time >= player.buff_effect_delay)
  74         {
  75                 Send_Effect_(eff, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
  76                 player.buff_effect_delay = time + 0.05; // prevent spam
  77         }
  78 }
  79
  80 // buff item
  81 bool buff_Waypoint_visible_for_player(entity this, entity player, entity view)
  82 {
  83         if(!this.owner.buff_active && !this.owner.buff_activetime)
  84                 return false;
  85
  86         if (view.buffs)
  87         {
  88                 return view.cvar_cl_buffs_autoreplace == false || view.buffs != this.owner.buffs;
  89         }
  90
  91         return WaypointSprite_visible_for_player(this, player, view);
  92 }
  93
  94 void buff_Waypoint_Spawn(entity e)
  95 {
  96         entity buff = buff_FirstFromFlags(e.buffs);
  97         entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, NULL, e.team, e, buff_waypoint, true, RADARICON_Buff);
  98         wp.wp_extra = buff.m_id;
  99         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
 100         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
 101 }
 102
 103 void buff_SetCooldown(entity this, float cd)
 104 {
 105         cd = max(0, cd);
 106
 107         if(!this.buff_waypoint)
 108                 buff_Waypoint_Spawn(this);
 109
 110         WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + cd);
 111         this.buff_activetime = cd;
 112         this.buff_active = !cd;
 113 }
 114
 115 void buff_Respawn(entity this)
 116 {
 117         if(game_stopped) return;
 118
 119         vector oldbufforigin = this.origin;
 120         this.velocity = '0 0 200';
 121
 122         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY,
 123                 ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 124         {
 125                 entity spot = SelectSpawnPoint(this, true);
 126                 setorigin(this, spot.origin);
 127                 this.velocity = ((randomvec() * 100) + '0 0 200');
 128                 this.angles = spot.angles;
 129         }
 130
 131         tracebox(this.origin, this.mins * 1.5, this.maxs * 1.5, this.origin, MOVE_NOMONSTERS, this);
 132
 133         setorigin(this, trace_endpos); // attempt to unstick
 134
 135         set_movetype(this, MOVETYPE_TOSS);
 136
 137         makevectors(this.angles);
 138         this.angles = '0 0 0';
 139         if(autocvar_g_buffs_random_lifetime > 0)
 140                 this.lifetime = time + autocvar_g_buffs_random_lifetime;
 141
 142         Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((this.mins + this.maxs) * 0.5), '0 0 0', 1);
 143         Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 144
 145         WaypointSprite_Ping(this.buff_waypoint);
 146
 147         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 148 }
 149
 150 void buff_Touch(entity this, entity toucher)
 151 {
 152         if(game_stopped) return;
 153
 154         if(ITEM_TOUCH_NEEDKILL())
 155         {
 156                 buff_Respawn(this);
 157                 return;
 158         }
 159
 160         if((this.team && DIFF_TEAM(toucher, this))
 161         || (STAT(FROZEN, toucher))
 162         || (toucher.vehicle)
 163         || (time < toucher.buff_shield)
 164         || (!this.buff_active)
 165         )
 166         {
 167                 // can't touch this
 168                 return;
 169         }
 170
 171         if(MUTATOR_CALLHOOK(BuffTouch, this, toucher))
 172                 return;
 173         toucher = M_ARGV(1, entity);
 174
 175         if(!IS_PLAYER(toucher))
 176                 return; // incase mutator changed toucher
 177
 178         if (toucher.buffs)
 179         {
 180                 if (toucher.cvar_cl_buffs_autoreplace && toucher.buffs != this.buffs)
 181                 {
 182                         int buffid = buff_FirstFromFlags(toucher.buffs).m_id;
 183                         //Send_Notification(NOTIF_ONE, toucher, MSG_MULTI, ITEM_BUFF_DROP, toucher.buffs);
 184                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ITEM_BUFF_LOST, toucher.netname, buffid);
 185
 186                         toucher.buffs = 0;
 187                         //sound(toucher, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 188                 }
 189                 else { return; } // do nothing
 190         }
 191
 192         this.owner = toucher;
 193         this.buff_active = false;
 194         this.lifetime = 0;
 195         int buffid = buff_FirstFromFlags(this.buffs).m_id;
 196         Send_Notification(NOTIF_ONE, toucher, MSG_MULTI, ITEM_BUFF_GOT, buffid);
 197         Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_INFO, INFO_ITEM_BUFF, toucher.netname, buffid);
 198
 199         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 200         sound(toucher, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
 201         toucher.buffs |= (this.buffs);
 202 }
 203
 204 float buff_Available(entity buff)
 205 {
 206         if (buff == BUFF_Null)
 207                 return false;
 208         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 209                 return false;
 210         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
 211                 return false;
 212         return cvar(strcat("g_buffs_", buff.m_name));
 213 }
 214
 215 .int buff_seencount;
 216
 217 void buff_NewType(entity ent, float cb)
 218 {
 219         RandomSelection_Init();
 220         FOREACH(Buffs, buff_Available(it), LAMBDA(
 221                 it.buff_seencount += 1;
 222                 // if it's already been chosen, give it a lower priority
 223                 RandomSelection_AddFloat(it.m_itemid, 1, max(0.2, 1 / it.buff_seencount));
 224         ));
 225         ent.buffs = RandomSelection_chosen_float;
 226 }
 227
 228 void buff_Think(entity this)
 229 {
 230         if(this.buffs != this.oldbuffs)
 231         {
 232                 entity buff = buff_FirstFromFlags(this.buffs);
 233                 this.color = buff.m_color;
 234                 this.glowmod = buff_GlowColor(buff);
 235                 this.skin = buff.m_skin;
 236
 237                 setmodel(this, MDL_BUFF);
 238                 setsize(this, BUFF_MIN, BUFF_MAX);
 239
 240                 if(this.buff_waypoint)
 241                 {
 242                         //WaypointSprite_Disown(this.buff_waypoint, 1);
 243                         WaypointSprite_Kill(this.buff_waypoint);
 244                         buff_Waypoint_Spawn(this);
 245                         if(this.buff_activetime)
 246                                 WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + this.buff_activetime - frametime);
 247                 }
 248
 249                 this.oldbuffs = this.buffs;
 250         }
 251
 252         if(!game_stopped)
 253         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 254         if(!this.buff_activetime_updated)
 255         {
 256                 buff_SetCooldown(this, this.buff_activetime);
 257                 this.buff_activetime_updated = true;
 258         }
 259
 260         if(!this.buff_active && !this.buff_activetime)
 261         if(!this.owner || STAT(FROZEN, this.owner) || IS_DEAD(this.owner) || !this.owner.iscreature || !(this.owner.buffs & this.buffs) || this.pickup_anyway > 0 || (this.pickup_anyway >= 0 && autocvar_g_buffs_pickup_anyway))
 262         {
 263                 buff_SetCooldown(this, autocvar_g_buffs_cooldown_respawn + frametime);
 264                 this.owner = NULL;
 265                 if(autocvar_g_buffs_randomize)
 266                         buff_NewType(this, this.buffs);
 267
 268                 if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 269                         buff_Respawn(this);
 270         }
 271
 272         if(this.buff_activetime)
 273         if(!game_stopped)
 274         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 275         {
 276                 this.buff_activetime = max(0, this.buff_activetime - frametime);
 277
 278                 if(!this.buff_activetime)
 279                 {
 280                         this.buff_active = true;
 281                         sound(this, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
 282                         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
 283                 }
 284         }
 285
 286         if(this.buff_active)
 287         {
 288                 if(this.team && !this.buff_waypoint)
 289                         buff_Waypoint_Spawn(this);
 290
 291                 if(this.lifetime)
 292                 if(time >= this.lifetime)
 293                         buff_Respawn(this);
 294         }
 295
 296         this.nextthink = time;
 297         //this.angles_y = time * 110.1;
 298 }
 299
 300 void buff_Waypoint_Reset(entity this)
 301 {
 302         WaypointSprite_Kill(this.buff_waypoint);
 303
 304         if(this.buff_activetime) { buff_Waypoint_Spawn(this); }
 305 }
 306
 307 void buff_Reset(entity this)
 308 {
 309         if(autocvar_g_buffs_randomize)
 310                 buff_NewType(this, this.buffs);
 311         this.owner = NULL;
 312         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate);
 313         buff_Waypoint_Reset(this);
 314         this.buff_activetime_updated = false;
 315
 316         if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
 317                 buff_Respawn(this);
 318 }
 319
 320 bool buff_Customize(entity this, entity client)
 321 {
 322         entity player = WaypointSprite_getviewentity(client);
 323         if(!this.buff_active || (this.team && DIFF_TEAM(player, this)))
 324         {
 325                 this.alpha = 0.3;
 326                 if(this.effects & EF_FULLBRIGHT) { this.effects &= ~(EF_FULLBRIGHT); }
 327                 this.pflags = 0;
 328         }
 329         else
 330         {
 331                 this.alpha = 1;
 332                 if(!(this.effects & EF_FULLBRIGHT)) { this.effects |= EF_FULLBRIGHT; }
 333                 this.light_lev = 220 + 36 * sin(time);
 334                 this.pflags = PFLAGS_FULLDYNAMIC;
 335         }
 336         return true;
 337 }
 338
 339 void buff_Init(entity this)
 340 {
 341         if(!cvar("g_buffs")) { delete(this); return; }
 342
 343         if(!teamplay && this.team) { this.team = 0; }
 344
 345         entity buff = buff_FirstFromFlags(this.buffs);
 346
 347         if(!this.buffs || !buff_Available(buff))
 348                 buff_NewType(this, 0);
 349
 350         this.classname = "item_buff";
 351         this.solid = SOLID_TRIGGER;
 352         this.flags = FL_ITEM;
 353         this.bot_pickup = true;
 354         this.bot_pickupevalfunc = generic_pickupevalfunc;
 355         this.bot_pickupbasevalue = 1000;
 356         IL_PUSH(g_items, this);
 357         setthink(this, buff_Think);
 358         settouch(this, buff_Touch);
 359         this.reset = buff_Reset;
 360         this.nextthink = time + 0.1;
 361         this.gravity = 1;
 362         set_movetype(this, MOVETYPE_TOSS);
 363         this.scale = 1;
 364         this.skin = buff.m_skin;
 365         this.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 366         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 367         setcefc(this, buff_Customize);
 368         //this.gravity = 100;
 369         this.color = buff.m_color;
 370         this.glowmod = buff_GlowColor(this);
 371         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate + game_starttime);
 372         this.buff_active = !this.buff_activetime;
 373         this.pflags = PFLAGS_FULLDYNAMIC;
 374
 375         if(this.spawnflags & 1)
 376                 this.noalign = true;
 377
 378         if(this.noalign)
 379                 set_movetype(this, MOVETYPE_NONE); // reset by random location
 380
 381         setmodel(this, MDL_BUFF);
 382         setsize(this, BUFF_MIN, BUFF_MAX);
 383
 384         if(cvar("g_buffs_random_location") || (this.spawnflags & 64))
 385                 buff_Respawn(this);
 386 }
 387
 388 void buff_Init_Compat(entity ent, entity replacement)
 389 {
 390         if (ent.spawnflags & 2)
 391                 ent.team = NUM_TEAM_1;
 392         else if (ent.spawnflags & 4)
 393                 ent.team = NUM_TEAM_2;
 394
 395         ent.buffs = replacement.m_itemid;
 396
 397         buff_Init(ent);
 398 }
 399
 400 void buff_SpawnReplacement(entity ent, entity old)
 401 {
 402         setorigin(ent, old.origin);
 403         ent.angles = old.angles;
 404         ent.noalign = (old.noalign || (old.spawnflags & 1));
 405
 406         buff_Init(ent);
 407 }
 408
 409 void buff_Vengeance_DelayedDamage(entity this)
 410 {
 411         if(this.enemy)
 412                 Damage(this.enemy, this.owner, this.owner, this.dmg, DEATH_BUFF.m_id, this.enemy.origin, '0 0 0');
 413
 414         delete(this);
 415         return;
 416 }
 417
 418 // note: only really useful in teamplay
 419 void buff_Medic_Heal(entity this)
 420 {
 421         FOREACH_CLIENT(IS_PLAYER(it) && it != this && vdist(it.origin - this.origin, <=, autocvar_g_buffs_medic_heal_range),
 422         {
 423                 if(SAME_TEAM(it, this))
 424                 if(it.health < autocvar_g_balance_health_regenstable)
 425                 {
 426                         Send_Effect(EFFECT_HEALING, it.origin, '0 0 0', 1);
 427                         it.health = bound(0, it.health + autocvar_g_buffs_medic_heal_amount, autocvar_g_balance_health_regenstable);
 428                 }
 429         });
 430 }
 431
 432 float buff_Inferno_CalculateTime(float damg, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 433 {
 434         return offset_y + (intersect_y - offset_y) * logn(((damg - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 435 }
 436
 437 // mutator hooks
 438 MUTATOR_HOOKFUNCTION(buffs, PlayerDamage_SplitHealthArmor)
 439 {
 440         entity frag_target = M_ARGV(2, entity);
 441         float frag_deathtype = M_ARGV(6, float);
 442         float frag_damage = M_ARGV(7, float);
 443
 444         if(frag_deathtype == DEATH_BUFF.m_id) { return; }
 445
 446         if(frag_target.buffs & BUFF_RESISTANCE.m_itemid)
 447         {
 448                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 449                 M_ARGV(4, float) = v.x; // take
 450                 M_ARGV(5, float) = v.y; // save
 451         }
 452 }
 453
 454 MUTATOR_HOOKFUNCTION(buffs, Damage_Calculate)
 455 {
 456         entity frag_attacker = M_ARGV(1, entity);
 457         entity frag_target = M_ARGV(2, entity);
 458         float frag_deathtype = M_ARGV(3, float);
 459         float frag_damage = M_ARGV(4, float);
 460         vector frag_force = M_ARGV(6, vector);
 461
 462         if(frag_deathtype == DEATH_BUFF.m_id) { return; }
 463
 464         if(frag_target.buffs & BUFF_SPEED.m_itemid)
 465         if(frag_target != frag_attacker)
 466                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 467
 468         if(frag_target.buffs & BUFF_MEDIC.m_itemid)
 469         if((frag_target.health - frag_damage) <= 0)
 470         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 471         if(frag_attacker)
 472         if(random() <= autocvar_g_buffs_medic_survive_chance)
 473                 frag_damage = max(5, frag_target.health - autocvar_g_buffs_medic_survive_health);
 474
 475         if(frag_target.buffs & BUFF_JUMP.m_itemid)
 476         if(frag_deathtype == DEATH_FALL.m_id)
 477                 frag_damage = 0;
 478
 479         if(frag_target.buffs & BUFF_VENGEANCE.m_itemid)
 480         if(frag_attacker)
 481         if(frag_attacker != frag_target)
 482         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 483         {
 484                 entity dmgent = spawn();
 485
 486                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 487                 dmgent.enemy = frag_attacker;
 488                 dmgent.owner = frag_target;
 489                 setthink(dmgent, buff_Vengeance_DelayedDamage);
 490                 dmgent.nextthink = time + 0.1;
 491         }
 492
 493         if(frag_target.buffs & BUFF_BASH.m_itemid)
 494         if(frag_attacker != frag_target)
 495                 frag_force = '0 0 0';
 496
 497         if(frag_attacker.buffs & BUFF_BASH.m_itemid)
 498         if(frag_force)
 499         if(frag_attacker == frag_target)
 500                 frag_force *= autocvar_g_buffs_bash_force_self;
 501         else
 502                 frag_force *= autocvar_g_buffs_bash_force;
 503
 504         if(frag_attacker.buffs & BUFF_DISABILITY.m_itemid)
 505         if(frag_target != frag_attacker)
 506                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 507
 508         if(frag_target.buffs & BUFF_INFERNO.m_itemid)
 509         {
 510                 if(frag_deathtype == DEATH_FIRE.m_id)
 511                         frag_damage = 0;
 512                 if(frag_deathtype == DEATH_LAVA.m_id)
 513                         frag_damage *= 0.5; // TODO: cvarize?
 514         }
 515
 516         if(frag_attacker.buffs & BUFF_LUCK.m_itemid)
 517         if(frag_attacker != frag_target)
 518         if(autocvar_g_buffs_luck_damagemultiplier > 0)
 519         if(random() <= autocvar_g_buffs_luck_chance)
 520                 frag_damage *= autocvar_g_buffs_luck_damagemultiplier;
 521
 522         if(frag_attacker.buffs & BUFF_INFERNO.m_itemid)
 523         if(frag_target != frag_attacker) {
 524                 float btime = buff_Inferno_CalculateTime(
 525                         frag_damage,
 526                         0,
 527                         autocvar_g_buffs_inferno_burntime_min_time,
 528                         autocvar_g_buffs_inferno_burntime_target_damage,
 529                         autocvar_g_buffs_inferno_burntime_target_time,
 530                         autocvar_g_buffs_inferno_burntime_factor
 531                 );
 532                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier), btime, DEATH_BUFF.m_id);
 533         }
 534
 535         // this... is ridiculous (TODO: fix!)
 536         if(frag_attacker.buffs & BUFF_VAMPIRE.m_itemid)
 537         if(!frag_target.vehicle)
 538         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 539         if(!IS_DEAD(frag_target))
 540         if(IS_PLAYER(frag_target) || IS_MONSTER(frag_target))
 541         if(frag_attacker != frag_target)
 542         if(!STAT(FROZEN, frag_target))
 543         if(frag_target.takedamage)
 544         if(DIFF_TEAM(frag_attacker, frag_target))
 545         {
 546                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 547                 if(frag_target.armorvalue)
 548                         frag_attacker.armorvalue = bound(0, frag_attacker.armorvalue + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.armorvalue), g_pickup_armorsmall_max);
 549         }
 550
 551         M_ARGV(4, float) = frag_damage;
 552         M_ARGV(6, vector) = frag_force;
 553 }
 554
 555 MUTATOR_HOOKFUNCTION(buffs, PlayerSpawn)
 556 {
 557         entity player = M_ARGV(0, entity);
 558
 559         player.buffs = 0;
 560         player.buff_time = 0;
 561         // reset timers here to prevent them continuing after re-spawn
 562         player.buff_disability_time = 0;
 563         player.buff_disability_effect_time = 0;
 564 }
 565
 566 .float stat_sv_maxspeed;
 567 .float stat_sv_airspeedlimit_nonqw;
 568 .float stat_sv_jumpvelocity;
 569
 570 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics)
 571 {
 572         entity player = M_ARGV(0, entity);
 573
 574         if(player.buffs & BUFF_SPEED.m_itemid)
 575         {
 576                 player.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 577                 player.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 578         }
 579
 580         if(time < player.buff_disability_time)
 581         {
 582                 player.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 583                 player.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 584         }
 585
 586         if(player.buffs & BUFF_JUMP.m_itemid)
 587         {
 588                 // automatically reset, no need to worry
 589                 player.stat_sv_jumpvelocity = autocvar_g_buffs_jump_height;
 590         }
 591 }
 592
 593 MUTATOR_HOOKFUNCTION(buffs, PlayerJump)
 594 {
 595         entity player = M_ARGV(0, entity);
 596
 597         if(player.buffs & BUFF_JUMP.m_itemid)
 598                 M_ARGV(1, float) = autocvar_g_buffs_jump_height;
 599 }
 600
 601 MUTATOR_HOOKFUNCTION(buffs, MonsterMove)
 602 {
 603         entity mon = M_ARGV(0, entity);
 604
 605         if(time < mon.buff_disability_time)
 606         {
 607                 M_ARGV(1, float) *= autocvar_g_buffs_disability_speed; // run speed
 608                 M_ARGV(2, float) *= autocvar_g_buffs_disability_speed; // walk speed
 609         }
 610 }
 611
 612 MUTATOR_HOOKFUNCTION(buffs, PlayerDies)
 613 {
 614         entity frag_target = M_ARGV(2, entity);
 615
 616         if(frag_target.buffs)
 617         {
 618                 int buffid = buff_FirstFromFlags(frag_target.buffs).m_id;
 619                 Send_Notification(NOTIF_ALL_EXCEPT, frag_target, MSG_INFO, INFO_ITEM_BUFF_LOST, frag_target.netname, buffid);
 620                 frag_target.buffs = 0;
 621
 622                 if(frag_target.buff_model)
 623                 {
 624                         delete(frag_target.buff_model);
 625                         frag_target.buff_model = NULL;
 626                 }
 627         }
 628 }
 629
 630 MUTATOR_HOOKFUNCTION(buffs, PlayerUseKey, CBC_ORDER_FIRST)
 631 {
 632         if(MUTATOR_RETURNVALUE || game_stopped || !autocvar_g_buffs_drop) return;
 633
 634         entity player = M_ARGV(0, entity);
 635
 636         if(player.buffs)
 637         {
 638                 int buffid = buff_FirstFromFlags(player.buffs).m_id;
 639                 Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 640                 Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
 641
 642                 player.buffs = 0;
 643                 player.buff_shield = time + max(0, autocvar_g_buffs_pickup_delay);
 644                 //player.buff_time = 0; // already notified
 645                 sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 646                 return true;
 647         }
 648 }
 649
 650 MUTATOR_HOOKFUNCTION(buffs, ForbidThrowCurrentWeapon)
 651 {
 652         if(MUTATOR_RETURNVALUE || game_stopped) return;
 653         entity player = M_ARGV(0, entity);
 654
 655         if(player.buffs & BUFF_SWAPPER.m_itemid)
 656         {
 657                 float best_distance = autocvar_g_buffs_swapper_range;
 658                 entity closest = NULL;
 659                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 660                         if(!IS_DEAD(it) && !STAT(FROZEN, it) && !it.vehicle)
 661                         if(DIFF_TEAM(it, player))
 662                         {
 663                                 float test = vlen2(player.origin - it.origin);
 664                                 if(test <= best_distance * best_distance)
 665                                 {
 666                                         best_distance = sqrt(test);
 667                                         closest = it;
 668                                 }
 669                         }
 670                 ));
 671
 672                 if(closest)
 673                 {
 674                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 675
 676                         my_org = player.origin;
 677                         my_vel = player.velocity;
 678                         my_ang = player.angles;
 679                         their_org = closest.origin;
 680                         their_vel = closest.velocity;
 681                         their_ang = closest.angles;
 682
 683                         Drop_Special_Items(closest);
 684
 685                         MUTATOR_CALLHOOK(PortalTeleport, player); // initiate flag dropper
 686
 687                         setorigin(player, their_org);
 688                         setorigin(closest, my_org);
 689
 690                         closest.velocity = my_vel;
 691                         closest.angles = my_ang;
 692                         closest.fixangle = true;
 693                         closest.oldorigin = my_org;
 694                         closest.oldvelocity = my_vel;
 695                         player.velocity = their_vel;
 696                         player.angles = their_ang;
 697                         player.fixangle = true;
 698                         player.oldorigin = their_org;
 699                         player.oldvelocity = their_vel;
 700
 701                         // set pusher so player gets the kill if they fall into void
 702                         closest.pusher = player;
 703                         closest.pushltime = time + autocvar_g_maxpushtime;
 704                         closest.istypefrag = PHYS_INPUT_BUTTON_CHAT(closest);
 705
 706                         Send_Effect(EFFECT_ELECTRO_COMBO, their_org, '0 0 0', 1);
 707                         Send_Effect(EFFECT_ELECTRO_COMBO, my_org, '0 0 0', 1);
 708
 709                         sound(player, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 710                         sound(closest, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
 711
 712                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 713                         player.buffs = 0;
 714                         return true;
 715                 }
 716         }
 717 }
 718
 719 bool buffs_RemovePlayer(entity player)
 720 {
 721         if(player.buff_model)
 722         {
 723                 delete(player.buff_model);
 724                 player.buff_model = NULL;
 725         }
 726
 727         // also reset timers here to prevent them continuing after spectating
 728         player.buff_disability_time = 0;
 729         player.buff_disability_effect_time = 0;
 730
 731         return false;
 732 }
 733 MUTATOR_HOOKFUNCTION(buffs, MakePlayerObserver) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
 734 MUTATOR_HOOKFUNCTION(buffs, ClientDisconnect) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
 735
 736 MUTATOR_HOOKFUNCTION(buffs, CustomizeWaypoint)
 737 {
 738         entity wp = M_ARGV(0, entity);
 739         entity player = M_ARGV(1, entity);
 740
 741         entity e = WaypointSprite_getviewentity(player);
 742
 743         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 744         // but only apply this to real players, not to spectators
 745         if((wp.owner.flags & FL_CLIENT) && (wp.owner.buffs & BUFF_INVISIBLE.m_itemid) && (e == player))
 746         if(DIFF_TEAM(wp.owner, e))
 747                 return true;
 748 }
 749
 750 MUTATOR_HOOKFUNCTION(buffs, OnEntityPreSpawn, CBC_ORDER_LAST)
 751 {
 752         if(autocvar_g_buffs < 0)
 753                 return; // no auto replacing of entities in this mode
 754
 755         entity ent = M_ARGV(0, entity);
 756
 757         if(autocvar_g_buffs_replace_powerups)
 758         switch(ent.classname)
 759         {
 760                 case "item_strength":
 761                 case "item_invincible":
 762                 {
 763                         entity e = spawn();
 764                         buff_SpawnReplacement(e, ent);
 765                         return true;
 766                 }
 767         }
 768 }
 769
 770 MUTATOR_HOOKFUNCTION(buffs, WeaponRateFactor)
 771 {
 772         entity player = M_ARGV(1, entity);
 773
 774         if(player.buffs & BUFF_SPEED.m_itemid)
 775                 M_ARGV(0, float) *= autocvar_g_buffs_speed_rate;
 776
 777         if(time < player.buff_disability_time)
 778                 M_ARGV(0, float) *= autocvar_g_buffs_disability_rate;
 779 }
 780
 781 MUTATOR_HOOKFUNCTION(buffs, WeaponSpeedFactor)
 782 {
 783         entity player = M_ARGV(1, entity);
 784
 785         if(player.buffs & BUFF_SPEED.m_itemid)
 786                 M_ARGV(0, float) *= autocvar_g_buffs_speed_weaponspeed;
 787
 788         if(time < player.buff_disability_time)
 789                 M_ARGV(0, float) *= autocvar_g_buffs_disability_weaponspeed;
 790 }
 791
 792 .bool buff_flight_crouchheld;
 793
 794 MUTATOR_HOOKFUNCTION(buffs, PlayerPreThink)
 795 {
 796         entity player = M_ARGV(0, entity);
 797
 798         if(game_stopped || IS_DEAD(player) || frametime || !IS_PLAYER(player)) return;
 799
 800         if(player.buffs & BUFF_FLIGHT.m_itemid)
 801         {
 802                 if(!PHYS_INPUT_BUTTON_CROUCH(player))
 803                         player.buff_flight_crouchheld = false;
 804                 else if(!player.buff_flight_crouchheld)
 805                 {
 806                         player.buff_flight_crouchheld = true;
 807                         player.gravity *= -1;
 808                 }
 809         }
 810
 811         if(time < player.buff_disability_time)
 812         if(time >= player.buff_disability_effect_time)
 813         {
 814                 Send_Effect(EFFECT_SMOKING, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
 815                 player.buff_disability_effect_time = time + 0.5;
 816         }
 817
 818         // handle buff lost status
 819         // 1: notify everyone else
 820         // 2: notify carrier as well
 821         int buff_lost = 0;
 822
 823         if(player.buff_time && player.buffs)
 824         if(time >= player.buff_time)
 825         {
 826                 player.buff_time = 0;
 827                 buff_lost = 2;
 828         }
 829
 830         if(STAT(FROZEN, player)) { buff_lost = 1; }
 831
 832         if(buff_lost)
 833         {
 834                 if(player.buffs)
 835                 {
 836                         int buffid = buff_FirstFromFlags(player.buffs).m_id;
 837                         if(buff_lost == 2)
 838                         {
 839                                 Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
 840                                 sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 841                         }
 842                         else
 843                                 Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
 844                         player.buffs = 0;
 845                         player.buff_shield = time + max(0, autocvar_g_buffs_pickup_delay); // always put in a delay, even if small
 846                 }
 847         }
 848
 849         if(player.buffs & BUFF_MAGNET.m_itemid)
 850         {
 851                 vector pickup_size;
 852                 IL_EACH(g_items, it.itemdef,
 853                 {
 854                         if(it.buffs)
 855                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_buff;
 856                         else
 857                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 858
 859                         if(boxesoverlap(player.absmin - pickup_size, player.absmax + pickup_size, it.absmin, it.absmax))
 860                         {
 861                                 if(gettouch(it))
 862                                         gettouch(it)(it, player);
 863                         }
 864                 });
 865         }
 866
 867         if(player.buffs & BUFF_AMMO.m_itemid)
 868         {
 869                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 870                 {
 871                         .entity weaponentity = weaponentities[slot];
 872                         if(player.(weaponentity).clip_size)
 873                                 player.(weaponentity).clip_load = player.(weaponentity).(weapon_load[player.(weaponentity).m_switchweapon.m_id]) = player.(weaponentity).clip_size;
 874                 }
 875         }
 876
 877         if((player.buffs & BUFF_INVISIBLE.m_itemid) && (player.oldbuffs & BUFF_INVISIBLE.m_itemid))
 878                 player.alpha = ((autocvar_g_buffs_invisible_alpha) ? autocvar_g_buffs_invisible_alpha : -1); // powerups reset alpha, so we must enforce this (TODO)
 879
 880         if(player.buffs & BUFF_MEDIC.m_itemid)
 881         if(time >= player.buff_medic_healtime)
 882         {
 883                 buff_Medic_Heal(player);
 884                 player.buff_medic_healtime = time + autocvar_g_buffs_medic_heal_delay;
 885         }
 886
 887 #define BUFF_ONADD(b) if ( (player.buffs & (b).m_itemid) && !(player.oldbuffs & (b).m_itemid))
 888 #define BUFF_ONREM(b) if (!(player.buffs & (b).m_itemid) &&  (player.oldbuffs & (b).m_itemid))
 889
 890         if(player.buffs != player.oldbuffs)
 891         {
 892                 entity buff = buff_FirstFromFlags(player.buffs);
 893                 float bufftime = buff != BUFF_Null ? buff.m_time(buff) : 0;
 894                 player.buff_time = (bufftime) ? time + bufftime : 0;
 895
 896                 BUFF_ONADD(BUFF_AMMO)
 897                 {
 898                         player.buff_ammo_prev_infitems = (player.items & IT_UNLIMITED_WEAPON_AMMO);
 899                         player.items |= IT_UNLIMITED_WEAPON_AMMO;
 900
 901                         if(player.buffs & BUFF_AMMO.m_itemid)
 902                         {
 903                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 904                                 {
 905                                         .entity weaponentity = weaponentities[slot];
 906                                         if(player.(weaponentity).clip_load)
 907                                                 player.(weaponentity).buff_ammo_prev_clipload = player.(weaponentity).clip_load;
 908                                         if(player.(weaponentity).clip_size)
 909                                                 player.(weaponentity).clip_load = player.(weaponentity).(weapon_load[player.(weaponentity).m_switchweapon.m_id]) = player.(weaponentity).clip_size;
 910                                 }
 911                         }
 912                 }
 913
 914                 BUFF_ONREM(BUFF_AMMO)
 915                 {
 916                         if(player.buff_ammo_prev_infitems)
 917                                 player.items |= IT_UNLIMITED_WEAPON_AMMO;
 918                         else
 919                                 player.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 920
 921                         if(player.buffs & BUFF_AMMO.m_itemid)
 922                         {
 923                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 924                                 {
 925                                         .entity weaponentity = weaponentities[slot];
 926                                         if(player.(weaponentity).buff_ammo_prev_clipload)
 927                                                 player.(weaponentity).clip_load = player.(weaponentity).buff_ammo_prev_clipload;
 928                                 }
 929                         }
 930                 }
 931
 932                 BUFF_ONADD(BUFF_INVISIBLE)
 933                 {
 934                         if(time < player.strength_finished && g_instagib)
 935                                 player.buff_invisible_prev_alpha = default_player_alpha; // we don't want to save the powerup's alpha, as player may lose the powerup while holding the buff
 936                         else
 937                                 player.buff_invisible_prev_alpha = player.alpha;
 938                         player.alpha = autocvar_g_buffs_invisible_alpha;
 939                 }
 940
 941                 BUFF_ONREM(BUFF_INVISIBLE)
 942                 {
 943                         if(time < player.strength_finished && g_instagib)
 944                                 player.alpha = autocvar_g_instagib_invis_alpha;
 945                         else
 946                                 player.alpha = player.buff_invisible_prev_alpha;
 947                 }
 948
 949                 BUFF_ONADD(BUFF_FLIGHT)
 950                 {
 951                         player.buff_flight_oldgravity = player.gravity;
 952                         if(!player.gravity)
 953                                 player.gravity = 1;
 954                 }
 955
 956                 BUFF_ONREM(BUFF_FLIGHT)
 957                         player.gravity = ((player.trigger_gravity_check) ? player.trigger_gravity_check.enemy.gravity : player.buff_flight_oldgravity);
 958
 959                 player.oldbuffs = player.buffs;
 960                 if(player.buffs)
 961                 {
 962                         if(!player.buff_model)
 963                                 buffs_BuffModel_Spawn(player);
 964
 965                         player.buff_model.color = buff.m_color;
 966                         player.buff_model.glowmod = buff_GlowColor(player.buff_model);
 967                         player.buff_model.skin = buff.m_skin;
 968
 969                         player.effects |= EF_NOSHADOW;
 970                 }
 971                 else
 972                 {
 973                         if(player.buff_model)
 974                                 delete(player.buff_model);
 975                         player.buff_model = NULL;
 976
 977                         player.effects &= ~(EF_NOSHADOW);
 978                 }
 979         }
 980
 981         if(player.buff_model)
 982         {
 983                 player.buff_model.effects = player.effects;
 984                 player.buff_model.effects |= EF_LOWPRECISION;
 985                 player.buff_model.effects = player.buff_model.effects & EFMASK_CHEAP; // eat performance
 986
 987                 player.buff_model.alpha = player.alpha;
 988         }
 989
 990 #undef BUFF_ONADD
 991 #undef BUFF_ONREM
 992 }
 993
 994 MUTATOR_HOOKFUNCTION(buffs, SpectateCopy)
 995 {
 996         entity spectatee = M_ARGV(0, entity);
 997         entity client = M_ARGV(1, entity);
 998
 999         client.buffs = spectatee.buffs;
1000         client.buff_time = spectatee.buff_time;
1001 }
1002
1003 MUTATOR_HOOKFUNCTION(buffs, VehicleEnter)
1004 {
1005         entity player = M_ARGV(0, entity);
1006         entity veh = M_ARGV(1, entity);
1007
1008         veh.buffs = player.buffs;
1009         player.buffs = 0;
1010         veh.buff_time = max(0, player.buff_time - time);
1011         player.buff_time = 0;
1012 }
1013
1014 MUTATOR_HOOKFUNCTION(buffs, VehicleExit)
1015 {
1016         entity player = M_ARGV(0, entity);
1017         entity veh = M_ARGV(1, entity);
1018
1019         player.buffs = player.oldbuffs = veh.buffs;
1020         veh.buffs = 0;
1021         player.buff_time = time + veh.buff_time;
1022         veh.buff_time = 0;
1023 }
1024
1025 MUTATOR_HOOKFUNCTION(buffs, PlayerRegen)
1026 {
1027         entity player = M_ARGV(0, entity);
1028
1029         if(player.buffs & BUFF_MEDIC.m_itemid)
1030         {
1031                 M_ARGV(2, float) = autocvar_g_buffs_medic_rot; // rot_mod
1032                 M_ARGV(4, float) = M_ARGV(1, float) = autocvar_g_buffs_medic_max; // limit_mod = max_mod
1033                 M_ARGV(2, float) = autocvar_g_buffs_medic_regen; // regen_mod
1034         }
1035
1036         if(player.buffs & BUFF_SPEED.m_itemid)
1037                 M_ARGV(2, float) = autocvar_g_buffs_speed_regen; // regen_mod
1038 }
1039
1040 REPLICATE(cvar_cl_buffs_autoreplace, bool, "cl_buffs_autoreplace");
1041
1042 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsString)
1043 {
1044         if(autocvar_g_buffs > 0) // only report as a mutator if they're enabled
1045                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Buffs");
1046 }
1047
1048 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsPrettyString)
1049 {
1050         if(autocvar_g_buffs > 0)
1051                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Buffs");
1052 }
1053
1054 void buffs_DelayedInit(entity this)
1055 {
1056         if(autocvar_g_buffs_spawn_count > 0)
1057         if(find(NULL, classname, "item_buff") == NULL)
1058         {
1059                 float i;
1060                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
1061                 {
1062                         entity e = spawn();
1063                         e.spawnflags |= 64; // always randomize
1064                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
1065                         buff_Init(e);
1066                 }
1067         }
1068 }