remove IT_UNLIMITED_BOTH
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mutators / mutator / buffs / sv_buffs.qc
1 #include "sv_buffs.qh"
2
3 #include <common/mapobjects/target/music.qh>
4 #include <common/gamemodes/_mod.qh>
5
6 void buffs_DelayedInit(entity this);
7
8 AUTOCVAR(g_buffs, int, -1, "Enable buffs, -1: enabled but no auto location or replacing powerups, 1: enabled and can replace them");
9
10 REGISTER_MUTATOR(buffs, autocvar_g_buffs)
11 {
12         MUTATOR_ONADD
13         {
14                 if(autocvar_g_buffs > 0)
15                         InitializeEntity(NULL, buffs_DelayedInit, INITPRIO_FINDTARGET);
16         }
17 }
18
19 bool buffs_BuffModel_Customize(entity this, entity client)
20 {
21         entity player, myowner;
22         bool same_team;
23
24         player = WaypointSprite_getviewentity(client);
25         myowner = this.owner;
26         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
27
28         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
29                 return false;
30
31         if(MUTATOR_CALLHOOK(BuffModel_Customize, this, player))
32                 return false;
33
34         if(player == myowner || (IS_SPEC(client) && client.enemy == myowner))
35         {
36                 // somewhat hide the model, but keep the glow
37                 this.effects = 0;
38                 this.alpha = -1;
39         }
40         else
41         {
42                 this.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
43                 this.alpha = 1;
44         }
45         return true;
46 }
47
48 void buffs_BuffModel_Spawn(entity player)
49 {
50         player.buff_model = spawn();
51         setmodel(player.buff_model, MDL_BUFF);
52         setsize(player.buff_model, '0 0 -40', '0 0 40');
53         setattachment(player.buff_model, player, "");
54         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
55         player.buff_model.owner = player;
56         player.buff_model.scale = 0.7;
57         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
58         player.buff_model.light_lev = 200;
59         setcefc(player.buff_model, buffs_BuffModel_Customize);
60 }
61
62 vector buff_GlowColor(entity buff)
63 {
64         //if(buff.team) { return Team_ColorRGB(buff.team); }
65         return buff.m_color;
66 }
67
68 void buff_Effect(entity player, string eff)
69 {
70         if(!autocvar_g_buffs_effects) { return; }
71
72         if(time >= player.buff_effect_delay)
73         {
74                 Send_Effect_(eff, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
75                 player.buff_effect_delay = time + 0.05; // prevent spam
76         }
77 }
78
79 // buff item
80 bool buff_Waypoint_visible_for_player(entity this, entity player, entity view)
81 {
82         if(!this.owner.buff_active && !this.owner.buff_activetime)
83                 return false;
84
85         if (STAT(BUFFS, view))
86         {
87                 return CS(view).cvar_cl_buffs_autoreplace == false || STAT(BUFFS, view) != STAT(BUFFS, this.owner);
88         }
89
90         return WaypointSprite_visible_for_player(this, player, view);
91 }
92
93 void buff_Waypoint_Spawn(entity e)
94 {
95         entity buff = buff_FirstFromFlags(STAT(BUFFS, e));
96         entity wp = WaypointSprite_Spawn(WP_Buff, 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, NULL, e.team, e, buff_waypoint, true, RADARICON_Buff);
97         wp.wp_extra = buff.m_id;
98         WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_Buff, e.glowmod);
99         e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
100 }
101
102 void buff_SetCooldown(entity this, float cd)
103 {
104         cd = max(0, cd);
105
106         if(!this.buff_waypoint)
107                 buff_Waypoint_Spawn(this);
108
109         WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + cd);
110         this.buff_activetime = cd;
111         this.buff_active = !cd;
112 }
113
114 void buff_Respawn(entity this)
115 {
116         if(game_stopped) return;
117
118         vector oldbufforigin = this.origin;
119         this.velocity = '0 0 200';
120
121         if(!MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY,
122                 ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
123         {
124                 entity spot = SelectSpawnPoint(this, true);
125                 setorigin(this, spot.origin);
126                 this.velocity = ((randomvec() * 100) + '0 0 200');
127                 this.angles = spot.angles;
128         }
129
130         tracebox(this.origin, this.mins * 1.5, this.maxs * 1.5, this.origin, MOVE_NOMONSTERS, this);
131
132         setorigin(this, trace_endpos); // attempt to unstick
133
134         set_movetype(this, MOVETYPE_TOSS);
135
136         makevectors(this.angles);
137         this.angles = '0 0 0';
138         if(autocvar_g_buffs_random_lifetime > 0)
139                 this.lifetime = time + autocvar_g_buffs_random_lifetime;
140
141         Send_Effect(EFFECT_ELECTRO_COMBO, oldbufforigin + ((this.mins + this.maxs) * 0.5), '0 0 0', 1);
142         Send_Effect(EFFECT_ELECTRO_COMBO, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
143
144         WaypointSprite_Ping(this.buff_waypoint);
145
146         sound(this, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
147 }
148
149 void buff_Touch(entity this, entity toucher)
150 {
151         if(game_stopped) return;
152
153         if(ITEM_TOUCH_NEEDKILL())
154         {
155                 buff_Respawn(this);
156                 return;
157         }
158
159         if(!this.buff_active)
160                 return;
161
162         if(MUTATOR_CALLHOOK(BuffTouch, this, toucher))
163                 return;
164         toucher = M_ARGV(1, entity);
165
166         if(!IS_PLAYER(toucher))
167                 return; // incase mutator changed toucher
168
169         if((this.team && DIFF_TEAM(toucher, this))
170         || (STAT(FROZEN, toucher))
171         || (toucher.vehicle)
172         || (time < PS(toucher).buff_shield)
173         )
174         {
175                 // can't touch this
176                 return;
177         }
178
179         if (STAT(BUFFS, toucher))
180         {
181                 if (CS(toucher).cvar_cl_buffs_autoreplace && STAT(BUFFS, toucher) != STAT(BUFFS, this))
182                 {
183                         // TODO: lost-gained notification for this case
184                         int buffid = buff_FirstFromFlags(STAT(BUFFS, toucher)).m_id;
185                         Send_Notification(NOTIF_ONE, toucher, MSG_INFO, INFO_ITEM_BUFF_LOST, toucher.netname, buffid);
186                         if(!IS_INDEPENDENT_PLAYER(toucher))
187                                 Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_INFO, INFO_ITEM_BUFF_LOST, toucher.netname, buffid);
188
189                         STAT(BUFFS, toucher) = 0;
190                         //sound(toucher, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
191                 }
192                 else { return; } // do nothing
193         }
194
195         this.owner = toucher;
196         this.buff_active = false;
197         this.lifetime = 0;
198         entity thebuff = buff_FirstFromFlags(STAT(BUFFS, this));
199         Send_Notification(NOTIF_ONE, toucher, MSG_MULTI, ITEM_BUFF_GOT, thebuff.m_id);
200         if(!IS_INDEPENDENT_PLAYER(toucher))
201                 Send_Notification(NOTIF_ALL_EXCEPT, toucher, MSG_INFO, INFO_ITEM_BUFF, toucher.netname, thebuff.m_id);
202
203         Send_Effect(EFFECT_ITEM_PICKUP, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
204         sound(toucher, CH_TRIGGER, SND_SHIELD_RESPAWN, VOL_BASE, ATTN_NORM);
205         STAT(BUFFS, toucher) |= (STAT(BUFFS, this));
206         float bufftime = ((this.count) ? this.count : thebuff.m_time(thebuff));
207         if(bufftime)
208                 STAT(BUFF_TIME, toucher) = min(time + bufftime, max(STAT(BUFF_TIME, toucher), time) + bufftime);
209 }
210
211 float buff_Available(entity buff)
212 {
213         if (buff == BUFF_Null)
214                 return false;
215         if (buff == BUFF_AMMO && ((start_items & IT_UNLIMITED_AMMO) || cvar("g_melee_only")))
216                 return false;
217         if (buff == BUFF_VAMPIRE && cvar("g_vampire"))
218                 return false;
219         return cvar(strcat("g_buffs_", buff.netname));
220 }
221
222 .int buff_seencount;
223
224 void buff_NewType(entity ent)
225 {
226         RandomSelection_Init();
227         FOREACH(Buffs, buff_Available(it),
228         {
229                 // if it's already been chosen, give it a lower priority
230                 RandomSelection_AddEnt(it, max(0.2, 1 / it.buff_seencount), 1);
231         });
232         entity newbuff = RandomSelection_chosen_ent;
233         newbuff.buff_seencount += 1; // lower chances of seeing this buff again soon
234         STAT(BUFFS, ent) = newbuff.m_itemid;
235 }
236
237 void buff_Think(entity this)
238 {
239         if(STAT(BUFFS, this) != this.oldbuffs)
240         {
241                 entity buff = buff_FirstFromFlags(STAT(BUFFS, this));
242                 this.color = buff.m_color;
243                 this.glowmod = buff_GlowColor(buff);
244                 this.skin = buff.m_skin;
245
246                 setmodel(this, MDL_BUFF);
247                 setsize(this, BUFF_MIN, BUFF_MAX);
248
249                 if(this.buff_waypoint)
250                 {
251                         //WaypointSprite_Disown(this.buff_waypoint, 1);
252                         WaypointSprite_Kill(this.buff_waypoint);
253                         buff_Waypoint_Spawn(this);
254                         if(this.buff_activetime)
255                                 WaypointSprite_UpdateBuildFinished(this.buff_waypoint, time + this.buff_activetime - frametime);
256                 }
257
258                 this.oldbuffs = STAT(BUFFS, this);
259         }
260
261         if(!game_stopped)
262         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
263         if(!this.buff_activetime_updated)
264         {
265                 buff_SetCooldown(this, this.buff_activetime);
266                 this.buff_activetime_updated = true;
267         }
268
269         if(!this.buff_active && !this.buff_activetime)
270         if(!this.owner || STAT(FROZEN, this.owner) || IS_DEAD(this.owner) || !this.owner.iscreature || this.owner.vehicle || !(STAT(BUFFS, this.owner) & STAT(BUFFS, this)) || this.pickup_anyway > 0 || (this.pickup_anyway >= 0 && autocvar_g_buffs_pickup_anyway))
271         {
272                 buff_SetCooldown(this, autocvar_g_buffs_cooldown_respawn + frametime);
273                 this.owner = NULL;
274                 if(autocvar_g_buffs_randomize)
275                         buff_NewType(this);
276
277                 if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
278                         buff_Respawn(this);
279         }
280
281         if(this.buff_activetime)
282         if(!game_stopped)
283         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
284         {
285                 this.buff_activetime = max(0, this.buff_activetime - frametime);
286
287                 if(!this.buff_activetime)
288                 {
289                         this.buff_active = true;
290                         sound(this, CH_TRIGGER, SND_STRENGTH_RESPAWN, VOL_BASE, ATTN_NORM);
291                         Send_Effect(EFFECT_ITEM_RESPAWN, CENTER_OR_VIEWOFS(this), '0 0 0', 1);
292                 }
293         }
294
295         if(this.buff_active)
296         {
297                 if(this.team && !this.buff_waypoint)
298                         buff_Waypoint_Spawn(this);
299
300                 if(this.lifetime)
301                 if(time >= this.lifetime)
302                         buff_Respawn(this);
303         }
304
305         this.nextthink = time;
306         //this.angles_y = time * 110.1;
307 }
308
309 void buff_Waypoint_Reset(entity this)
310 {
311         WaypointSprite_Kill(this.buff_waypoint);
312
313         if(this.buff_activetime) { buff_Waypoint_Spawn(this); }
314 }
315
316 void buff_Reset(entity this)
317 {
318         if(autocvar_g_buffs_randomize)
319                 buff_NewType(this);
320         this.owner = NULL;
321         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate);
322         buff_Waypoint_Reset(this);
323         this.buff_activetime_updated = false;
324
325         if(autocvar_g_buffs_random_location || (this.spawnflags & 64))
326                 buff_Respawn(this);
327 }
328
329 bool buff_Customize(entity this, entity client)
330 {
331         entity player = WaypointSprite_getviewentity(client);
332         if(!this.buff_active || (this.team && DIFF_TEAM(player, this)))
333         {
334                 this.alpha = 0.3;
335                 if(this.effects & EF_FULLBRIGHT) { this.effects &= ~(EF_FULLBRIGHT); }
336                 this.pflags = 0;
337         }
338         else
339         {
340                 this.alpha = 1;
341                 if(!(this.effects & EF_FULLBRIGHT)) { this.effects |= EF_FULLBRIGHT; }
342                 this.light_lev = 220 + 36 * sin(time);
343                 this.pflags = PFLAGS_FULLDYNAMIC;
344         }
345         return true;
346 }
347
348 void buff_Delete(entity this)
349 {
350         WaypointSprite_Kill(this.buff_waypoint);
351         delete_fn(this);
352 }
353
354 void buff_Init(entity this)
355 {
356         if(!cvar("g_buffs")) { delete(this); return; }
357
358         if(!teamplay && this.team) { this.team = 0; }
359
360         entity buff = buff_FirstFromFlags(STAT(BUFFS, this));
361
362         if(!STAT(BUFFS, this) || !buff_Available(buff))
363                 buff_NewType(this);
364
365         this.classname = "item_buff";
366         this.solid = SOLID_TRIGGER;
367         this.flags = FL_ITEM;
368         this.bot_pickup = true;
369         this.bot_pickupevalfunc = generic_pickupevalfunc;
370         this.bot_pickupbasevalue = 1000;
371         IL_PUSH(g_items, this);
372         setthink(this, buff_Think);
373         settouch(this, buff_Touch);
374         this.reset = buff_Reset;
375         this.nextthink = time + 0.1;
376         this.gravity = 1;
377         set_movetype(this, MOVETYPE_TOSS);
378         this.scale = 1;
379         this.skin = buff.m_skin;
380         this.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
381         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
382         setcefc(this, buff_Customize);
383         //this.gravity = 100;
384         this.color = buff.m_color;
385         this.glowmod = buff_GlowColor(this);
386         buff_SetCooldown(this, autocvar_g_buffs_cooldown_activate + max(0, game_starttime - time));
387         this.buff_active = !this.buff_activetime;
388         this.pflags = PFLAGS_FULLDYNAMIC;
389         this.dtor = buff_Delete;
390
391         if(this.spawnflags & 1)
392                 this.noalign = true;
393
394         if(this.noalign)
395                 set_movetype(this, MOVETYPE_NONE); // reset by random location
396
397         setmodel(this, MDL_BUFF);
398         setsize(this, BUFF_MIN, BUFF_MAX);
399
400         if(cvar("g_buffs_random_location") || (this.spawnflags & 64))
401                 buff_Respawn(this);
402 }
403
404 void buff_Init_Compat(entity ent, entity replacement)
405 {
406         if (ent.spawnflags & 2)
407                 ent.team = NUM_TEAM_1;
408         else if (ent.spawnflags & 4)
409                 ent.team = NUM_TEAM_2;
410
411         STAT(BUFFS, ent) = replacement.m_itemid;
412
413         buff_Init(ent);
414 }
415
416 void buff_SpawnReplacement(entity ent, entity old)
417 {
418         setorigin(ent, old.origin);
419         ent.angles = old.angles;
420         ent.noalign = Item_ShouldKeepPosition(old);
421
422         buff_Init(ent);
423 }
424
425 void buff_Vengeance_DelayedDamage(entity this)
426 {
427         if(this.enemy)
428                 Damage(this.enemy, this.owner, this.owner, this.dmg, DEATH_BUFF.m_id, DMG_NOWEP, this.enemy.origin, '0 0 0');
429
430         delete(this);
431         return;
432 }
433
434 // note: only really useful in teamplay
435 void buff_Medic_Heal(entity this)
436 {
437         FOREACH_CLIENT(IS_PLAYER(it) && it != this && vdist(it.origin - this.origin, <=, autocvar_g_buffs_medic_heal_range),
438         {
439                 if (DIFF_TEAM(it, this))
440                 {
441                         continue;
442                 }
443                 float hp = GetResource(it, RES_HEALTH);
444                 if(hp >= autocvar_g_balance_health_regenstable)
445                 {
446                         continue;
447                 }
448                 Send_Effect(EFFECT_HEALING, it.origin, '0 0 0', 1);
449                 SetResource(it, RES_HEALTH, bound(0, hp + autocvar_g_buffs_medic_heal_amount, autocvar_g_balance_health_regenstable));
450         });
451 }
452
453 float buff_Inferno_CalculateTime(float damg, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
454 {
455         return offset_y + (intersect_y - offset_y) * logn(((damg - offset_x) * ((base - 1) / intersect_x)) + 1, base);
456 }
457
458 // mutator hooks
459 MUTATOR_HOOKFUNCTION(buffs, Damage_Calculate)
460 {
461         entity frag_attacker = M_ARGV(1, entity);
462         entity frag_target = M_ARGV(2, entity);
463         float frag_deathtype = M_ARGV(3, float);
464         float frag_damage = M_ARGV(4, float);
465         vector frag_force = M_ARGV(6, vector);
466
467         if(frag_deathtype == DEATH_BUFF.m_id) { return; }
468
469         if(STAT(BUFFS, frag_target) & BUFF_RESISTANCE.m_itemid)
470         {
471                 float reduced = frag_damage * autocvar_g_buffs_resistance_blockpercent;
472                 frag_damage = bound(0, frag_damage - reduced, frag_damage);
473         }
474
475         if(STAT(BUFFS, frag_target) & BUFF_SPEED.m_itemid)
476         if(frag_target != frag_attacker)
477                 frag_damage *= autocvar_g_buffs_speed_damage_take;
478
479         if(STAT(BUFFS, frag_target) & BUFF_MEDIC.m_itemid)
480         if((GetResource(frag_target, RES_HEALTH) - frag_damage) <= 0)
481         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
482         if(frag_attacker)
483         if(random() <= autocvar_g_buffs_medic_survive_chance)
484                 frag_damage = max(5, GetResource(frag_target, RES_HEALTH) - autocvar_g_buffs_medic_survive_health);
485
486         if(STAT(BUFFS, frag_target) & BUFF_JUMP.m_itemid)
487         if(frag_deathtype == DEATH_FALL.m_id)
488                 frag_damage = 0;
489
490         if(STAT(BUFFS, frag_target) & BUFF_VENGEANCE.m_itemid)
491         if(frag_attacker)
492         if(frag_attacker != frag_target)
493         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
494         {
495                 entity dmgent = spawn();
496
497                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
498                 dmgent.enemy = frag_attacker;
499                 dmgent.owner = frag_target;
500                 setthink(dmgent, buff_Vengeance_DelayedDamage);
501                 dmgent.nextthink = time + 0.1;
502         }
503
504         if(STAT(BUFFS, frag_target) & BUFF_BASH.m_itemid)
505         if(frag_attacker != frag_target)
506                 frag_force = '0 0 0';
507
508         if(STAT(BUFFS, frag_attacker) & BUFF_BASH.m_itemid)
509         if(frag_force)
510         {
511                 if(frag_attacker == frag_target)
512                         frag_force *= autocvar_g_buffs_bash_force_self;
513                 else
514                         frag_force *= autocvar_g_buffs_bash_force;
515         }
516
517         if(STAT(BUFFS, frag_attacker) & BUFF_DISABILITY.m_itemid)
518         if(frag_target != frag_attacker)
519                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
520
521         if(STAT(BUFFS, frag_target) & BUFF_INFERNO.m_itemid)
522         {
523                 if(frag_deathtype == DEATH_FIRE.m_id)
524                         frag_damage = 0;
525                 if(frag_deathtype == DEATH_LAVA.m_id)
526                         frag_damage *= 0.5; // TODO: cvarize?
527         }
528
529         if(STAT(BUFFS, frag_attacker) & BUFF_LUCK.m_itemid)
530         if(frag_attacker != frag_target)
531         if(autocvar_g_buffs_luck_damagemultiplier > 0)
532         if(random() <= autocvar_g_buffs_luck_chance)
533                 frag_damage *= autocvar_g_buffs_luck_damagemultiplier;
534
535         if(STAT(BUFFS, frag_attacker) & BUFF_INFERNO.m_itemid)
536         if(frag_target != frag_attacker) {
537                 float btime = buff_Inferno_CalculateTime(
538                         frag_damage,
539                         0,
540                         autocvar_g_buffs_inferno_burntime_min_time,
541                         autocvar_g_buffs_inferno_burntime_target_damage,
542                         autocvar_g_buffs_inferno_burntime_target_time,
543                         autocvar_g_buffs_inferno_burntime_factor
544                 );
545                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier), btime, DEATH_BUFF.m_id);
546         }
547
548         // this... is ridiculous (TODO: fix!)
549         if(STAT(BUFFS, frag_attacker) & BUFF_VAMPIRE.m_itemid)
550         if(!frag_target.vehicle)
551         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
552         if(!IS_DEAD(frag_target))
553         if(IS_PLAYER(frag_target) || IS_MONSTER(frag_target))
554         if(frag_attacker != frag_target)
555         if(!STAT(FROZEN, frag_target))
556         if(frag_target.takedamage)
557         if(DIFF_TEAM(frag_attacker, frag_target))
558         {
559                 float amount = bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal,
560                         GetResource(frag_target, RES_HEALTH));
561                 GiveResourceWithLimit(frag_attacker, RES_HEALTH, amount, g_pickup_healthsmall_max);
562                 if (GetResource(frag_target, RES_ARMOR))
563                 {
564                         amount = bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal,
565                                 GetResource(frag_target, RES_ARMOR));
566                         GiveResourceWithLimit(frag_attacker, RES_ARMOR, amount, g_pickup_armorsmall_max);
567                 }
568         }
569
570         M_ARGV(4, float) = frag_damage;
571         M_ARGV(6, vector) = frag_force;
572 }
573
574 MUTATOR_HOOKFUNCTION(buffs, PlayerSpawn)
575 {
576         entity player = M_ARGV(0, entity);
577
578         player.oldbuffs = 0;
579         PS(player).buff_shield = time + 0.5; // prevent picking up buffs immediately
580         // reset timers here to prevent them continuing after re-spawn
581         player.buff_disability_time = 0;
582         player.buff_disability_effect_time = 0;
583 }
584
585 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics_UpdateStats)
586 {
587         entity player = M_ARGV(0, entity);
588         // these automatically reset, no need to worry
589
590         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
591                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_buffs_speed_speed;
592
593         if(time < player.buff_disability_time)
594                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_buffs_disability_speed;
595 }
596
597 MUTATOR_HOOKFUNCTION(buffs, PlayerPhysics)
598 {
599         entity player = M_ARGV(0, entity);
600         // these automatically reset, no need to worry
601
602         if(STAT(BUFFS, player) & BUFF_JUMP.m_itemid)
603                 STAT(MOVEVARS_JUMPVELOCITY, player) = autocvar_g_buffs_jump_height;
604 }
605
606 MUTATOR_HOOKFUNCTION(buffs, MonsterMove)
607 {
608         entity mon = M_ARGV(0, entity);
609
610         if(time < mon.buff_disability_time)
611         {
612                 M_ARGV(1, float) *= autocvar_g_buffs_disability_speed; // run speed
613                 M_ARGV(2, float) *= autocvar_g_buffs_disability_speed; // walk speed
614         }
615 }
616
617 MUTATOR_HOOKFUNCTION(buffs, PlayerDies)
618 {
619         entity frag_target = M_ARGV(2, entity);
620
621         if(STAT(BUFFS, frag_target))
622         {
623                 int buffid = buff_FirstFromFlags(STAT(BUFFS, frag_target)).m_id;
624                 if(!IS_INDEPENDENT_PLAYER(frag_target))
625                         Send_Notification(NOTIF_ALL_EXCEPT, frag_target, MSG_INFO, INFO_ITEM_BUFF_LOST, frag_target.netname, buffid);
626                 STAT(BUFFS, frag_target) = 0;
627                 STAT(BUFF_TIME, frag_target) = 0;
628
629                 if(frag_target.buff_model)
630                 {
631                         delete(frag_target.buff_model);
632                         frag_target.buff_model = NULL;
633                 }
634         }
635 }
636
637 MUTATOR_HOOKFUNCTION(buffs, PlayerUseKey, CBC_ORDER_FIRST)
638 {
639         if(MUTATOR_RETURNVALUE || game_stopped || !autocvar_g_buffs_drop) return;
640
641         entity player = M_ARGV(0, entity);
642
643         if(STAT(BUFFS, player))
644         {
645                 int buffid = buff_FirstFromFlags(STAT(BUFFS, player)).m_id;
646                 Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid);
647                 if(!IS_INDEPENDENT_PLAYER(player))
648                         Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
649
650                 STAT(BUFFS, player) = 0;
651                 STAT(BUFF_TIME, player) = 0;
652                 PS(player).buff_shield = time + max(0, autocvar_g_buffs_pickup_delay);
653                 sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
654                 return true;
655         }
656 }
657
658 MUTATOR_HOOKFUNCTION(buffs, ForbidThrowCurrentWeapon)
659 {
660         if(MUTATOR_RETURNVALUE || game_stopped) return;
661         entity player = M_ARGV(0, entity);
662
663         if(STAT(BUFFS, player) & BUFF_SWAPPER.m_itemid)
664         {
665                 float best_distance = autocvar_g_buffs_swapper_range;
666                 entity closest = NULL;
667                 FOREACH_CLIENT(IS_PLAYER(it), {
668                         if(!IS_DEAD(it) && !STAT(FROZEN, it) && !it.vehicle)
669                         if(DIFF_TEAM(it, player))
670                         {
671                                 float test = vlen2(player.origin - it.origin);
672                                 if(test <= best_distance * best_distance)
673                                 {
674                                         best_distance = sqrt(test);
675                                         closest = it;
676                                 }
677                         }
678                 });
679
680                 if(closest)
681                 {
682                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
683
684                         my_org = player.origin;
685                         my_vel = player.velocity;
686                         my_ang = player.angles;
687                         their_org = closest.origin;
688                         their_vel = closest.velocity;
689                         their_ang = closest.angles;
690
691                         Drop_Special_Items(closest);
692
693                         MUTATOR_CALLHOOK(PortalTeleport, player); // initiate flag dropper
694
695                         setorigin(player, their_org);
696                         setorigin(closest, my_org);
697
698                         closest.velocity = my_vel;
699                         closest.angles = my_ang;
700                         if (IS_BOT_CLIENT(closest))
701                         {
702                                 closest.v_angle = closest.angles;
703                                 bot_aim_reset(closest);
704                         }
705                         closest.fixangle = true;
706                         closest.oldorigin = my_org;
707                         closest.oldvelocity = my_vel;
708                         player.velocity = their_vel;
709                         player.angles = their_ang;
710                         if (IS_BOT_CLIENT(player))
711                         {
712                                 player.v_angle = player.angles;
713                                 bot_aim_reset(player);
714                         }
715                         player.fixangle = true;
716                         player.oldorigin = their_org;
717                         player.oldvelocity = their_vel;
718
719                         // set pusher so player gets the kill if they fall into void
720                         closest.pusher = player;
721                         closest.pushltime = time + autocvar_g_maxpushtime;
722                         closest.istypefrag = PHYS_INPUT_BUTTON_CHAT(closest);
723
724                         Send_Effect(EFFECT_ELECTRO_COMBO, their_org, '0 0 0', 1);
725                         Send_Effect(EFFECT_ELECTRO_COMBO, my_org, '0 0 0', 1);
726
727                         sound(player, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
728                         sound(closest, CH_TRIGGER, SND_KA_RESPAWN, VOL_BASE, ATTEN_NORM);
729
730                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
731                         STAT(BUFFS, player) = 0;
732                         return true;
733                 }
734         }
735 }
736
737 bool buffs_RemovePlayer(entity player)
738 {
739         if(player.buff_model)
740         {
741                 delete(player.buff_model);
742                 player.buff_model = NULL;
743         }
744
745         // also reset timers here to prevent them continuing after spectating
746         player.buff_disability_time = 0;
747         player.buff_disability_effect_time = 0;
748
749         return false;
750 }
751 MUTATOR_HOOKFUNCTION(buffs, MakePlayerObserver) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
752 MUTATOR_HOOKFUNCTION(buffs, ClientDisconnect) { entity player = M_ARGV(0, entity); return buffs_RemovePlayer(player); }
753
754 MUTATOR_HOOKFUNCTION(buffs, CustomizeWaypoint)
755 {
756         entity wp = M_ARGV(0, entity);
757         entity player = M_ARGV(1, entity);
758
759         entity e = WaypointSprite_getviewentity(player);
760
761         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
762         // but only apply this to real players, not to spectators
763         if((wp.owner.flags & FL_CLIENT) && (STAT(BUFFS, wp.owner) & BUFF_INVISIBLE.m_itemid) && (e == player))
764         if(DIFF_TEAM(wp.owner, e))
765                 return true;
766 }
767
768 MUTATOR_HOOKFUNCTION(buffs, FilterItem)
769 {
770         if(autocvar_g_buffs < 0)
771                 return false; // no auto replacing of entities in this mode
772
773         entity item = M_ARGV(0, entity);
774
775         if(autocvar_g_buffs_replace_powerups)
776         {
777                 switch(item.classname)
778                 {
779                         case "item_strength":
780                         case "item_shield":
781                         {
782                                 entity e = spawn();
783                                 buff_SpawnReplacement(e, item);
784                                 return true;
785                         }
786                 }
787         }
788
789         return false;
790 }
791
792 MUTATOR_HOOKFUNCTION(buffs, WeaponRateFactor)
793 {
794         entity player = M_ARGV(1, entity);
795
796         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
797                 M_ARGV(0, float) *= autocvar_g_buffs_speed_rate;
798
799         if(time < player.buff_disability_time)
800                 M_ARGV(0, float) *= autocvar_g_buffs_disability_rate;
801 }
802
803 MUTATOR_HOOKFUNCTION(buffs, WeaponSpeedFactor)
804 {
805         entity player = M_ARGV(1, entity);
806
807         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
808                 M_ARGV(0, float) *= autocvar_g_buffs_speed_weaponspeed;
809
810         if(time < player.buff_disability_time)
811                 M_ARGV(0, float) *= autocvar_g_buffs_disability_weaponspeed;
812 }
813
814 .bool buff_flight_crouchheld;
815
816 MUTATOR_HOOKFUNCTION(buffs, PlayerPreThink)
817 {
818         entity player = M_ARGV(0, entity);
819
820         if(game_stopped || IS_DEAD(player) || frametime || !IS_PLAYER(player)) return;
821
822         if(STAT(BUFFS, player) & BUFF_FLIGHT.m_itemid)
823         {
824                 if(!PHYS_INPUT_BUTTON_CROUCH(player))
825                         player.buff_flight_crouchheld = false;
826                 else if(!player.buff_flight_crouchheld)
827                 {
828                         player.buff_flight_crouchheld = true;
829                         player.gravity *= -1;
830                 }
831         }
832
833         if(time < player.buff_disability_time)
834         if(time >= player.buff_disability_effect_time)
835         {
836                 Send_Effect(EFFECT_SMOKING, player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
837                 player.buff_disability_effect_time = time + 0.5;
838         }
839
840         // handle buff lost status
841         // 1: notify everyone else
842         // 2: notify carrier as well
843         int buff_lost = 0;
844
845         if(STAT(BUFF_TIME, player) && STAT(BUFFS, player))
846         if(time >= STAT(BUFF_TIME, player))
847         {
848                 STAT(BUFF_TIME, player) = 0;
849                 buff_lost = 2;
850         }
851
852         if(STAT(FROZEN, player)) { buff_lost = 1; }
853
854         if(buff_lost)
855         {
856                 if(STAT(BUFFS, player))
857                 {
858                         int buffid = buff_FirstFromFlags(STAT(BUFFS, player)).m_id;
859                         if(buff_lost == 2)
860                         {
861                                 Send_Notification(NOTIF_ONE, player, MSG_MULTI, ITEM_BUFF_DROP, buffid); // TODO: special timeout message?
862                                 sound(player, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
863                         }
864                         else if(!IS_INDEPENDENT_PLAYER(player))
865                                 Send_Notification(NOTIF_ALL_EXCEPT, player, MSG_INFO, INFO_ITEM_BUFF_LOST, player.netname, buffid);
866                         STAT(BUFFS, player) = 0;
867                         PS(player).buff_shield = time + max(0, autocvar_g_buffs_pickup_delay); // always put in a delay, even if small
868                 }
869         }
870
871         if(STAT(BUFFS, player) & BUFF_MAGNET.m_itemid)
872         {
873                 vector pickup_size;
874                 IL_EACH(g_items, it.itemdef,
875                 {
876                         if(STAT(BUFFS, it))
877                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_buff;
878                         else
879                                 pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
880
881                         if(boxesoverlap(player.absmin - pickup_size, player.absmax + pickup_size, it.absmin, it.absmax))
882                         {
883                                 if(gettouch(it))
884                                         gettouch(it)(it, player);
885                         }
886                 });
887         }
888
889         if(STAT(BUFFS, player) & BUFF_AMMO.m_itemid)
890         {
891                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
892                 {
893                         .entity weaponentity = weaponentities[slot];
894                         if(player.(weaponentity).clip_size)
895                                 player.(weaponentity).clip_load = player.(weaponentity).(weapon_load[player.(weaponentity).m_switchweapon.m_id]) = player.(weaponentity).clip_size;
896                 }
897         }
898
899         if((STAT(BUFFS, player) & BUFF_INVISIBLE.m_itemid) && (player.oldbuffs & BUFF_INVISIBLE.m_itemid))
900                 player.alpha = ((autocvar_g_buffs_invisible_alpha) ? autocvar_g_buffs_invisible_alpha : -1); // powerups reset alpha, so we must enforce this (TODO)
901
902         if(STAT(BUFFS, player) & BUFF_MEDIC.m_itemid)
903         if(time >= player.buff_medic_healtime)
904         {
905                 buff_Medic_Heal(player);
906                 player.buff_medic_healtime = time + autocvar_g_buffs_medic_heal_delay;
907         }
908
909 #define BUFF_ONADD(b) if ( (STAT(BUFFS, player) & (b).m_itemid) && !(player.oldbuffs & (b).m_itemid))
910 #define BUFF_ONREM(b) if (!(STAT(BUFFS, player) & (b).m_itemid) &&  (player.oldbuffs & (b).m_itemid))
911
912         if(STAT(BUFFS, player) != player.oldbuffs)
913         {
914                 entity buff = buff_FirstFromFlags(STAT(BUFFS, player));
915                 float bufftime = buff != BUFF_Null ? buff.m_time(buff) : 0;
916                 if(STAT(BUFF_TIME, player) <= time) // if the player still has a buff countdown, don't reset it!
917                         STAT(BUFF_TIME, player) = (bufftime) ? time + bufftime : 0;
918
919                 BUFF_ONADD(BUFF_AMMO)
920                 {
921                         player.buff_ammo_prev_infitems = (player.items & IT_UNLIMITED_AMMO);
922                         player.items |= IT_UNLIMITED_AMMO;
923
924                         if(STAT(BUFFS, player) & BUFF_AMMO.m_itemid)
925                         {
926                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
927                                 {
928                                         .entity weaponentity = weaponentities[slot];
929                                         if(player.(weaponentity).clip_load)
930                                                 player.(weaponentity).buff_ammo_prev_clipload = player.(weaponentity).clip_load;
931                                         if(player.(weaponentity).clip_size)
932                                                 player.(weaponentity).clip_load = player.(weaponentity).(weapon_load[player.(weaponentity).m_switchweapon.m_id]) = player.(weaponentity).clip_size;
933                                 }
934                         }
935                 }
936
937                 BUFF_ONREM(BUFF_AMMO)
938                 {
939                         if(player.buff_ammo_prev_infitems)
940                                 player.items |= IT_UNLIMITED_AMMO;
941                         else
942                                 player.items &= ~IT_UNLIMITED_AMMO;
943
944                         if(STAT(BUFFS, player) & BUFF_AMMO.m_itemid)
945                         {
946                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
947                                 {
948                                         .entity weaponentity = weaponentities[slot];
949                                         if(player.(weaponentity).buff_ammo_prev_clipload)
950                                                 player.(weaponentity).clip_load = player.(weaponentity).buff_ammo_prev_clipload;
951                                 }
952                         }
953                 }
954
955                 BUFF_ONADD(BUFF_INVISIBLE)
956                 {
957                         if(time < player.strength_finished && MUTATOR_IS_ENABLED(mutator_instagib))
958                                 player.buff_invisible_prev_alpha = default_player_alpha; // we don't want to save the powerup's alpha, as player may lose the powerup while holding the buff
959                         else
960                                 player.buff_invisible_prev_alpha = player.alpha;
961                         player.alpha = autocvar_g_buffs_invisible_alpha;
962                 }
963
964                 BUFF_ONREM(BUFF_INVISIBLE)
965                 {
966                         if(time < player.strength_finished && MUTATOR_IS_ENABLED(mutator_instagib))
967                                 player.alpha = autocvar_g_instagib_invis_alpha;
968                         else
969                                 player.alpha = player.buff_invisible_prev_alpha;
970                 }
971
972                 BUFF_ONADD(BUFF_FLIGHT)
973                 {
974                         player.buff_flight_oldgravity = player.gravity;
975                         if(!player.gravity)
976                                 player.gravity = 1;
977                 }
978
979                 BUFF_ONREM(BUFF_FLIGHT)
980                         player.gravity = ((player.trigger_gravity_check) ? player.trigger_gravity_check.enemy.gravity : player.buff_flight_oldgravity);
981
982                 player.oldbuffs = STAT(BUFFS, player);
983                 if(STAT(BUFFS, player))
984                 {
985                         if(!player.buff_model)
986                                 buffs_BuffModel_Spawn(player);
987
988                         player.buff_model.color = buff.m_color;
989                         player.buff_model.glowmod = buff_GlowColor(player.buff_model);
990                         player.buff_model.skin = buff.m_skin;
991
992                         player.effects |= EF_NOSHADOW;
993                 }
994                 else
995                 {
996                         if(player.buff_model)
997                                 delete(player.buff_model);
998                         player.buff_model = NULL;
999
1000                         player.effects &= ~(EF_NOSHADOW);
1001                 }
1002         }
1003
1004         if(player.buff_model)
1005         {
1006                 player.buff_model.effects = player.effects;
1007                 player.buff_model.effects |= EF_LOWPRECISION;
1008                 player.buff_model.effects = player.buff_model.effects & EFMASK_CHEAP; // eat performance
1009
1010                 player.buff_model.alpha = player.alpha;
1011         }
1012
1013 #undef BUFF_ONADD
1014 #undef BUFF_ONREM
1015 }
1016
1017 MUTATOR_HOOKFUNCTION(buffs, SpectateCopy)
1018 {
1019         entity spectatee = M_ARGV(0, entity);
1020         entity client = M_ARGV(1, entity);
1021
1022         STAT(BUFFS, client) = STAT(BUFFS, spectatee);
1023         STAT(BUFF_TIME, client) = STAT(BUFF_TIME, spectatee);
1024 }
1025
1026 MUTATOR_HOOKFUNCTION(buffs, PlayerRegen)
1027 {
1028         entity player = M_ARGV(0, entity);
1029
1030         if(STAT(BUFFS, player) & BUFF_MEDIC.m_itemid)
1031         {
1032                 M_ARGV(2, float) = autocvar_g_buffs_medic_rot; // rot_mod
1033                 M_ARGV(4, float) = M_ARGV(1, float) = autocvar_g_buffs_medic_max; // limit_mod = max_mod
1034                 M_ARGV(2, float) = autocvar_g_buffs_medic_regen; // regen_mod
1035         }
1036
1037         if(STAT(BUFFS, player) & BUFF_SPEED.m_itemid)
1038                 M_ARGV(2, float) = autocvar_g_buffs_speed_regen; // regen_mod
1039 }
1040
1041 REPLICATE(cvar_cl_buffs_autoreplace, bool, "cl_buffs_autoreplace");
1042
1043 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsString)
1044 {
1045         if(autocvar_g_buffs > 0) // only report as a mutator if they're enabled
1046                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Buffs");
1047 }
1048
1049 MUTATOR_HOOKFUNCTION(buffs, BuildMutatorsPrettyString)
1050 {
1051         if(autocvar_g_buffs > 0)
1052                 M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Buffs");
1053 }
1054
1055 void buffs_DelayedInit(entity this)
1056 {
1057         if(autocvar_g_buffs_spawn_count > 0)
1058         if(find(NULL, classname, "item_buff") == NULL)
1059         {
1060                 float i;
1061                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
1062                 {
1063                         entity e = spawn();
1064                         e.spawnflags |= 64; // always randomize
1065                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
1066                         buff_Init(e);
1067                 }
1068         }
1069 }