qcsrc/common/mutators/mutator/campcheck/sv_campcheck.qc

   1 #include "sv_campcheck.qh"
   2
   3 string autocvar_g_campcheck;
   4 float autocvar_g_campcheck_damage;
   5 float autocvar_g_campcheck_distance;
   6 float autocvar_g_campcheck_interval;
   7 bool autocvar_g_campcheck_typecheck;
   8
   9 REGISTER_MUTATOR(campcheck, expr_evaluate(autocvar_g_campcheck));
  10
  11 .float campcheck_nextcheck;
  12 .float campcheck_traveled_distance;
  13
  14 .vector campcheck_prevorigin;
  15
  16 MUTATOR_HOOKFUNCTION(campcheck, PlayerDies)
  17 {
  18         entity frag_target = M_ARGV(2, entity);
  19
  20         Kill_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CPID_CAMPCHECK);
  21 }
  22
  23 MUTATOR_HOOKFUNCTION(campcheck, Damage_Calculate)
  24 {
  25         entity frag_attacker = M_ARGV(1, entity);
  26         entity frag_target = M_ARGV(2, entity);
  27
  28         if(IS_PLAYER(frag_target))
  29         if(IS_PLAYER(frag_attacker))
  30         if(frag_attacker != frag_target)
  31         {
  32                 frag_target.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  33                 frag_attacker.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  34         }
  35 }
  36
  37 MUTATOR_HOOKFUNCTION(campcheck, PlayerPreThink)
  38 {
  39         entity player = M_ARGV(0, entity);
  40         bool checked = false;
  41
  42         if(autocvar_g_campcheck_interval)
  43         if(!game_stopped && !warmup_stage && time >= game_starttime)
  44         if(IS_PLAYER(player))
  45         if(!IS_DEAD(player))
  46         if(!STAT(FROZEN, player))
  47         if(autocvar_g_campcheck_typecheck || !PHYS_INPUT_BUTTON_CHAT(player))
  48         if(IS_REAL_CLIENT(player)) // bots may camp, but that's no reason to constantly kill them
  49         if(!weaponLocked(player))
  50         {
  51                 // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
  52                 vector dist = vec2(player.campcheck_prevorigin - player.origin);
  53                 player.campcheck_traveled_distance += fabs(vlen(dist));
  54
  55                 if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime) || (round_handler_IsActive() && !round_handler_IsRoundStarted()))
  56                 {
  57                         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  58                         player.campcheck_traveled_distance = 0;
  59                 }
  60
  61                 if(time > player.campcheck_nextcheck)
  62                 {
  63                         if(player.campcheck_traveled_distance < autocvar_g_campcheck_distance)
  64                         {
  65                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_CAMPCHECK);
  66                                 if(player.vehicle)
  67                                         Damage(player.vehicle, NULL, NULL, autocvar_g_campcheck_damage * 2, DEATH_CAMP.m_id, DMG_NOWEP, player.vehicle.origin, '0 0 0');
  68                                 else
  69                                         Damage(player, NULL, NULL, bound(0, autocvar_g_campcheck_damage, GetResource(player, RES_HEALTH) + GetResource(player, RES_ARMOR) * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP.m_id, DMG_NOWEP, player.origin, '0 0 0');
  70                         }
  71                         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval;
  72                         player.campcheck_traveled_distance = 0;
  73                 }
  74
  75                 checked = true;
  76         }
  77
  78         if(!checked)
  79                 player.campcheck_nextcheck = time + autocvar_g_campcheck_interval; // one of the above checks failed, so keep the timer up to date
  80
  81         player.campcheck_prevorigin = player.origin;
  82 }
  83
  84 MUTATOR_HOOKFUNCTION(campcheck, CopyBody)
  85 {
  86         entity player = M_ARGV(0, entity);
  87         entity clone = M_ARGV(1, entity);
  88
  89         clone.campcheck_prevorigin = player.campcheck_prevorigin;
  90 }
  91
  92 MUTATOR_HOOKFUNCTION(campcheck, PlayerSpawn)
  93 {
  94         entity player = M_ARGV(0, entity);
  95
  96         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  97         player.campcheck_traveled_distance = 0;
  98 }
  99
 100 MUTATOR_HOOKFUNCTION(campcheck, BuildMutatorsString)
 101 {
 102         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":CampCheck");
 103 }