qcsrc/common/mutators/mutator/campcheck/sv_campcheck.qc

   1 #include "sv_campcheck.qh"
   2
   3 float autocvar_g_campcheck_damage;
   4 float autocvar_g_campcheck_distance;
   5 float autocvar_g_campcheck_interval;
   6
   7 REGISTER_MUTATOR(campcheck, cvar("g_campcheck"));
   8
   9 .float campcheck_nextcheck;
  10 .float campcheck_traveled_distance;
  11
  12 .vector campcheck_prevorigin;
  13
  14 MUTATOR_HOOKFUNCTION(campcheck, PlayerDies)
  15 {
  16         entity frag_target = M_ARGV(2, entity);
  17
  18         Kill_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CPID_CAMPCHECK);
  19 }
  20
  21 MUTATOR_HOOKFUNCTION(campcheck, Damage_Calculate)
  22 {
  23         entity frag_attacker = M_ARGV(1, entity);
  24         entity frag_target = M_ARGV(2, entity);
  25
  26         if(IS_PLAYER(frag_target))
  27         if(IS_PLAYER(frag_attacker))
  28         if(frag_attacker != frag_target)
  29         {
  30                 frag_target.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  31                 frag_attacker.campcheck_traveled_distance = autocvar_g_campcheck_distance;
  32         }
  33 }
  34
  35 MUTATOR_HOOKFUNCTION(campcheck, PlayerPreThink)
  36 {
  37         entity player = M_ARGV(0, entity);
  38         bool checked = false;
  39
  40         if(autocvar_g_campcheck_interval)
  41         if(!game_stopped && !warmup_stage && time >= game_starttime)
  42         if(IS_PLAYER(player))
  43         if(!IS_DEAD(player))
  44         if(!STAT(FROZEN, player))
  45         if(!PHYS_INPUT_BUTTON_CHAT(player))
  46         if(IS_REAL_CLIENT(player)) // bots may camp, but that's no reason to constantly kill them
  47         if(!forbidWeaponUse(player))
  48         {
  49                 // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
  50                 vector dist = vec2(player.campcheck_prevorigin - player.origin);
  51                 player.campcheck_traveled_distance += fabs(vlen(dist));
  52
  53                 if((autocvar_g_campaign && !campaign_bots_may_start) || (time < game_starttime) || (round_handler_IsActive() && !round_handler_IsRoundStarted()))
  54                 {
  55                         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  56                         player.campcheck_traveled_distance = 0;
  57                 }
  58
  59                 if(time > player.campcheck_nextcheck)
  60                 {
  61                         if(player.campcheck_traveled_distance < autocvar_g_campcheck_distance)
  62                         {
  63                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_CAMPCHECK);
  64                                 if(player.vehicle)
  65                                         Damage(player.vehicle, NULL, NULL, autocvar_g_campcheck_damage * 2, DEATH_CAMP.m_id, player.vehicle.origin, '0 0 0');
  66                                 else
  67                                         Damage(player, NULL, NULL, bound(0, autocvar_g_campcheck_damage, GetResourceAmount(player, RESOURCE_HEALTH) + GetResourceAmount(player, RESOURCE_ARMOR) * autocvar_g_balance_armor_blockpercent + 5), DEATH_CAMP.m_id, player.origin, '0 0 0');
  68                         }
  69                         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval;
  70                         player.campcheck_traveled_distance = 0;
  71                 }
  72
  73                 checked = true;
  74         }
  75
  76         if(!checked)
  77                 player.campcheck_nextcheck = time + autocvar_g_campcheck_interval; // one of the above checks failed, so keep the timer up to date
  78
  79         player.campcheck_prevorigin = player.origin;
  80 }
  81
  82 MUTATOR_HOOKFUNCTION(campcheck, CopyBody)
  83 {
  84         entity player = M_ARGV(0, entity);
  85         entity clone = M_ARGV(1, entity);
  86
  87         clone.campcheck_prevorigin = player.campcheck_prevorigin;
  88 }
  89
  90 MUTATOR_HOOKFUNCTION(campcheck, PlayerSpawn)
  91 {
  92         entity player = M_ARGV(0, entity);
  93
  94         player.campcheck_nextcheck = time + autocvar_g_campcheck_interval * 2;
  95         player.campcheck_traveled_distance = 0;
  96 }
  97
  98 MUTATOR_HOOKFUNCTION(campcheck, BuildMutatorsString)
  99 {
 100         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":CampCheck");
 101 }