qcsrc/common/mutators/mutator/damagetext.qc

   1 REGISTER_MUTATOR(damagetext, true);
   2
   3 #if defined(CSQC) || defined(MENUQC)
   4 AUTOCVAR_SAVE(cl_damagetext,                    bool,   false,      _("Draw damage dealt. 0: disabled, 1: enabled"));
   5 AUTOCVAR_SAVE(cl_damagetext_format,             string, "-%3$d",    _("How to format the damage text. 1$ is health, 2$ is armor, 3$ is both"));
   6 AUTOCVAR_SAVE(cl_damagetext_color,              vector, '1 1 0',    _("Default damage text color"));
   7 AUTOCVAR_SAVE(cl_damagetext_size,               float,  8,          _("Damage text font size"));
   8 AUTOCVAR_SAVE(cl_damagetext_alpha_start,        float,  1,          _("Damage text initial alpha"));
   9 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,     float,  3,          _("Damage text lifetime in seconds"));
  10 AUTOCVAR_SAVE(cl_damagetext_velocity,           vector, '0 0 20',   _("Damage text move direction"));
  11 AUTOCVAR_SAVE(cl_damagetext_offset,             vector, '0 -40 0',  _("Damage text offset"));
  12 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,   float,  30,         _("Damage text spawned within this range is accumulated"));
  13 #endif
  14
  15 #ifdef CSQC
  16 CLASS(DamageText, Object)
  17     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color)
  18     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size)
  19     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start)
  20     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime)
  21     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity)
  22     ATTRIB(DamageText, m_group, int, 0)
  23     ATTRIB(DamageText, m_damage, int, 0)
  24     ATTRIB(DamageText, m_armordamage, int, 0)
  25     ATTRIB(DamageText, time_prev, float, time)
  26
  27     void DamageText_draw2d(DamageText this) {
  28         float dt = time - this.time_prev;
  29         this.time_prev = time;
  30         setorigin(this, this.origin + dt * this.velocity);
  31         this.alpha -= dt * this.fade_rate;
  32         if (this.alpha < 0) remove(this);
  33         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  34         if (pos.z >= 0 && this.m_size > 0) {
  35             pos.z = 0;
  36             string s = sprintf(autocvar_cl_damagetext_format, this.m_damage, this.m_armordamage, this.m_damage + this.m_armordamage);
  37             drawcolorcodedstring2(pos, s, this.m_size * '1 1 0', this.m_color, this.alpha, DRAWFLAG_NORMAL);
  38         }
  39     }
  40     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d)
  41
  42     void DamageText_update(DamageText this, vector _origin, int _health, int _armor) {
  43         this.m_damage = _health;
  44         this.m_armordamage = _armor;
  45         setorigin(this, _origin);
  46         this.alpha = 1;
  47     }
  48
  49     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor) {
  50         CONSTRUCT(DamageText);
  51         this.m_group = _group;
  52         DamageText_update(this, _origin, _health, _armor);
  53     }
  54 ENDCLASS(DamageText)
  55 #endif
  56
  57 #ifdef SVQC
  58 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
  59 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  60 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
  61 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
  62 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
  63 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
  64     if (SV_DAMAGETEXT_DISABLED()) return;
  65     const entity attacker = mutator_argv_entity_0;
  66     const entity hit = mutator_argv_entity_1; if (hit == attacker) return;
  67     const int health = mutator_argv_int_0;
  68     const int armor = mutator_argv_int_1;
  69     const vector location = hit.origin;
  70     entity e;
  71     FOR_EACH_REALCLIENT(e) if (
  72         (SV_DAMAGETEXT_ALL()) ||
  73         (SV_DAMAGETEXT_PLAYERS() && e == attacker) ||
  74         (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(e) && e.enemy == attacker) ||
  75         (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(e))
  76     ) {
  77         msg_entity = e;
  78         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  79         WriteMutator(MSG_ONE, damagetext);
  80         WriteShort(MSG_ONE, health);
  81         WriteShort(MSG_ONE, armor);
  82         WriteEntity(MSG_ONE, hit);
  83         WriteCoord(MSG_ONE, location.x);
  84         WriteCoord(MSG_ONE, location.y);
  85         WriteCoord(MSG_ONE, location.z);
  86     }
  87 }
  88 #endif
  89
  90 #ifdef CSQC
  91 MUTATOR_HOOKFUNCTION(damagetext, CSQC_Parse_TempEntity) {
  92     if (MUTATOR_RETURNVALUE) return false;
  93     if (!ReadMutatorEquals(mutator_argv_int_0, damagetext)) return false;
  94     int health = ReadShort();
  95     int armor = ReadShort();
  96     int group = ReadShort();
  97     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
  98     if (autocvar_cl_damagetext) {
  99         if (autocvar_cl_damagetext_accumulate_range) {
 100             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 101                 if (e.instanceOfDamageText && e.m_group == group) {
 102                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor);
 103                     return true;
 104                 }
 105             }
 106         }
 107         NEW(DamageText, group, location, health, armor);
 108     }
 109     return true;
 110 }
 111 #endif
 112
 113 #ifdef MENUQC
 114 #include "../../../menu/xonotic/tab.qc"
 115 CLASS(XonoticDamageTextSettings, XonoticTab)
 116     #include "../../../menu/gamesettings.qh"
 117     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 118     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"))
 119     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9)
 120     ATTRIB(XonoticDamageTextSettings, rows, float, 13)
 121     ATTRIB(XonoticDamageTextSettings, columns, float, 5)
 122     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 123     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 124     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 125     {
 126         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 127             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 128         this.TR(this);
 129             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Font size:")));
 130             this.TD(this, 1, 2, makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 131         this.TR(this);
 132             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Accumulate range:")));
 133             this.TD(this, 1, 2, makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 134         this.TR(this);
 135             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Lifetime:")));
 136             this.TD(this, 1, 2, makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 137         this.TR(this);
 138             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Color:")));
 139             this.TD(this, 2, 2, makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 140     }
 141 ENDCLASS(XonoticDamageTextSettings)
 142 #endif