qcsrc/common/mutators/mutator/damagetext.qc

   1 REGISTER_MUTATOR(damagetext, true);
   2
   3 #if defined(CSQC) || defined(MENUQC)
   4 AUTOCVAR(cl_damagetext,                     bool,   false,      _("Draw damage dealt. 0: disabled, 1: enabled"));
   5 AUTOCVAR(cl_damagetext_format,              string, "-%3$d",    _("How to format the damage text. 1$ is health, 2$ is armor, 3$ is both"));
   6 AUTOCVAR(cl_damagetext_color,               vector, '1 1 0',    _("Default damage text color"));
   7 AUTOCVAR(cl_damagetext_size,                float,  8,          _("Damage text font size"));
   8 AUTOCVAR(cl_damagetext_alpha_start,         float,  1,          _("Damage text initial alpha"));
   9 AUTOCVAR(cl_damagetext_alpha_lifetime,      float,  3,          _("Damage text lifetime in seconds"));
  10 AUTOCVAR(cl_damagetext_velocity,            vector, '0 0 20',   _("Damage text move direction"));
  11 AUTOCVAR(cl_damagetext_offset,              vector, '0 -40 0',  _("Damage text offset"));
  12 AUTOCVAR(cl_damagetext_accumulate_range,    float,  30,         _("Damage text spawned within this range is accumulated"));
  13 #endif
  14
  15 #ifdef CSQC
  16 CLASS(DamageText, Object)
  17     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color)
  18     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size)
  19     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start)
  20     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime)
  21     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity)
  22     ATTRIB(DamageText, m_group, int, 0)
  23     ATTRIB(DamageText, m_damage, int, 0)
  24     ATTRIB(DamageText, m_armordamage, int, 0)
  25     ATTRIB(DamageText, time_prev, float, time)
  26
  27     void DamageText_draw() {
  28         entity this = self;
  29         float dt = time - this.time_prev;
  30         this.time_prev = time;
  31         setorigin(this, this.origin + dt * this.velocity);
  32         this.alpha -= dt * this.fade_rate;
  33         if (this.alpha < 0) remove(this);
  34         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  35         if (pos.z >= 0 && this.m_size > 0) {
  36             pos.z = 0;
  37             string s = sprintf(autocvar_cl_damagetext_format, this.m_damage, this.m_armordamage, this.m_damage + this.m_armordamage);
  38             drawcolorcodedstring2(pos, s, this.m_size * '1 1 0', this.m_color, this.alpha, DRAWFLAG_NORMAL);
  39         }
  40     }
  41     ATTRIB(DamageText, draw2d, void(), DamageText_draw)
  42
  43     void DamageText_update(DamageText this, vector _origin, int _health, int _armor) {
  44         this.m_damage = _health;
  45         this.m_armordamage = _armor;
  46         setorigin(this, _origin);
  47         this.alpha = 1;
  48     }
  49
  50     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor) {
  51         CONSTRUCT(DamageText);
  52         this.m_group = _group;
  53         DamageText_update(this, _origin, _health, _armor);
  54     }
  55 ENDCLASS(DamageText)
  56 #endif
  57
  58 #ifdef SVQC
  59 int autocvar_sv_damagetext = 2;
  60 STATIC_INIT(sv_damagetext) {
  61     CVAR_DESCRIBE(sv_damagetext, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
  62 }
  63 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  64 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
  65 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
  66 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
  67 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
  68     if (SV_DAMAGETEXT_DISABLED()) return;
  69     const entity attacker = mutator_argv_entity_0;
  70     const entity hit = mutator_argv_entity_1; if (hit == attacker) return;
  71     const int health = mutator_argv_int_0;
  72     const int armor = mutator_argv_int_1;
  73     const vector location = hit.origin;
  74     entity e;
  75     FOR_EACH_REALCLIENT(e) if (
  76         (SV_DAMAGETEXT_ALL()) ||
  77         (SV_DAMAGETEXT_PLAYERS() && e == attacker) ||
  78         (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(e) && e.enemy == attacker) ||
  79         (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(e))
  80     ) {
  81         msg_entity = e;
  82         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  83         WriteMutator(MSG_ONE, damagetext);
  84         WriteShort(MSG_ONE, health);
  85         WriteShort(MSG_ONE, armor);
  86         WriteEntity(MSG_ONE, hit);
  87         WriteCoord(MSG_ONE, location.x);
  88         WriteCoord(MSG_ONE, location.y);
  89         WriteCoord(MSG_ONE, location.z);
  90     }
  91 }
  92 #endif
  93
  94 #ifdef CSQC
  95 MUTATOR_HOOKFUNCTION(damagetext, CSQC_Parse_TempEntity) {
  96     if (MUTATOR_RETURNVALUE) return false;
  97     if (!ReadMutatorEquals(mutator_argv_int_0, damagetext)) return false;
  98     int health = ReadShort();
  99     int armor = ReadShort();
 100     int group = ReadShort();
 101     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 102     if (autocvar_cl_damagetext) {
 103         if (autocvar_cl_damagetext_accumulate_range) {
 104             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 105                 if (e.instanceOfDamageText && e.m_group == group) {
 106                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor);
 107                     return true;
 108                 }
 109             }
 110         }
 111         NEW(DamageText, group, location, health, armor);
 112     }
 113     return true;
 114 }
 115 #endif
 116
 117 #ifdef MENUQC
 118 #include "../../../menu/xonotic/tab.qc"
 119 CLASS(XonoticDamageTextSettings, XonoticTab)
 120     #include "../../../menu/gamesettings.qh"
 121     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 122     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"))
 123     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9)
 124     ATTRIB(XonoticDamageTextSettings, rows, float, 13)
 125     ATTRIB(XonoticDamageTextSettings, columns, float, 5)
 126     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 127     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 128     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 129     {
 130         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 131             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 132         this.TR(this);
 133             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Font size:")));
 134             this.TD(this, 1, 2, makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 135         this.TR(this);
 136             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Accumulate range:")));
 137             this.TD(this, 1, 2, makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 138         this.TR(this);
 139             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Lifetime:")));
 140             this.TD(this, 1, 2, makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 141         this.TR(this);
 142             this.TD(this, 1, 1, makeXonoticTextLabel(0, _("Color:")));
 143             this.TD(this, 2, 2, makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 144     }
 145 ENDCLASS(XonoticDamageTextSettings)
 146 #endif