qcsrc/common/mutators/mutator/damagetext/cl_damagetext.qc

   1 #include "cl_damagetext.qh"
   2
   3 // no translatable cvar description please
   4 AUTOCVAR_SAVE(cl_damagetext,                        bool,   true,       "Draw damage dealt where you hit the enemy");
   5 AUTOCVAR_SAVE(cl_damagetext_format,                 string, "-{total}", "How to format the damage text. {health}, {armor}, {total}, {potential}: full damage not capped to target's health, {potential_health}: health damage not capped to target's health");
   6 AUTOCVAR_SAVE(cl_damagetext_format_verbose,         bool,   false,      "{health} shows {potential_health} too when they differ; {total} shows {potential} too when they differ");
   7 AUTOCVAR_SAVE(cl_damagetext_format_hide_redundant,  bool,   false,      "hide {armor} if 0; hide {potential} and {potential_health} when same as actual");
   8 STATIC_INIT(DamageText_LegacyFormat) {
   9     // damagetext used to be off by default and the cvar got saved in people's configs along with the old format
  10     // enable damagetext while updating the format for a one time effect
  11     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) {
  12         localcmd("\nseta cl_damagetext 1\n");
  13         localcmd("\nseta cl_damagetext_format -{total}\n");
  14     };
  15 }
  16 AUTOCVAR_SAVE(cl_damagetext_color,                  vector, '1 1 0',    "Damage text color");
  17 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,       bool,   false,      "Damage text uses weapon color");
  18 AUTOCVAR_SAVE(cl_damagetext_size_min,               float,  10,          "Damage text font size for small damage");
  19 AUTOCVAR_SAVE(cl_damagetext_size_min_damage,        float,  25,          "How much damage is considered small");
  20 AUTOCVAR_SAVE(cl_damagetext_size_max,               float,  16,         "Damage text font size for large damage");
  21 AUTOCVAR_SAVE(cl_damagetext_size_max_damage,        float,  140,        "How much damage is considered large");
  22 AUTOCVAR_SAVE(cl_damagetext_alpha_start,            float,  1,          "Damage text initial alpha");
  23 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,         float,  3,          "Damage text lifetime in seconds");
  24 AUTOCVAR_SAVE(cl_damagetext_velocity_screen,        vector, '0 0 0',    "Damage text move direction (screen coordinates)");
  25 AUTOCVAR_SAVE(cl_damagetext_velocity_world,         vector, '0 0 20',   "Damage text move direction (world coordinates relative to player's view)");
  26 AUTOCVAR_SAVE(cl_damagetext_offset_screen,          vector, '0 -40 0',  "Damage text offset (screen coordinates)");
  27 AUTOCVAR_SAVE(cl_damagetext_offset_world,           vector, '0 0 0',    "Damage text offset (world coordinates relative to player's view)");
  28 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,       float,  30,         "Damage text spawned within this range is accumulated");
  29 AUTOCVAR_SAVE(cl_damagetext_accumulate_alpha_rel,   float,  0.65,       "Only update existing damage text when it's above this much percentage (0 to 1) of the starting alpha");
  30 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,           int,    1,          "0: never show for friendly fire, 1: when more than 0 damage, 2: always");
  31 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color,     vector, '1 0 0',    "Damage text color for friendlyfire");
  32
  33 AUTOCVAR_SAVE(cl_damagetext_2d,                     bool,   true,       "Show damagetext in 2D coordinates if the enemy's location is not known");
  34 AUTOCVAR_SAVE(cl_damagetext_2d_pos,                 vector, '0.47 0.53 0',     "2D damage text initial position (X and Y between 0 and 1)");
  35 AUTOCVAR_SAVE(cl_damagetext_2d_alpha_start,         float,  1,          "2D damage text initial alpha");
  36 AUTOCVAR_SAVE(cl_damagetext_2d_alpha_lifetime,      float,  1.3,        "2D damage text lifetime (alpha fading) in seconds");
  37 AUTOCVAR_SAVE(cl_damagetext_2d_size_lifetime,       float,  3,          "2D damage text lifetime (size shrinking) in seconds");
  38 AUTOCVAR_SAVE(cl_damagetext_2d_velocity,            vector, '-25 0 0',  "2D damage text move direction (screen coordinates)");
  39 AUTOCVAR_SAVE(cl_damagetext_2d_overlap_offset,      vector, '0 -15 0',  "Offset 2D damage text by this much to prevent overlapping (screen coordinates)");
  40 AUTOCVAR_SAVE(cl_damagetext_2d_close_range,         float,  125,        "Always use 2D damagetext for hits closer that this");
  41 AUTOCVAR_SAVE(cl_damagetext_2d_out_of_view,         bool,   true,       "Always use 2D damagetext for hits that occurred off-screen");
  42
  43 CLASS(DamageText, Object)
  44     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color);
  45     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color);
  46     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size_min);
  47     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start);
  48     ATTRIB(DamageText, fade_rate, float, 0);
  49     ATTRIB(DamageText, m_shrink_rate, float, 0);
  50     ATTRIB(DamageText, m_group, int, 0);
  51     ATTRIB(DamageText, m_friendlyfire, bool, false);
  52     ATTRIB(DamageText, m_healthdamage, int, 0);
  53     ATTRIB(DamageText, m_armordamage, int, 0);
  54     ATTRIB(DamageText, m_potential_damage, int, 0);
  55     ATTRIB(DamageText, m_deathtype, int, 0);
  56     ATTRIB(DamageText, hit_time, float, 0);
  57     ATTRIB(DamageText, text, string, string_null);
  58     ATTRIB(DamageText, m_screen_coords, bool, false);
  59
  60     STATIC_ATTRIB(DamageText, screen_first, DamageText, NULL);
  61     STATIC_ATTRIB(DamageText, screen_count, int, 0);
  62
  63     void DamageText_draw2d(DamageText this) {
  64         float since_hit = time - this.hit_time;
  65         // can't use `dt = hit_time - prev_update_time` because shrinking wouldn't be linear
  66         float size = this.m_size - since_hit * this.m_shrink_rate * this.m_size;
  67         float alpha_ = this.alpha - since_hit * this.fade_rate;
  68         if (alpha_ <= 0 || size <= 0) {
  69             delete(this);
  70             return;
  71         }
  72         vector screen_pos;
  73         if (this.m_screen_coords) {
  74             screen_pos = this.origin + since_hit * autocvar_cl_damagetext_2d_velocity;
  75         } else {
  76             makevectors(view_angles);
  77             vector world_offset = since_hit * autocvar_cl_damagetext_velocity_world + autocvar_cl_damagetext_offset_world;
  78             vector world_pos = this.origin + world_offset.x * v_forward + world_offset.y * v_right + world_offset.z * v_up;
  79             screen_pos = project_3d_to_2d(world_pos) + since_hit * autocvar_cl_damagetext_velocity_screen + autocvar_cl_damagetext_offset_screen;
  80         }
  81         if (screen_pos.z >= 0) {
  82             screen_pos.z = 0;
  83             vector rgb;
  84             if (this.m_friendlyfire) {
  85                 rgb = this.m_color_friendlyfire;
  86             } else {
  87                 rgb = this.m_color;
  88             }
  89             if (autocvar_cl_damagetext_color_per_weapon) {
  90                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  91                 if (w != WEP_Null) rgb = w.wpcolor;
  92             }
  93
  94             vector drawfontscale_save = drawfontscale;
  95             drawfontscale = (size / autocvar_cl_damagetext_size_max) * '1 1 0';
  96             drawcolorcodedstring2_builtin(screen_pos, this.text, autocvar_cl_damagetext_size_max * '1 1 0', rgb, alpha_, DRAWFLAG_NORMAL);
  97             drawfontscale = drawfontscale_save;
  98         }
  99     }
 100     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d);
 101
 102     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype) {
 103         this.m_healthdamage = _health;
 104         this.m_armordamage = _armor;
 105         this.m_potential_damage = _potential_damage;
 106         this.m_deathtype = _deathtype;
 107         setorigin(this, _origin);
 108         if (this.m_screen_coords) {
 109             this.alpha = autocvar_cl_damagetext_2d_alpha_start;
 110         } else {
 111             this.alpha = autocvar_cl_damagetext_alpha_start;
 112         }
 113         this.hit_time = time;
 114
 115         int health = rint(this.m_healthdamage / DAMAGETEXT_PRECISION_MULTIPLIER);
 116         int armor = rint(this.m_armordamage / DAMAGETEXT_PRECISION_MULTIPLIER);
 117         int total = rint((this.m_healthdamage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER);
 118         int potential = rint(this.m_potential_damage / DAMAGETEXT_PRECISION_MULTIPLIER);
 119         int potential_health = rint((this.m_potential_damage - this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER);
 120
 121         bool redundant = almost_equals_eps(this.m_healthdamage + this.m_armordamage, this.m_potential_damage, 5);
 122
 123         string s = autocvar_cl_damagetext_format;
 124         s = strreplace("{armor}", (
 125             (this.m_armordamage == 0 && autocvar_cl_damagetext_format_hide_redundant)
 126                 ? ""
 127                 : sprintf("%d", armor)
 128             ), s);
 129         s = strreplace("{potential}", (
 130             (redundant && autocvar_cl_damagetext_format_hide_redundant)
 131                 ? ""
 132                 : sprintf("%d", potential)
 133             ), s);
 134         s = strreplace("{potential_health}", (
 135             (redundant && autocvar_cl_damagetext_format_hide_redundant)
 136                 ? ""
 137                 : sprintf("%d", potential_health)
 138             ), s);
 139
 140         s = strreplace("{health}", (
 141             (health == potential_health || !autocvar_cl_damagetext_format_verbose)
 142                 ? sprintf("%d",      health)
 143                 : sprintf("%d (%d)", health, potential_health)
 144             ), s);
 145         s = strreplace("{total}", (
 146             (total == potential || !autocvar_cl_damagetext_format_verbose)
 147                 ? sprintf("%d",      total)
 148                 : sprintf("%d (%d)", total, potential)
 149             ), s);
 150
 151         // futureproofing: remove any remaining (unknown) format strings in case we add new ones in the future
 152         // so players can use them on new servers and still have working damagetext on old ones
 153         while (true) {
 154             int opening_pos = strstrofs(s, "{", 0);
 155             if (opening_pos == -1) break;
 156             int closing_pos = strstrofs(s, "}", opening_pos);
 157             if (closing_pos == -1 || closing_pos <= opening_pos) break;
 158             s = strcat(
 159                 substring(s, 0, opening_pos),
 160                 substring_range(s, closing_pos + 1, strlen(s))
 161             );
 162         }
 163
 164         strcpy(this.text, s);
 165
 166         this.m_size = map_bound_ranges(potential,
 167             autocvar_cl_damagetext_size_min_damage, autocvar_cl_damagetext_size_max_damage,
 168             autocvar_cl_damagetext_size_min, autocvar_cl_damagetext_size_max);
 169     }
 170
 171     CONSTRUCTOR(DamageText, int _group, vector _origin, bool _screen_coords, int _health, int _armor, int _potential_damage, int _deathtype, bool _friendlyfire) {
 172         CONSTRUCT(DamageText);
 173         this.m_group = _group;
 174         this.m_friendlyfire = _friendlyfire;
 175         this.m_screen_coords = _screen_coords;
 176         if (_screen_coords) {
 177             this.fade_rate = 1 / autocvar_cl_damagetext_2d_alpha_lifetime;
 178             this.m_shrink_rate = 1 / autocvar_cl_damagetext_2d_size_lifetime;
 179         } else {
 180             this.fade_rate = 1 / autocvar_cl_damagetext_alpha_lifetime;
 181             this.m_shrink_rate = 0;
 182         }
 183         DamageText_update(this, _origin, _health, _armor, _potential_damage, _deathtype);
 184         IL_PUSH(g_drawables_2d, this);
 185     }
 186
 187     DESTRUCTOR(DamageText) {
 188         strfree(this.text);
 189         if (this == DamageText_screen_first) {
 190             // start from 0 offset again, hopefully, others (if any) will have faded away by now
 191             DamageText_screen_first = NULL;
 192             DamageText_screen_count = 0;
 193         }
 194     }
 195 ENDCLASS(DamageText)
 196
 197 float current_alpha(entity damage_text) {
 198     // alpha doesn't change - actual alpha is always calculated from the initial value
 199     return damage_text.alpha - (time - damage_text.hit_time) * damage_text.fade_rate;
 200 }
 201
 202 NET_HANDLE(damagetext, bool isNew)
 203 {
 204     int server_entity_index = ReadByte();
 205     int deathtype = ReadInt24_t();
 206     int flags = ReadByte();
 207     bool friendlyfire = flags & DTFLAG_SAMETEAM;
 208
 209     int health, armor, potential_damage;
 210     if (flags & DTFLAG_BIG_HEALTH) health = ReadInt24_t();
 211     else health = ReadShort();
 212     if (flags & DTFLAG_NO_ARMOR) armor = 0;
 213     else if (flags & DTFLAG_BIG_ARMOR) armor = ReadInt24_t();
 214     else armor = ReadShort();
 215     if (flags & DTFLAG_NO_POTENTIAL) potential_damage = health + armor;
 216     else if (flags & DTFLAG_BIG_POTENTIAL) potential_damage = ReadInt24_t();
 217     else potential_damage = ReadShort();
 218
 219     return = true;
 220     if (autocvar_cl_damagetext == 0) return;
 221     if (friendlyfire) {
 222         if (autocvar_cl_damagetext_friendlyfire == 0) return;
 223         if (autocvar_cl_damagetext_friendlyfire == 1 && health == 0 && armor == 0) return;
 224     }
 225
 226     int client_entity_index = server_entity_index - 1;
 227     entity entcs = entcs_receiver(client_entity_index);
 228
 229     bool can_use_3d = entcs && entcs.has_origin;
 230     bool too_close = vdist(entcs.origin - view_origin, <, autocvar_cl_damagetext_2d_close_range);
 231     bool prefer_in_view = autocvar_cl_damagetext_2d_out_of_view && !projected_on_screen(project_3d_to_2d(entcs.origin));
 232     bool prefer_2d = spectatee_status != -1 && autocvar_cl_damagetext_2d && (too_close || prefer_in_view);
 233
 234     if (can_use_3d && !prefer_2d) {
 235         // world coords
 236         if (autocvar_cl_damagetext_accumulate_range) {
 237             for (entity e = findradius(entcs.origin, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 238                 if (e.instanceOfDamageText
 239                     && !e.m_screen_coords // we're using origin for both world coords and screen coords so avoid mismatches
 240                     && e.m_group == server_entity_index
 241                     && current_alpha(e) > autocvar_cl_damagetext_accumulate_alpha_rel * autocvar_cl_damagetext_alpha_start) {
 242                     DamageText_update(e, entcs.origin, e.m_healthdamage + health, e.m_armordamage + armor, e.m_potential_damage + potential_damage, deathtype);
 243                     return;
 244                 }
 245             }
 246         }
 247         make_impure(NEW(DamageText, server_entity_index, entcs.origin, false, health, armor, potential_damage, deathtype, friendlyfire));
 248     } else if (autocvar_cl_damagetext_2d && spectatee_status != -1) {
 249         // never show 2d damagetext when observing - might be a bug in .has_origin
 250
 251         // screen coords only
 252         vector screen_pos = vec2(vid_conwidth * autocvar_cl_damagetext_2d_pos.x, vid_conheight * autocvar_cl_damagetext_2d_pos.y);
 253         IL_EACH(g_drawables_2d, it.instanceOfDamageText && it.m_screen_coords && it.m_group == server_entity_index, {
 254             DamageText_update(it, screen_pos, it.m_healthdamage + health, it.m_armordamage + armor, it.m_potential_damage + potential_damage, deathtype);
 255             return;
 256         });
 257
 258         // when hitting multiple enemies, dmgtext would overlap
 259         if (DamageText_screen_first == NULL) {
 260             DamageText dt = NEW(DamageText, server_entity_index, screen_pos, true, health, armor, potential_damage, deathtype, friendlyfire);
 261             make_impure(dt);
 262             DamageText_screen_first = dt;
 263             DamageText_screen_count = 1;
 264         } else {
 265             screen_pos += autocvar_cl_damagetext_2d_overlap_offset * DamageText_screen_count;
 266             DamageText_screen_count++;
 267             make_impure(NEW(DamageText, server_entity_index, screen_pos, true, health, armor, potential_damage, deathtype, friendlyfire));
 268         }
 269     }
 270 }