qcsrc/common/mutators/mutator/damagetext/cl_damagetext.qc

   1 #include "cl_damagetext.qh"
   2
   3 // no translatable cvar description please
   4 AUTOCVAR_SAVE(cl_damagetext,                        bool,   true,       "Draw damage dealt where you hit the enemy");
   5 AUTOCVAR_SAVE(cl_damagetext_format,                 string, "-{total}", "How to format the damage text. {health}, {armor}, {total}, {potential}: full damage not capped to target's health, {potential_health}: health damage not capped to target's health");
   6 AUTOCVAR_SAVE(cl_damagetext_format_verbose,         bool,   false,      "{health} shows {potential_health} too when they differ; {total} shows {potential} too when they differ");
   7 AUTOCVAR_SAVE(cl_damagetext_format_hide_redundant,  bool,   false,      "hide {armor} if 0; hide {potential} and {potential_health} when same as actual");
   8 STATIC_INIT(DamageText_LegacyFormat) {
   9     // damagetext used to be off by default and the cvar got saved in people's configs along with the old format
  10     // enable damagetext while updating the format for a one time effect
  11     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) {
  12         localcmd("\nseta cl_damagetext 1\n");
  13         localcmd("\nseta cl_damagetext_format -{total}\n");
  14     };
  15 }
  16 AUTOCVAR_SAVE(cl_damagetext_color,                  vector, '1 1 0',    "Damage text color");
  17 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,       bool,   false,      "Damage text uses weapon color");
  18 AUTOCVAR_SAVE(cl_damagetext_size_min,               float,  10,          "Damage text font size for small damage");
  19 AUTOCVAR_SAVE(cl_damagetext_size_min_damage,        float,  25,          "How much damage is considered small");
  20 AUTOCVAR_SAVE(cl_damagetext_size_max,               float,  16,         "Damage text font size for large damage");
  21 AUTOCVAR_SAVE(cl_damagetext_size_max_damage,        float,  140,        "How much damage is considered large");
  22 AUTOCVAR_SAVE(cl_damagetext_alpha_start,            float,  1,          "Damage text initial alpha");
  23 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,         float,  3,          "Damage text lifetime in seconds");
  24 AUTOCVAR_SAVE(cl_damagetext_velocity_screen,        vector, '0 0 0',    "Damage text move direction (screen coordinates)");
  25 AUTOCVAR_SAVE(cl_damagetext_velocity_world,         vector, '0 0 20',   "Damage text move direction (world coordinates relative to player's view)");
  26 AUTOCVAR_SAVE(cl_damagetext_offset_screen,          vector, '0 -45 0',  "Damage text offset (screen coordinates)");
  27 AUTOCVAR_SAVE(cl_damagetext_offset_world,           vector, '0 0 0',    "Damage text offset (world coordinates relative to player's view)");
  28 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,       float,  30,         "Damage text spawned within this range is accumulated");
  29 AUTOCVAR_SAVE(cl_damagetext_accumulate_alpha_rel,   float,  0.65,       "Only update existing damage text when it's above this much percentage (0 to 1) of the starting alpha");
  30 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,           int,    1,          "0: never show for friendly fire, 1: when more than 0 damage, 2: always");
  31 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color,     vector, '1 0 0',    "Damage text color for friendlyfire");
  32
  33 AUTOCVAR_SAVE(cl_damagetext_2d,                     bool,   true,       "Show damagetext in 2D coordinates if the enemy's location is not known");
  34 AUTOCVAR_SAVE(cl_damagetext_2d_pos,                 vector, '0.47 0.53 0',     "2D damage text initial position (X and Y between 0 and 1)");
  35 AUTOCVAR_SAVE(cl_damagetext_2d_alpha_start,         float,  1,          "2D damage text initial alpha");
  36 AUTOCVAR_SAVE(cl_damagetext_2d_alpha_lifetime,      float,  1.3,        "2D damage text lifetime (alpha fading) in seconds");
  37 AUTOCVAR_SAVE(cl_damagetext_2d_size_lifetime,       float,  3,          "2D damage text lifetime (size shrinking) in seconds");
  38 AUTOCVAR_SAVE(cl_damagetext_2d_velocity,            vector, '-25 0 0',  "2D damage text move direction (screen coordinates)");
  39 AUTOCVAR_SAVE(cl_damagetext_2d_overlap_offset,      vector, '0 -15 0',  "Offset 2D damage text by this much to prevent overlapping (screen coordinates)");
  40 AUTOCVAR_SAVE(cl_damagetext_2d_close_range,         float,  125,        "Always use 2D damagetext for hits closer that this");
  41 AUTOCVAR_SAVE(cl_damagetext_2d_out_of_view,         bool,   true,       "Always use 2D damagetext for hits that occurred off-screen");
  42
  43 CLASS(DamageText, Object)
  44     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color);
  45     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color);
  46     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size_min);
  47     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start);
  48     ATTRIB(DamageText, fade_rate, float, 0);
  49     ATTRIB(DamageText, m_shrink_rate, float, 0);
  50     ATTRIB(DamageText, m_group, int, 0);
  51     ATTRIB(DamageText, m_friendlyfire, bool, false);
  52     ATTRIB(DamageText, m_healthdamage, int, 0);
  53     ATTRIB(DamageText, m_armordamage, int, 0);
  54     ATTRIB(DamageText, m_potential_damage, int, 0);
  55     ATTRIB(DamageText, m_deathtype, int, 0);
  56     ATTRIB(DamageText, hit_time, float, 0);
  57     ATTRIB(DamageText, text, string, string_null);
  58     ATTRIB(DamageText, m_screen_coords, bool, false);
  59
  60     STATIC_ATTRIB(DamageText, screen_first, DamageText, NULL);
  61     STATIC_ATTRIB(DamageText, screen_count, int, 0);
  62
  63     void DamageText_draw2d(DamageText this) {
  64         float since_hit = time - this.hit_time;
  65         // can't use `dt = hit_time - prev_update_time` because shrinking wouldn't be linear
  66         float size = this.m_size - since_hit * this.m_shrink_rate * this.m_size;
  67         float alpha_ = this.alpha - since_hit * this.fade_rate;
  68         if (alpha_ <= 0 || size <= 0) {
  69             delete(this);
  70             return;
  71         }
  72
  73         vector screen_pos;
  74         if (this.m_screen_coords) {
  75             screen_pos = this.origin + since_hit * autocvar_cl_damagetext_2d_velocity;
  76         } else {
  77             MAKE_VECTORS_NEW(view_angles, forward, right, up);
  78             vector world_offset = since_hit * autocvar_cl_damagetext_velocity_world + autocvar_cl_damagetext_offset_world;
  79             vector world_pos = this.origin + world_offset.x * forward + world_offset.y * right + world_offset.z * up;
  80             screen_pos = project_3d_to_2d(world_pos) + since_hit * autocvar_cl_damagetext_velocity_screen + autocvar_cl_damagetext_offset_screen;
  81         }
  82         screen_pos.y += size / 2;
  83
  84         if (screen_pos.z >= 0) {
  85             screen_pos.z = 0;
  86             vector rgb;
  87             if (this.m_friendlyfire) {
  88                 rgb = this.m_color_friendlyfire;
  89             } else {
  90                 rgb = this.m_color;
  91             }
  92             if (autocvar_cl_damagetext_color_per_weapon) {
  93                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  94                 if (w != WEP_Null) rgb = w.wpcolor;
  95             }
  96
  97             vector drawfontscale_save = drawfontscale;
  98             drawfontscale = (size / autocvar_cl_damagetext_size_max) * '1 1 0';
  99             screen_pos.y -= drawfontscale.x * size / 2;
 100             drawcolorcodedstring2_builtin(screen_pos, this.text, autocvar_cl_damagetext_size_max * '1 1 0', rgb, alpha_, DRAWFLAG_NORMAL);
 101             drawfontscale = drawfontscale_save;
 102         }
 103     }
 104     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d);
 105
 106     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _potential_damage, int _deathtype) {
 107         this.m_healthdamage = _health;
 108         this.m_armordamage = _armor;
 109         this.m_potential_damage = _potential_damage;
 110         this.m_deathtype = _deathtype;
 111         setorigin(this, _origin);
 112         if (this.m_screen_coords) {
 113             this.alpha = autocvar_cl_damagetext_2d_alpha_start;
 114         } else {
 115             this.alpha = autocvar_cl_damagetext_alpha_start;
 116         }
 117         this.hit_time = time;
 118
 119         int health = rint(this.m_healthdamage / DAMAGETEXT_PRECISION_MULTIPLIER);
 120         int armor = rint(this.m_armordamage / DAMAGETEXT_PRECISION_MULTIPLIER);
 121         int total = rint((this.m_healthdamage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER);
 122         int potential = rint(this.m_potential_damage / DAMAGETEXT_PRECISION_MULTIPLIER);
 123         int potential_health = rint((this.m_potential_damage - this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER);
 124
 125         bool redundant = almost_equals_eps(this.m_healthdamage + this.m_armordamage, this.m_potential_damage, 5);
 126
 127         string s = autocvar_cl_damagetext_format;
 128         s = strreplace("{armor}", (
 129             (this.m_armordamage == 0 && autocvar_cl_damagetext_format_hide_redundant)
 130                 ? ""
 131                 : sprintf("%d", armor)
 132             ), s);
 133         s = strreplace("{potential}", (
 134             (redundant && autocvar_cl_damagetext_format_hide_redundant)
 135                 ? ""
 136                 : sprintf("%d", potential)
 137             ), s);
 138         s = strreplace("{potential_health}", (
 139             (redundant && autocvar_cl_damagetext_format_hide_redundant)
 140                 ? ""
 141                 : sprintf("%d", potential_health)
 142             ), s);
 143
 144         s = strreplace("{health}", (
 145             (health == potential_health || !autocvar_cl_damagetext_format_verbose)
 146                 ? sprintf("%d",      health)
 147                 : sprintf("%d (%d)", health, potential_health)
 148             ), s);
 149         s = strreplace("{total}", (
 150             (total == potential || !autocvar_cl_damagetext_format_verbose)
 151                 ? sprintf("%d",      total)
 152                 : sprintf("%d (%d)", total, potential)
 153             ), s);
 154
 155         // futureproofing: remove any remaining (unknown) format strings in case we add new ones in the future
 156         // so players can use them on new servers and still have working damagetext on old ones
 157         while (true) {
 158             int opening_pos = strstrofs(s, "{", 0);
 159             if (opening_pos == -1) break;
 160             int closing_pos = strstrofs(s, "}", opening_pos);
 161             if (closing_pos == -1 || closing_pos <= opening_pos) break;
 162             s = strcat(
 163                 substring(s, 0, opening_pos),
 164                 substring_range(s, closing_pos + 1, strlen(s))
 165             );
 166         }
 167
 168         strcpy(this.text, s);
 169
 170         this.m_size = map_bound_ranges(potential,
 171             autocvar_cl_damagetext_size_min_damage, autocvar_cl_damagetext_size_max_damage,
 172             autocvar_cl_damagetext_size_min, autocvar_cl_damagetext_size_max);
 173     }
 174
 175     CONSTRUCTOR(DamageText, int _group, vector _origin, bool _screen_coords, int _health, int _armor, int _potential_damage, int _deathtype, bool _friendlyfire) {
 176         CONSTRUCT(DamageText);
 177         this.m_group = _group;
 178         this.m_friendlyfire = _friendlyfire;
 179         this.m_screen_coords = _screen_coords;
 180         if (_screen_coords) {
 181             this.fade_rate = 1 / autocvar_cl_damagetext_2d_alpha_lifetime;
 182             this.m_shrink_rate = 1 / autocvar_cl_damagetext_2d_size_lifetime;
 183         } else {
 184             this.fade_rate = 1 / autocvar_cl_damagetext_alpha_lifetime;
 185             this.m_shrink_rate = 0;
 186         }
 187         DamageText_update(this, _origin, _health, _armor, _potential_damage, _deathtype);
 188         IL_PUSH(g_drawables_2d, this);
 189     }
 190
 191     DESTRUCTOR(DamageText) {
 192         strfree(this.text);
 193         if (this == DamageText_screen_first) {
 194             // start from 0 offset again, hopefully, others (if any) will have faded away by now
 195             DamageText_screen_first = NULL;
 196             DamageText_screen_count = 0;
 197         }
 198     }
 199 ENDCLASS(DamageText)
 200
 201 float current_alpha(entity damage_text) {
 202     // alpha doesn't change - actual alpha is always calculated from the initial value
 203     return damage_text.alpha - (time - damage_text.hit_time) * damage_text.fade_rate;
 204 }
 205
 206 NET_HANDLE(damagetext, bool isNew)
 207 {
 208     int server_entity_index = ReadByte();
 209     int deathtype = ReadInt24_t();
 210     int flags = ReadByte();
 211     bool friendlyfire = flags & DTFLAG_SAMETEAM;
 212
 213     int health, armor, potential_damage;
 214     if (flags & DTFLAG_BIG_HEALTH) health = ReadInt24_t();
 215     else health = ReadShort();
 216     if (flags & DTFLAG_NO_ARMOR) armor = 0;
 217     else if (flags & DTFLAG_BIG_ARMOR) armor = ReadInt24_t();
 218     else armor = ReadShort();
 219     if (flags & DTFLAG_NO_POTENTIAL) potential_damage = health + armor;
 220     else if (flags & DTFLAG_BIG_POTENTIAL) potential_damage = ReadInt24_t();
 221     else potential_damage = ReadShort();
 222
 223     return = true;
 224     if (autocvar_cl_damagetext == 0) return;
 225     if (friendlyfire) {
 226         if (autocvar_cl_damagetext_friendlyfire == 0) return;
 227         if (autocvar_cl_damagetext_friendlyfire == 1 && health == 0 && armor == 0) return;
 228     }
 229
 230     int client_entity_index = server_entity_index - 1;
 231     entity entcs = entcs_receiver(client_entity_index);
 232
 233     bool can_use_3d = entcs && entcs.has_origin;
 234     bool too_close = vdist(entcs.origin - view_origin, <, autocvar_cl_damagetext_2d_close_range);
 235     bool prefer_in_view = autocvar_cl_damagetext_2d_out_of_view && !projected_on_screen(project_3d_to_2d(entcs.origin));
 236     bool prefer_2d = spectatee_status != -1 && autocvar_cl_damagetext_2d && (too_close || prefer_in_view);
 237
 238     if (can_use_3d && !prefer_2d) {
 239         // world coords
 240         // using 1 as minimum because of shotgun (same as menu)
 241         for (entity e = findradius(entcs.origin, max(autocvar_cl_damagetext_accumulate_range, 1)); e; e = e.chain) {
 242             if (e.instanceOfDamageText
 243                 && !e.m_screen_coords // we're using origin for both world coords and screen coords so avoid mismatches
 244                 && e.m_group == server_entity_index
 245                 && current_alpha(e) > autocvar_cl_damagetext_accumulate_alpha_rel * autocvar_cl_damagetext_alpha_start) {
 246                 DamageText_update(e, entcs.origin, e.m_healthdamage + health, e.m_armordamage + armor, e.m_potential_damage + potential_damage, deathtype);
 247                 return;
 248             }
 249         }
 250         make_impure(NEW(DamageText, server_entity_index, entcs.origin, false, health, armor, potential_damage, deathtype, friendlyfire));
 251     } else if (autocvar_cl_damagetext_2d && spectatee_status != -1) {
 252         // never show 2d damagetext when observing - might be a bug in .has_origin
 253
 254         // screen coords only
 255         vector screen_pos = vec2(vid_conwidth * autocvar_cl_damagetext_2d_pos.x, vid_conheight * autocvar_cl_damagetext_2d_pos.y);
 256         IL_EACH(g_drawables_2d, it.instanceOfDamageText && it.m_screen_coords && it.m_group == server_entity_index, {
 257             DamageText_update(it, screen_pos, it.m_healthdamage + health, it.m_armordamage + armor, it.m_potential_damage + potential_damage, deathtype);
 258             return;
 259         });
 260
 261         // when hitting multiple enemies, dmgtext would overlap
 262         if (DamageText_screen_first == NULL) {
 263             DamageText dt = NEW(DamageText, server_entity_index, screen_pos, true, health, armor, potential_damage, deathtype, friendlyfire);
 264             make_impure(dt);
 265             DamageText_screen_first = dt;
 266             DamageText_screen_count = 1;
 267         } else {
 268             screen_pos += autocvar_cl_damagetext_2d_overlap_offset * DamageText_screen_count;
 269             DamageText_screen_count++;
 270             make_impure(NEW(DamageText, server_entity_index, screen_pos, true, health, armor, potential_damage, deathtype, friendlyfire));
 271         }
 272     }
 273 }