qcsrc/common/mutators/mutator/damagetext/damagetext.qc

   1 #include "damagetext.qh"
   2
   3 #define DAMAGETEXT_PRECISION_MULTIPLIER 128
   4 #define DAMAGETEXT_MAX_SHORT 255 // 2^15 (signed short) / DAMAGETEXT_PRECISION_MULTIPLIER - 1
   5
   6 REGISTER_MUTATOR(damagetext, true);
   7
   8 #if defined(CSQC) || defined(MENUQC)
   9 // no translatable cvar description please
  10 AUTOCVAR_SAVE(cl_damagetext,                    bool,   true,      "Draw damage dealt where you hit the enemy");
  11 AUTOCVAR_SAVE(cl_damagetext_format,             string, "-{total}", "How to format the damage text. {health}, {armor}, {total}");
  12 STATIC_INIT(DamageText_LegacyFormat) {
  13     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) autocvar_cl_damagetext_format = "-{total}";
  14 }
  15 AUTOCVAR_SAVE(cl_damagetext_color,              vector, '1 1 0',    "Damage text color");
  16 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,   bool,   false,      "Damage text uses weapon color");
  17 AUTOCVAR_SAVE(cl_damagetext_size,               float,  8,          "Damage text font size");
  18 AUTOCVAR_SAVE(cl_damagetext_alpha_start,        float,  1,          "Damage text initial alpha");
  19 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,     float,  3,          "Damage text lifetime in seconds");
  20 AUTOCVAR_SAVE(cl_damagetext_velocity,           vector, '0 0 20',   "Damage text move direction");
  21 AUTOCVAR_SAVE(cl_damagetext_offset,             vector, '0 -40 0',  "Damage text offset");
  22 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,   float,  30,         "Damage text spawned within this range is accumulated");
  23 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,       bool,   true,       "Show damage text for friendlyfire too");
  24 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color, vector, '1 0 0',    "Damage text color for friendlyfire");
  25 #endif
  26
  27 #ifdef CSQC
  28 CLASS(DamageText, Object)
  29     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color);
  30     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color);
  31     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size);
  32     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start);
  33     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime);
  34     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity);
  35     ATTRIB(DamageText, m_group, int, 0);
  36     ATTRIB(DamageText, m_friendlyfire, bool, false);
  37     ATTRIB(DamageText, m_damage, int, 0);
  38     ATTRIB(DamageText, m_armordamage, int, 0);
  39     ATTRIB(DamageText, m_deathtype, int, 0);
  40     ATTRIB(DamageText, time_prev, float, time);
  41
  42     void DamageText_draw2d(DamageText this) {
  43         float dt = time - this.time_prev;
  44         this.time_prev = time;
  45         setorigin(this, this.origin + dt * this.velocity);
  46         this.alpha -= dt * this.fade_rate;
  47         if (this.alpha < 0) delete(this);
  48         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  49         if (pos.z >= 0 && this.m_size > 0) {
  50             pos.z = 0;
  51             vector rgb;
  52             if (this.m_friendlyfire) {
  53                 rgb = this.m_color_friendlyfire;
  54             }
  55             else {
  56                 rgb = this.m_color;
  57             }
  58             if (autocvar_cl_damagetext_color_per_weapon) {
  59                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  60                 if (w != WEP_Null) rgb = w.wpcolor;
  61             }
  62             string s = autocvar_cl_damagetext_format;
  63             s = strreplace("{health}", sprintf("%d", rint(this.m_damage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  64             s = strreplace("{armor}",  sprintf("%d", rint(this.m_armordamage / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  65             s = strreplace("{total}",  sprintf("%d", rint((this.m_damage + this.m_armordamage) / DAMAGETEXT_PRECISION_MULTIPLIER)), s);
  66             drawcolorcodedstring2_builtin(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
  67         }
  68     }
  69     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d);
  70
  71     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _deathtype) {
  72         this.m_damage = _health;
  73         this.m_armordamage = _armor;
  74         this.m_deathtype = _deathtype;
  75         setorigin(this, _origin);
  76         this.alpha = 1;
  77     }
  78
  79     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _deathtype, bool _friendlyfire) {
  80         CONSTRUCT(DamageText);
  81         this.m_group = _group;
  82         this.m_friendlyfire = _friendlyfire;
  83         DamageText_update(this, _origin, _health, _armor, _deathtype);
  84                 IL_PUSH(g_drawables_2d, this);
  85     }
  86 ENDCLASS(DamageText)
  87 #endif
  88
  89 REGISTER_NET_TEMP(damagetext)
  90
  91 #ifdef SVQC
  92 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
  93 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  94 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
  95 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
  96 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
  97 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
  98     if (SV_DAMAGETEXT_DISABLED()) return;
  99     const entity attacker = M_ARGV(0, entity);
 100     const entity hit = M_ARGV(1, entity); if (hit == attacker) return;
 101     const float health = M_ARGV(2, float);
 102     const float armor = M_ARGV(3, float);
 103     const int deathtype = M_ARGV(5, int);
 104     const vector location = hit.origin;
 105     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 106         if (
 107             (SV_DAMAGETEXT_ALL()) ||
 108             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
 109             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
 110             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
 111         ) {
 112             int flags = SAME_TEAM(hit, attacker); // BIT(0)
 113             if (health > DAMAGETEXT_MAX_SHORT) flags |= BIT(1);
 114             if (armor > DAMAGETEXT_MAX_SHORT) flags |= BIT(2);
 115
 116             msg_entity = it;
 117             WriteHeader(MSG_ONE, damagetext);
 118             WriteEntity(MSG_ONE, hit);
 119             WriteCoord(MSG_ONE, location.x);
 120             WriteCoord(MSG_ONE, location.y);
 121             WriteCoord(MSG_ONE, location.z);
 122             WriteInt24_t(MSG_ONE, deathtype);
 123             WriteByte(MSG_ONE, flags);
 124
 125             // we need to send a few decimal places to minimize errors when accumulating damage
 126             // sending them multiplied saves bandwidth compared to using WriteCoord,
 127             // however if the multiplied damage would be too much for (signed) short, we send an int24
 128             if (health > DAMAGETEXT_MAX_SHORT) WriteInt24_t(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
 129             else WriteShort(MSG_ONE, health * DAMAGETEXT_PRECISION_MULTIPLIER);
 130             if (armor > DAMAGETEXT_MAX_SHORT) WriteInt24_t(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
 131             else WriteShort(MSG_ONE, armor * DAMAGETEXT_PRECISION_MULTIPLIER);
 132         }
 133     ));
 134 }
 135 #endif
 136
 137 #ifdef CSQC
 138 NET_HANDLE(damagetext, bool isNew)
 139 {
 140     int group = ReadShort();
 141     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 142     int deathtype = ReadInt24_t();
 143     int flags = ReadByte();
 144     bool friendlyfire = flags & 1;
 145
 146     int health, armor;
 147     if (flags & BIT(1)) health = ReadInt24_t();
 148     else health = ReadShort();
 149     if (flags & BIT(2)) armor = ReadInt24_t();
 150     else armor = ReadShort();
 151
 152     return = true;
 153     if (autocvar_cl_damagetext) {
 154         if (friendlyfire && !autocvar_cl_damagetext_friendlyfire) {
 155             return;
 156         }
 157         if (autocvar_cl_damagetext_accumulate_range) {
 158             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 159                 if (e.instanceOfDamageText && e.m_group == group) {
 160                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, deathtype);
 161                     return;
 162                 }
 163             }
 164         }
 165         make_impure(NEW(DamageText, group, location, health, armor, deathtype, friendlyfire));
 166     }
 167 }
 168 #endif
 169
 170 #ifdef MENUQC
 171
 172 #include <menu/gamesettings.qh>
 173
 174 CLASS(XonoticDamageTextSettings, XonoticTab)
 175     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 176     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"));
 177     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9);
 178     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5);
 179     ATTRIB(XonoticDamageTextSettings, columns, float, 5);
 180     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 181     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 182     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 183     {
 184         entity e;
 185         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 186             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 187         this.TR(this);
 188             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Font size:")));
 189                 setDependent(e, "cl_damagetext", 1, 1);
 190             this.TD(this, 1, 2, e = makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 191                 setDependent(e, "cl_damagetext", 1, 1);
 192         this.TR(this);
 193             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Accumulate range:")));
 194                 setDependent(e, "cl_damagetext", 1, 1);
 195             this.TD(this, 1, 2, e = makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 196                 setDependent(e, "cl_damagetext", 1, 1);
 197         this.TR(this);
 198             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Lifetime:")));
 199                 setDependent(e, "cl_damagetext", 1, 1);
 200             this.TD(this, 1, 2, e = makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 201                 setDependent(e, "cl_damagetext", 1, 1);
 202         this.TR(this);
 203             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 204                 setDependent(e, "cl_damagetext", 1, 1);
 205             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 206                 setDependent(e, "cl_damagetext", 1, 1);
 207         this.TR(this);
 208         this.TR(this);
 209             this.TD(this, 1, 3, e = makeXonoticCheckBox(0, "cl_damagetext_friendlyfire", _("Draw damage numbers for friendly fire")));
 210                 setDependent(e, "cl_damagetext", 1, 1);
 211         this.TR(this);
 212             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 213                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 214             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_friendlyfire_color", "cl_damagetext_friendlyfire_color"));
 215                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 216         this.TR(this);
 217     }
 218 ENDCLASS(XonoticDamageTextSettings)
 219 #endif