qcsrc/common/mutators/mutator/damagetext/damagetext.qc

   1 #ifndef MUTATOR_DAMAGETEXT_H
   2 #define MUTATOR_DAMAGETEXT_H
   3
   4 #ifdef MENUQC
   5 #include <menu/xonotic/tab.qh>
   6 #endif
   7
   8 #endif
   9
  10 #ifdef IMPLEMENTATION
  11 REGISTER_MUTATOR(damagetext, true);
  12
  13 #if defined(CSQC) || defined(MENUQC)
  14 // no translatable cvar description please
  15 AUTOCVAR_SAVE(cl_damagetext,                    bool,   true,      "Draw damage dealt where you hit the enemy");
  16 AUTOCVAR_SAVE(cl_damagetext_format,             string, "-{total}", "How to format the damage text. {health}, {armor}, {total}");
  17 STATIC_INIT(DamageText_LegacyFormat) {
  18     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) autocvar_cl_damagetext_format = "-{total}";
  19 }
  20 AUTOCVAR_SAVE(cl_damagetext_color,              vector, '1 1 0',    "Damage text color");
  21 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,   bool,   false,      "Damage text uses weapon color");
  22 AUTOCVAR_SAVE(cl_damagetext_size,               float,  8,          "Damage text font size");
  23 AUTOCVAR_SAVE(cl_damagetext_alpha_start,        float,  1,          "Damage text initial alpha");
  24 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,     float,  3,          "Damage text lifetime in seconds");
  25 AUTOCVAR_SAVE(cl_damagetext_velocity,           vector, '0 0 20',   "Damage text move direction");
  26 AUTOCVAR_SAVE(cl_damagetext_offset,             vector, '0 -40 0',  "Damage text offset");
  27 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,   float,  30,         "Damage text spawned within this range is accumulated");
  28 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,       bool,   true,       "Show damage text for friendlyfire too");
  29 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color, vector, '1 0 0',    "Damage text color for friendlyfire");
  30 #endif
  31
  32 #ifdef CSQC
  33 CLASS(DamageText, Object)
  34     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color)
  35     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color)
  36     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size)
  37     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start)
  38     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime)
  39     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity)
  40     ATTRIB(DamageText, m_group, int, 0)
  41     ATTRIB(DamageText, m_friendlyfire, bool, false)
  42     ATTRIB(DamageText, m_damage, int, 0)
  43     ATTRIB(DamageText, m_armordamage, int, 0)
  44     ATTRIB(DamageText, m_deathtype, int, 0)
  45     ATTRIB(DamageText, time_prev, float, time)
  46
  47     void DamageText_draw2d(DamageText this) {
  48         float dt = time - this.time_prev;
  49         this.time_prev = time;
  50         setorigin(this, this.origin + dt * this.velocity);
  51         this.alpha -= dt * this.fade_rate;
  52         if (this.alpha < 0) delete(this);
  53         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  54         if (pos.z >= 0 && this.m_size > 0) {
  55             pos.z = 0;
  56             vector rgb;
  57             if (this.m_friendlyfire) {
  58                 rgb = this.m_color_friendlyfire;
  59             }
  60             else {
  61                 rgb = this.m_color;
  62             }
  63             if (autocvar_cl_damagetext_color_per_weapon) {
  64                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  65                 if (w != WEP_Null) rgb = w.wpcolor;
  66             }
  67             string s = autocvar_cl_damagetext_format;
  68             s = strreplace("{health}", sprintf("%d", this.m_damage), s);
  69             s = strreplace("{armor}",  sprintf("%d", this.m_armordamage), s);
  70             s = strreplace("{total}",  sprintf("%d", this.m_damage + this.m_armordamage), s);
  71             drawcolorcodedstring2_builtin(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
  72         }
  73     }
  74     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d)
  75
  76     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _deathtype) {
  77         this.m_damage = _health;
  78         this.m_armordamage = _armor;
  79         this.m_deathtype = _deathtype;
  80         setorigin(this, _origin);
  81         this.alpha = 1;
  82     }
  83
  84     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _deathtype, bool _friendlyfire) {
  85         CONSTRUCT(DamageText);
  86         this.m_group = _group;
  87         this.m_friendlyfire = _friendlyfire;
  88         DamageText_update(this, _origin, _health, _armor, _deathtype);
  89                 IL_PUSH(g_drawables_2d, this);
  90     }
  91 ENDCLASS(DamageText)
  92 #endif
  93
  94 REGISTER_NET_TEMP(damagetext)
  95
  96 #ifdef SVQC
  97 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
  98 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  99 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
 100 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
 101 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
 102 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
 103     if (SV_DAMAGETEXT_DISABLED()) return;
 104     const entity attacker = M_ARGV(0, entity);
 105     const entity hit = M_ARGV(1, entity); if (hit == attacker) return;
 106     const int health = M_ARGV(2, int);
 107     const int armor = M_ARGV(3, int);
 108     const int deathtype = M_ARGV(5, int);
 109     const vector location = hit.origin;
 110     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 111         if (
 112             (SV_DAMAGETEXT_ALL()) ||
 113             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
 114             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
 115             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
 116         ) {
 117             msg_entity = it;
 118             WriteHeader(MSG_ONE, damagetext);
 119             WriteShort(MSG_ONE, rint(health));
 120             WriteShort(MSG_ONE, rint(armor));
 121             WriteEntity(MSG_ONE, hit);
 122             WriteCoord(MSG_ONE, location.x);
 123             WriteCoord(MSG_ONE, location.y);
 124             WriteCoord(MSG_ONE, location.z);
 125             WriteInt24_t(MSG_ONE, deathtype);
 126             WriteByte(MSG_ONE, SAME_TEAM(hit, attacker));
 127         }
 128     ));
 129 }
 130 #endif
 131
 132 #ifdef CSQC
 133 NET_HANDLE(damagetext, bool isNew)
 134 {
 135     int health = ReadShort();
 136     int armor = ReadShort();
 137     int group = ReadShort();
 138     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 139     int deathtype = ReadInt24_t();
 140     bool friendlyfire = ReadByte();
 141     return = true;
 142     if (autocvar_cl_damagetext) {
 143         if (friendlyfire && !autocvar_cl_damagetext_friendlyfire) {
 144             return;
 145         }
 146         if (autocvar_cl_damagetext_accumulate_range) {
 147             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 148                 if (e.instanceOfDamageText && e.m_group == group) {
 149                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, deathtype);
 150                     return;
 151                 }
 152             }
 153         }
 154         make_impure(NEW(DamageText, group, location, health, armor, deathtype, friendlyfire));
 155     }
 156 }
 157 #endif
 158
 159 #ifdef MENUQC
 160 CLASS(XonoticDamageTextSettings, XonoticTab)
 161     #include <menu/gamesettings.qh>
 162     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 163     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"))
 164     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9)
 165     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5)
 166     ATTRIB(XonoticDamageTextSettings, columns, float, 5)
 167     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 168     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 169     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 170     {
 171         entity e;
 172         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 173             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 174         this.TR(this);
 175             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Font size:")));
 176                 setDependent(e, "cl_damagetext", 1, 1);
 177             this.TD(this, 1, 2, e = makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 178                 setDependent(e, "cl_damagetext", 1, 1);
 179         this.TR(this);
 180             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Accumulate range:")));
 181                 setDependent(e, "cl_damagetext", 1, 1);
 182             this.TD(this, 1, 2, e = makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 183                 setDependent(e, "cl_damagetext", 1, 1);
 184         this.TR(this);
 185             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Lifetime:")));
 186                 setDependent(e, "cl_damagetext", 1, 1);
 187             this.TD(this, 1, 2, e = makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 188                 setDependent(e, "cl_damagetext", 1, 1);
 189         this.TR(this);
 190             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 191                 setDependent(e, "cl_damagetext", 1, 1);
 192             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 193                 setDependent(e, "cl_damagetext", 1, 1);
 194         this.TR(this);
 195         this.TR(this);
 196         // friendly fire
 197             this.TD(this, 1, 3, e = makeXonoticCheckBox(0, "cl_damagetext_friendlyfire", _("Draw damage numbers for friendly fire")));
 198                 setDependent(e, "cl_damagetext", 1, 1);
 199         this.TR(this);
 200             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color (Friendly Fire):")));
 201                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 202             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_friendlyfire_color", "cl_damagetext_friendlyfire_color"));
 203                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 204         this.TR(this);
 205     }
 206 ENDCLASS(XonoticDamageTextSettings)
 207 #endif
 208 #endif