qcsrc/common/mutators/mutator/damagetext/damagetext.qc

   1 #ifndef MUTATOR_DAMAGETEXT_H
   2 #define MUTATOR_DAMAGETEXT_H
   3
   4 #ifdef MENUQC
   5 #include <menu/xonotic/tab.qh>
   6 #endif
   7
   8 #endif
   9
  10 #ifdef IMPLEMENTATION
  11 REGISTER_MUTATOR(damagetext, true);
  12
  13 #if defined(CSQC) || defined(MENUQC)
  14 // no translatable cvar description please
  15 AUTOCVAR_SAVE(cl_damagetext,                    bool,   true,      "Draw damage dealt where you hit the enemy");
  16 AUTOCVAR_SAVE(cl_damagetext_format,             string, "-{total}", "How to format the damage text. {health}, {armor}, {total}");
  17 STATIC_INIT(DamageText_LegacyFormat) {
  18     if (strstrofs(autocvar_cl_damagetext_format, "{", 0) < 0) autocvar_cl_damagetext_format = "-{total}";
  19 }
  20 AUTOCVAR_SAVE(cl_damagetext_color,              vector, '1 1 0',    "Damage text color");
  21 AUTOCVAR_SAVE(cl_damagetext_color_per_weapon,   bool,   false,      "Damage text uses weapon color");
  22 AUTOCVAR_SAVE(cl_damagetext_size,               float,  8,          "Damage text font size");
  23 AUTOCVAR_SAVE(cl_damagetext_alpha_start,        float,  1,          "Damage text initial alpha");
  24 AUTOCVAR_SAVE(cl_damagetext_alpha_lifetime,     float,  3,          "Damage text lifetime in seconds");
  25 AUTOCVAR_SAVE(cl_damagetext_velocity,           vector, '0 0 20',   "Damage text move direction");
  26 AUTOCVAR_SAVE(cl_damagetext_offset,             vector, '0 -40 0',  "Damage text offset");
  27 AUTOCVAR_SAVE(cl_damagetext_accumulate_range,   float,  30,         "Damage text spawned within this range is accumulated");
  28 AUTOCVAR_SAVE(cl_damagetext_friendlyfire,       bool,   true,       "Show damage text for friendlyfire too");
  29 AUTOCVAR_SAVE(cl_damagetext_friendlyfire_color, vector, '1 0 0',    "Damage text color for friendlyfire");
  30 #endif
  31
  32 #ifdef CSQC
  33 CLASS(DamageText, Object)
  34     ATTRIB(DamageText, m_color, vector, autocvar_cl_damagetext_color)
  35     ATTRIB(DamageText, m_color_friendlyfire, vector, autocvar_cl_damagetext_friendlyfire_color)
  36     ATTRIB(DamageText, m_size, float, autocvar_cl_damagetext_size)
  37     ATTRIB(DamageText, alpha, float, autocvar_cl_damagetext_alpha_start)
  38     ATTRIB(DamageText, fade_rate, float, 1 / autocvar_cl_damagetext_alpha_lifetime)
  39     ATTRIB(DamageText, velocity, vector, autocvar_cl_damagetext_velocity)
  40     ATTRIB(DamageText, m_group, int, 0)
  41     ATTRIB(DamageText, m_friendlyfire, bool, false)
  42     ATTRIB(DamageText, m_damage, int, 0)
  43     ATTRIB(DamageText, m_armordamage, int, 0)
  44     ATTRIB(DamageText, m_deathtype, int, 0)
  45     ATTRIB(DamageText, time_prev, float, time)
  46
  47     void DamageText_draw2d(DamageText this) {
  48         float dt = time - this.time_prev;
  49         this.time_prev = time;
  50         setorigin(this, this.origin + dt * this.velocity);
  51         this.alpha -= dt * this.fade_rate;
  52         if (this.alpha < 0) remove(this);
  53         vector pos = project_3d_to_2d(this.origin) + autocvar_cl_damagetext_offset;
  54         if (pos.z >= 0 && this.m_size > 0) {
  55             pos.z = 0;
  56             vector rgb;
  57             if (this.m_friendlyfire) {
  58                 rgb = this.m_color_friendlyfire;
  59             }
  60             else {
  61                 rgb = this.m_color;
  62             }
  63             if (autocvar_cl_damagetext_color_per_weapon) {
  64                 Weapon w = DEATH_WEAPONOF(this.m_deathtype);
  65                 if (w != WEP_Null) rgb = w.wpcolor;
  66             }
  67             string s = autocvar_cl_damagetext_format;
  68             s = strreplace("{health}", sprintf("%d", this.m_damage), s);
  69             s = strreplace("{armor}",  sprintf("%d", this.m_armordamage), s);
  70             s = strreplace("{total}",  sprintf("%d", this.m_damage + this.m_armordamage), s);
  71             drawcolorcodedstring2_builtin(pos, s, this.m_size * '1 1 0', rgb, this.alpha, DRAWFLAG_NORMAL);
  72         }
  73     }
  74     ATTRIB(DamageText, draw2d, void(DamageText), DamageText_draw2d)
  75
  76     void DamageText_update(DamageText this, vector _origin, int _health, int _armor, int _deathtype) {
  77         this.m_damage = _health;
  78         this.m_armordamage = _armor;
  79         this.m_deathtype = _deathtype;
  80         setorigin(this, _origin);
  81         this.alpha = 1;
  82     }
  83
  84     CONSTRUCTOR(DamageText, int _group, vector _origin, int _health, int _armor, int _deathtype, bool _friendlyfire) {
  85         CONSTRUCT(DamageText);
  86         this.m_group = _group;
  87         this.m_friendlyfire = _friendlyfire;
  88         DamageText_update(this, _origin, _health, _armor, _deathtype);
  89     }
  90 ENDCLASS(DamageText)
  91 #endif
  92
  93 REGISTER_NET_TEMP(damagetext)
  94
  95 #ifdef SVQC
  96 AUTOCVAR(sv_damagetext, int, 2, _("<= 0: disabled, >= 1: spectators, >= 2: players, >= 3: all players"));
  97 #define SV_DAMAGETEXT_DISABLED()        (autocvar_sv_damagetext <= 0 /* disabled */)
  98 #define SV_DAMAGETEXT_SPECTATORS_ONLY() (autocvar_sv_damagetext >= 1 /* spectators only */)
  99 #define SV_DAMAGETEXT_PLAYERS()         (autocvar_sv_damagetext >= 2 /* players */)
 100 #define SV_DAMAGETEXT_ALL()             (autocvar_sv_damagetext >= 3 /* all players */)
 101 MUTATOR_HOOKFUNCTION(damagetext, PlayerDamaged) {
 102     if (SV_DAMAGETEXT_DISABLED()) return;
 103     const entity attacker = M_ARGV(0, entity);
 104     const entity hit = M_ARGV(1, entity); if (hit == attacker) return;
 105     const int health = M_ARGV(2, int);
 106     const int armor = M_ARGV(3, int);
 107     const int deathtype = M_ARGV(5, int);
 108     const vector location = hit.origin;
 109     FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
 110         if (
 111             (SV_DAMAGETEXT_ALL()) ||
 112             (SV_DAMAGETEXT_PLAYERS() && it == attacker) ||
 113             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_SPEC(it) && it.enemy == attacker) ||
 114             (SV_DAMAGETEXT_SPECTATORS_ONLY() && IS_OBSERVER(it))
 115         ) {
 116             msg_entity = it;
 117             WriteHeader(MSG_ONE, damagetext);
 118             WriteShort(MSG_ONE, rint(health));
 119             WriteShort(MSG_ONE, rint(armor));
 120             WriteEntity(MSG_ONE, hit);
 121             WriteCoord(MSG_ONE, location.x);
 122             WriteCoord(MSG_ONE, location.y);
 123             WriteCoord(MSG_ONE, location.z);
 124             WriteInt24_t(MSG_ONE, deathtype);
 125             WriteByte(MSG_ONE, SAME_TEAM(hit, attacker));
 126         }
 127     ));
 128 }
 129 #endif
 130
 131 #ifdef CSQC
 132 NET_HANDLE(damagetext, bool isNew)
 133 {
 134     int health = ReadShort();
 135     int armor = ReadShort();
 136     int group = ReadShort();
 137     vector location = vec3(ReadCoord(), ReadCoord(), ReadCoord());
 138     int deathtype = ReadInt24_t();
 139     bool friendlyfire = ReadByte();
 140     return = true;
 141     if (autocvar_cl_damagetext) {
 142         if (friendlyfire && !autocvar_cl_damagetext_friendlyfire) {
 143             return;
 144         }
 145         if (autocvar_cl_damagetext_accumulate_range) {
 146             for (entity e = findradius(location, autocvar_cl_damagetext_accumulate_range); e; e = e.chain) {
 147                 if (e.instanceOfDamageText && e.m_group == group) {
 148                     DamageText_update(e, location, e.m_damage + health, e.m_armordamage + armor, deathtype);
 149                     return;
 150                 }
 151             }
 152         }
 153         make_impure(NEW(DamageText, group, location, health, armor, deathtype, friendlyfire));
 154     }
 155 }
 156 #endif
 157
 158 #ifdef MENUQC
 159 CLASS(XonoticDamageTextSettings, XonoticTab)
 160     #include <menu/gamesettings.qh>
 161     REGISTER_SETTINGS(damagetext, NEW(XonoticDamageTextSettings));
 162     ATTRIB(XonoticDamageTextSettings, title, string, _("Damage text"))
 163     ATTRIB(XonoticDamageTextSettings, intendedWidth, float, 0.9)
 164     ATTRIB(XonoticDamageTextSettings, rows, float, 15.5)
 165     ATTRIB(XonoticDamageTextSettings, columns, float, 5)
 166     INIT(XonoticDamageTextSettings) { this.configureDialog(this); }
 167     METHOD(XonoticDamageTextSettings, showNotify, void(entity this)) { loadAllCvars(this); }
 168     METHOD(XonoticDamageTextSettings, fill, void(entity this))
 169     {
 170         entity e;
 171         this.gotoRC(this, 0, 1); this.setFirstColumn(this, this.currentColumn);
 172             this.TD(this, 1, 3, makeXonoticCheckBox(0, "cl_damagetext", _("Draw damage numbers")));
 173         this.TR(this);
 174             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Font size:")));
 175                 setDependent(e, "cl_damagetext", 1, 1);
 176             this.TD(this, 1, 2, e = makeXonoticSlider(0, 50, 1, "cl_damagetext_size"));
 177                 setDependent(e, "cl_damagetext", 1, 1);
 178         this.TR(this);
 179             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Accumulate range:")));
 180                 setDependent(e, "cl_damagetext", 1, 1);
 181             this.TD(this, 1, 2, e = makeXonoticSlider(0, 500, 1, "cl_damagetext_accumulate_range"));
 182                 setDependent(e, "cl_damagetext", 1, 1);
 183         this.TR(this);
 184             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Lifetime:")));
 185                 setDependent(e, "cl_damagetext", 1, 1);
 186             this.TD(this, 1, 2, e = makeXonoticSlider(0, 10, 1, "cl_damagetext_alpha_lifetime"));
 187                 setDependent(e, "cl_damagetext", 1, 1);
 188         this.TR(this);
 189             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color:")));
 190                 setDependent(e, "cl_damagetext", 1, 1);
 191             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_color", "cl_damagetext_color"));
 192                 setDependent(e, "cl_damagetext", 1, 1);
 193         this.TR(this);
 194         this.TR(this);
 195         // friendly fire
 196             this.TD(this, 1, 3, e = makeXonoticCheckBox(0, "cl_damagetext_friendlyfire", _("Draw damage numbers for friendly fire")));
 197                 setDependent(e, "cl_damagetext", 1, 1);
 198         this.TR(this);
 199             this.TD(this, 1, 1, e = makeXonoticTextLabel(0, _("Color (Friendly Fire):")));
 200                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 201             this.TD(this, 2, 2, e = makeXonoticColorpickerString("cl_damagetext_friendlyfire_color", "cl_damagetext_friendlyfire_color"));
 202                 setDependentAND(e, "cl_damagetext", 1, 1, "cl_damagetext_friendlyfire", 1, 1);
 203         this.TR(this);
 204     }
 205 ENDCLASS(XonoticDamageTextSettings)
 206 #endif
 207 #endif