qcsrc/common/mutators/mutator/dodging/sv_dodging.qc

   1 #include "sv_dodging.qh"
   2
   3 // TODO the CSQC blocks in this sv_ file are currently not compiled but will be when dodging prediction gets enabled
   4
   5 #define PHYS_DODGING                                            g_dodging
   6 #define PHYS_DODGING_DELAY                                      autocvar_sv_dodging_delay
   7 #define PHYS_DODGING_DISTANCE_THRESHOLD         autocvar_sv_dodging_wall_distance_threshold
   8 #define PHYS_DODGING_FROZEN_DOUBLETAP           autocvar_sv_dodging_frozen_doubletap
   9 #define PHYS_DODGING_HEIGHT_THRESHOLD           autocvar_sv_dodging_height_threshold
  10 #define PHYS_DODGING_HORIZ_SPEED_MIN            autocvar_sv_dodging_horiz_speed_min
  11 #define PHYS_DODGING_HORIZ_SPEED_MAX            autocvar_sv_dodging_horiz_speed_max
  12 #define PHYS_DODGING_HORIZ_FORCE_SLOWEST        autocvar_sv_dodging_horiz_force_slowest
  13 #define PHYS_DODGING_HORIZ_FORCE_FASTEST        autocvar_sv_dodging_horiz_force_fastest
  14 #define PHYS_DODGING_HORIZ_FORCE_FROZEN         autocvar_sv_dodging_horiz_force_frozen
  15 #define PHYS_DODGING_RAMP_TIME                          autocvar_sv_dodging_ramp_time
  16 #define PHYS_DODGING_UP_SPEED                           autocvar_sv_dodging_up_speed
  17 #define PHYS_DODGING_WALL                                       autocvar_sv_dodging_wall_dodging
  18 #define PHYS_DODGING_AIR                                        autocvar_sv_dodging_air_dodging
  19 #define PHYS_DODGING_MAXSPEED                           autocvar_sv_dodging_maxspeed
  20 #define PHYS_DODGING_AIR_MAXSPEED                       autocvar_sv_dodging_air_maxspeed
  21
  22 // we ran out of stats slots! TODO: re-enable this when prediction is available for dodging
  23 #if 0
  24 #define PHYS_DODGING                                            STAT(DODGING, this)
  25 #define PHYS_DODGING_DELAY                                      STAT(DODGING_DELAY, this)
  26 #define PHYS_DODGING_DISTANCE_THRESHOLD         STAT(DODGING_DISTANCE_THRESHOLD, this)
  27 #define PHYS_DODGING_FROZEN_DOUBLETAP           STAT(DODGING_FROZEN_DOUBLETAP, this)
  28 #define PHYS_DODGING_HEIGHT_THRESHOLD           STAT(DODGING_HEIGHT_THRESHOLD, this)
  29 #define PHYS_DODGING_HORIZ_SPEED_MIN            STAT(DODGING_HORIZ_SPEED_MIN, this)
  30 #define PHYS_DODGING_HORIZ_SPEED_MAX            STAT(DODGING_HORIZ_SPEED_MAX, this)
  31 #define PHYS_DODGING_HORIZ_FORCE_SLOWEST        STAT(DODGING_HORIZ_FORCE_SLOWEST, this)
  32 #define PHYS_DODGING_HORIZ_FORCE_FASTEST        STAT(DODGING_HORIZ_FORCE_FASTEST, this)
  33 #define PHYS_DODGING_HORIZ_FORCE_FROZEN         STAT(DODGING_HORIZ_FORCE_FROZEN, this)
  34 #define PHYS_DODGING_RAMP_TIME                          STAT(DODGING_RAMP_TIME, this)
  35 #define PHYS_DODGING_UP_SPEED                           STAT(DODGING_UP_SPEED, this)
  36 #define PHYS_DODGING_WALL                                       STAT(DODGING_WALL, this)
  37 #define PHYS_DODGING_AIR                                        STAT(DODGING_AIR, this)
  38 #define PHYS_DODGING_MAXSPEED                           STAT(DODGING_MAXSPEED, this)
  39 #define PHYS_DODGING_AIR_MAXSPEED                       STAT(DODGING_AIR_MAXSPEED, this)
  40 #endif
  41
  42 #ifdef CSQC
  43         float cvar_cl_dodging_timeout;
  44         #define PHYS_DODGING_FRAMETIME                          (1 / (frametime <= 0 ? 60 : frametime))
  45         #define PHYS_DODGING_TIMEOUT(s)                         STAT(DODGING_TIMEOUT)
  46         #define PHYS_DODGING_PRESSED_KEYS(s)            (s).pressedkeys
  47 #elif defined(SVQC)
  48         .float cvar_cl_dodging_timeout;
  49         #define PHYS_DODGING_FRAMETIME                          sys_frametime
  50         #define PHYS_DODGING_TIMEOUT(s)                         CS(s).cvar_cl_dodging_timeout
  51         #define PHYS_DODGING_PRESSED_KEYS(s)            CS(s).pressedkeys
  52 #endif
  53
  54 #ifdef SVQC
  55
  56 bool autocvar_sv_dodging_sound;
  57
  58 #include <common/animdecide.qh>
  59 #include <common/physics/player.qh>
  60
  61 REGISTER_MUTATOR(dodging, cvar("g_dodging"))
  62 {
  63         // this just turns on the cvar.
  64         MUTATOR_ONADD
  65         {
  66                 g_dodging = cvar("g_dodging");
  67         }
  68
  69         // this just turns off the cvar.
  70         MUTATOR_ONROLLBACK_OR_REMOVE
  71         {
  72                 g_dodging = 0;
  73         }
  74
  75         return false;
  76 }
  77
  78 #elif defined(CSQC)
  79 REGISTER_MUTATOR(dodging, true);
  80 #endif
  81
  82 // set to 1 to indicate dodging has started.. reset by physics hook after dodge has been done..
  83 .float dodging_action;
  84
  85 // the jump part of the dodge cannot be ramped
  86 .float dodging_single_action;
  87
  88 // these are used to store the last key press time for each of the keys..
  89 .float last_FORWARD_KEY_time;
  90 .float last_BACKWARD_KEY_time;
  91 .float last_LEFT_KEY_time;
  92 .float last_RIGHT_KEY_time;
  93
  94 // these store the movement direction at the time of the dodge action happening.
  95 .vector dodging_direction;
  96
  97 // this indicates the last time a dodge was executed. used to check if another one is allowed
  98 // and to ramp up the dodge acceleration in the physics hook.
  99 .float last_dodging_time;
 100
 101 // the total speed that will be added over the ramp time
 102 .float dodging_force_total;
 103 // the part of total yet to be added
 104 .float dodging_force_remaining;
 105
 106 #ifdef CSQC
 107 .int pressedkeys;
 108 #endif
 109
 110 #define X(dir) \
 111         tracebox(this.origin, this.mins, this.maxs, this.origin + threshold * dir, true, this); \
 112         if (trace_fraction < 1 && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)) \
 113                 return true;
 114
 115 // returns true if the player is close to a wall
 116 bool is_close_to_wall(entity this, float threshold)
 117 {
 118         X(v_right);
 119         X(-v_right);
 120         X(v_forward);
 121         X(-v_forward);
 122
 123         return false;
 124 }
 125
 126 bool is_close_to_ground(entity this, float threshold)
 127 {
 128         if (IS_ONGROUND(this)) return true;
 129         X(-v_up); // necessary for dodging down a slope using doubletap (using `+dodge` works anyway)
 130
 131         return false;
 132 }
 133
 134 #undef X
 135
 136 float determine_force(entity player) {
 137         if (PHYS_FROZEN(player)) return PHYS_DODGING_HORIZ_FORCE_FROZEN;
 138
 139         float horiz_vel = vlen(vec2(player.velocity));
 140         return map_bound_ranges(horiz_vel,
 141                                 PHYS_DODGING_HORIZ_SPEED_MIN, PHYS_DODGING_HORIZ_SPEED_MAX,
 142                                 PHYS_DODGING_HORIZ_FORCE_SLOWEST, PHYS_DODGING_HORIZ_FORCE_FASTEST);
 143 }
 144
 145 bool PM_dodging_checkpressedkeys(entity this)
 146 {
 147         bool frozen_dodging = (PHYS_FROZEN(this) && PHYS_DODGING_FROZEN(this));
 148         bool frozen_no_doubletap = (frozen_dodging && !PHYS_DODGING_FROZEN_DOUBLETAP);
 149
 150         float tap_direction_x = 0;
 151         float tap_direction_y = 0;
 152         bool dodge_detected = false;
 153         vector mymovement = PHYS_CS(this).movement;
 154
 155         #define X(COND,BTN,RESULT)                                                                                                                                                              \
 156         if (mymovement_##COND) {                                                                                                                                                                \
 157                 /* is this a state change? */                                                                                                                                           \
 158                 if(!(PHYS_DODGING_PRESSED_KEYS(this) & KEY_##BTN) || frozen_no_doubletap) {                                                     \
 159                         tap_direction_##RESULT;                                                                                                                                                 \
 160                         if ((time - this.last_##BTN##_KEY_time) < PHYS_DODGING_TIMEOUT(this) || frozen_no_doubletap) {  \
 161                                 dodge_detected = true;                                                                                                                                          \
 162                         } else if(PHYS_INPUT_BUTTON_DODGE(this)) {                                                                                                              \
 163                                 dodge_detected = true;                                                                                                                                          \
 164                         }                                                                                                                                                                                               \
 165                         this.last_##BTN##_KEY_time = time;                                                                                                                              \
 166                 }                                                                                                                                                                                                       \
 167         }
 168         X(x < 0, BACKWARD,      x--);
 169         X(x > 0, FORWARD,       x++);
 170         X(y < 0, LEFT,          y--);
 171         X(y > 0, RIGHT,         y++);
 172         #undef X
 173
 174         if (!dodge_detected) return false;
 175
 176         // this check has to be after checking keys:
 177         // the first key press of the double tap is allowed to be before dodging delay,
 178         // only the second has to be after, otherwise +dodge gives an advantage because typical repress time is 0.1 s
 179         // or higher which means players using +dodge would be able to do it more often
 180         if ((time - this.last_dodging_time) < PHYS_DODGING_DELAY)
 181                 return false;
 182
 183         makevectors(this.angles);
 184
 185         bool can_dodge = (is_close_to_ground(this, PHYS_DODGING_HEIGHT_THRESHOLD) && (PHYS_DODGING_MAXSPEED == 0 || vdist(this.velocity, <, PHYS_DODGING_MAXSPEED)));
 186         bool can_wall_dodge = (PHYS_DODGING_WALL && is_close_to_wall(this, PHYS_DODGING_DISTANCE_THRESHOLD));
 187         bool can_air_dodge = (PHYS_DODGING_AIR && (PHYS_DODGING_AIR_MAXSPEED == 0 || vdist(this.velocity, <, PHYS_DODGING_AIR_MAXSPEED)));
 188         if (!can_dodge && !can_wall_dodge && !can_air_dodge) return false;
 189
 190         this.last_dodging_time = time;
 191
 192         this.dodging_action = 1;
 193         this.dodging_single_action = 1;
 194
 195         this.dodging_force_total = determine_force(this);
 196         this.dodging_force_remaining = this.dodging_force_total;
 197
 198         this.dodging_direction.x = tap_direction_x;
 199         this.dodging_direction.y = tap_direction_y;
 200
 201         // normalize the dodging_direction vector.. (unlike UT99) XD
 202         float length = sqrt(this.dodging_direction.x ** 2 + this.dodging_direction.y ** 2);
 203
 204         this.dodging_direction.x = this.dodging_direction.x / length;
 205         this.dodging_direction.y = this.dodging_direction.y / length;
 206
 207         return true;
 208 }
 209
 210 void PM_dodging(entity this)
 211 {
 212         // can't use return value from PM_dodging_checkpressedkeys because they're called from different hooks
 213         if (!this.dodging_action) return;
 214
 215         // when swimming or dead, no dodging allowed..
 216         if (this.waterlevel >= WATERLEVEL_SWIMMING || IS_DEAD(this))
 217         {
 218                 this.dodging_action = 0;
 219                 this.dodging_direction.x = 0;
 220                 this.dodging_direction.y = 0;
 221                 return;
 222         }
 223
 224         // make sure v_up, v_right and v_forward are sane
 225         if(PHYS_DODGING_AIR)
 226                 makevectors(this.v_angle);
 227         else
 228                 makevectors(this.angles);
 229
 230         // fraction of the force to apply each frame
 231         // if we have e.g. 0.5 sec ramptime and a frametime of 0.25, then the ramp code
 232         // will be called ramp_time/frametime times = 2 times. so, we need to
 233         // add 0.5 * the total speed each frame until the dodge action is done..
 234         float common_factor = PHYS_DODGING_FRAMETIME / PHYS_DODGING_RAMP_TIME;
 235         // NOTE: depending on cl_netfps the client may (and probably will) send more input frames during each server frame
 236         // but common_factor uses server frame rate so players with higher cl_netfps will ramp slightly faster
 237
 238         float velocity_increase = min(common_factor * this.dodging_force_total, this.dodging_force_remaining);
 239         this.dodging_force_remaining -= velocity_increase;
 240         this.velocity += this.dodging_direction.x * velocity_increase * v_forward
 241                        + this.dodging_direction.y * velocity_increase * v_right;
 242
 243         // the up part of the dodge is a single shot action
 244         if (this.dodging_single_action == 1)
 245         {
 246                 UNSET_ONGROUND(this);
 247
 248                 this.velocity += PHYS_DODGING_UP_SPEED * v_up;
 249
 250 #ifdef SVQC
 251                 if (autocvar_sv_dodging_sound)
 252                         PlayerSound(this, playersound_jump, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
 253
 254                 animdecide_setaction(this, ANIMACTION_JUMP, true);
 255 #endif
 256
 257                 this.dodging_single_action = 0;
 258         }
 259
 260         if(this.dodging_force_remaining <= 0)
 261         {
 262                 // reset state so next dodge can be done correctly
 263                 this.dodging_action = 0;
 264                 this.dodging_direction.x = 0;
 265                 this.dodging_direction.y = 0;
 266         }
 267 }
 268
 269 #ifdef CSQC
 270 void PM_dodging_GetPressedKeys(entity this)
 271 {
 272         PM_dodging_checkpressedkeys(this);
 273
 274         int keys = this.pressedkeys;
 275         keys = BITSET(keys, KEY_FORWARD,        PHYS_CS(this).movement.x > 0);
 276         keys = BITSET(keys, KEY_BACKWARD,       PHYS_CS(this).movement.x < 0);
 277         keys = BITSET(keys, KEY_RIGHT,          PHYS_CS(this).movement.y > 0);
 278         keys = BITSET(keys, KEY_LEFT,           PHYS_CS(this).movement.y < 0);
 279
 280         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
 281         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
 282         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
 283         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
 284         this.pressedkeys = keys;
 285 }
 286 #endif
 287
 288 MUTATOR_HOOKFUNCTION(dodging, PlayerPhysics)
 289 {
 290         entity player = M_ARGV(0, entity);
 291
 292 #ifdef CSQC
 293         PM_dodging_GetPressedKeys(player);
 294 #endif
 295         PM_dodging(player);
 296 }
 297
 298 #ifdef SVQC
 299
 300 REPLICATE(cvar_cl_dodging_timeout, float, "cl_dodging_timeout");
 301
 302 MUTATOR_HOOKFUNCTION(dodging, GetPressedKeys)
 303 {
 304         entity player = M_ARGV(0, entity);
 305
 306         PM_dodging_checkpressedkeys(player);
 307 }
 308
 309 #endif