qcsrc/common/mutators/mutator/instagib/instagib.qc

   1 #ifndef MUTATOR_INSTAGIB_H
   2 #define MUTATOR_INSTAGIB_H
   3
   4 #include "items.qc"
   5
   6 #ifdef SVQC
   7 float autocvar_g_instagib_invis_alpha;
   8 #endif
   9
  10 #endif
  11
  12 #ifdef IMPLEMENTATION
  13 #ifdef SVQC
  14
  15 int autocvar_g_instagib_ammo_drop;
  16 int autocvar_g_instagib_extralives;
  17 float autocvar_g_instagib_speed_highspeed;
  18
  19 #include <server/cl_client.qh>
  20
  21 #include <common/items/all.qc>
  22
  23 REGISTER_MUTATOR(mutator_instagib, cvar("g_instagib") && !g_nexball);
  24
  25 spawnfunc(item_minst_cells)
  26 {
  27         if (!g_instagib) { remove(self); return; }
  28         if (!self.ammo_cells) self.ammo_cells = autocvar_g_instagib_ammo_drop;
  29         StartItem(this, ITEM_VaporizerCells);
  30 }
  31
  32 void instagib_invisibility()
  33 {SELFPARAM();
  34         self.strength_finished = autocvar_g_balance_powerup_strength_time;
  35         StartItem(this, ITEM_Invisibility);
  36 }
  37
  38 void instagib_extralife()
  39 {SELFPARAM();
  40         StartItem(this, ITEM_ExtraLife);
  41 }
  42
  43 void instagib_speed()
  44 {SELFPARAM();
  45         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
  46         StartItem(this, ITEM_Speed);
  47 }
  48
  49 .float instagib_nextthink;
  50 .float instagib_needammo;
  51 void instagib_stop_countdown(entity e)
  52 {
  53         if (!e.instagib_needammo)
  54                 return;
  55         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER, CPID_INSTAGIB_FINDAMMO);
  56         e.instagib_needammo = false;
  57 }
  58 void instagib_ammocheck()
  59 {SELFPARAM();
  60         if(time < self.instagib_nextthink)
  61                 return;
  62         if(!IS_PLAYER(self))
  63                 return; // not a player
  64
  65         if(IS_DEAD(self) || gameover)
  66                 instagib_stop_countdown(self);
  67         else if (self.ammo_cells > 0 || (self.items & IT_UNLIMITED_WEAPON_AMMO) || (self.flags & FL_GODMODE))
  68                 instagib_stop_countdown(self);
  69         else if(autocvar_g_rm && autocvar_g_rm_laser)
  70         {
  71                 if(!self.instagib_needammo)
  72                 {
  73                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_INSTAGIB_DOWNGRADE);
  74                         self.instagib_needammo = true;
  75                 }
  76         }
  77         else
  78         {
  79                 self.instagib_needammo = true;
  80                 if (self.health <= 5)
  81                 {
  82                         Damage(self, self, self, 5, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
  83                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_INSTAGIB_TERMINATED);
  84                 }
  85                 else if (self.health <= 10)
  86                 {
  87                         Damage(self, self, self, 5, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
  88                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_1);
  89                 }
  90                 else if (self.health <= 20)
  91                 {
  92                         Damage(self, self, self, 10, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
  93                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_2);
  94                 }
  95                 else if (self.health <= 30)
  96                 {
  97                         Damage(self, self, self, 10, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
  98                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_3);
  99                 }
 100                 else if (self.health <= 40)
 101                 {
 102                         Damage(self, self, self, 10, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
 103                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_4);
 104                 }
 105                 else if (self.health <= 50)
 106                 {
 107                         Damage(self, self, self, 10, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
 108                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_5);
 109                 }
 110                 else if (self.health <= 60)
 111                 {
 112                         Damage(self, self, self, 10, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
 113                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_6);
 114                 }
 115                 else if (self.health <= 70)
 116                 {
 117                         Damage(self, self, self, 10, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
 118                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_7);
 119                 }
 120                 else if (self.health <= 80)
 121                 {
 122                         Damage(self, self, self, 10, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
 123                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_8);
 124                 }
 125                 else if (self.health <= 90)
 126                 {
 127                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_INSTAGIB_FINDAMMO);
 128                         Damage(self, self, self, 10, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
 129                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_NUM_9);
 130                 }
 131                 else
 132                 {
 133                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_MULTI, MULTI_INSTAGIB_FINDAMMO);
 134                         Damage(self, self, self, 10, DEATH_NOAMMO.m_id, self.origin, '0 0 0');
 135                 }
 136         }
 137         self.instagib_nextthink = time + 1;
 138 }
 139
 140 MUTATOR_HOOKFUNCTION(mutator_instagib, MatchEnd)
 141 {
 142         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(instagib_stop_countdown(it)));
 143         return false;
 144 }
 145
 146 MUTATOR_HOOKFUNCTION(mutator_instagib, MonsterDropItem)
 147 {
 148         other.monster_loot = spawnfunc_item_minst_cells;
 149
 150         return false;
 151 }
 152
 153 MUTATOR_HOOKFUNCTION(mutator_instagib, MonsterSpawn)
 154 {SELFPARAM();
 155         // always refill ammo
 156         if(self.monsterid == MON_MAGE.monsterid)
 157                 self.skin = 1;
 158
 159         return false;
 160 }
 161
 162 MUTATOR_HOOKFUNCTION(mutator_instagib, BotShouldAttack)
 163 {
 164         if (checkentity.items & ITEM_Invisibility.m_itemid)
 165                 return true;
 166
 167         return false;
 168 }
 169
 170 MUTATOR_HOOKFUNCTION(mutator_instagib, MakePlayerObserver)
 171 {SELFPARAM();
 172         instagib_stop_countdown(self);
 173         return false;
 174 }
 175
 176 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerSpawn)
 177 {SELFPARAM();
 178         self.effects |= EF_FULLBRIGHT;
 179         return false;
 180 }
 181
 182 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerPreThink)
 183 {
 184         instagib_ammocheck();
 185         return false;
 186 }
 187
 188 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerRegen)
 189 {
 190         // no regeneration in instagib
 191         return true;
 192 }
 193
 194 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerPowerups)
 195 {SELFPARAM();
 196         if (!(self.effects & EF_FULLBRIGHT))
 197                 self.effects |= EF_FULLBRIGHT;
 198
 199         if (self.items & ITEM_Invisibility.m_itemid)
 200         {
 201                 play_countdown(self.strength_finished, SND_POWEROFF);
 202                 if (time > self.strength_finished)
 203                 {
 204                         self.alpha = default_player_alpha;
 205                         self.exteriorweaponentity.alpha = default_weapon_alpha;
 206                         self.items &= ~ITEM_Invisibility.m_itemid;
 207                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_INVISIBILITY);
 208                 }
 209         }
 210         else
 211         {
 212                 if (time < self.strength_finished)
 213                 {
 214                         self.alpha = autocvar_g_instagib_invis_alpha;
 215                         self.exteriorweaponentity.alpha = autocvar_g_instagib_invis_alpha;
 216                         self.items |= ITEM_Invisibility.m_itemid;
 217                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_INVISIBILITY, self.netname);
 218                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_INVISIBILITY);
 219                 }
 220         }
 221
 222         if (self.items & ITEM_Speed.m_itemid)
 223         {
 224                 play_countdown(self.invincible_finished, SND_POWEROFF);
 225                 if (time > self.invincible_finished)
 226                 {
 227                         self.items &= ~ITEM_Speed.m_itemid;
 228                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SPEED);
 229                 }
 230         }
 231         else
 232         {
 233                 if (time < self.invincible_finished)
 234                 {
 235                         self.items |= ITEM_Speed.m_itemid;
 236                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SPEED, self.netname);
 237                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SPEED);
 238                 }
 239         }
 240         return false;
 241 }
 242
 243 .float stat_sv_maxspeed;
 244
 245 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerPhysics)
 246 {SELFPARAM();
 247         if(self.items & ITEM_Speed.m_itemid)
 248                 self.stat_sv_maxspeed = self.stat_sv_maxspeed * autocvar_g_instagib_speed_highspeed;
 249
 250         return false;
 251 }
 252
 253 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerDamage_SplitHealthArmor)
 254 {
 255         damage_save = 0;
 256         damage_take = frag_damage;
 257
 258         return false;
 259 }
 260
 261 MUTATOR_HOOKFUNCTION(mutator_instagib, ForbidThrowCurrentWeapon)
 262 {
 263         // weapon dropping on death handled by FilterItem
 264
 265         return true;
 266 }
 267
 268 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerDamage_Calculate)
 269 {
 270         if(autocvar_g_friendlyfire == 0 && SAME_TEAM(frag_target, frag_attacker) && IS_PLAYER(frag_target) && IS_PLAYER(frag_attacker))
 271                 frag_damage = 0;
 272
 273         if(IS_PLAYER(frag_target))
 274         {
 275                 if(frag_deathtype == DEATH_FALL.m_id)
 276                         frag_damage = 0; // never count fall damage
 277
 278                 if(!autocvar_g_instagib_damagedbycontents)
 279                 switch(DEATH_ENT(frag_deathtype))
 280                 {
 281                         case DEATH_DROWN:
 282                         case DEATH_SLIME:
 283                         case DEATH_LAVA:
 284                                 frag_damage = 0;
 285                                 break;
 286                 }
 287
 288                 if(IS_PLAYER(frag_attacker))
 289                 if(DEATH_ISWEAPON(frag_deathtype, WEP_VAPORIZER))
 290                 {
 291                         if(frag_target.armorvalue)
 292                         {
 293                                 frag_target.armorvalue -= 1;
 294                                 frag_damage = 0;
 295                                 frag_target.damage_dealt += 1;
 296                                 frag_attacker.damage_dealt += 1;
 297                                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_INSTAGIB_LIVES_REMAINING, frag_target.armorvalue);
 298                         }
 299                 }
 300
 301                 if(IS_PLAYER(frag_attacker) && DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
 302                 {
 303                         if(frag_deathtype & HITTYPE_SECONDARY)
 304                         {
 305                                 if(!autocvar_g_instagib_blaster_keepdamage || frag_attacker == frag_target)
 306                                         frag_damage = frag_mirrordamage = 0;
 307
 308                                 if(frag_target != frag_attacker)
 309                                 {
 310                                         if(frag_damage <= 0 && frag_target.health > 0) { Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE); }
 311                                         if(!autocvar_g_instagib_blaster_keepforce)
 312                                                 frag_force = '0 0 0';
 313                                 }
 314                         }
 315                 }
 316         }
 317
 318         if(IS_PLAYER(frag_attacker))
 319         if(frag_mirrordamage > 0)
 320         {
 321                 // just lose extra LIVES, don't kill the player for mirror damage
 322                 if(frag_attacker.armorvalue > 0)
 323                 {
 324                         frag_attacker.armorvalue -= 1;
 325                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_INSTAGIB_LIVES_REMAINING, frag_attacker.armorvalue);
 326                         frag_attacker.damage_dealt += frag_mirrordamage;
 327                 }
 328                 frag_mirrordamage = 0;
 329         }
 330
 331         if(frag_target.alpha && frag_target.alpha < 1)
 332                 yoda = 1;
 333
 334         return false;
 335 }
 336
 337 MUTATOR_HOOKFUNCTION(mutator_instagib, SetStartItems)
 338 {
 339         start_health       = warmup_start_health       = 100;
 340         start_armorvalue   = warmup_start_armorvalue   = 0;
 341
 342         start_ammo_shells  = warmup_start_ammo_shells  = 0;
 343         start_ammo_nails   = warmup_start_ammo_nails   = 0;
 344         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_instagib_ammo_start");
 345         start_ammo_plasma  = warmup_start_ammo_plasma  = 0;
 346         start_ammo_rockets = warmup_start_ammo_rockets = 0;
 347         start_ammo_fuel    = warmup_start_ammo_fuel    = 0;
 348
 349         start_weapons = warmup_start_weapons = WEPSET(VAPORIZER);
 350         start_items |= IT_UNLIMITED_SUPERWEAPONS;
 351
 352         return false;
 353 }
 354
 355 MUTATOR_HOOKFUNCTION(mutator_instagib, FilterItem)
 356 {SELFPARAM();
 357         if(self.classname == "item_cells")
 358                 return true; // no normal cells?
 359
 360         if(self.weapon == WEP_VAPORIZER.m_id && self.classname == "droppedweapon")
 361         {
 362                 self.ammo_cells = autocvar_g_instagib_ammo_drop;
 363                 return false;
 364         }
 365
 366         if(self.weapon == WEP_DEVASTATOR.m_id || self.weapon == WEP_VORTEX.m_id)
 367         {
 368                 entity e = spawn();
 369                 setorigin(e, self.origin);
 370                 e.noalign = self.noalign;
 371         e.cnt = self.cnt;
 372         e.team = self.team;
 373         e.spawnfunc_checked = true;
 374                 WITHSELF(e, spawnfunc_item_minst_cells(e));
 375                 return true;
 376         }
 377
 378         if(self.flags & FL_POWERUP)
 379                 return false;
 380
 381         if(self.ammo_cells > autocvar_g_instagib_ammo_drop && self.classname != "item_minst_cells")
 382                 self.ammo_cells = autocvar_g_instagib_ammo_drop;
 383
 384         if(self.ammo_cells && !self.weapon)
 385                 return false;
 386
 387         return true;
 388 }
 389
 390 MUTATOR_HOOKFUNCTION(mutator_instagib, CustomizeWaypoint)
 391 {SELFPARAM();
 392         entity e = WaypointSprite_getviewentity(other);
 393
 394         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 395         // but only apply this to real players, not to spectators
 396         if((self.owner.flags & FL_CLIENT) && (self.owner.items & ITEM_Invisibility.m_itemid) && (e == other))
 397         if(DIFF_TEAM(self.owner, e))
 398                 return true;
 399
 400         return false;
 401 }
 402
 403 MUTATOR_HOOKFUNCTION(mutator_instagib, PlayerDies)
 404 {
 405         if(DEATH_ISWEAPON(frag_deathtype, WEP_VAPORIZER))
 406                 frag_damage = 1000; // always gib if it was a vaporizer death
 407
 408         return false;
 409 }
 410
 411 MUTATOR_HOOKFUNCTION(mutator_instagib, ItemTouch)
 412 {SELFPARAM();
 413         if(self.ammo_cells)
 414         {
 415                 // play some cool sounds ;)
 416                 if (IS_CLIENT(other))
 417                 {
 418                         if(other.health <= 5)
 419                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_INSTAGIB_LASTSECOND);
 420                         else if(other.health < 50)
 421                                 Send_Notification(NOTIF_ONE, other, MSG_ANNCE, ANNCE_INSTAGIB_NARROWLY);
 422                 }
 423
 424                 if(other.health < 100)
 425                         other.health = 100;
 426
 427                 return MUT_ITEMTOUCH_CONTINUE;
 428         }
 429
 430         if(self.itemdef == ITEM_ExtraLife)
 431         {
 432                 other.armorvalue = bound(other.armorvalue, 999, other.armorvalue + autocvar_g_instagib_extralives);
 433                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 434                 return MUT_ITEMTOUCH_PICKUP;
 435         }
 436
 437         return MUT_ITEMTOUCH_CONTINUE;
 438 }
 439
 440 MUTATOR_HOOKFUNCTION(mutator_instagib, OnEntityPreSpawn)
 441 {SELFPARAM();
 442         if (!autocvar_g_powerups) { return false; }
 443         // Can't use .itemdef here
 444         if (!(self.classname == "item_strength" || self.classname == "item_invincible" || self.classname == "item_health_mega"))
 445                 return false;
 446
 447         entity e = spawn();
 448
 449         float r = random();
 450         if (r < 0.3)
 451                 e.think = instagib_invisibility;
 452         else if (r < 0.6)
 453                 e.think = instagib_extralife;
 454         else
 455                 e.think = instagib_speed;
 456
 457         e.nextthink = time + 0.1;
 458         e.spawnflags = self.spawnflags;
 459         e.noalign = self.noalign;
 460         setorigin(e, self.origin);
 461
 462         return true;
 463 }
 464
 465 MUTATOR_HOOKFUNCTION(mutator_instagib, BuildMutatorsString)
 466 {
 467         ret_string = strcat(ret_string, ":instagib");
 468         return false;
 469 }
 470
 471 MUTATOR_HOOKFUNCTION(mutator_instagib, BuildMutatorsPrettyString)
 472 {
 473         ret_string = strcat(ret_string, ", instagib");
 474         return false;
 475 }
 476
 477 MUTATOR_HOOKFUNCTION(mutator_instagib, SetModname)
 478 {
 479         modname = "InstaGib";
 480         return true;
 481 }
 482
 483 #endif
 484 #endif