qcsrc/common/mutators/mutator/itemstime.qc

   1 #ifdef IMPLEMENTATION
   2 REGISTER_MUTATOR(itemstime, true);
   3
   4 REGISTER_NET_TEMP(itemstime)
   5
   6 #ifdef SVQC
   7 void IT_Write(entity e, int i, float f) {
   8     if (!IS_REAL_CLIENT(e)) return;
   9     msg_entity = e;
  10     WriteHeader(MSG_ONE, itemstime);
  11     WriteByte(MSG_ONE, i);
  12     WriteFloat(MSG_ONE, f);
  13 }
  14 #endif
  15
  16 #ifdef CSQC
  17 // reserve one more spot for superweapons time
  18 float ItemsTime_time[Items_MAX + 1];
  19 float ItemsTime_availableTime[Items_MAX + 1];
  20 NET_HANDLE(itemstime, bool isNew)
  21 {
  22     int i = ReadByte();
  23     float f = ReadFloat();
  24     return = true;
  25     ItemsTime_time[i] = f;
  26 }
  27 #endif
  28
  29 #ifdef CSQC
  30 void Item_ItemsTime_Init()
  31 {
  32     FOREACH(Items, true, LAMBDA(
  33         ItemsTime_time[it.m_id] = -1;
  34     ));
  35     ItemsTime_time[Items_MAX] = -1;
  36 }
  37
  38 STATIC_INIT(ItemsTime_Init) {
  39     Item_ItemsTime_Init();
  40 }
  41
  42 int autocvar_hud_panel_itemstime = 2;
  43 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  44 float autocvar_hud_panel_itemstime_ratio = 2;
  45 int autocvar_hud_panel_itemstime_iconalign;
  46 bool autocvar_hud_panel_itemstime_progressbar = 0;
  47 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  48 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  49 float autocvar_hud_panel_itemstime_progressbar_reduced;
  50 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  51 bool autocvar_hud_panel_itemstime_hidelarge = false;
  52 int autocvar_hud_panel_itemstime_text = 1;
  53 #define hud_panel_itemstime_hidelarge autocvar_hud_panel_itemstime_hidelarge
  54 #else
  55 #define hud_panel_itemstime_hidelarge false
  56 #endif
  57
  58 bool Item_ItemsTime_SpectatorOnly(GameItem it)
  59 {
  60     return (false
  61     || it == ITEM_ArmorMega     || (it == ITEM_ArmorLarge && !hud_panel_itemstime_hidelarge)
  62     || it == ITEM_HealthMega    || (it == ITEM_HealthLarge && !hud_panel_itemstime_hidelarge)
  63     );
  64 }
  65
  66 bool Item_ItemsTime_Allow(GameItem it)
  67 {
  68     return (false
  69     || it.instanceOfPowerup
  70     || Item_ItemsTime_SpectatorOnly(it)
  71     );
  72 }
  73
  74 #ifdef SVQC
  75
  76 // reserve one more spot for superweapons time
  77 float it_times[Items_MAX + 1];
  78
  79 void Item_ItemsTime_Init()
  80 {
  81     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  82         it_times[it.m_id] = -1;
  83     ));
  84     it_times[Items_MAX] = -1;
  85 }
  86
  87 STATIC_INIT(ItemsTime_Init) {
  88     // items time
  89     Item_ItemsTime_Init();
  90 }
  91
  92 void Item_ItemsTime_ResetTimes()
  93 {
  94     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  95         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  96     ));
  97     it_times[Items_MAX] = (it_times[Items_MAX] == -1) ? -1 : 0;
  98 }
  99
 100 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 101 {
 102     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 103         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
 104     ));
 105     IT_Write(e, Items_MAX, (it_times[Items_MAX] == -1) ? -1 : 0);
 106 }
 107
 108 void Item_ItemsTime_SetTimesForPlayer(entity e)
 109 {
 110     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 111         IT_Write(e, it.m_id, it_times[it.m_id]);
 112     ));
 113     IT_Write(e, Items_MAX, it_times[Items_MAX]);
 114 }
 115
 116 void Item_ItemsTime_SetTime(entity e, float t)
 117 {
 118     if (!autocvar_sv_itemstime)
 119         return;
 120
 121     GameItem item = e.itemdef;
 122     if (item.instanceOfGameItem)
 123     {
 124                 if (!item.instanceOfWeaponPickup)
 125                         it_times[item.m_id] = t;
 126                 else if (e.weapons & WEPSET_SUPERWEAPONS)
 127                         it_times[Items_MAX] = t;
 128     }
 129 }
 130
 131 void Item_ItemsTime_SetTimesForAllPlayers()
 132 {
 133     FOREACH_CLIENT(IS_REAL_CLIENT(it) && (warmup_stage || !IS_PLAYER(it)), LAMBDA(Item_ItemsTime_SetTimesForPlayer(it)));
 134 }
 135
 136 float Item_ItemsTime_UpdateTime(entity e, float t)
 137 {
 138     bool isavailable = (t == 0);
 139     FOREACH_ENTITY(it.itemdef == e.itemdef || ((e.weapons & WEPSET_SUPERWEAPONS) && (it.weapons & WEPSET_SUPERWEAPONS) && clienttype(it) == CLIENTTYPE_NOTACLIENT), LAMBDA(
 140         if (e == it) continue;
 141         if (it.scheduledrespawntime <= time)
 142             isavailable = true;
 143         else if (t == 0 || it.scheduledrespawntime < t)
 144             t = it.scheduledrespawntime;
 145     ));
 146     if (isavailable)
 147         t = -t; // let know the client there's another available item
 148     return t;
 149 }
 150
 151 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global)
 152 {
 153     Item_ItemsTime_ResetTimes();
 154     // ALL the times need to be reset before .reset()ing each item
 155     // since Item_Reset schedules respawn of superweapons and powerups
 156     FOREACH_ENTITY(IS_NOT_A_CLIENT(it), LAMBDA(
 157         if (it.reset) Item_ItemsTime_SetTime(it, 0);
 158     ));
 159     Item_ItemsTime_SetTimesForAllPlayers();
 160 }
 161
 162 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver)
 163 {SELFPARAM();
 164     Item_ItemsTime_SetTimesForPlayer(self);
 165 }
 166
 167 MUTATOR_HOOKFUNCTION(itemstime, ClientConnect, CBC_ORDER_LAST)
 168 {SELFPARAM();
 169         if(IS_PLAYER(self))
 170         {
 171                 // client became player on connection skipping putObserverInServer step
 172                 if (IS_REAL_CLIENT(self))
 173                 if (warmup_stage)
 174                         Item_ItemsTime_SetTimesForPlayer(self);
 175         }
 176 }
 177
 178 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn)
 179 {SELFPARAM();
 180     if (warmup_stage) return;
 181     Item_ItemsTime_ResetTimesForPlayer(self);
 182 }
 183
 184 #endif
 185
 186 #ifdef CSQC
 187
 188 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, string item_icon, float item_time, bool item_available, float item_availableTime)
 189 {
 190     float t = 0;
 191     vector color = '0 0 0';
 192     float picalpha;
 193
 194     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 195         picalpha = 1;
 196     else if (item_available)
 197     {
 198         float BLINK_FACTOR = 0.15;
 199         float BLINK_BASE = 0.85;
 200         float BLINK_FREQ = 5;
 201         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 202     }
 203     else
 204         picalpha = 0.5;
 205     t = floor(item_time - time + 0.999);
 206     if (t < 5)
 207         color = '0.7 0 0';
 208     else if (t < 10)
 209         color = '0.7 0.7 0';
 210     else
 211         color = '1 1 1';
 212
 213     vector picpos, numpos;
 214     if (autocvar_hud_panel_itemstime_iconalign)
 215     {
 216         numpos = myPos;
 217         picpos = myPos + eX * (ar - 1) * mySize_y;
 218     }
 219     else
 220     {
 221         numpos = myPos + eX * mySize_y;
 222         picpos = myPos;
 223     }
 224
 225     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 226     {
 227         vector p_pos, p_size;
 228         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 229         {
 230             p_pos = numpos;
 231             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
 232         }
 233         else
 234         {
 235             p_pos = myPos;
 236             p_size = mySize;
 237         }
 238         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 239     }
 240
 241     if(autocvar_hud_panel_itemstime_text)
 242     {
 243         if(t > 0)
 244             drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 245         else if(precache_pic("gfx/hud/default/checkmark")) // COMPAT: check if this image exists, as 0.8.1 clients lack it
 246             drawpic_aspect_skin(numpos, "checkmark", eX * (ar - 1) * mySize_y + eY * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 247         else // legacy code, if the image is missing just center the icon
 248             picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 249     }
 250     if (item_availableTime)
 251         drawpic_aspect_skin_expanding(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 252     drawpic_aspect_skin(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 253 }
 254
 255 void HUD_ItemsTime()
 256 {
 257     if (!autocvar__hud_configure)
 258     {
 259         if (!(
 260             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 261         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage))
 262             )) { return; }
 263     }
 264     else
 265     {
 266         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
 267         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
 268         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
 269         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
 270     }
 271
 272     int count = 0;
 273     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 274     {
 275         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 276             count += (ItemsTime_time[it.m_id] > time || -ItemsTime_time[it.m_id] > time);
 277         ));
 278         count += (ItemsTime_time[Items_MAX] > time || -ItemsTime_time[Items_MAX] > time);
 279     }
 280     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 281     {
 282         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 283             count += (ItemsTime_time[it.m_id] > time);
 284         ));
 285         count += (ItemsTime_time[Items_MAX] > time);
 286     }
 287     else
 288     {
 289         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 290             count += (ItemsTime_time[it.m_id] != -1);
 291         ));
 292         count += (ItemsTime_time[Items_MAX] != -1);
 293     }
 294     if (count == 0)
 295         return;
 296
 297     HUD_Panel_UpdateCvars();
 298
 299     vector pos, mySize;
 300     pos = panel_pos;
 301     mySize = panel_size;
 302
 303     if (panel_bg_padding)
 304     {
 305         pos += '1 1 0' * panel_bg_padding;
 306         mySize -= '2 2 0' * panel_bg_padding;
 307     }
 308
 309     float rows, columns;
 310     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 311     rows = HUD_GetRowCount(count, mySize, ar);
 312     columns = ceil(count/rows);
 313
 314     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 315
 316     vector offset = '0 0 0';
 317     float newSize;
 318     if (autocvar_hud_panel_itemstime_dynamicsize)
 319     {
 320         if (autocvar__hud_configure)
 321         if (menu_enabled != 2)
 322             HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 323
 324         // reduce panel to avoid spacing items
 325         if (itemstime_size.x / itemstime_size.y < ar)
 326         {
 327             newSize = rows * itemstime_size.x / ar;
 328             pos.y += (mySize.y - newSize) / 2;
 329             mySize.y = newSize;
 330             itemstime_size.y = mySize.y / rows;
 331         }
 332         else
 333         {
 334             newSize = columns * itemstime_size.y * ar;
 335             pos.x += (mySize.x - newSize) / 2;
 336             mySize.x = newSize;
 337             itemstime_size.x = mySize.x / columns;
 338         }
 339         panel_pos = pos - '1 1 0' * panel_bg_padding;
 340         panel_size = mySize + '2 2 0' * panel_bg_padding;
 341     }
 342     else
 343     {
 344         if (itemstime_size.x/itemstime_size.y > ar)
 345         {
 346             newSize = ar * itemstime_size.y;
 347             offset.x = itemstime_size.x - newSize;
 348             pos.x += offset.x/2;
 349             itemstime_size.x = newSize;
 350         }
 351         else
 352         {
 353             newSize = 1/ar * itemstime_size.x;
 354             offset.y = itemstime_size.y - newSize;
 355             pos.y += offset.y/2;
 356             itemstime_size.y = newSize;
 357         }
 358     }
 359
 360     HUD_Panel_DrawBg(1);
 361
 362     float row = 0, column = 0;
 363     bool item_available;
 364     int id = 0;
 365     string icon = "";
 366     FOREACH(Items, Item_ItemsTime_Allow(it) && ItemsTime_time[it.m_id] != -1, LAMBDA(
 367         id = it.m_id;
 368         icon = it.m_icon;
 369
 370         :iteration
 371         float item_time = ItemsTime_time[id];
 372         if (item_time < -1)
 373         {
 374             item_available = true;
 375             item_time = -item_time;
 376         }
 377         else
 378             item_available = (item_time <= time);
 379
 380         if (ItemsTime_time[id] >= 0)
 381         {
 382             if (time <= ItemsTime_time[id])
 383                 ItemsTime_availableTime[id] = 0;
 384             else if (ItemsTime_availableTime[id] == 0)
 385                 ItemsTime_availableTime[id] = time;
 386         }
 387         else if (ItemsTime_availableTime[id] == 0)
 388             ItemsTime_availableTime[id] = time;
 389
 390         float f = (time - ItemsTime_availableTime[id]) * 2;
 391         f = (f > 1) ? 0 : bound(0, f, 1);
 392
 393         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 394             if (!(ItemsTime_time[id] > time || -ItemsTime_time[id] > time))
 395                 continue;
 396
 397         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 398             if (!(ItemsTime_time[id] > time))
 399                 continue;
 400
 401         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, icon, item_time, item_available, f);
 402         ++row;
 403         if (row >= rows)
 404         {
 405             row = 0;
 406             column = column + 1;
 407         }
 408         if(id == Items_MAX) // can happen only in the last fake iteration
 409                 break;
 410     ));
 411     // add another fake iteration for superweapons time
 412     if(id < Items_MAX && ItemsTime_time[Items_MAX] != -1)
 413     {
 414                 id = Items_MAX;
 415                 icon = "superweapons";
 416                 goto iteration;
 417     }
 418 }
 419
 420 #endif
 421 #endif