qcsrc/common/mutators/mutator/itemstime.qc

   1 #ifdef IMPLEMENTATION
   2 REGISTER_MUTATOR(itemstime, true);
   3
   4 REGISTER_NET_TEMP(itemstime)
   5
   6 #ifdef SVQC
   7 void IT_Write(entity e, int i, float f) {
   8     if (!IS_REAL_CLIENT(e)) return;
   9     msg_entity = e;
  10     WriteHeader(MSG_ONE, itemstime);
  11     WriteByte(MSG_ONE, i);
  12     WriteFloat(MSG_ONE, f);
  13 }
  14 #endif
  15
  16 #ifdef CSQC
  17 float ItemsTime_time[Items_MAX];
  18 float ItemsTime_availableTime[Items_MAX];
  19 NET_HANDLE(itemstime, bool isNew)
  20 {
  21     int i = ReadByte();
  22     float f = ReadFloat();
  23     return = true;
  24     ItemsTime_time[i] = f;
  25 }
  26 #endif
  27
  28 #ifdef CSQC
  29 int autocvar_hud_panel_itemstime = 2;
  30 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  31 float autocvar_hud_panel_itemstime_ratio = 2;
  32 int autocvar_hud_panel_itemstime_iconalign;
  33 bool autocvar_hud_panel_itemstime_progressbar = 0;
  34 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  35 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  36 float autocvar_hud_panel_itemstime_progressbar_reduced;
  37 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  38 bool autocvar_hud_panel_itemstime_hidelarge = false;
  39 int autocvar_hud_panel_itemstime_text = 1;
  40 #define hud_panel_itemstime_hidelarge autocvar_hud_panel_itemstime_hidelarge
  41 #else
  42 #define hud_panel_itemstime_hidelarge false
  43 #endif
  44
  45 bool Item_ItemsTime_SpectatorOnly(GameItem it)
  46 {
  47     return (false
  48     || it == ITEM_ArmorMega     || (it == ITEM_ArmorLarge && !hud_panel_itemstime_hidelarge)
  49     || it == ITEM_HealthMega    || (it == ITEM_HealthLarge && !hud_panel_itemstime_hidelarge)
  50     );
  51 }
  52
  53 bool Item_ItemsTime_Allow(GameItem it, WepSet _weapons)
  54 {
  55     return (false
  56     || it.instanceOfPowerup
  57     || Item_ItemsTime_SpectatorOnly(it)
  58     || (_weapons & WEPSET_SUPERWEAPONS)
  59     );
  60 }
  61
  62 #ifdef SVQC
  63
  64 float it_times[Items_MAX];
  65
  66 void Item_ItemsTime_Init()
  67 {
  68     FOREACH(Items, true, LAMBDA(
  69         it_times[it.m_id] = -1;
  70     ));
  71 }
  72
  73 STATIC_INIT(ItemsTime_Init) {
  74     // items time
  75     Item_ItemsTime_Init();
  76 }
  77
  78 void Item_ItemsTime_ResetTimes()
  79 {
  80     FOREACH(Items, true, LAMBDA(
  81         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  82     ));
  83 }
  84
  85 void Item_ItemsTime_ResetTimesForPlayer(entity e)
  86 {
  87     FOREACH(Items, true, LAMBDA(
  88         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
  89     ));
  90 }
  91
  92 void Item_ItemsTime_SetTimesForPlayer(entity e)
  93 {
  94     FOREACH(Items, true, LAMBDA(
  95         IT_Write(e, it.m_id, it_times[it.m_id]);
  96     ));
  97 }
  98
  99 void Item_ItemsTime_SetTime(entity e, float t)
 100 {
 101     if (!autocvar_sv_itemstime)
 102         return;
 103
 104     GameItem item = e.itemdef;
 105     if (item.instanceOfGameItem && !item.instanceOfWeaponPickup)
 106     {
 107         it_times[item.m_id] = t;
 108     }
 109 }
 110
 111 void Item_ItemsTime_SetTimesForAllPlayers()
 112 {
 113     entity e;
 114     FOR_EACH_REALCLIENT(e) if (warmup_stage || !IS_PLAYER(e))
 115         Item_ItemsTime_SetTimesForPlayer(e);
 116 }
 117
 118 float Item_ItemsTime_UpdateTime(entity e, float t)
 119 {
 120     bool isavailable = (t == 0);
 121     FOREACH_ENTITY(it.itemdef == e.itemdef || ((it.weapons & WEPSET_SUPERWEAPONS) && clienttype(it) == CLIENTTYPE_NOTACLIENT), LAMBDA(
 122         if (e == it) continue;
 123         if (it.scheduledrespawntime <= time)
 124             isavailable = true;
 125         else if (t == 0 || it.scheduledrespawntime < t)
 126             t = it.scheduledrespawntime;
 127     ));
 128     if (isavailable)
 129         t = -t; // let know the client there's another available item
 130     return t;
 131 }
 132
 133 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global)
 134 {SELFPARAM();
 135     Item_ItemsTime_ResetTimes();
 136     // ALL the times need to be reset before .reset()ing each item
 137     // since Item_Reset schedules respawn of superweapons and powerups
 138     FOREACH_ENTITY(IS_NOT_A_CLIENT(it), LAMBDA(
 139         if (it.reset) Item_ItemsTime_SetTime(it, 0);
 140     ));
 141     Item_ItemsTime_SetTimesForAllPlayers();
 142 }
 143
 144 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver)
 145 {SELFPARAM();
 146     Item_ItemsTime_SetTimesForPlayer(self);
 147 }
 148
 149 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn)
 150 {SELFPARAM();
 151     if (warmup_stage) return;
 152     Item_ItemsTime_ResetTimesForPlayer(self);
 153 }
 154
 155 #endif
 156
 157 #ifdef CSQC
 158
 159 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, entity item, float item_time, bool item_available, float item_availableTime)
 160 {
 161     float t = 0;
 162     vector color = '0 0 0';
 163     float picalpha;
 164
 165     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 166         picalpha = 1;
 167     else if (item_available)
 168     {
 169         float BLINK_FACTOR = 0.15;
 170         float BLINK_BASE = 0.85;
 171         float BLINK_FREQ = 5;
 172         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 173     }
 174     else
 175         picalpha = 0.5;
 176     t = floor(item_time - time + 0.999);
 177     if (t < 5)
 178         color = '0.7 0 0';
 179     else if (t < 10)
 180         color = '0.7 0.7 0';
 181     else
 182         color = '1 1 1';
 183
 184     vector picpos, numpos;
 185     if (autocvar_hud_panel_itemstime_iconalign)
 186     {
 187         numpos = myPos;
 188         picpos = myPos + eX * (ar - 1) * mySize_y;
 189     }
 190     else
 191     {
 192         numpos = myPos + eX * mySize_y;
 193         picpos = myPos;
 194     }
 195
 196     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 197     {
 198         vector p_pos, p_size;
 199         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 200         {
 201             p_pos = numpos;
 202             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
 203         }
 204         else
 205         {
 206             p_pos = myPos;
 207             p_size = mySize;
 208         }
 209         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 210     }
 211
 212     if(autocvar_hud_panel_itemstime_text)
 213     {
 214         if(t > 0)
 215             drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 216         else if(precache_pic("gfx/hud/default/checkmark")) // COMPAT: check if this image exists, as 0.8.1 clients lack it
 217             drawpic_aspect_skin(numpos, "checkmark", eX * (ar - 1) * mySize_y + eY * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 218         else // legacy code, if the image is missing just center the icon
 219             picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 220     }
 221     if (item_availableTime)
 222         drawpic_aspect_skin_expanding(picpos, item.m_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 223     drawpic_aspect_skin(picpos, item.m_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 224 }
 225
 226 void HUD_ItemsTime()
 227 {
 228     if (!autocvar__hud_configure)
 229     {
 230         if (!(
 231             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 232         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage))
 233             )) { return; }
 234     }
 235     else
 236     {
 237         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
 238         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
 239         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
 240         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
 241     }
 242
 243     int count = 0;
 244     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 245         FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 246             count += (ItemsTime_time[it.m_id] > time || -ItemsTime_time[it.m_id] > time);
 247         ));
 248     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 249         FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 250             count += (ItemsTime_time[it.m_id] > time);
 251         ));
 252     else
 253         FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0'), LAMBDA(
 254             count += (ItemsTime_time[it.m_id] != -1);
 255         ));
 256     if (count == 0)
 257         return;
 258
 259     HUD_Panel_UpdateCvars();
 260
 261     vector pos, mySize;
 262     pos = panel_pos;
 263     mySize = panel_size;
 264
 265     if (panel_bg_padding)
 266     {
 267         pos += '1 1 0' * panel_bg_padding;
 268         mySize -= '2 2 0' * panel_bg_padding;
 269     }
 270
 271     float rows, columns;
 272     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 273     rows = HUD_GetRowCount(count, mySize, ar);
 274     columns = ceil(count/rows);
 275
 276     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 277
 278     vector offset = '0 0 0';
 279     float newSize;
 280     if (autocvar_hud_panel_itemstime_dynamicsize)
 281     {
 282         if (autocvar__hud_configure)
 283         if (menu_enabled != 2)
 284             HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 285
 286         // reduce panel to avoid spacing items
 287         if (itemstime_size.x / itemstime_size.y < ar)
 288         {
 289             newSize = rows * itemstime_size.x / ar;
 290             pos.y += (mySize.y - newSize) / 2;
 291             mySize.y = newSize;
 292             itemstime_size.y = mySize.y / rows;
 293         }
 294         else
 295         {
 296             newSize = columns * itemstime_size.y * ar;
 297             pos.x += (mySize.x - newSize) / 2;
 298             mySize.x = newSize;
 299             itemstime_size.x = mySize.x / columns;
 300         }
 301         panel_pos = pos - '1 1 0' * panel_bg_padding;
 302         panel_size = mySize + '2 2 0' * panel_bg_padding;
 303     }
 304     else
 305     {
 306         if (itemstime_size.x/itemstime_size.y > ar)
 307         {
 308             newSize = ar * itemstime_size.y;
 309             offset.x = itemstime_size.x - newSize;
 310             pos.x += offset.x/2;
 311             itemstime_size.x = newSize;
 312         }
 313         else
 314         {
 315             newSize = 1/ar * itemstime_size.x;
 316             offset.y = itemstime_size.y - newSize;
 317             pos.y += offset.y/2;
 318             itemstime_size.y = newSize;
 319         }
 320     }
 321
 322     HUD_Panel_DrawBg(1);
 323
 324     float row = 0, column = 0;
 325     bool item_available;
 326     FOREACH(Items, Item_ItemsTime_Allow(it, '0 0 0') && ItemsTime_time[it.m_id] != -1, LAMBDA(
 327         float item_time = ItemsTime_time[it.m_id];
 328         if (item_time < -1)
 329         {
 330             item_available = true;
 331             item_time = -item_time;
 332         }
 333         else
 334             item_available = (item_time <= time);
 335
 336         if (ItemsTime_time[it.m_id] >= 0)
 337         {
 338             if (time <= ItemsTime_time[it.m_id])
 339                 ItemsTime_availableTime[it.m_id] = 0;
 340             else if (ItemsTime_availableTime[it.m_id] == 0)
 341                 ItemsTime_availableTime[it.m_id] = time;
 342         }
 343         else if (ItemsTime_availableTime[it.m_id] == 0)
 344             ItemsTime_availableTime[it.m_id] = time;
 345
 346         float f = (time - ItemsTime_availableTime[it.m_id]) * 2;
 347         f = (f > 1) ? 0 : bound(0, f, 1);
 348
 349         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 350             if (!(ItemsTime_time[it.m_id] > time || -ItemsTime_time[it.m_id] > time))
 351                 continue;
 352
 353         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 354             if (!(ItemsTime_time[it.m_id] > time))
 355                 continue;
 356
 357         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, it, item_time, item_available, f);
 358         ++row;
 359         if (row >= rows)
 360         {
 361             row = 0;
 362             column = column + 1;
 363         }
 364     ));
 365 }
 366
 367 #endif
 368 #endif