qcsrc/common/mutators/mutator/itemstime/itemstime.qc

   1 #include "itemstime.qh"
   2
   3 REGISTER_MUTATOR(itemstime, true);
   4
   5 REGISTER_NET_TEMP(itemstime)
   6
   7 #ifdef SVQC
   8 void IT_Write(entity e, int i, float f) {
   9     if (!IS_REAL_CLIENT(e)) return;
  10     msg_entity = e;
  11     WriteHeader(MSG_ONE, itemstime);
  12     WriteByte(MSG_ONE, i);
  13     WriteFloat(MSG_ONE, f);
  14 }
  15 #endif
  16
  17 #ifdef CSQC
  18 // reserve one more spot for superweapons time
  19 float ItemsTime_time[Items_MAX + 1];
  20 float ItemsTime_availableTime[Items_MAX + 1];
  21 NET_HANDLE(itemstime, bool isNew)
  22 {
  23     int i = ReadByte();
  24     float f = ReadFloat();
  25     return = true;
  26     ItemsTime_time[i] = f;
  27 }
  28 #endif
  29
  30 #ifdef CSQC
  31 void Item_ItemsTime_Init()
  32 {
  33     FOREACH(Items, true, LAMBDA(
  34         ItemsTime_time[it.m_id] = -1;
  35     ));
  36     ItemsTime_time[Items_MAX] = -1;
  37 }
  38
  39 STATIC_INIT(ItemsTime_Init) {
  40     Item_ItemsTime_Init();
  41 }
  42
  43 int autocvar_hud_panel_itemstime = 2;
  44 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  45 float autocvar_hud_panel_itemstime_ratio = 2;
  46 int autocvar_hud_panel_itemstime_iconalign;
  47 bool autocvar_hud_panel_itemstime_progressbar = 0;
  48 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  49 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  50 float autocvar_hud_panel_itemstime_progressbar_reduced;
  51 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  52 bool autocvar_hud_panel_itemstime_hidelarge = false;
  53 int autocvar_hud_panel_itemstime_text = 1;
  54 #define hud_panel_itemstime_hidelarge autocvar_hud_panel_itemstime_hidelarge
  55 #else
  56 #define hud_panel_itemstime_hidelarge false
  57 #endif
  58
  59 bool Item_ItemsTime_SpectatorOnly(GameItem it)
  60 {
  61     return (false
  62     || it == ITEM_ArmorMega     || (it == ITEM_ArmorLarge && !hud_panel_itemstime_hidelarge)
  63     || it == ITEM_HealthMega    || (it == ITEM_HealthLarge && !hud_panel_itemstime_hidelarge)
  64     );
  65 }
  66
  67 bool Item_ItemsTime_Allow(GameItem it)
  68 {
  69     return (false
  70     || it.instanceOfPowerup
  71     || Item_ItemsTime_SpectatorOnly(it)
  72     );
  73 }
  74
  75 #ifdef SVQC
  76
  77 // reserve one more spot for superweapons time
  78 float it_times[Items_MAX + 1];
  79
  80 void Item_ItemsTime_Init()
  81 {
  82     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  83         it_times[it.m_id] = -1;
  84     ));
  85     it_times[Items_MAX] = -1;
  86 }
  87
  88 STATIC_INIT(ItemsTime_Init) {
  89     // items time
  90     Item_ItemsTime_Init();
  91 }
  92
  93 void Item_ItemsTime_ResetTimes()
  94 {
  95     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  96         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  97     ));
  98     it_times[Items_MAX] = (it_times[Items_MAX] == -1) ? -1 : 0;
  99 }
 100
 101 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 102 {
 103     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 104         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
 105     ));
 106     IT_Write(e, Items_MAX, (it_times[Items_MAX] == -1) ? -1 : 0);
 107 }
 108
 109 void Item_ItemsTime_SetTimesForPlayer(entity e)
 110 {
 111     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 112         IT_Write(e, it.m_id, it_times[it.m_id]);
 113     ));
 114     IT_Write(e, Items_MAX, it_times[Items_MAX]);
 115 }
 116
 117 void Item_ItemsTime_SetTime(entity e, float t)
 118 {
 119     if (!autocvar_sv_itemstime)
 120         return;
 121
 122     GameItem item = e.itemdef;
 123     if (item.instanceOfGameItem)
 124     {
 125                 if (!item.instanceOfWeaponPickup)
 126                         it_times[item.m_id] = t;
 127                 else if (e.weapons & WEPSET_SUPERWEAPONS)
 128                         it_times[Items_MAX] = t;
 129     }
 130 }
 131
 132 void Item_ItemsTime_SetTimesForAllPlayers()
 133 {
 134     FOREACH_CLIENT(IS_REAL_CLIENT(it) && (warmup_stage || !IS_PLAYER(it) || autocvar_sv_itemstime == 2), LAMBDA(Item_ItemsTime_SetTimesForPlayer(it)));
 135 }
 136
 137 float Item_ItemsTime_UpdateTime(entity e, float t)
 138 {
 139     bool isavailable = (t == 0);
 140     IL_EACH(g_items, it != e,
 141     {
 142         if(!(it.itemdef == e.itemdef || ((e.weapons & WEPSET_SUPERWEAPONS) && (it.weapons & WEPSET_SUPERWEAPONS))))
 143             continue;
 144         if (it.scheduledrespawntime <= time)
 145             isavailable = true;
 146         else if (t == 0 || it.scheduledrespawntime < t)
 147             t = it.scheduledrespawntime;
 148     });
 149     if (isavailable)
 150         t = -t; // let know the client there's another available item
 151     return t;
 152 }
 153
 154 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global)
 155 {
 156     Item_ItemsTime_ResetTimes();
 157     // ALL the times need to be reset before .reset()ing each item
 158     // since Item_Reset schedules respawn of superweapons and powerups
 159     IL_EACH(g_items, it.reset,
 160     {
 161         Item_ItemsTime_SetTime(it, 0);
 162     });
 163     Item_ItemsTime_SetTimesForAllPlayers();
 164 }
 165
 166 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver)
 167 {
 168     entity player = M_ARGV(0, entity);
 169
 170     Item_ItemsTime_SetTimesForPlayer(player);
 171 }
 172
 173 MUTATOR_HOOKFUNCTION(itemstime, ClientConnect, CBC_ORDER_LAST)
 174 {
 175     entity player = M_ARGV(0, entity);
 176
 177         if(IS_PLAYER(player))
 178         {
 179                 // client became player on connection skipping putObserverInServer step
 180                 if (IS_REAL_CLIENT(player))
 181                 if (warmup_stage || autocvar_sv_itemstime == 2)
 182                         Item_ItemsTime_SetTimesForPlayer(player);
 183         }
 184 }
 185
 186 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn)
 187 {
 188     if (warmup_stage || autocvar_sv_itemstime == 2) return;
 189     entity player = M_ARGV(0, entity);
 190
 191     Item_ItemsTime_ResetTimesForPlayer(player);
 192 }
 193
 194 #endif
 195
 196 #ifdef CSQC
 197
 198 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, string item_icon, float item_time, bool item_available, float item_availableTime)
 199 {
 200     float t = 0;
 201     vector color = '0 0 0';
 202     float picalpha;
 203
 204     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 205         picalpha = 1;
 206     else if (item_available)
 207     {
 208         float BLINK_FACTOR = 0.15;
 209         float BLINK_BASE = 0.85;
 210         float BLINK_FREQ = 5;
 211         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 212     }
 213     else
 214         picalpha = 0.5;
 215     t = floor(item_time - time + 0.999);
 216     if (t < 5)
 217         color = '0.7 0 0';
 218     else if (t < 10)
 219         color = '0.7 0.7 0';
 220     else
 221         color = '1 1 1';
 222
 223     vector picpos, numpos;
 224     if (autocvar_hud_panel_itemstime_iconalign)
 225     {
 226         numpos = myPos;
 227         picpos = myPos + eX * (ar - 1) * mySize_y;
 228     }
 229     else
 230     {
 231         numpos = myPos + eX * mySize_y;
 232         picpos = myPos;
 233     }
 234
 235     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 236     {
 237         vector p_pos, p_size;
 238         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 239         {
 240             p_pos = numpos;
 241             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
 242         }
 243         else
 244         {
 245             p_pos = myPos;
 246             p_size = mySize;
 247         }
 248         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 249     }
 250
 251     if(autocvar_hud_panel_itemstime_text)
 252     {
 253         if(t > 0)
 254             drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 255         else if(precache_pic("gfx/hud/default/checkmark")) // COMPAT: check if this image exists, as 0.8.1 clients lack it
 256             drawpic_aspect_skin(numpos, "checkmark", eX * (ar - 1) * mySize_y + eY * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 257         else // legacy code, if the image is missing just center the icon
 258             picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 259     }
 260     if (item_availableTime)
 261         drawpic_aspect_skin_expanding(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 262     drawpic_aspect_skin(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 263 }
 264
 265 void HUD_ItemsTime()
 266 {
 267     if (!autocvar__hud_configure)
 268     {
 269         if (!(
 270             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 271         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage || STAT(ITEMSTIME) == 2))
 272             )) { return; }
 273     }
 274     else
 275     {
 276         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
 277         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
 278         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
 279         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
 280     }
 281
 282     int count = 0;
 283     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 284     {
 285         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 286             count += (ItemsTime_time[it.m_id] > time || -ItemsTime_time[it.m_id] > time);
 287         ));
 288         count += (ItemsTime_time[Items_MAX] > time || -ItemsTime_time[Items_MAX] > time);
 289     }
 290     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 291     {
 292         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 293             count += (ItemsTime_time[it.m_id] > time);
 294         ));
 295         count += (ItemsTime_time[Items_MAX] > time);
 296     }
 297     else
 298     {
 299         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 300             count += (ItemsTime_time[it.m_id] != -1);
 301         ));
 302         count += (ItemsTime_time[Items_MAX] != -1);
 303     }
 304     if (count == 0)
 305         return;
 306
 307     HUD_Panel_LoadCvars();
 308
 309     vector pos, mySize;
 310     pos = panel_pos;
 311     mySize = panel_size;
 312
 313     if (panel_bg_padding)
 314     {
 315         pos += '1 1 0' * panel_bg_padding;
 316         mySize -= '2 2 0' * panel_bg_padding;
 317     }
 318
 319     float rows, columns;
 320     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 321     rows = HUD_GetRowCount(count, mySize, ar);
 322     columns = ceil(count/rows);
 323
 324     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 325
 326     vector offset = '0 0 0';
 327     float newSize;
 328     if (autocvar_hud_panel_itemstime_dynamicsize)
 329     {
 330         if (autocvar__hud_configure)
 331         if (hud_configure_menu_open != 2)
 332             HUD_Panel_DrawBg(); // also draw the bg of the entire panel
 333
 334         // reduce panel to avoid spacing items
 335         if (itemstime_size.x / itemstime_size.y < ar)
 336         {
 337             newSize = rows * itemstime_size.x / ar;
 338             pos.y += (mySize.y - newSize) / 2;
 339             mySize.y = newSize;
 340             itemstime_size.y = mySize.y / rows;
 341         }
 342         else
 343         {
 344             newSize = columns * itemstime_size.y * ar;
 345             pos.x += (mySize.x - newSize) / 2;
 346             mySize.x = newSize;
 347             itemstime_size.x = mySize.x / columns;
 348         }
 349         panel_pos = pos - '1 1 0' * panel_bg_padding;
 350         panel_size = mySize + '2 2 0' * panel_bg_padding;
 351     }
 352     else
 353     {
 354         if (itemstime_size.x/itemstime_size.y > ar)
 355         {
 356             newSize = ar * itemstime_size.y;
 357             offset.x = itemstime_size.x - newSize;
 358             pos.x += offset.x/2;
 359             itemstime_size.x = newSize;
 360         }
 361         else
 362         {
 363             newSize = 1/ar * itemstime_size.x;
 364             offset.y = itemstime_size.y - newSize;
 365             pos.y += offset.y/2;
 366             itemstime_size.y = newSize;
 367         }
 368     }
 369
 370     HUD_Scale_Enable();
 371     HUD_Panel_DrawBg();
 372
 373     float row = 0, column = 0;
 374     bool item_available;
 375     int id = 0;
 376     string icon = "";
 377     FOREACH(Items, Item_ItemsTime_Allow(it) && ItemsTime_time[it.m_id] != -1, LAMBDA(
 378         id = it.m_id;
 379         icon = it.m_icon;
 380
 381 LABEL(iteration)
 382         float item_time = ItemsTime_time[id];
 383         if (item_time < -1)
 384         {
 385             item_available = true;
 386             item_time = -item_time;
 387         }
 388         else
 389             item_available = (item_time <= time);
 390
 391         if (ItemsTime_time[id] >= 0)
 392         {
 393             if (time <= ItemsTime_time[id])
 394                 ItemsTime_availableTime[id] = 0;
 395             else if (ItemsTime_availableTime[id] == 0)
 396                 ItemsTime_availableTime[id] = time;
 397         }
 398         else if (ItemsTime_availableTime[id] == 0)
 399             ItemsTime_availableTime[id] = time;
 400
 401         float f = (time - ItemsTime_availableTime[id]) * 2;
 402         f = (f > 1) ? 0 : bound(0, f, 1);
 403
 404         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 405             if (!(ItemsTime_time[id] > time || -ItemsTime_time[id] > time))
 406                 continue;
 407
 408         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 409             if (!(ItemsTime_time[id] > time))
 410                 continue;
 411
 412         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, icon, item_time, item_available, f);
 413         ++row;
 414         if (row >= rows)
 415         {
 416             row = 0;
 417             column = column + 1;
 418         }
 419         if(id == Items_MAX) // can happen only in the last fake iteration
 420                 break;
 421     ));
 422     // add another fake iteration for superweapons time
 423     if(id < Items_MAX && ItemsTime_time[Items_MAX] != -1)
 424     {
 425                 id = Items_MAX;
 426                 icon = "superweapons";
 427                 goto iteration;
 428     }
 429 }
 430
 431 #endif