qcsrc/common/mutators/mutator/itemstime/itemstime.qc

   1 #include "itemstime.qh"
   2
   3 REGISTER_MUTATOR(itemstime, true);
   4
   5 REGISTER_NET_TEMP(itemstime)
   6
   7 #ifdef SVQC
   8 void IT_Write(entity e, int i, float f) {
   9     if (!IS_REAL_CLIENT(e)) return;
  10     msg_entity = e;
  11     WriteHeader(MSG_ONE, itemstime);
  12     WriteByte(MSG_ONE, i);
  13     WriteFloat(MSG_ONE, f);
  14 }
  15 #endif
  16
  17 #ifdef CSQC
  18 // reserve one more spot for superweapons time
  19 float ItemsTime_time[Items_MAX + 1];
  20 float ItemsTime_availableTime[Items_MAX + 1];
  21 NET_HANDLE(itemstime, bool isNew)
  22 {
  23     int i = ReadByte();
  24     float f = ReadFloat();
  25     return = true;
  26     ItemsTime_time[i] = f;
  27 }
  28 #endif
  29
  30 #ifdef CSQC
  31 void Item_ItemsTime_Init()
  32 {
  33     FOREACH(Items, true, LAMBDA(
  34         ItemsTime_time[it.m_id] = -1;
  35     ));
  36     ItemsTime_time[Items_MAX] = -1;
  37 }
  38
  39 STATIC_INIT(ItemsTime_Init) {
  40     Item_ItemsTime_Init();
  41 }
  42
  43 int autocvar_hud_panel_itemstime = 2;
  44 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  45 float autocvar_hud_panel_itemstime_ratio = 2;
  46 int autocvar_hud_panel_itemstime_iconalign;
  47 bool autocvar_hud_panel_itemstime_progressbar = 0;
  48 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  49 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  50 float autocvar_hud_panel_itemstime_progressbar_reduced;
  51 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  52 bool autocvar_hud_panel_itemstime_hidelarge = false;
  53 int autocvar_hud_panel_itemstime_text = 1;
  54 #define hud_panel_itemstime_hidelarge autocvar_hud_panel_itemstime_hidelarge
  55 #else
  56 #define hud_panel_itemstime_hidelarge false
  57 #endif
  58
  59 bool Item_ItemsTime_SpectatorOnly(GameItem it)
  60 {
  61     return (false
  62     || it == ITEM_ArmorMega     || (it == ITEM_ArmorLarge && !hud_panel_itemstime_hidelarge)
  63     || it == ITEM_HealthMega    || (it == ITEM_HealthLarge && !hud_panel_itemstime_hidelarge)
  64     );
  65 }
  66
  67 bool Item_ItemsTime_Allow(GameItem it)
  68 {
  69     return (false
  70     || it.instanceOfPowerup
  71     || Item_ItemsTime_SpectatorOnly(it)
  72     );
  73 }
  74
  75 #ifdef SVQC
  76
  77 // reserve one more spot for superweapons time
  78 float it_times[Items_MAX + 1];
  79
  80 void Item_ItemsTime_Init()
  81 {
  82     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  83         it_times[it.m_id] = -1;
  84     ));
  85     it_times[Items_MAX] = -1;
  86 }
  87
  88 STATIC_INIT(ItemsTime_Init) {
  89     // items time
  90     Item_ItemsTime_Init();
  91 }
  92
  93 void Item_ItemsTime_ResetTimes()
  94 {
  95     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
  96         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  97     ));
  98     it_times[Items_MAX] = (it_times[Items_MAX] == -1) ? -1 : 0;
  99 }
 100
 101 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 102 {
 103     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 104         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
 105     ));
 106     IT_Write(e, Items_MAX, (it_times[Items_MAX] == -1) ? -1 : 0);
 107 }
 108
 109 void Item_ItemsTime_SetTimesForPlayer(entity e)
 110 {
 111     FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 112         IT_Write(e, it.m_id, it_times[it.m_id]);
 113     ));
 114     IT_Write(e, Items_MAX, it_times[Items_MAX]);
 115 }
 116
 117 void Item_ItemsTime_SetTime(entity e, float t)
 118 {
 119     if (!autocvar_sv_itemstime)
 120         return;
 121
 122     GameItem item = e.itemdef;
 123     if (item.instanceOfGameItem)
 124     {
 125                 if (!item.instanceOfWeaponPickup)
 126                         it_times[item.m_id] = t;
 127                 else if (e.weapons & WEPSET_SUPERWEAPONS)
 128                         it_times[Items_MAX] = t;
 129     }
 130 }
 131
 132 void Item_ItemsTime_SetTimesForAllPlayers()
 133 {
 134     FOREACH_CLIENT(IS_REAL_CLIENT(it) && (warmup_stage || !IS_PLAYER(it) || autocvar_sv_itemstime == 2), LAMBDA(Item_ItemsTime_SetTimesForPlayer(it)));
 135 }
 136
 137 float Item_ItemsTime_UpdateTime(entity e, float t)
 138 {
 139     bool isavailable = (t == 0);
 140     FOREACH_ENTITY_FLOAT(pure_data, false,
 141     {
 142         if(!(it.itemdef == e.itemdef || ((e.weapons & WEPSET_SUPERWEAPONS) && (it.weapons & WEPSET_SUPERWEAPONS) && clienttype(it) == CLIENTTYPE_NOTACLIENT)))
 143             continue;
 144         if (e == it) continue;
 145         if (it.scheduledrespawntime <= time)
 146             isavailable = true;
 147         else if (t == 0 || it.scheduledrespawntime < t)
 148             t = it.scheduledrespawntime;
 149     });
 150     if (isavailable)
 151         t = -t; // let know the client there's another available item
 152     return t;
 153 }
 154
 155 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global)
 156 {
 157     Item_ItemsTime_ResetTimes();
 158     // ALL the times need to be reset before .reset()ing each item
 159     // since Item_Reset schedules respawn of superweapons and powerups
 160     FOREACH_ENTITY_FLOAT(pure_data, false,
 161     {
 162         if(IS_CLIENT(it))
 163             continue;
 164         if (it.reset) Item_ItemsTime_SetTime(it, 0);
 165     });
 166     Item_ItemsTime_SetTimesForAllPlayers();
 167 }
 168
 169 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver)
 170 {
 171     entity player = M_ARGV(0, entity);
 172
 173     Item_ItemsTime_SetTimesForPlayer(player);
 174 }
 175
 176 MUTATOR_HOOKFUNCTION(itemstime, ClientConnect, CBC_ORDER_LAST)
 177 {
 178     entity player = M_ARGV(0, entity);
 179
 180         if(IS_PLAYER(player))
 181         {
 182                 // client became player on connection skipping putObserverInServer step
 183                 if (IS_REAL_CLIENT(player))
 184                 if (warmup_stage || autocvar_sv_itemstime == 2)
 185                         Item_ItemsTime_SetTimesForPlayer(player);
 186         }
 187 }
 188
 189 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn)
 190 {
 191     if (warmup_stage || autocvar_sv_itemstime == 2) return;
 192     entity player = M_ARGV(0, entity);
 193
 194     Item_ItemsTime_ResetTimesForPlayer(player);
 195 }
 196
 197 #endif
 198
 199 #ifdef CSQC
 200
 201 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, string item_icon, float item_time, bool item_available, float item_availableTime)
 202 {
 203     float t = 0;
 204     vector color = '0 0 0';
 205     float picalpha;
 206
 207     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 208         picalpha = 1;
 209     else if (item_available)
 210     {
 211         float BLINK_FACTOR = 0.15;
 212         float BLINK_BASE = 0.85;
 213         float BLINK_FREQ = 5;
 214         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 215     }
 216     else
 217         picalpha = 0.5;
 218     t = floor(item_time - time + 0.999);
 219     if (t < 5)
 220         color = '0.7 0 0';
 221     else if (t < 10)
 222         color = '0.7 0.7 0';
 223     else
 224         color = '1 1 1';
 225
 226     vector picpos, numpos;
 227     if (autocvar_hud_panel_itemstime_iconalign)
 228     {
 229         numpos = myPos;
 230         picpos = myPos + eX * (ar - 1) * mySize_y;
 231     }
 232     else
 233     {
 234         numpos = myPos + eX * mySize_y;
 235         picpos = myPos;
 236     }
 237
 238     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 239     {
 240         vector p_pos, p_size;
 241         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 242         {
 243             p_pos = numpos;
 244             p_size = eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y;
 245         }
 246         else
 247         {
 248             p_pos = myPos;
 249             p_size = mySize;
 250         }
 251         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 252     }
 253
 254     if(autocvar_hud_panel_itemstime_text)
 255     {
 256         if(t > 0)
 257             drawstring_aspect(numpos, ftos(t), eX * ((ar - 1)/ar) * mySize_x + eY * mySize_y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 258         else if(precache_pic("gfx/hud/default/checkmark")) // COMPAT: check if this image exists, as 0.8.1 clients lack it
 259             drawpic_aspect_skin(numpos, "checkmark", eX * (ar - 1) * mySize_y + eY * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 260         else // legacy code, if the image is missing just center the icon
 261             picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 262     }
 263     if (item_availableTime)
 264         drawpic_aspect_skin_expanding(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 265     drawpic_aspect_skin(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 266 }
 267
 268 void HUD_ItemsTime()
 269 {
 270     if (!autocvar__hud_configure)
 271     {
 272         if (!(
 273             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 274         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage || STAT(ITEMSTIME) == 2))
 275             )) { return; }
 276     }
 277     else
 278     {
 279         ItemsTime_time[ITEM_ArmorMega.m_id] = time + 0;
 280         ItemsTime_time[ITEM_HealthMega.m_id] = time + 8;
 281         ItemsTime_time[ITEM_Strength.m_id] = time + 0;
 282         ItemsTime_time[ITEM_Shield.m_id] = time + 4;
 283     }
 284
 285     int count = 0;
 286     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 287     {
 288         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 289             count += (ItemsTime_time[it.m_id] > time || -ItemsTime_time[it.m_id] > time);
 290         ));
 291         count += (ItemsTime_time[Items_MAX] > time || -ItemsTime_time[Items_MAX] > time);
 292     }
 293     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 294     {
 295         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 296             count += (ItemsTime_time[it.m_id] > time);
 297         ));
 298         count += (ItemsTime_time[Items_MAX] > time);
 299     }
 300     else
 301     {
 302         FOREACH(Items, Item_ItemsTime_Allow(it), LAMBDA(
 303             count += (ItemsTime_time[it.m_id] != -1);
 304         ));
 305         count += (ItemsTime_time[Items_MAX] != -1);
 306     }
 307     if (count == 0)
 308         return;
 309
 310     HUD_Panel_LoadCvars();
 311
 312     vector pos, mySize;
 313     pos = panel_pos;
 314     mySize = panel_size;
 315
 316     if (panel_bg_padding)
 317     {
 318         pos += '1 1 0' * panel_bg_padding;
 319         mySize -= '2 2 0' * panel_bg_padding;
 320     }
 321
 322     float rows, columns;
 323     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 324     rows = HUD_GetRowCount(count, mySize, ar);
 325     columns = ceil(count/rows);
 326
 327     vector itemstime_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
 328
 329     vector offset = '0 0 0';
 330     float newSize;
 331     if (autocvar_hud_panel_itemstime_dynamicsize)
 332     {
 333         if (autocvar__hud_configure)
 334         if (hud_configure_menu_open != 2)
 335             HUD_Panel_DrawBg(); // also draw the bg of the entire panel
 336
 337         // reduce panel to avoid spacing items
 338         if (itemstime_size.x / itemstime_size.y < ar)
 339         {
 340             newSize = rows * itemstime_size.x / ar;
 341             pos.y += (mySize.y - newSize) / 2;
 342             mySize.y = newSize;
 343             itemstime_size.y = mySize.y / rows;
 344         }
 345         else
 346         {
 347             newSize = columns * itemstime_size.y * ar;
 348             pos.x += (mySize.x - newSize) / 2;
 349             mySize.x = newSize;
 350             itemstime_size.x = mySize.x / columns;
 351         }
 352         panel_pos = pos - '1 1 0' * panel_bg_padding;
 353         panel_size = mySize + '2 2 0' * panel_bg_padding;
 354     }
 355     else
 356     {
 357         if (itemstime_size.x/itemstime_size.y > ar)
 358         {
 359             newSize = ar * itemstime_size.y;
 360             offset.x = itemstime_size.x - newSize;
 361             pos.x += offset.x/2;
 362             itemstime_size.x = newSize;
 363         }
 364         else
 365         {
 366             newSize = 1/ar * itemstime_size.x;
 367             offset.y = itemstime_size.y - newSize;
 368             pos.y += offset.y/2;
 369             itemstime_size.y = newSize;
 370         }
 371     }
 372
 373     HUD_Scale_Enable();
 374     HUD_Panel_DrawBg();
 375
 376     float row = 0, column = 0;
 377     bool item_available;
 378     int id = 0;
 379     string icon = "";
 380     FOREACH(Items, Item_ItemsTime_Allow(it) && ItemsTime_time[it.m_id] != -1, LAMBDA(
 381         id = it.m_id;
 382         icon = it.m_icon;
 383
 384 LABEL(iteration)
 385         float item_time = ItemsTime_time[id];
 386         if (item_time < -1)
 387         {
 388             item_available = true;
 389             item_time = -item_time;
 390         }
 391         else
 392             item_available = (item_time <= time);
 393
 394         if (ItemsTime_time[id] >= 0)
 395         {
 396             if (time <= ItemsTime_time[id])
 397                 ItemsTime_availableTime[id] = 0;
 398             else if (ItemsTime_availableTime[id] == 0)
 399                 ItemsTime_availableTime[id] = time;
 400         }
 401         else if (ItemsTime_availableTime[id] == 0)
 402             ItemsTime_availableTime[id] = time;
 403
 404         float f = (time - ItemsTime_availableTime[id]) * 2;
 405         f = (f > 1) ? 0 : bound(0, f, 1);
 406
 407         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 408             if (!(ItemsTime_time[id] > time || -ItemsTime_time[id] > time))
 409                 continue;
 410
 411         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 412             if (!(ItemsTime_time[id] > time))
 413                 continue;
 414
 415         DrawItemsTimeItem(pos + eX * column * (itemstime_size.x + offset.x) + eY * row * (itemstime_size.y + offset.y), itemstime_size, ar, icon, item_time, item_available, f);
 416         ++row;
 417         if (row >= rows)
 418         {
 419             row = 0;
 420             column = column + 1;
 421         }
 422         if(id == Items_MAX) // can happen only in the last fake iteration
 423                 break;
 424     ));
 425     // add another fake iteration for superweapons time
 426     if(id < Items_MAX && ItemsTime_time[Items_MAX] != -1)
 427     {
 428                 id = Items_MAX;
 429                 icon = "superweapons";
 430                 goto iteration;
 431     }
 432 }
 433
 434 #endif