qcsrc/common/mutators/mutator/itemstime/itemstime.qc

   1 #include "itemstime.qh"
   2
   3 REGISTER_MUTATOR(itemstime, true);
   4
   5 REGISTER_NET_TEMP(itemstime)
   6
   7 #ifdef SVQC
   8 void IT_Write(entity e, int i, float f) {
   9     if (!IS_REAL_CLIENT(e)) return;
  10     msg_entity = e;
  11     WriteHeader(MSG_ONE, itemstime);
  12     WriteByte(MSG_ONE, i);
  13     WriteFloat(MSG_ONE, f);
  14 }
  15 #endif
  16
  17 #ifdef CSQC
  18 // reserve one more spot for superweapons time
  19 float ItemsTime_time[Items_MAX + 1];
  20 float ItemsTime_availableTime[Items_MAX + 1];
  21 NET_HANDLE(itemstime, bool isNew)
  22 {
  23     int i = ReadByte();
  24     float f = ReadFloat();
  25     return = true;
  26     ItemsTime_time[i] = f;
  27 }
  28 #endif
  29
  30 #ifdef CSQC
  31 void Item_ItemsTime_Init()
  32 {
  33     FOREACH(Items, true, {
  34         ItemsTime_time[it.m_id] = -1;
  35     });
  36     ItemsTime_time[Items_MAX] = -1;
  37 }
  38
  39 STATIC_INIT(ItemsTime_Init) {
  40     Item_ItemsTime_Init();
  41 }
  42
  43 int autocvar_hud_panel_itemstime = 2;
  44 float autocvar_hud_panel_itemstime_dynamicsize = 1;
  45 float autocvar_hud_panel_itemstime_ratio = 2;
  46 int autocvar_hud_panel_itemstime_iconalign;
  47 bool autocvar_hud_panel_itemstime_progressbar = 0;
  48 float autocvar_hud_panel_itemstime_progressbar_maxtime = 30;
  49 string autocvar_hud_panel_itemstime_progressbar_name = "progressbar";
  50 float autocvar_hud_panel_itemstime_progressbar_reduced;
  51 bool autocvar_hud_panel_itemstime_hidespawned = 1;
  52 bool autocvar_hud_panel_itemstime_hidebig = false;
  53 int autocvar_hud_panel_itemstime_text = 1;
  54 #define hud_panel_itemstime_hidebig autocvar_hud_panel_itemstime_hidebig
  55 #else
  56 #define hud_panel_itemstime_hidebig false
  57 #endif
  58
  59 bool Item_ItemsTime_SpectatorOnly(GameItem it)
  60 {
  61     return (false
  62     || it == ITEM_ArmorMega     || (it == ITEM_ArmorBig && !hud_panel_itemstime_hidebig)
  63     || it == ITEM_HealthMega    || (it == ITEM_HealthBig && !hud_panel_itemstime_hidebig)
  64     );
  65 }
  66
  67 bool Item_ItemsTime_Allow(GameItem it)
  68 {
  69     return (false
  70     || it.instanceOfPowerup
  71     || Item_ItemsTime_SpectatorOnly(it)
  72     );
  73 }
  74
  75 #ifdef SVQC
  76
  77 // reserve one more spot for superweapons time
  78 float it_times[Items_MAX + 1];
  79
  80 void Item_ItemsTime_Init()
  81 {
  82     FOREACH(Items, Item_ItemsTime_Allow(it), {
  83         it_times[it.m_id] = -1;
  84     });
  85     it_times[Items_MAX] = -1;
  86 }
  87
  88 STATIC_INIT(ItemsTime_Init) {
  89     // items time
  90     Item_ItemsTime_Init();
  91 }
  92
  93 void Item_ItemsTime_ResetTimes()
  94 {
  95     FOREACH(Items, Item_ItemsTime_Allow(it), {
  96         it_times[it.m_id] = (it_times[it.m_id] == -1) ? -1 : 0;
  97     });
  98     it_times[Items_MAX] = (it_times[Items_MAX] == -1) ? -1 : 0;
  99 }
 100
 101 void Item_ItemsTime_ResetTimesForPlayer(entity e)
 102 {
 103     FOREACH(Items, Item_ItemsTime_Allow(it), {
 104         IT_Write(e, it.m_id, (it_times[it.m_id] == -1) ? -1 : 0);
 105     });
 106     IT_Write(e, Items_MAX, (it_times[Items_MAX] == -1) ? -1 : 0);
 107 }
 108
 109 void Item_ItemsTime_SetTimesForPlayer(entity e)
 110 {
 111     FOREACH(Items, Item_ItemsTime_Allow(it), {
 112         IT_Write(e, it.m_id, it_times[it.m_id]);
 113     });
 114     IT_Write(e, Items_MAX, it_times[Items_MAX]);
 115 }
 116
 117 void Item_ItemsTime_SetTime(entity e, float t)
 118 {
 119     if (!autocvar_sv_itemstime)
 120         return;
 121
 122     GameItem item = e.itemdef;
 123     if (item.instanceOfGameItem)
 124     {
 125                 if (!item.instanceOfWeaponPickup)
 126                         it_times[item.m_id] = t;
 127                 else if (e.weapons & WEPSET_SUPERWEAPONS)
 128                         it_times[Items_MAX] = t;
 129     }
 130 }
 131
 132 void Item_ItemsTime_SetTimesForAllPlayers()
 133 {
 134     FOREACH_CLIENT(IS_REAL_CLIENT(it) && (warmup_stage || !IS_PLAYER(it) || autocvar_sv_itemstime == 2), { Item_ItemsTime_SetTimesForPlayer(it); });
 135 }
 136
 137 float Item_ItemsTime_UpdateTime(entity e, float t)
 138 {
 139     bool isavailable = (t == 0);
 140     IL_EACH(g_items, it != e,
 141     {
 142         if(!(it.itemdef == e.itemdef || ((e.weapons & WEPSET_SUPERWEAPONS) && (it.weapons & WEPSET_SUPERWEAPONS))))
 143             continue;
 144         if (it.scheduledrespawntime <= time)
 145             isavailable = true;
 146         else if (t == 0 || it.scheduledrespawntime < t)
 147             t = it.scheduledrespawntime;
 148     });
 149     if (isavailable)
 150         t = -t; // let know the client there's another available item
 151     return t;
 152 }
 153
 154 MUTATOR_HOOKFUNCTION(itemstime, reset_map_global)
 155 {
 156     Item_ItemsTime_ResetTimes();
 157     // ALL the times need to be reset before .reset()ing each item
 158     // since Item_Reset schedules respawn of superweapons and powerups
 159     IL_EACH(g_items, it.reset,
 160     {
 161         Item_ItemsTime_SetTime(it, 0);
 162     });
 163     Item_ItemsTime_SetTimesForAllPlayers();
 164 }
 165
 166 MUTATOR_HOOKFUNCTION(itemstime, MakePlayerObserver)
 167 {
 168     entity player = M_ARGV(0, entity);
 169
 170     Item_ItemsTime_SetTimesForPlayer(player);
 171 }
 172
 173 MUTATOR_HOOKFUNCTION(itemstime, ClientConnect, CBC_ORDER_LAST)
 174 {
 175     entity player = M_ARGV(0, entity);
 176
 177         if(IS_PLAYER(player))
 178         {
 179                 // client became player on connection skipping putObserverInServer step
 180                 if (IS_REAL_CLIENT(player))
 181                 if (warmup_stage || autocvar_sv_itemstime == 2)
 182                         Item_ItemsTime_SetTimesForPlayer(player);
 183         }
 184 }
 185
 186 MUTATOR_HOOKFUNCTION(itemstime, PlayerSpawn)
 187 {
 188     if (warmup_stage || autocvar_sv_itemstime == 2) return;
 189     entity player = M_ARGV(0, entity);
 190
 191     Item_ItemsTime_ResetTimesForPlayer(player);
 192 }
 193
 194 #endif
 195
 196 #ifdef CSQC
 197
 198 void DrawItemsTimeItem(vector myPos, vector mySize, float ar, string item_icon, float item_time, bool item_available, float item_availableTime)
 199 {
 200     float t = 0;
 201     vector color = '0 0 0';
 202     float picalpha;
 203
 204     if (autocvar_hud_panel_itemstime_hidespawned == 2)
 205         picalpha = 1;
 206     else if (item_available)
 207     {
 208         float BLINK_FACTOR = 0.15;
 209         float BLINK_BASE = 0.85;
 210         float BLINK_FREQ = 5;
 211         picalpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
 212     }
 213     else
 214         picalpha = 0.5;
 215     t = floor(item_time - time + 0.999);
 216     if (t < 5)
 217         color = '0.7 0 0';
 218     else if (t < 10)
 219         color = '0.7 0.7 0';
 220     else
 221         color = '1 1 1';
 222
 223     vector picpos, numpos;
 224     if (autocvar_hud_panel_itemstime_iconalign)
 225     {
 226         numpos = myPos;
 227         picpos = myPos + eX * (ar - 1) * mySize_y;
 228     }
 229     else
 230     {
 231         numpos = myPos + eX * mySize_y;
 232         picpos = myPos;
 233     }
 234
 235     if (t > 0 && autocvar_hud_panel_itemstime_progressbar)
 236     {
 237         vector p_pos, p_size;
 238         if (autocvar_hud_panel_itemstime_progressbar_reduced)
 239         {
 240             p_pos = numpos;
 241             p_size = vec2(((ar - 1)/ar) * mySize.x, mySize.y);
 242         }
 243         else
 244         {
 245             p_pos = myPos;
 246             p_size = mySize;
 247         }
 248         HUD_Panel_DrawProgressBar(p_pos, p_size, autocvar_hud_panel_itemstime_progressbar_name, t/autocvar_hud_panel_itemstime_progressbar_maxtime, 0, autocvar_hud_panel_itemstime_iconalign, color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 249     }
 250
 251     if(autocvar_hud_panel_itemstime_text)
 252     {
 253         if(t > 0)
 254             drawstring_aspect(numpos, ftos(t), vec2(((ar - 1)/ar) * mySize.x, mySize.y), color, panel_fg_alpha, DRAWFLAG_NORMAL);
 255         else if(precache_pic("gfx/hud/default/checkmark")) // COMPAT: check if this image exists, as 0.8.1 clients lack it
 256             drawpic_aspect_skin(numpos, "checkmark", vec2((ar - 1) * mySize.y, mySize.y), '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 257         else // legacy code, if the image is missing just center the icon
 258             picpos.x = myPos.x + mySize.x / 2 - mySize.y / 2;
 259     }
 260     if (item_availableTime)
 261         drawpic_aspect_skin_expanding(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL, item_availableTime);
 262     drawpic_aspect_skin(picpos, item_icon, '1 1 0' * mySize_y, '1 1 1', panel_fg_alpha * picalpha, DRAWFLAG_NORMAL);
 263 }
 264
 265 float Item_ItemsTime_GetTime(int item)
 266 {
 267     if(autocvar__hud_configure)
 268     {
 269         switch(item)
 270         {
 271             case ITEM_ArmorMega.m_id: return time + 0;
 272             case ITEM_HealthMega.m_id: return time + 8;
 273             case ITEM_Strength.m_id: return time + 0;
 274             case ITEM_Shield.m_id: return time + 4;
 275         }
 276
 277         return -1; // don't show others
 278     }
 279     else
 280         return ItemsTime_time[item];
 281 }
 282
 283 void HUD_ItemsTime()
 284 {
 285     if (!autocvar__hud_configure)
 286     {
 287         if (!(
 288             (autocvar_hud_panel_itemstime == 1 && spectatee_status != 0)
 289         ||      (autocvar_hud_panel_itemstime == 2 && (spectatee_status != 0 || warmup_stage || STAT(ITEMSTIME) == 2))
 290             )) { return; }
 291     }
 292
 293     int count = 0;
 294     if (autocvar_hud_panel_itemstime_hidespawned == 1)
 295     {
 296         FOREACH(Items, Item_ItemsTime_Allow(it), {
 297             count += (Item_ItemsTime_GetTime(it.m_id) > time || -Item_ItemsTime_GetTime(it.m_id) > time);
 298         });
 299         count += (Item_ItemsTime_GetTime(Items_MAX) > time || -Item_ItemsTime_GetTime(Items_MAX) > time);
 300     }
 301     else if (autocvar_hud_panel_itemstime_hidespawned == 2)
 302     {
 303         FOREACH(Items, Item_ItemsTime_Allow(it), {
 304             count += (Item_ItemsTime_GetTime(it.m_id) > time);
 305         });
 306         count += (Item_ItemsTime_GetTime(Items_MAX) > time);
 307     }
 308     else
 309     {
 310         FOREACH(Items, Item_ItemsTime_Allow(it), {
 311             count += (Item_ItemsTime_GetTime(it.m_id) != -1);
 312         });
 313         count += (Item_ItemsTime_GetTime(Items_MAX) != -1);
 314     }
 315     if (count == 0)
 316         return;
 317
 318     HUD_Panel_LoadCvars();
 319
 320     vector pos, mySize;
 321     pos = panel_pos;
 322     mySize = panel_size;
 323
 324     if (panel_bg_padding)
 325     {
 326         pos += '1 1 0' * panel_bg_padding;
 327         mySize -= '2 2 0' * panel_bg_padding;
 328     }
 329
 330     float rows, columns;
 331     float ar = max(2, autocvar_hud_panel_itemstime_ratio) + 1;
 332     rows = HUD_GetRowCount(count, mySize, ar);
 333     columns = ceil(count/rows);
 334
 335     vector itemstime_size = vec2(mySize.x / columns, mySize.y / rows);
 336
 337     vector offset = '0 0 0';
 338     float newSize;
 339     if (autocvar_hud_panel_itemstime_dynamicsize)
 340     {
 341         if (autocvar__hud_configure)
 342         if (hud_configure_menu_open != 2)
 343             HUD_Panel_DrawBg(); // also draw the bg of the entire panel
 344
 345         // reduce panel to avoid spacing items
 346         if (itemstime_size.x / itemstime_size.y < ar)
 347         {
 348             newSize = rows * itemstime_size.x / ar;
 349             pos.y += (mySize.y - newSize) / 2;
 350             mySize.y = newSize;
 351             itemstime_size.y = mySize.y / rows;
 352         }
 353         else
 354         {
 355             newSize = columns * itemstime_size.y * ar;
 356             pos.x += (mySize.x - newSize) / 2;
 357             mySize.x = newSize;
 358             itemstime_size.x = mySize.x / columns;
 359         }
 360         panel_pos = pos - '1 1 0' * panel_bg_padding;
 361         panel_size = mySize + '2 2 0' * panel_bg_padding;
 362     }
 363     else
 364     {
 365         if (itemstime_size.x/itemstime_size.y > ar)
 366         {
 367             newSize = ar * itemstime_size.y;
 368             offset.x = itemstime_size.x - newSize;
 369             pos.x += offset.x/2;
 370             itemstime_size.x = newSize;
 371         }
 372         else
 373         {
 374             newSize = 1/ar * itemstime_size.x;
 375             offset.y = itemstime_size.y - newSize;
 376             pos.y += offset.y/2;
 377             itemstime_size.y = newSize;
 378         }
 379     }
 380
 381     HUD_Scale_Enable();
 382     HUD_Panel_DrawBg();
 383
 384     float row = 0, column = 0;
 385     bool item_available;
 386     int id = 0;
 387     string icon = "";
 388     FOREACH(Items, Item_ItemsTime_Allow(it) && Item_ItemsTime_GetTime(it.m_id) != -1, {
 389         id = it.m_id;
 390         icon = it.m_icon;
 391
 392 LABEL(iteration)
 393         float item_time = Item_ItemsTime_GetTime(id);
 394         if (item_time < -1)
 395         {
 396             item_available = true;
 397             item_time = -item_time;
 398         }
 399         else
 400             item_available = (item_time <= time);
 401
 402         if (Item_ItemsTime_GetTime(id) >= 0)
 403         {
 404             if (time <= Item_ItemsTime_GetTime(id))
 405                 ItemsTime_availableTime[id] = 0;
 406             else if (ItemsTime_availableTime[id] == 0)
 407                 ItemsTime_availableTime[id] = time;
 408         }
 409         else if (ItemsTime_availableTime[id] == 0)
 410             ItemsTime_availableTime[id] = time;
 411
 412         float f = (time - ItemsTime_availableTime[id]) * 2;
 413         f = (f > 1) ? 0 : bound(0, f, 1);
 414
 415         if (autocvar_hud_panel_itemstime_hidespawned == 1)
 416             if (!(Item_ItemsTime_GetTime(id) > time || -Item_ItemsTime_GetTime(id) > time))
 417                 continue;
 418
 419         if (autocvar_hud_panel_itemstime_hidespawned == 2)
 420             if (!(Item_ItemsTime_GetTime(id) > time))
 421                 continue;
 422
 423         DrawItemsTimeItem(pos + vec2(column * (itemstime_size.x + offset.x), row * (itemstime_size.y + offset.y)), itemstime_size, ar, icon, item_time, item_available, f);
 424         ++row;
 425         if (row >= rows)
 426         {
 427             row = 0;
 428             column = column + 1;
 429         }
 430         if(id == Items_MAX) // can happen only in the last fake iteration
 431                 break;
 432     });
 433     // add another fake iteration for superweapons time
 434     if(id < Items_MAX && Item_ItemsTime_GetTime(Items_MAX) != -1)
 435     {
 436                 id = Items_MAX;
 437                 icon = "superweapons";
 438                 goto iteration;
 439     }
 440 }
 441
 442 #endif