qcsrc/common/mutators/mutator/nades/nades.qc

   1 #include "nades.qh"
   2
   3 #include "../overkill/okmachinegun.qh"
   4 #include "../overkill/okshotgun.qh"
   5
   6 #ifdef SVQC
   7 bool autocvar_g_nades_nade_small;
   8 float autocvar_g_nades_spread = 0.04;
   9 #endif
  10
  11 REGISTER_STAT(NADES_SMALL, int, autocvar_g_nades_nade_small)
  12
  13 #ifdef GAMEQC
  14 REPLICATE(cvar_cl_nade_type, int, "cl_nade_type");
  15 REPLICATE(cvar_cl_pokenade_type, string, "cl_pokenade_type");
  16
  17 entity Nade_TrailEffect(int proj, int nade_team)
  18 {
  19     switch (proj)
  20     {
  21         case PROJECTILE_NADE:       return EFFECT_NADE_TRAIL(nade_team);
  22         case PROJECTILE_NADE_BURN:  return EFFECT_NADE_TRAIL_BURN(nade_team);
  23     }
  24
  25     FOREACH(Nades, true, {
  26         for (int j = 0; j < 2; j++)
  27         {
  28             if (it.m_projectile[j] == proj)
  29             {
  30                 string trail = it.m_trail[j].eent_eff_name;
  31                 if (trail) return it.m_trail[j];
  32                 break;
  33             }
  34         }
  35     });
  36
  37     return EFFECT_Null;
  38 }
  39 #endif
  40
  41 #ifdef CSQC
  42 REGISTER_MUTATOR(cl_nades, true);
  43 MUTATOR_HOOKFUNCTION(cl_nades, HUD_Draw_overlay)
  44 {
  45         // TODO: make a common orb state!
  46         if (STAT(HEALING_ORB) > time)
  47         {
  48                 M_ARGV(0, vector) = NADE_TYPE_HEAL.m_color;
  49                 M_ARGV(1, float) = STAT(HEALING_ORB_ALPHA);
  50                 return true;
  51         }
  52         if (STAT(ENTRAP_ORB) > time)
  53         {
  54                 M_ARGV(0, vector) = NADE_TYPE_ENTRAP.m_color;
  55                 M_ARGV(1, float) = STAT(ENTRAP_ORB_ALPHA);
  56                 return true;
  57         }
  58         if (STAT(VEIL_ORB) > time)
  59         {
  60                 M_ARGV(0, vector) = NADE_TYPE_VEIL.m_color;
  61                 M_ARGV(1, float) = STAT(VEIL_ORB_ALPHA);
  62                 return true;
  63         }
  64         return false;
  65 }
  66 MUTATOR_HOOKFUNCTION(cl_nades, Ent_Projectile)
  67 {
  68         entity proj = M_ARGV(0, entity);
  69
  70         if (proj.cnt == PROJECTILE_NAPALM_FOUNTAIN)
  71         {
  72                 proj.modelindex = 0;
  73                 proj.traileffect = EFFECT_FIREBALL.m_id;
  74                 return true;
  75         }
  76         if (Nade_FromProjectile(proj.cnt) != NADE_TYPE_Null)
  77         {
  78                 setmodel(proj, MDL_PROJECTILE_NADE);
  79                 entity trail = Nade_TrailEffect(proj.cnt, proj.team);
  80                 if (trail.eent_eff_name) proj.traileffect = trail.m_id;
  81                 return true;
  82         }
  83 }
  84 MUTATOR_HOOKFUNCTION(cl_nades, EditProjectile)
  85 {
  86         entity proj = M_ARGV(0, entity);
  87
  88         if (proj.cnt == PROJECTILE_NAPALM_FOUNTAIN)
  89         {
  90                 loopsound(proj, CH_SHOTS_SINGLE, SND_FIREBALL_FLY2, VOL_BASE, ATTEN_NORM);
  91                 proj.mins = '-16 -16 -16';
  92                 proj.maxs = '16 16 16';
  93         }
  94
  95         entity nade_type = Nade_FromProjectile(proj.cnt);
  96         if (nade_type == NADE_TYPE_Null) return;
  97         if(STAT(NADES_SMALL))
  98         {
  99                 proj.mins = '-8 -8 -8';
 100                 proj.maxs = '8 8 8';
 101         }
 102         else
 103         {
 104                 proj.mins = '-16 -16 -16';
 105                 proj.maxs = '16 16 16';
 106         }
 107         proj.colormod = nade_type.m_color;
 108         set_movetype(proj, MOVETYPE_BOUNCE);
 109         settouch(proj, func_null);
 110         proj.scale = 1.5;
 111         proj.avelocity = randomvec() * 720;
 112         proj.alphamod = nade_type.m_alpha;
 113
 114         if (nade_type == NADE_TYPE_TRANSLOCATE || nade_type == NADE_TYPE_SPAWN)
 115                 proj.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 116         else
 117                 proj.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 118 }
 119 bool Projectile_isnade(int p)
 120 {
 121         return Nade_FromProjectile(p) != NADE_TYPE_Null;
 122 }
 123 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 124 {
 125         float bonusNades    = STAT(NADE_BONUS);
 126         float bonusProgress = STAT(NADE_BONUS_SCORE);
 127         float bonusType     = STAT(NADE_BONUS_TYPE);
 128         Nade def = Nades_from(bonusType);
 129         vector nadeColor    = def.m_color;
 130         string nadeIcon     = def.m_icon;
 131
 132         vector iconPos, textPos;
 133
 134         if(autocvar_hud_panel_ammo_iconalign)
 135         {
 136                 iconPos = myPos + eX * 2 * mySize.y;
 137                 textPos = myPos;
 138         }
 139         else
 140         {
 141                 iconPos = myPos;
 142                 textPos = myPos + eX * mySize.y;
 143         }
 144
 145         if(bonusNades > 0 || bonusProgress > 0)
 146         {
 147                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
 148
 149                 if(autocvar_hud_panel_ammo_text)
 150                         drawstring_aspect(textPos, ftos(bonusNades), vec2((2/3) * mySize.x, mySize.y), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 151
 152                 if(draw_expanding)
 153                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
 154
 155                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 156         }
 157 }
 158 #endif
 159
 160 #ifdef SVQC
 161
 162 #include <common/gamemodes/_mod.qh>
 163 #include <common/monsters/sv_spawn.qh>
 164 #include <common/monsters/sv_monsters.qh>
 165
 166 REGISTER_MUTATOR(nades, autocvar_g_nades);
 167
 168 .float nade_time_primed;
 169 .float nade_lifetime;
 170
 171 .entity nade_spawnloc;
 172
 173
 174 void nade_timer_think(entity this)
 175 {
 176         this.skin = 8 - (this.owner.wait - time) / (this.owner.nade_lifetime / 10);
 177         this.nextthink = time;
 178         if(!this.owner || wasfreed(this.owner))
 179                 delete(this);
 180 }
 181
 182 void nade_burn_spawn(entity _nade)
 183 {
 184         CSQCProjectile(_nade, true, Nades_from(STAT(NADE_BONUS_TYPE, _nade)).m_projectile[true], true);
 185 }
 186
 187 void nade_spawn(entity _nade)
 188 {
 189         entity timer = new(nade_timer);
 190         setmodel(timer, MDL_NADE_TIMER);
 191         setattachment(timer, _nade, "");
 192         timer.colormap = _nade.colormap;
 193         timer.glowmod = _nade.glowmod;
 194         setthink(timer, nade_timer_think);
 195         timer.nextthink = time;
 196         timer.wait = _nade.wait;
 197         timer.owner = _nade;
 198         timer.skin = 10;
 199
 200         _nade.effects |= EF_LOWPRECISION;
 201
 202         CSQCProjectile(_nade, true, Nades_from(STAT(NADE_BONUS_TYPE, _nade)).m_projectile[false], true);
 203 }
 204
 205 void napalm_damage(entity this, float dist, float damage, float edgedamage, float burntime)
 206 {
 207         entity e;
 208         float d;
 209         vector p;
 210
 211         if ( damage < 0 )
 212                 return;
 213
 214         RandomSelection_Init();
 215         for(e = WarpZone_FindRadius(this.origin, dist, true); e; e = e.chain)
 216                 if(e.takedamage == DAMAGE_AIM)
 217                 if(this.realowner != e || autocvar_g_nades_napalm_selfdamage)
 218                 if(!IS_PLAYER(e) || !this.realowner || DIFF_TEAM(e, this))
 219                 if(!STAT(FROZEN, e))
 220                 {
 221                         p = e.origin;
 222                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
 223                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
 224                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
 225                         d = vlen(WarpZone_UnTransformOrigin(e, this.origin) - p);
 226                         if(d < dist)
 227                         {
 228                                 e.fireball_impactvec = p;
 229                                 RandomSelection_AddEnt(e, 1 / (1 + d), !Fire_IsBurning(e));
 230                         }
 231                 }
 232         if(RandomSelection_chosen_ent)
 233         {
 234                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, this.origin) - RandomSelection_chosen_ent.fireball_impactvec);
 235                 d = damage + (edgedamage - damage) * (d / dist);
 236                 Fire_AddDamage(RandomSelection_chosen_ent, this.realowner, d * burntime, burntime, this.projectiledeathtype);
 237                 //trailparticles(this, particleeffectnum(EFFECT_FIREBALL_LASER), this.origin, RandomSelection_chosen_ent.fireball_impactvec);
 238                 Send_Effect(EFFECT_FIREBALL_LASER, this.origin, RandomSelection_chosen_ent.fireball_impactvec - this.origin, 1);
 239         }
 240 }
 241
 242
 243 void napalm_ball_think(entity this)
 244 {
 245         if(round_handler_IsActive())
 246         if(!round_handler_IsRoundStarted())
 247         {
 248                 delete(this);
 249                 return;
 250         }
 251
 252         if(time > this.pushltime)
 253         {
 254                 delete(this);
 255                 return;
 256         }
 257
 258         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 259         if(pointcontents(midpoint) == CONTENT_WATER)
 260         {
 261                 this.velocity = this.velocity * 0.5;
 262
 263                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 264                         { this.velocity_z = 200; }
 265         }
 266
 267         this.angles = vectoangles(this.velocity);
 268
 269         napalm_damage(this, autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 270                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 271
 272         this.nextthink = time + 0.1;
 273 }
 274
 275
 276 void nade_napalm_ball(entity this)
 277 {
 278         entity proj;
 279         vector kick;
 280
 281         spamsound(this, CH_SHOTS, SND_FIREBALL_FIRE, VOL_BASE, ATTEN_NORM);
 282
 283         proj = new(grenade);
 284         proj.owner = this.owner;
 285         proj.realowner = this.realowner;
 286         proj.team = this.owner.team;
 287         proj.bot_dodge = true;
 288         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 289         set_movetype(proj, MOVETYPE_BOUNCE);
 290         proj.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
 291         PROJECTILE_MAKETRIGGER(proj);
 292         setmodel(proj, MDL_Null);
 293         proj.scale = 1;//0.5;
 294         setsize(proj, '-4 -4 -4', '4 4 4');
 295         setorigin(proj, this.origin);
 296         setthink(proj, napalm_ball_think);
 297         proj.nextthink = time;
 298         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 299         proj.effects = EF_LOWPRECISION | EF_FLAME;
 300
 301         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 302         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 303         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 304         proj.velocity = kick;
 305
 306         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 307
 308         proj.angles = vectoangles(proj.velocity);
 309         proj.flags = FL_PROJECTILE;
 310         IL_PUSH(g_projectiles, proj);
 311         IL_PUSH(g_bot_dodge, proj);
 312         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 313
 314         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
 315 }
 316
 317
 318 void napalm_fountain_think(entity this)
 319 {
 320
 321         if(round_handler_IsActive())
 322         if(!round_handler_IsRoundStarted())
 323         {
 324                 delete(this);
 325                 return;
 326         }
 327
 328         if(time >= this.ltime)
 329         {
 330                 delete(this);
 331                 return;
 332         }
 333
 334         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 335         if(pointcontents(midpoint) == CONTENT_WATER)
 336         {
 337                 this.velocity = this.velocity * 0.5;
 338
 339                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 340                         { this.velocity_z = 200; }
 341
 342                 UpdateCSQCProjectile(this);
 343         }
 344
 345         napalm_damage(this, autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 346                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 347
 348         this.nextthink = time + 0.1;
 349         if(time >= this.nade_special_time)
 350         {
 351                 this.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 352                 nade_napalm_ball(this);
 353         }
 354 }
 355
 356 void nade_napalm_boom(entity this)
 357 {
 358         entity fountain;
 359         int c;
 360         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
 361                 nade_napalm_ball(this);
 362
 363
 364         fountain = spawn();
 365         fountain.owner = this.owner;
 366         fountain.realowner = this.realowner;
 367         fountain.origin = this.origin;
 368         fountain.flags = FL_PROJECTILE;
 369         IL_PUSH(g_projectiles, fountain);
 370         IL_PUSH(g_bot_dodge, fountain);
 371         setorigin(fountain, fountain.origin);
 372         setthink(fountain, napalm_fountain_think);
 373         fountain.nextthink = time;
 374         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 375         fountain.pushltime = fountain.ltime;
 376         fountain.team = this.team;
 377         set_movetype(fountain, MOVETYPE_TOSS);
 378         fountain.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
 379         fountain.bot_dodge = true;
 380         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 381         fountain.nade_special_time = time;
 382         setsize(fountain, '-16 -16 -16', '16 16 16');
 383         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
 384 }
 385
 386 void nade_ice_freeze(entity freezefield, entity frost_target, float freezetime)
 387 {
 388         frost_target.frozen_by = freezefield.realowner;
 389         Send_Effect(EFFECT_ELECTRO_IMPACT, frost_target.origin, '0 0 0', 1);
 390         Freeze(frost_target, 1 / freezetime, FROZEN_TEMP_DYING, false);
 391
 392         Drop_Special_Items(frost_target);
 393 }
 394
 395 void nade_ice_think(entity this)
 396 {
 397         if(round_handler_IsActive())
 398         if(!round_handler_IsRoundStarted())
 399         {
 400                 delete(this);
 401                 return;
 402         }
 403
 404         if(time >= this.ltime)
 405         {
 406                 if ( autocvar_g_nades_ice_explode )
 407                 {
 408                         entity expef = EFFECT_NADE_EXPLODE(this.realowner.team);
 409                         Send_Effect(expef, this.origin + '0 0 1', '0 0 0', 1);
 410                         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 411
 412                         RadiusDamage(this, this.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 413                                 autocvar_g_nades_nade_radius, this, NULL, autocvar_g_nades_nade_force, this.projectiledeathtype, DMG_NOWEP, this.enemy);
 414                         Damage_DamageInfo(this.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 415                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, this.projectiledeathtype, 0, this);
 416                 }
 417                 delete(this);
 418                 return;
 419         }
 420
 421
 422         this.nextthink = time+0.1;
 423
 424         // gaussian
 425         float randomr;
 426         randomr = random();
 427         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 428         float randomw;
 429         randomw = random()*M_PI*2;
 430         vector randomp;
 431         randomp.x = randomr*cos(randomw);
 432         randomp.y = randomr*sin(randomw);
 433         randomp.z = 1;
 434         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, this.origin + randomp, '0 0 0', 1);
 435
 436         if(time >= this.nade_special_time)
 437         {
 438                 this.nade_special_time = time+0.7;
 439
 440                 Send_Effect(EFFECT_ELECTRO_IMPACT, this.origin, '0 0 0', 1);
 441                 Send_Effect(EFFECT_ICEFIELD, this.origin, '0 0 0', 1);
 442         }
 443
 444
 445         float current_freeze_time = this.ltime - time - 0.1;
 446
 447         FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_nades_nade_radius, it != this && it.takedamage && !IS_DEAD(it) && GetResource(it, RES_HEALTH) > 0 && current_freeze_time > 0,
 448         {
 449                 if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(it, this.realowner) || it == this.realowner))
 450                 if(!it.revival_time || ((time - it.revival_time) >= 1.5))
 451                 if(!STAT(FROZEN, it))
 452                         nade_ice_freeze(this, it, current_freeze_time);
 453         });
 454 }
 455
 456 void nade_ice_boom(entity this)
 457 {
 458         entity fountain;
 459         fountain = spawn();
 460         fountain.owner = this.owner;
 461         fountain.realowner = this.realowner;
 462         fountain.origin = this.origin;
 463         setorigin(fountain, fountain.origin);
 464         setthink(fountain, nade_ice_think);
 465         fountain.nextthink = time;
 466         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 467         fountain.pushltime = fountain.wait = fountain.ltime;
 468         fountain.team = this.team;
 469         set_movetype(fountain, MOVETYPE_TOSS);
 470         fountain.projectiledeathtype = DEATH_NADE_ICE.m_id;
 471         fountain.bot_dodge = false;
 472         setsize(fountain, '-16 -16 -16', '16 16 16');
 473         fountain.nade_special_time = time+0.3;
 474         fountain.angles = this.angles;
 475
 476         if ( autocvar_g_nades_ice_explode )
 477         {
 478                 setmodel(fountain, MDL_PROJECTILE_GRENADE);
 479                 entity timer = new(nade_timer);
 480                 setmodel(timer, MDL_NADE_TIMER);
 481                 setattachment(timer, fountain, "");
 482                 timer.colormap = this.colormap;
 483                 timer.glowmod = this.glowmod;
 484                 setthink(timer, nade_timer_think);
 485                 timer.nextthink = time;
 486                 timer.wait = fountain.ltime;
 487                 timer.owner = fountain;
 488                 timer.skin = 10;
 489         }
 490         else
 491                 setmodel(fountain, MDL_Null);
 492 }
 493
 494 void nade_translocate_boom(entity this)
 495 {
 496         if(this.realowner.vehicle)
 497                 return;
 498
 499         vector locout = this.origin + '0 0 1' * (1 - this.realowner.mins.z - 24);
 500         tracebox(locout, this.realowner.mins, this.realowner.maxs, locout, MOVE_NOMONSTERS, this.realowner);
 501         locout = trace_endpos;
 502
 503         makevectors(this.realowner.angles);
 504
 505         MUTATOR_CALLHOOK(PortalTeleport, this.realowner);
 506
 507         TeleportPlayer(this, this.realowner, locout, this.realowner.angles, v_forward * vlen(this.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 508 }
 509
 510 void nade_spawn_boom(entity this)
 511 {
 512         entity spawnloc = spawn();
 513         setorigin(spawnloc, this.origin);
 514         setsize(spawnloc, this.realowner.mins, this.realowner.maxs);
 515         set_movetype(spawnloc, MOVETYPE_NONE);
 516         spawnloc.solid = SOLID_NOT;
 517         spawnloc.drawonlytoclient = this.realowner;
 518         spawnloc.effects = EF_STARDUST;
 519         spawnloc.cnt = autocvar_g_nades_spawn_count;
 520
 521         if(this.realowner.nade_spawnloc)
 522         {
 523                 delete(this.realowner.nade_spawnloc);
 524                 this.realowner.nade_spawnloc = NULL;
 525         }
 526
 527         this.realowner.nade_spawnloc = spawnloc;
 528 }
 529
 530 void nades_orb_think(entity this)
 531 {
 532         if(time >= this.ltime)
 533         {
 534                 delete(this);
 535                 return;
 536         }
 537
 538         this.nextthink = time;
 539
 540         if(time >= this.nade_special_time)
 541         {
 542                 this.nade_special_time = time+0.25;
 543                 this.nade_show_particles = 1;
 544         }
 545         else
 546                 this.nade_show_particles = 0;
 547 }
 548
 549 entity nades_spawn_orb(entity own, entity realown, vector org, float orb_ltime, float orb_rad)
 550 {
 551         // NOTE: this function merely places an orb
 552         // you must add a custom touch function to the returned entity if desired
 553         // also set .colormod if you wish to have it colorized
 554         entity orb = spawn(); // Net_LinkEntity sets the classname (TODO)
 555         orb.owner = own;
 556         orb.realowner = realown;
 557         setorigin(orb, org);
 558
 559         orb.orb_lifetime = orb_ltime; // required for timers
 560         orb.ltime = time + orb.orb_lifetime;
 561         orb.bot_dodge = false;
 562         orb.team = realown.team;
 563         orb.solid = SOLID_TRIGGER;
 564
 565         setmodel(orb, MDL_NADE_ORB);
 566         orb.skin = 1;
 567         orb.orb_radius = orb_rad; // required for fading
 568         vector size = '1 1 1' * orb.orb_radius / 2;
 569         setsize(orb, -size, size);
 570
 571         Net_LinkEntity(orb, true, 0, orb_send);
 572         orb.SendFlags |= 1;
 573
 574         setthink(orb, nades_orb_think);
 575         orb.nextthink = time;
 576
 577         return orb;
 578 }
 579
 580 void nade_entrap_touch(entity this, entity toucher)
 581 {
 582         if(DIFF_TEAM(toucher, this.realowner)) // TODO: what if realowner changes team or disconnects?
 583         {
 584                 if (!isPushable(toucher))
 585                         return;
 586
 587                 float pushdeltatime = time - toucher.lastpushtime;
 588                 if (pushdeltatime > 0.15) pushdeltatime = 0;
 589                 toucher.lastpushtime = time;
 590                 if(!pushdeltatime) return;
 591
 592                 // div0: ticrate independent, 1 = identity (not 20)
 593                 toucher.velocity = toucher.velocity * (autocvar_g_nades_entrap_strength ** pushdeltatime);
 594
 595         #ifdef SVQC
 596                 UpdateCSQCProjectile(toucher);
 597         #endif
 598         }
 599
 600         if ( IS_REAL_CLIENT(toucher) || IS_VEHICLE(toucher) || IS_MONSTER(toucher) )
 601         {
 602                 entity show_tint = (IS_VEHICLE(toucher)) ? toucher.owner : toucher;
 603                 STAT(ENTRAP_ORB, show_tint) = time + 0.1;
 604
 605                 float tint_alpha = 0.75;
 606                 if(SAME_TEAM(toucher, this.realowner))
 607                         tint_alpha = 0.45;
 608                 STAT(ENTRAP_ORB_ALPHA, show_tint) = tint_alpha * (this.ltime - time) / this.orb_lifetime;
 609         }
 610 }
 611
 612 void nade_entrap_boom(entity this)
 613 {
 614         entity orb = nades_spawn_orb(this.owner, this.realowner, this.origin, autocvar_g_nades_entrap_time, autocvar_g_nades_entrap_radius);
 615
 616         settouch(orb, nade_entrap_touch);
 617         orb.colormod = NADE_TYPE_ENTRAP.m_color;
 618 }
 619
 620 void nade_heal_touch(entity this, entity toucher)
 621 {
 622         float maxhealth;
 623         float health_factor;
 624         if(IS_PLAYER(toucher) || IS_MONSTER(toucher))
 625         if(!IS_DEAD(toucher))
 626         if(!STAT(FROZEN, toucher))
 627         {
 628                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 629                 if ( toucher != this.realowner )
 630                 {
 631                         if ( SAME_TEAM(toucher,this) )
 632                                 health_factor *= autocvar_g_nades_heal_friend;
 633                         else
 634                                 health_factor *= autocvar_g_nades_heal_foe;
 635                 }
 636                 if ( health_factor > 0 )
 637                 {
 638                         maxhealth = (IS_MONSTER(toucher)) ? toucher.max_health : g_pickup_healthmega_max;
 639                         float hp = GetResource(toucher, RES_HEALTH);
 640                         if (hp < maxhealth)
 641                         {
 642                                 if (this.nade_show_particles)
 643                                 {
 644                                         Send_Effect(EFFECT_HEALING, toucher.origin, '0 0 0', 1);
 645                                 }
 646                                 GiveResourceWithLimit(toucher, RES_HEALTH, health_factor, maxhealth);
 647                         }
 648                 }
 649                 else if ( health_factor < 0 )
 650                 {
 651                         Damage(toucher,this,this.realowner,-health_factor,DEATH_NADE_HEAL.m_id,DMG_NOWEP,toucher.origin,'0 0 0');
 652                 }
 653
 654         }
 655
 656         if ( IS_REAL_CLIENT(toucher) || IS_VEHICLE(toucher) )
 657         {
 658                 entity show_red = (IS_VEHICLE(toucher)) ? toucher.owner : toucher;
 659                 STAT(HEALING_ORB, show_red) = time+0.1;
 660                 STAT(HEALING_ORB_ALPHA, show_red) = 0.75 * (this.ltime - time) / this.orb_lifetime;
 661         }
 662 }
 663
 664 void nade_heal_boom(entity this)
 665 {
 666         entity orb = nades_spawn_orb(this.owner, this.realowner, this.origin, autocvar_g_nades_heal_time, autocvar_g_nades_nade_radius);
 667
 668         settouch(orb, nade_heal_touch);
 669         orb.colormod = '1 0 0';
 670 }
 671
 672 void nade_monster_boom(entity this)
 673 {
 674         entity e = spawnmonster(spawn(), this.pokenade_type, 0, this.realowner, this.realowner, this.origin, false, false, 1);
 675
 676         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 677                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 678         e.monster_skill = MONSTER_SKILL_INSANE;
 679 }
 680
 681 void nade_veil_touch(entity this, entity toucher)
 682 {
 683         if ( IS_REAL_CLIENT(toucher) || IS_VEHICLE(toucher) || IS_MONSTER(toucher) )
 684         {
 685                 entity show_tint = (IS_VEHICLE(toucher)) ? toucher.owner : toucher;
 686
 687                 float tint_alpha = 0.75;
 688                 if(SAME_TEAM(toucher, this.realowner))
 689                 {
 690                         tint_alpha = 0.45;
 691                         if(!STAT(VEIL_ORB, show_tint))
 692                         {
 693                                 toucher.nade_veil_prevalpha = toucher.alpha;
 694                                 toucher.alpha = -1;
 695                         }
 696                 }
 697                 STAT(VEIL_ORB, show_tint) = time + 0.1;
 698                 STAT(VEIL_ORB_ALPHA, show_tint) = tint_alpha * (this.ltime - time) / this.orb_lifetime;
 699         }
 700 }
 701
 702 void nade_veil_boom(entity this)
 703 {
 704         entity orb = nades_spawn_orb(this.owner, this.realowner, this.origin, autocvar_g_nades_veil_time, autocvar_g_nades_veil_radius);
 705
 706         settouch(orb, nade_veil_touch);
 707         orb.colormod = NADE_TYPE_VEIL.m_color;
 708 }
 709
 710 void nade_boom(entity this)
 711 {
 712         entity expef = NULL;
 713         bool nade_blast = true;
 714
 715         switch ( Nades_from(STAT(NADE_BONUS_TYPE, this)) )
 716         {
 717                 case NADE_TYPE_NAPALM:
 718                         nade_blast = autocvar_g_nades_napalm_blast;
 719                         expef = EFFECT_EXPLOSION_MEDIUM;
 720                         break;
 721                 case NADE_TYPE_ICE:
 722                         nade_blast = false;
 723                         expef = EFFECT_ELECTRO_COMBO; // hookbomb_explode electro_combo bigplasma_impact
 724                         break;
 725                 case NADE_TYPE_TRANSLOCATE:
 726                         nade_blast = false;
 727                         break;
 728                 case NADE_TYPE_MONSTER:
 729                 case NADE_TYPE_SPAWN:
 730                         nade_blast = false;
 731                         switch(this.realowner.team)
 732                         {
 733                                 case NUM_TEAM_1: expef = EFFECT_SPAWN_RED; break;
 734                                 case NUM_TEAM_2: expef = EFFECT_SPAWN_BLUE; break;
 735                                 case NUM_TEAM_3: expef = EFFECT_SPAWN_YELLOW; break;
 736                                 case NUM_TEAM_4: expef = EFFECT_SPAWN_PINK; break;
 737                                 default: expef = EFFECT_SPAWN_NEUTRAL; break;
 738                         }
 739                         break;
 740                 case NADE_TYPE_HEAL:
 741                         nade_blast = false;
 742                         expef = EFFECT_SPAWN_RED;
 743                         break;
 744
 745                 case NADE_TYPE_ENTRAP:
 746                         nade_blast = false;
 747                         expef = EFFECT_SPAWN_YELLOW;
 748                         break;
 749
 750                 case NADE_TYPE_VEIL:
 751                         nade_blast = false;
 752                         expef = EFFECT_SPAWN_NEUTRAL;
 753                         break;
 754
 755                 default:
 756                 case NADE_TYPE_NORMAL:
 757                         expef = EFFECT_NADE_EXPLODE(this.realowner.team);
 758                         break;
 759         }
 760
 761         if(expef)
 762                 Send_Effect(expef, findbetterlocation(this.origin, 8), '0 0 0', 1);
 763
 764         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 765         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 766
 767         this.event_damage = func_null; // prevent somehow calling damage in the next call
 768
 769         if(nade_blast)
 770         {
 771                 RadiusDamage(this, this.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 772                                  autocvar_g_nades_nade_radius, this, NULL, autocvar_g_nades_nade_force, this.projectiledeathtype, DMG_NOWEP, this.enemy);
 773                 Damage_DamageInfo(this.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, this.projectiledeathtype, 0, this);
 774         }
 775
 776         if(this.takedamage)
 777         switch ( Nades_from(STAT(NADE_BONUS_TYPE, this)) )
 778         {
 779                 case NADE_TYPE_NAPALM: nade_napalm_boom(this); break;
 780                 case NADE_TYPE_ICE: nade_ice_boom(this); break;
 781                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(this); break;
 782                 case NADE_TYPE_SPAWN: nade_spawn_boom(this); break;
 783                 case NADE_TYPE_HEAL: nade_heal_boom(this); break;
 784                 case NADE_TYPE_MONSTER: nade_monster_boom(this); break;
 785                 case NADE_TYPE_ENTRAP: nade_entrap_boom(this); break;
 786                 case NADE_TYPE_VEIL: nade_veil_boom(this); break;
 787         }
 788
 789         IL_EACH(g_projectiles, it.classname == "grapplinghook" && it.aiment == this,
 790         {
 791                 RemoveHook(it);
 792         });
 793
 794         delete(this);
 795 }
 796
 797 void spawn_held_nade(entity player, entity nowner, float ntime, int ntype, string pntype);
 798 void nade_pickup(entity this, entity thenade)
 799 {
 800         spawn_held_nade(this, thenade.realowner, autocvar_g_nades_pickup_time, STAT(NADE_BONUS_TYPE, thenade), thenade.pokenade_type);
 801
 802         // set refire so player can't even
 803         this.nade_refire = time + autocvar_g_nades_nade_refire;
 804         STAT(NADE_TIMER, this) = 0;
 805
 806         if(this.nade)
 807                 this.nade.nade_time_primed = thenade.nade_time_primed;
 808 }
 809
 810 bool CanThrowNade(entity this);
 811 void nade_touch(entity this, entity toucher)
 812 {
 813         if(toucher)
 814                 UpdateCSQCProjectile(this);
 815
 816         if(toucher == this.realowner)
 817                 return; // no this impacts
 818
 819         if(autocvar_g_nades_pickup)
 820         if(time >= this.spawnshieldtime)
 821         if(!toucher.nade && GetResource(this, RES_HEALTH) == this.max_health) // no boosted shot pickups, thank you very much
 822         if(CanThrowNade(toucher)) // prevent some obvious things, like dead players
 823         if(IS_REAL_CLIENT(toucher)) // above checks for IS_PLAYER, don't need to do it here
 824         {
 825                 nade_pickup(toucher, this);
 826                 sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 827                 delete(this);
 828                 return;
 829         }
 830         /*float is_weapclip = 0;
 831         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 832         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 833         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 834                 is_weapclip = 1;*/
 835         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
 836         {
 837                 IL_EACH(g_projectiles, it.classname == "grapplinghook" && it.aiment == this,
 838                 {
 839                         RemoveHook(it);
 840                 });
 841                 delete(this);
 842                 return;
 843         }
 844
 845         PROJECTILE_TOUCH(this, toucher);
 846
 847         //setsize(this, '-2 -2 -2', '2 2 2');
 848         //UpdateCSQCProjectile(this);
 849         if(GetResource(this, RES_HEALTH) == this.max_health)
 850         {
 851                 spamsound(this, CH_SHOTS, SND_GRENADE_BOUNCE_RANDOM(), VOL_BASE, ATTEN_NORM);
 852                 return;
 853         }
 854
 855         this.enemy = toucher;
 856         nade_boom(this);
 857 }
 858
 859 void nade_beep(entity this)
 860 {
 861         sound(this, CH_SHOTS_SINGLE, SND_NADE_BEEP, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 862         setthink(this, nade_boom);
 863         this.nextthink = max(this.wait, time);
 864 }
 865
 866 void nade_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 867 {
 868         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 869         {
 870                 this.takedamage = DAMAGE_NO;
 871                 nade_boom(this);
 872                 return;
 873         }
 874
 875         if(STAT(NADE_BONUS_TYPE, this) == NADE_TYPE_TRANSLOCATE.m_id || STAT(NADE_BONUS_TYPE, this) == NADE_TYPE_SPAWN.m_id)
 876                 return;
 877
 878         if (MUTATOR_CALLHOOK(Nade_Damage, this, DEATH_WEAPONOF(deathtype), force, damage)) {}
 879         else if(DEATH_ISWEAPON(deathtype, WEP_BLASTER))
 880         {
 881                 force *= 1.5;
 882                 damage = 0;
 883         }
 884         else if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) && (deathtype & HITTYPE_SECONDARY))
 885         {
 886                 force *= 0.5; // too much
 887                 damage = 0;
 888         }
 889         else if(DEATH_ISWEAPON(deathtype, WEP_VORTEX) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) || DEATH_ISWEAPON(deathtype, WEP_OVERKILL_NEX))
 890         {
 891                 force *= 6;
 892                 damage = this.max_health * 0.55;
 893         }
 894         else if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN) || DEATH_ISWEAPON(deathtype, WEP_OVERKILL_MACHINEGUN))
 895                 damage = this.max_health * 0.1;
 896         else if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN) || DEATH_ISWEAPON(deathtype, WEP_OVERKILL_SHOTGUN)) // WEAPONTODO
 897         {
 898                 if(!(deathtype & HITTYPE_SECONDARY))
 899                         damage = this.max_health * 1.15;
 900         }
 901
 902         // melee slaps
 903         entity death_weapon = DEATH_WEAPONOF(deathtype);
 904         if(((deathtype & HITTYPE_SECONDARY) ? (death_weapon.spawnflags & WEP_TYPE_MELEE_SEC) : (death_weapon.spawnflags & WEP_TYPE_MELEE_PRI)))
 905         {
 906                 damage = this.max_health * 0.1;
 907                 force *= 10;
 908         }
 909
 910         this.velocity += force;
 911         UpdateCSQCProjectile(this);
 912
 913         if(damage <= 0 || ((IS_ONGROUND(this)) && IS_PLAYER(attacker)))
 914                 return;
 915
 916         float hp = GetResource(this, RES_HEALTH);
 917         if(hp == this.max_health)
 918         {
 919                 sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 920                 this.nextthink = max(time + this.nade_lifetime, time);
 921                 setthink(this, nade_beep);
 922         }
 923
 924         hp -= damage;
 925         SetResource(this, RES_HEALTH, hp);
 926
 927
 928         if ( STAT(NADE_BONUS_TYPE, this) != NADE_TYPE_HEAL.m_id || IS_PLAYER(attacker) )
 929                 this.realowner = attacker;
 930
 931         if(hp <= 0)
 932                 W_PrepareExplosionByDamage(this, attacker, nade_boom);
 933         else
 934                 nade_burn_spawn(this);
 935 }
 936
 937 void toss_nade(entity e, bool set_owner, vector _velocity, float _time)
 938 {
 939         if(e.nade == NULL)
 940                 return;
 941
 942         entity _nade = e.nade;
 943         e.nade = NULL;
 944
 945         delete(e.fake_nade);
 946         e.fake_nade = NULL;
 947
 948         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER, CPID_NADES);
 949
 950         makevectors(e.v_angle);
 951
 952         // NOTE: always throw from first weapon entity?
 953         W_SetupShot(e, _nade.weaponentity_fld, false, false, SND_Null, CH_WEAPON_A, 0, DEATH_NADE.m_id);
 954
 955         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
 956                       + (v_right * autocvar_g_nades_throw_offset.y)
 957                       + (v_up * autocvar_g_nades_throw_offset.z);
 958
 959         setorigin(_nade, w_shotorg + offset);
 960         //setmodel(_nade, MDL_PROJECTILE_NADE);
 961         //setattachment(_nade, NULL, "");
 962         PROJECTILE_MAKETRIGGER(_nade);
 963         if(STAT(NADES_SMALL, e))
 964                 setsize(_nade, '-8 -8 -8', '8 8 8');
 965         else
 966                 setsize(_nade, '-16 -16 -16', '16 16 16');
 967         set_movetype(_nade, MOVETYPE_BOUNCE);
 968
 969         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, MOVE_NOMONSTERS, _nade);
 970         if (trace_startsolid)
 971                 setorigin(_nade, e.origin);
 972
 973         if(e.v_angle.x >= 70 && e.v_angle.x <= 110 && PHYS_INPUT_BUTTON_CROUCH(e))
 974                 _nade.velocity = '0 0 100';
 975         else if(autocvar_g_nades_nade_newton_style == 1)
 976                 _nade.velocity = e.velocity + _velocity;
 977         else if(autocvar_g_nades_nade_newton_style == 2)
 978                 _nade.velocity = _velocity;
 979         else
 980                 _nade.velocity = W_CalculateProjectileVelocity(e, e.velocity, _velocity, true);
 981
 982         if(set_owner)
 983                 _nade.realowner = e;
 984
 985         settouch(_nade, nade_touch);
 986         _nade.spawnshieldtime = time + 0.1; // prevent instantly picking up again
 987         SetResource(_nade, RES_HEALTH, autocvar_g_nades_nade_health);
 988         _nade.max_health = GetResource(_nade, RES_HEALTH);
 989         _nade.takedamage = DAMAGE_AIM;
 990         _nade.event_damage = nade_damage;
 991         setcefc(_nade, func_null);
 992         _nade.exteriormodeltoclient = NULL;
 993         _nade.traileffectnum = 0;
 994         _nade.teleportable = true;
 995         _nade.pushable = true;
 996         _nade.gravity = 1;
 997         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 998         _nade.damagedbycontents = true;
 999         IL_PUSH(g_damagedbycontents, _nade);
1000         _nade.angles = vectoangles(_nade.velocity);
1001         _nade.flags = FL_PROJECTILE;
1002         IL_PUSH(g_projectiles, _nade);
1003         IL_PUSH(g_bot_dodge, _nade);
1004         _nade.projectiledeathtype = DEATH_NADE.m_id;
1005         _nade.toss_time = time;
1006         _nade.solid = SOLID_CORPSE; //((STAT(NADE_BONUS_TYPE, _nade) == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
1007
1008         if(STAT(NADE_BONUS_TYPE, _nade) == NADE_TYPE_TRANSLOCATE.m_id || STAT(NADE_BONUS_TYPE, _nade) == NADE_TYPE_SPAWN.m_id)
1009                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
1010         else
1011                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
1012
1013         nade_spawn(_nade);
1014
1015         if(_time)
1016         {
1017                 setthink(_nade, nade_boom);
1018                 _nade.nextthink = _time;
1019         }
1020
1021         e.nade_refire = time + autocvar_g_nades_nade_refire;
1022         STAT(NADE_TIMER, e) = 0;
1023 }
1024
1025 void nades_GiveBonus(entity player, float score)
1026 {
1027         if (autocvar_g_nades)
1028         if (autocvar_g_nades_bonus)
1029         if (IS_REAL_CLIENT(player))
1030         if (IS_PLAYER(player) && STAT(NADE_BONUS, player) < autocvar_g_nades_bonus_max)
1031         if (!STAT(FROZEN, player))
1032         if (!IS_DEAD(player))
1033         {
1034                 if ( STAT(NADE_BONUS_SCORE, player) < 1 )
1035                         STAT(NADE_BONUS_SCORE, player) += score/autocvar_g_nades_bonus_score_max;
1036
1037                 if ( STAT(NADE_BONUS_SCORE, player) >= 1 )
1038                 {
1039                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
1040                         play2(player, SND(NADE_BONUS));
1041                         STAT(NADE_BONUS, player)++;
1042                         STAT(NADE_BONUS_SCORE, player) -= 1;
1043                 }
1044         }
1045 }
1046
1047 /** Remove all bonus nades from a player */
1048 void nades_RemoveBonus(entity player)
1049 {
1050         STAT(NADE_BONUS, player) = STAT(NADE_BONUS_SCORE, player) = 0;
1051 }
1052
1053 MUTATOR_HOOKFUNCTION(nades, PutClientInServer)
1054 {
1055     entity player = M_ARGV(0, entity);
1056
1057         nades_RemoveBonus(player);
1058 }
1059
1060 bool nade_customize(entity this, entity client)
1061 {
1062         //if(IS_SPEC(client)) { return false; }
1063         if(client == this.exteriormodeltoclient || (IS_SPEC(client) && client.enemy == this.exteriormodeltoclient))
1064         {
1065                 // somewhat hide the model, but keep the glow
1066                 //this.effects = 0;
1067                 if(this.traileffectnum)
1068                         this.traileffectnum = 0;
1069                 this.alpha = -1;
1070         }
1071         else
1072         {
1073                 //this.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
1074                 if(!this.traileffectnum)
1075                         this.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(STAT(NADE_BONUS_TYPE, this)).m_projectile[false], this.team).eent_eff_name);
1076                 this.alpha = 1;
1077         }
1078
1079         return true;
1080 }
1081
1082 void spawn_held_nade(entity player, entity nowner, float ntime, int ntype, string pntype)
1083 {
1084         entity n = new(nade), fn = new(fake_nade);
1085
1086         STAT(NADE_BONUS_TYPE, n) = max(1, ntype);
1087         n.pokenade_type = pntype;
1088
1089         if(Nades_from(STAT(NADE_BONUS_TYPE, n)) == NADE_TYPE_Null)
1090                 STAT(NADE_BONUS_TYPE, n) = NADE_TYPE_NORMAL.m_id;
1091
1092         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
1093
1094         setmodel(n, MDL_PROJECTILE_NADE);
1095         //setattachment(n, player, "bip01 l hand");
1096         n.exteriormodeltoclient = player;
1097         setcefc(n, nade_customize);
1098         n.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(STAT(NADE_BONUS_TYPE, n)).m_projectile[false], player.team).eent_eff_name);
1099         n.colormod = Nades_from(STAT(NADE_BONUS_TYPE, n)).m_color;
1100         n.realowner = nowner;
1101         n.colormap = player.colormap;
1102         n.glowmod = player.glowmod;
1103         n.wait = time + max(0, ntime);
1104         n.nade_time_primed = time;
1105         setthink(n, nade_beep);
1106         n.nextthink = max(n.wait - 3, time);
1107         n.projectiledeathtype = DEATH_NADE.m_id;
1108         n.weaponentity_fld = weaponentity;
1109         n.nade_lifetime = ntime;
1110         n.alpha = Nades_from(STAT(NADE_BONUS_TYPE, n)).m_alpha;
1111
1112         setmodel(fn, MDL_NADE_VIEW);
1113         //setattachment(fn, player.(weaponentity), "");
1114         fn.viewmodelforclient = player;
1115         fn.realowner = fn.owner = player;
1116         fn.colormod = Nades_from(STAT(NADE_BONUS_TYPE, n)).m_color;
1117         fn.colormap = player.colormap;
1118         fn.glowmod = player.glowmod;
1119         setthink(fn, SUB_Remove);
1120         fn.nextthink = n.wait;
1121         fn.weaponentity_fld = weaponentity;
1122         fn.alpha = Nades_from(STAT(NADE_BONUS_TYPE, n)).m_alpha;
1123
1124         player.nade = n;
1125         player.fake_nade = fn;
1126 }
1127
1128 void nade_prime(entity this)
1129 {
1130         if(autocvar_g_nades_bonus_only)
1131         if(!STAT(NADE_BONUS, this))
1132                 return; // only allow bonus nades
1133
1134         if(this.nade)
1135                 delete(this.nade);
1136
1137         if(this.fake_nade)
1138                 delete(this.fake_nade);
1139
1140         int ntype;
1141         string pntype = this.pokenade_type;
1142
1143         if((this.items & ITEM_Strength.m_itemid) && autocvar_g_nades_bonus_onstrength)
1144                 ntype = STAT(NADE_BONUS_TYPE, this);
1145         else if (STAT(NADE_BONUS, this) >= 1)
1146         {
1147                 ntype = STAT(NADE_BONUS_TYPE, this);
1148                 pntype = this.pokenade_type;
1149                 STAT(NADE_BONUS, this) -= 1;
1150         }
1151         else
1152         {
1153                 ntype = ((autocvar_g_nades_client_select) ? CS(this).cvar_cl_nade_type : autocvar_g_nades_nade_type);
1154                 pntype = ((autocvar_g_nades_client_select) ? CS(this).cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
1155         }
1156
1157         spawn_held_nade(this, this, autocvar_g_nades_nade_lifetime, ntype, pntype);
1158 }
1159
1160 bool CanThrowNade(entity this)
1161 {
1162         if(this.vehicle)
1163                 return false;
1164
1165         if(IS_DEAD(this))
1166                 return false;
1167
1168         if (!autocvar_g_nades)
1169                 return false; // allow turning them off mid match
1170
1171         if (weaponLocked(this))
1172                 return false;
1173
1174         if (!IS_PLAYER(this))
1175                 return false;
1176
1177         return true;
1178 }
1179
1180 .bool nade_altbutton;
1181
1182 void nades_CheckThrow(entity this)
1183 {
1184         if(!CanThrowNade(this))
1185                 return;
1186
1187         entity held_nade = this.nade;
1188         if (!held_nade)
1189         {
1190                 this.nade_altbutton = true;
1191                 if(time > this.nade_refire)
1192                 {
1193                         nade_prime(this);
1194                         this.nade_refire = time + autocvar_g_nades_nade_refire;
1195                 }
1196         }
1197         else
1198         {
1199                 this.nade_altbutton = false;
1200                 if (time >= held_nade.nade_time_primed + 1) {
1201                         makevectors(this.v_angle);
1202                         float _force = time - held_nade.nade_time_primed;
1203                         _force /= autocvar_g_nades_nade_lifetime;
1204                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1205                         vector dir = (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05);
1206                         dir = W_CalculateSpread(dir, autocvar_g_nades_spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
1207                         toss_nade(this, true, dir * _force, 0);
1208                 }
1209         }
1210 }
1211
1212 void nades_Clear(entity player)
1213 {
1214         if(player.nade)
1215                 delete(player.nade);
1216         if(player.fake_nade)
1217                 delete(player.fake_nade);
1218
1219         player.nade = player.fake_nade = NULL;
1220         STAT(NADE_TIMER, player) = 0;
1221 }
1222
1223 MUTATOR_HOOKFUNCTION(nades, VehicleEnter)
1224 {
1225         entity player = M_ARGV(0, entity);
1226
1227         if(player.nade)
1228                 toss_nade(player, true, '0 0 100', max(player.nade.wait, time + 0.05));
1229 }
1230
1231 CLASS(NadeOffhand, OffhandWeapon)
1232     METHOD(NadeOffhand, offhand_think, void(NadeOffhand this, entity player, bool key_pressed))
1233     {
1234         entity held_nade = player.nade;
1235
1236         if (!CanThrowNade(player)) return;
1237         if (!(time > player.nade_refire)) return;
1238                 if (key_pressed) {
1239                         if (!held_nade) {
1240                                 nade_prime(player);
1241                                 held_nade = player.nade;
1242                         }
1243                 } else if (time >= held_nade.nade_time_primed + 1) {
1244                         if (held_nade) {
1245                                 makevectors(player.v_angle);
1246                                 float _force = time - held_nade.nade_time_primed;
1247                                 _force /= autocvar_g_nades_nade_lifetime;
1248                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1249                                 vector dir = (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1);
1250                                 dir = W_CalculateSpread(dir, autocvar_g_nades_spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
1251                                 toss_nade(player, false, dir * _force, 0);
1252                         }
1253                 }
1254     }
1255 ENDCLASS(NadeOffhand)
1256 NadeOffhand OFFHAND_NADE;
1257 STATIC_INIT(OFFHAND_NADE) { OFFHAND_NADE = NEW(NadeOffhand); }
1258
1259 MUTATOR_HOOKFUNCTION(nades, ForbidThrowCurrentWeapon, CBC_ORDER_LAST)
1260 {
1261     entity player = M_ARGV(0, entity);
1262
1263         if (player.offhand != OFFHAND_NADE || (STAT(WEAPONS, player) & WEPSET(HOOK)) || autocvar_g_nades_override_dropweapon) {
1264                 nades_CheckThrow(player);
1265                 return true;
1266         }
1267 }
1268
1269 #ifdef IS_REVIVING
1270         #undef IS_REVIVING
1271 #endif
1272
1273 // returns true if player is reviving it
1274 #define IS_REVIVING(player, it, revive_extra_size) \
1275         (it != player && !STAT(FROZEN, it) && !IS_DEAD(it) && SAME_TEAM(it, player) \
1276         && boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
1277
1278 MUTATOR_HOOKFUNCTION(nades, PlayerPreThink)
1279 {
1280         entity player = M_ARGV(0, entity);
1281
1282         if (!IS_PLAYER(player)) { return; }
1283
1284         if (player.nade && (player.offhand != OFFHAND_NADE || (STAT(WEAPONS, player) & WEPSET(HOOK)))) OFFHAND_NADE.offhand_think(OFFHAND_NADE, player, player.nade_altbutton);
1285
1286         entity held_nade = player.nade;
1287         if (held_nade)
1288         {
1289                 STAT(NADE_TIMER, player) = bound(0, (time - held_nade.nade_time_primed) / held_nade.nade_lifetime, 1);
1290                 // LOG_TRACEF("%d %d", STAT(NADE_TIMER, player), time - held_nade.nade_time_primed);
1291                 makevectors(player.angles);
1292                 held_nade.velocity = player.velocity;
1293                 setorigin(held_nade, player.origin + player.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
1294                 held_nade.angles_y = player.angles.y;
1295
1296                 if (time + 0.1 >= held_nade.wait)
1297                 {
1298                         toss_nade(player, false, '0 0 0', time + 0.05);
1299                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_THROW);
1300                 }
1301         }
1302
1303         if(IS_PLAYER(player))
1304         {
1305                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
1306                 {
1307                         entity key;
1308                         float key_count = 0;
1309                         FOR_EACH_KH_KEY(key) if(key.owner == player) { ++key_count; }
1310
1311                         float time_score;
1312                         if(GameRules_scoring_is_vip(player))
1313                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
1314                         else
1315                                 time_score = autocvar_g_nades_bonus_score_time;
1316
1317                         if(key_count)
1318                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
1319
1320                         if(autocvar_g_nades_bonus_client_select)
1321                         {
1322                                 STAT(NADE_BONUS_TYPE, player) = CS(player).cvar_cl_nade_type;
1323                                 player.pokenade_type = CS(player).cvar_cl_pokenade_type;
1324                         }
1325                         else
1326                         {
1327                                 STAT(NADE_BONUS_TYPE, player) = autocvar_g_nades_bonus_type;
1328                                 player.pokenade_type = autocvar_g_nades_pokenade_monster_type;
1329                         }
1330
1331                         STAT(NADE_BONUS_TYPE, player) = bound(1, STAT(NADE_BONUS_TYPE, player), Nades_COUNT);
1332
1333                         if(STAT(NADE_BONUS_SCORE, player) >= 0 && autocvar_g_nades_bonus_score_max)
1334                                 nades_GiveBonus(player, time_score / autocvar_g_nades_bonus_score_max);
1335                 }
1336                 else
1337                 {
1338                         STAT(NADE_BONUS, player) = STAT(NADE_BONUS_SCORE, player) = 0;
1339                 }
1340
1341                 if(STAT(VEIL_ORB, player) && STAT(VEIL_ORB, player) <= time)
1342                 {
1343                         STAT(VEIL_ORB, player) = 0;
1344                         if(player.vehicle)
1345                                 player.vehicle.alpha = player.vehicle.nade_veil_prevalpha;
1346                         else
1347                                 player.alpha = player.nade_veil_prevalpha;
1348                 }
1349         }
1350
1351         if (frametime && IS_PLAYER(player))
1352         {
1353                 int n = 0;
1354
1355                 IntrusiveList reviving_players = NULL;
1356
1357                 if(player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
1358                         n = -1;
1359                 else if (STAT(FROZEN, player) == FROZEN_TEMP_DYING)
1360                 {
1361                         vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1362                         n = 0;
1363                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REVIVING(player, it, revive_extra_size), {
1364                                 if (!reviving_players)
1365                                         reviving_players = IL_NEW();
1366                                 IL_PUSH(reviving_players, it);
1367                                 ++n;
1368                         });
1369                 }
1370
1371                 if (n > 0 && STAT(FROZEN, player) == FROZEN_TEMP_DYING) // OK, there is at least one teammate reviving us
1372                 {
1373                         STAT(REVIVE_PROGRESS, player) = bound(0, STAT(REVIVE_PROGRESS, player) + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1374                         SetResource(player, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, player) * start_health));
1375
1376                         if(STAT(REVIVE_PROGRESS, player) >= 1)
1377                         {
1378                                 Unfreeze(player, false);
1379
1380                                 entity first = IL_FIRST(reviving_players);
1381                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, first.netname);
1382                                 Send_Notification(NOTIF_ONE, first, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
1383                         }
1384
1385                         IL_EACH(reviving_players, true, {
1386                                 STAT(REVIVE_PROGRESS, it) = STAT(REVIVE_PROGRESS, player);
1387                         });
1388                 }
1389                 if (reviving_players)
1390                         IL_DELETE(reviving_players);
1391         }
1392 }
1393
1394 MUTATOR_HOOKFUNCTION(nades, PlayerPhysics_UpdateStats)
1395 {
1396         entity player = M_ARGV(0, entity);
1397         // these automatically reset, no need to worry
1398
1399         if(STAT(ENTRAP_ORB, player) > time)
1400                 STAT(MOVEVARS_HIGHSPEED, player) *= autocvar_g_nades_entrap_speed;
1401 }
1402
1403 MUTATOR_HOOKFUNCTION(nades, MonsterMove)
1404 {
1405     entity mon = M_ARGV(0, entity);
1406
1407         if (STAT(ENTRAP_ORB, mon) > time)
1408         {
1409                 M_ARGV(1, float) *= autocvar_g_nades_entrap_speed; // run speed
1410                 M_ARGV(2, float) *= autocvar_g_nades_entrap_speed; // walk speed
1411         }
1412
1413         if (STAT(VEIL_ORB, mon) && STAT(VEIL_ORB, mon) <= time)
1414         {
1415                 mon.alpha = mon.nade_veil_prevalpha;
1416                 STAT(VEIL_ORB, mon) = 0;
1417         }
1418 }
1419
1420 MUTATOR_HOOKFUNCTION(nades, PlayerSpawn)
1421 {
1422         entity player = M_ARGV(0, entity);
1423
1424         if(autocvar_g_nades_spawn)
1425                 player.nade_refire = time + autocvar_g_spawnshieldtime;
1426         else
1427                 player.nade_refire  = time + autocvar_g_nades_nade_refire;
1428
1429         if(autocvar_g_nades_bonus_client_select)
1430                 STAT(NADE_BONUS_TYPE, player) = CS(player).cvar_cl_nade_type;
1431
1432         STAT(NADE_TIMER, player) = 0;
1433
1434         if (!player.offhand) player.offhand = OFFHAND_NADE;
1435
1436         if(player.nade_spawnloc)
1437         {
1438                 setorigin(player, player.nade_spawnloc.origin);
1439                 player.nade_spawnloc.cnt -= 1;
1440
1441                 if(player.nade_spawnloc.cnt <= 0)
1442                 {
1443                         delete(player.nade_spawnloc);
1444                         player.nade_spawnloc = NULL;
1445                 }
1446         }
1447 }
1448
1449 MUTATOR_HOOKFUNCTION(nades, PlayerDies, CBC_ORDER_LAST)
1450 {
1451         entity frag_attacker = M_ARGV(1, entity);
1452         entity frag_target = M_ARGV(2, entity);
1453
1454         if(frag_target.nade)
1455         if(!STAT(FROZEN, frag_target) || !autocvar_g_freezetag_revive_nade)
1456                 toss_nade(frag_target, true, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1457
1458         if(IS_PLAYER(frag_attacker))
1459         {
1460                 float killcount_bonus = ((CS(frag_attacker).killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * CS(frag_attacker).killcount, autocvar_g_nades_bonus_score_medium)
1461                                                                                                                                         : autocvar_g_nades_bonus_score_minor);
1462                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1463                         nades_RemoveBonus(frag_attacker);
1464                 else if(GameRules_scoring_is_vip(frag_target))
1465                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1466                 else if(autocvar_g_nades_bonus_score_spree && CS(frag_attacker).killcount > 1)
1467                 {
1468                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1469                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1470                         switch(CS(frag_attacker).killcount)
1471                         {
1472                                 KILL_SPREE_LIST
1473                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1474                         }
1475                         #undef SPREE_ITEM
1476                 }
1477                 else
1478                         nades_GiveBonus(frag_attacker, killcount_bonus);
1479         }
1480
1481         nades_RemoveBonus(frag_target);
1482 }
1483
1484 MUTATOR_HOOKFUNCTION(nades, Damage_Calculate)
1485 {
1486         entity frag_inflictor = M_ARGV(0, entity);
1487         entity frag_attacker = M_ARGV(1, entity);
1488         entity frag_target = M_ARGV(2, entity);
1489         float frag_deathtype = M_ARGV(3, float);
1490
1491         if(autocvar_g_freezetag_revive_nade && STAT(FROZEN, frag_target) && frag_attacker == frag_target && frag_deathtype == DEATH_NADE.m_id)
1492         if(time - frag_inflictor.toss_time <= 0.1)
1493         {
1494                 Unfreeze(frag_target, false);
1495                 SetResource(frag_target, RES_HEALTH, autocvar_g_freezetag_revive_nade_health);
1496                 Send_Effect(EFFECT_ICEORGLASS, frag_target.origin, '0 0 0', 3);
1497                 M_ARGV(4, float) = 0;
1498                 M_ARGV(6, vector) = '0 0 0';
1499                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1500                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1501         }
1502 }
1503
1504 MUTATOR_HOOKFUNCTION(nades, MonsterDies)
1505 {
1506         entity frag_target = M_ARGV(0, entity);
1507         entity frag_attacker = M_ARGV(1, entity);
1508
1509         if(IS_PLAYER(frag_attacker))
1510         if(DIFF_TEAM(frag_attacker, frag_target))
1511         if(!(frag_target.spawnflags & MONSTERFLAG_SPAWNED))
1512                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1513 }
1514
1515 MUTATOR_HOOKFUNCTION(nades, DropSpecialItems)
1516 {
1517         entity frag_target = M_ARGV(0, entity);
1518
1519         if(frag_target.nade)
1520                 toss_nade(frag_target, true, '0 0 0', time + 0.05);
1521 }
1522
1523 void nades_RemovePlayer(entity this)
1524 {
1525         nades_Clear(this);
1526         nades_RemoveBonus(this);
1527 }
1528
1529 MUTATOR_HOOKFUNCTION(nades, MakePlayerObserver) { entity player = M_ARGV(0, entity); nades_RemovePlayer(player); }
1530 MUTATOR_HOOKFUNCTION(nades, ClientDisconnect) { entity player = M_ARGV(0, entity); nades_RemovePlayer(player); }
1531 MUTATOR_HOOKFUNCTION(nades, reset_map_global)
1532 {
1533         FOREACH_CLIENT(IS_PLAYER(it),
1534         {
1535                 nades_RemovePlayer(it);
1536         });
1537 }
1538
1539 MUTATOR_HOOKFUNCTION(nades, SpectateCopy)
1540 {
1541         entity spectatee = M_ARGV(0, entity);
1542         entity client = M_ARGV(1, entity);
1543
1544         STAT(NADE_TIMER, client) = STAT(NADE_TIMER, spectatee);
1545         STAT(NADE_BONUS_TYPE, client) = STAT(NADE_BONUS_TYPE, spectatee);
1546         client.pokenade_type = spectatee.pokenade_type;
1547         STAT(NADE_BONUS, client) = STAT(NADE_BONUS, spectatee);
1548         STAT(NADE_BONUS_SCORE, client) = STAT(NADE_BONUS_SCORE, spectatee);
1549         STAT(HEALING_ORB, client) = STAT(HEALING_ORB, spectatee);
1550         STAT(HEALING_ORB_ALPHA, client) = STAT(HEALING_ORB_ALPHA, spectatee);
1551         STAT(ENTRAP_ORB, client) = STAT(ENTRAP_ORB, spectatee);
1552         STAT(ENTRAP_ORB_ALPHA, client) = STAT(ENTRAP_ORB_ALPHA, spectatee);
1553         STAT(VEIL_ORB, client) = STAT(VEIL_ORB, spectatee);
1554         STAT(VEIL_ORB_ALPHA, client) = STAT(VEIL_ORB_ALPHA, spectatee);
1555 }
1556
1557 MUTATOR_HOOKFUNCTION(nades, BuildMutatorsString)
1558 {
1559         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Nades");
1560 }
1561
1562 MUTATOR_HOOKFUNCTION(nades, BuildGameplayTipsString)
1563 {
1564         M_ARGV(0, string) = strcat(M_ARGV(0, string), "\n\n^3nades^8 are enabled, press 'g' (dropweapon) to use them\n");
1565 }
1566
1567 #endif