qcsrc/common/mutators/mutator/nades/nades.qc

   1 #include "nades.qh"
   2
   3 #ifdef SVQC
   4 bool autocvar_g_nades_nade_small;
   5 float autocvar_g_nades_spread = 0.04;
   6 #endif
   7
   8 REGISTER_STAT(NADES_SMALL, int, autocvar_g_nades_nade_small)
   9
  10 #ifdef GAMEQC
  11 entity Nade_TrailEffect(int proj, int nade_team)
  12 {
  13     switch (proj)
  14     {
  15         case PROJECTILE_NADE:       return EFFECT_NADE_TRAIL(nade_team);
  16         case PROJECTILE_NADE_BURN:  return EFFECT_NADE_TRAIL_BURN(nade_team);
  17     }
  18
  19     FOREACH(Nades, true, LAMBDA(
  20         for (int j = 0; j < 2; j++)
  21         {
  22             if (it.m_projectile[j] == proj)
  23             {
  24                 string trail = it.m_trail[j].eent_eff_name;
  25                 if (trail) return it.m_trail[j];
  26                 break;
  27             }
  28         }
  29     ));
  30
  31     return EFFECT_Null;
  32 }
  33 #endif
  34
  35 #ifdef CSQC
  36 REGISTER_MUTATOR(cl_nades, true);
  37 MUTATOR_HOOKFUNCTION(cl_nades, HUD_Draw_overlay)
  38 {
  39         if (STAT(HEALING_ORB) > time)
  40         {
  41                 M_ARGV(0, vector) = NADE_TYPE_HEAL.m_color;
  42                 M_ARGV(1, float) = STAT(HEALING_ORB_ALPHA);
  43                 return true;
  44         }
  45         if (STAT(ENTRAP_ORB) > time)
  46         {
  47                 M_ARGV(0, vector) = NADE_TYPE_ENTRAP.m_color;
  48                 M_ARGV(1, float) = STAT(ENTRAP_ORB_ALPHA);
  49                 return true;
  50         }
  51         return false;
  52 }
  53 MUTATOR_HOOKFUNCTION(cl_nades, Ent_Projectile)
  54 {
  55         entity proj = M_ARGV(0, entity);
  56
  57         if (proj.cnt == PROJECTILE_NAPALM_FOUNTAIN)
  58         {
  59                 proj.modelindex = 0;
  60                 proj.traileffect = EFFECT_FIREBALL.m_id;
  61                 return true;
  62         }
  63         if (Nade_FromProjectile(proj.cnt) != NADE_TYPE_Null)
  64         {
  65                 setmodel(proj, MDL_PROJECTILE_NADE);
  66                 entity trail = Nade_TrailEffect(proj.cnt, proj.team);
  67                 if (trail.eent_eff_name) proj.traileffect = trail.m_id;
  68                 return true;
  69         }
  70 }
  71 MUTATOR_HOOKFUNCTION(cl_nades, EditProjectile)
  72 {
  73         entity proj = M_ARGV(0, entity);
  74
  75         if (proj.cnt == PROJECTILE_NAPALM_FOUNTAIN)
  76         {
  77                 loopsound(proj, CH_SHOTS_SINGLE, SND(FIREBALL_FLY2), VOL_BASE, ATTEN_NORM);
  78                 proj.mins = '-16 -16 -16';
  79                 proj.maxs = '16 16 16';
  80         }
  81
  82         entity nade_type = Nade_FromProjectile(proj.cnt);
  83         if (nade_type == NADE_TYPE_Null) return;
  84         if(STAT(NADES_SMALL, NULL))
  85         {
  86                 proj.mins = '-8 -8 -8';
  87                 proj.maxs = '8 8 8';
  88         }
  89         else
  90         {
  91                 proj.mins = '-16 -16 -16';
  92                 proj.maxs = '16 16 16';
  93         }
  94         proj.colormod = nade_type.m_color;
  95         set_movetype(proj, MOVETYPE_BOUNCE);
  96         settouch(proj, func_null);
  97         proj.scale = 1.5;
  98         proj.avelocity = randomvec() * 720;
  99
 100         if (nade_type == NADE_TYPE_TRANSLOCATE || nade_type == NADE_TYPE_SPAWN)
 101                 proj.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 102         else
 103                 proj.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 104 }
 105 bool Projectile_isnade(int p)
 106 {
 107         return Nade_FromProjectile(p) != NADE_TYPE_Null;
 108 }
 109 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 110 {
 111         float bonusNades    = STAT(NADE_BONUS);
 112         float bonusProgress = STAT(NADE_BONUS_SCORE);
 113         float bonusType     = STAT(NADE_BONUS_TYPE);
 114         Nade def = Nades_from(bonusType);
 115         vector nadeColor    = def.m_color;
 116         string nadeIcon     = def.m_icon;
 117
 118         vector iconPos, textPos;
 119
 120         if(autocvar_hud_panel_ammo_iconalign)
 121         {
 122                 iconPos = myPos + eX * 2 * mySize.y;
 123                 textPos = myPos;
 124         }
 125         else
 126         {
 127                 iconPos = myPos;
 128                 textPos = myPos + eX * mySize.y;
 129         }
 130
 131         if(bonusNades > 0 || bonusProgress > 0)
 132         {
 133                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
 134
 135                 if(autocvar_hud_panel_ammo_text)
 136                         drawstring_aspect(textPos, ftos(bonusNades), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 137
 138                 if(draw_expanding)
 139                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
 140
 141                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 142         }
 143 }
 144 #endif
 145
 146 #ifdef SVQC
 147
 148 #include <common/gamemodes/_mod.qh>
 149 #include <common/monsters/spawn.qh>
 150 #include <common/monsters/sv_monsters.qh>
 151 #include <server/g_subs.qh>
 152
 153 REGISTER_MUTATOR(nades, cvar("g_nades"));
 154
 155 .float nade_time_primed;
 156
 157 .entity nade_spawnloc;
 158
 159 void nade_timer_think(entity this)
 160 {
 161         this.skin = 8 - (this.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
 162         this.nextthink = time;
 163         if(!this.owner || wasfreed(this.owner))
 164                 delete(this);
 165 }
 166
 167 void nade_burn_spawn(entity _nade)
 168 {
 169         CSQCProjectile(_nade, true, Nades_from(_nade.nade_type).m_projectile[true], true);
 170 }
 171
 172 void nade_spawn(entity _nade)
 173 {
 174         entity timer = new(nade_timer);
 175         setmodel(timer, MDL_NADE_TIMER);
 176         setattachment(timer, _nade, "");
 177         timer.colormap = _nade.colormap;
 178         timer.glowmod = _nade.glowmod;
 179         setthink(timer, nade_timer_think);
 180         timer.nextthink = time;
 181         timer.wait = _nade.wait;
 182         timer.owner = _nade;
 183         timer.skin = 10;
 184
 185         _nade.effects |= EF_LOWPRECISION;
 186
 187         CSQCProjectile(_nade, true, Nades_from(_nade.nade_type).m_projectile[false], true);
 188 }
 189
 190 void napalm_damage(entity this, float dist, float damage, float edgedamage, float burntime)
 191 {
 192         entity e;
 193         float d;
 194         vector p;
 195
 196         if ( damage < 0 )
 197                 return;
 198
 199         RandomSelection_Init();
 200         for(e = WarpZone_FindRadius(this.origin, dist, true); e; e = e.chain)
 201                 if(e.takedamage == DAMAGE_AIM)
 202                 if(this.realowner != e || autocvar_g_nades_napalm_selfdamage)
 203                 if(!IS_PLAYER(e) || !this.realowner || DIFF_TEAM(e, this))
 204                 if(!STAT(FROZEN, e))
 205                 {
 206                         p = e.origin;
 207                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
 208                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
 209                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
 210                         d = vlen(WarpZone_UnTransformOrigin(e, this.origin) - p);
 211                         if(d < dist)
 212                         {
 213                                 e.fireball_impactvec = p;
 214                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
 215                         }
 216                 }
 217         if(RandomSelection_chosen_ent)
 218         {
 219                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, this.origin) - RandomSelection_chosen_ent.fireball_impactvec);
 220                 d = damage + (edgedamage - damage) * (d / dist);
 221                 Fire_AddDamage(RandomSelection_chosen_ent, this.realowner, d * burntime, burntime, this.projectiledeathtype | HITTYPE_BOUNCE);
 222                 //trailparticles(this, particleeffectnum(EFFECT_FIREBALL_LASER), this.origin, RandomSelection_chosen_ent.fireball_impactvec);
 223                 Send_Effect(EFFECT_FIREBALL_LASER, this.origin, RandomSelection_chosen_ent.fireball_impactvec - this.origin, 1);
 224         }
 225 }
 226
 227
 228 void napalm_ball_think(entity this)
 229 {
 230         if(round_handler_IsActive())
 231         if(!round_handler_IsRoundStarted())
 232         {
 233                 delete(this);
 234                 return;
 235         }
 236
 237         if(time > this.pushltime)
 238         {
 239                 delete(this);
 240                 return;
 241         }
 242
 243         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 244         if(pointcontents(midpoint) == CONTENT_WATER)
 245         {
 246                 this.velocity = this.velocity * 0.5;
 247
 248                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 249                         { this.velocity_z = 200; }
 250         }
 251
 252         this.angles = vectoangles(this.velocity);
 253
 254         napalm_damage(this, autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 255                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 256
 257         this.nextthink = time + 0.1;
 258 }
 259
 260
 261 void nade_napalm_ball(entity this)
 262 {
 263         entity proj;
 264         vector kick;
 265
 266         spamsound(this, CH_SHOTS, SND(FIREBALL_FIRE), VOL_BASE, ATTEN_NORM);
 267
 268         proj = new(grenade);
 269         proj.owner = this.owner;
 270         proj.realowner = this.realowner;
 271         proj.team = this.owner.team;
 272         proj.bot_dodge = true;
 273         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 274         set_movetype(proj, MOVETYPE_BOUNCE);
 275         proj.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
 276         PROJECTILE_MAKETRIGGER(proj);
 277         setmodel(proj, MDL_Null);
 278         proj.scale = 1;//0.5;
 279         setsize(proj, '-4 -4 -4', '4 4 4');
 280         setorigin(proj, this.origin);
 281         setthink(proj, napalm_ball_think);
 282         proj.nextthink = time;
 283         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 284         proj.effects = EF_LOWPRECISION | EF_FLAME;
 285
 286         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 287         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 288         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 289         proj.velocity = kick;
 290
 291         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 292
 293         proj.angles = vectoangles(proj.velocity);
 294         proj.flags = FL_PROJECTILE;
 295         IL_PUSH(g_projectiles, proj);
 296         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 297
 298         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
 299 }
 300
 301
 302 void napalm_fountain_think(entity this)
 303 {
 304
 305         if(round_handler_IsActive())
 306         if(!round_handler_IsRoundStarted())
 307         {
 308                 delete(this);
 309                 return;
 310         }
 311
 312         if(time >= this.ltime)
 313         {
 314                 delete(this);
 315                 return;
 316         }
 317
 318         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 319         if(pointcontents(midpoint) == CONTENT_WATER)
 320         {
 321                 this.velocity = this.velocity * 0.5;
 322
 323                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 324                         { this.velocity_z = 200; }
 325
 326                 UpdateCSQCProjectile(this);
 327         }
 328
 329         napalm_damage(this, autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 330                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 331
 332         this.nextthink = time + 0.1;
 333         if(time >= this.nade_special_time)
 334         {
 335                 this.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 336                 nade_napalm_ball(this);
 337         }
 338 }
 339
 340 void nade_napalm_boom(entity this)
 341 {
 342         entity fountain;
 343         int c;
 344         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
 345                 nade_napalm_ball(this);
 346
 347
 348         fountain = spawn();
 349         fountain.owner = this.owner;
 350         fountain.realowner = this.realowner;
 351         fountain.origin = this.origin;
 352         setorigin(fountain, fountain.origin);
 353         setthink(fountain, napalm_fountain_think);
 354         fountain.nextthink = time;
 355         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 356         fountain.pushltime = fountain.ltime;
 357         fountain.team = this.team;
 358         set_movetype(fountain, MOVETYPE_TOSS);
 359         fountain.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
 360         fountain.bot_dodge = true;
 361         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 362         fountain.nade_special_time = time;
 363         setsize(fountain, '-16 -16 -16', '16 16 16');
 364         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
 365 }
 366
 367 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 368 {
 369         frost_target.frozen_by = freezefield.realowner;
 370         Send_Effect(EFFECT_ELECTRO_IMPACT, frost_target.origin, '0 0 0', 1);
 371         Freeze(frost_target, 1/freeze_time, 3, false);
 372
 373         Drop_Special_Items(frost_target);
 374 }
 375
 376 void nade_ice_think(entity this)
 377 {
 378         if(round_handler_IsActive())
 379         if(!round_handler_IsRoundStarted())
 380         {
 381                 delete(this);
 382                 return;
 383         }
 384
 385         if(time >= this.ltime)
 386         {
 387                 if ( autocvar_g_nades_ice_explode )
 388                 {
 389                         entity expef = EFFECT_NADE_EXPLODE(this.realowner.team);
 390                         Send_Effect(expef, this.origin + '0 0 1', '0 0 0', 1);
 391                         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 392
 393                         RadiusDamage(this, this.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 394                                 autocvar_g_nades_nade_radius, this, NULL, autocvar_g_nades_nade_force, this.projectiledeathtype, this.enemy);
 395                         Damage_DamageInfo(this.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 396                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, this.projectiledeathtype, 0, this);
 397                 }
 398                 delete(this);
 399                 return;
 400         }
 401
 402
 403         this.nextthink = time+0.1;
 404
 405         // gaussian
 406         float randomr;
 407         randomr = random();
 408         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 409         float randomw;
 410         randomw = random()*M_PI*2;
 411         vector randomp;
 412         randomp.x = randomr*cos(randomw);
 413         randomp.y = randomr*sin(randomw);
 414         randomp.z = 1;
 415         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, this.origin + randomp, '0 0 0', 1);
 416
 417         if(time >= this.nade_special_time)
 418         {
 419                 this.nade_special_time = time+0.7;
 420
 421                 Send_Effect(EFFECT_ELECTRO_IMPACT, this.origin, '0 0 0', 1);
 422                 Send_Effect(EFFECT_ICEFIELD, this.origin, '0 0 0', 1);
 423         }
 424
 425
 426         float current_freeze_time = this.ltime - time - 0.1;
 427
 428         FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_nades_nade_radius, it != this && it.takedamage && !IS_DEAD(it) && it.health > 0 && current_freeze_time > 0,
 429         {
 430                 if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(it, this.realowner) || it == this.realowner))
 431                 if(!it.revival_time || ((time - it.revival_time) >= 1.5))
 432                 if(!STAT(FROZEN, it))
 433                         nade_ice_freeze(this, it, current_freeze_time);
 434         });
 435 }
 436
 437 void nade_ice_boom(entity this)
 438 {
 439         entity fountain;
 440         fountain = spawn();
 441         fountain.owner = this.owner;
 442         fountain.realowner = this.realowner;
 443         fountain.origin = this.origin;
 444         setorigin(fountain, fountain.origin);
 445         setthink(fountain, nade_ice_think);
 446         fountain.nextthink = time;
 447         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 448         fountain.pushltime = fountain.wait = fountain.ltime;
 449         fountain.team = this.team;
 450         set_movetype(fountain, MOVETYPE_TOSS);
 451         fountain.projectiledeathtype = DEATH_NADE_ICE.m_id;
 452         fountain.bot_dodge = false;
 453         setsize(fountain, '-16 -16 -16', '16 16 16');
 454         fountain.nade_special_time = time+0.3;
 455         fountain.angles = this.angles;
 456
 457         if ( autocvar_g_nades_ice_explode )
 458         {
 459                 setmodel(fountain, MDL_PROJECTILE_GRENADE);
 460                 entity timer = new(nade_timer);
 461                 setmodel(timer, MDL_NADE_TIMER);
 462                 setattachment(timer, fountain, "");
 463                 timer.colormap = this.colormap;
 464                 timer.glowmod = this.glowmod;
 465                 setthink(timer, nade_timer_think);
 466                 timer.nextthink = time;
 467                 timer.wait = fountain.ltime;
 468                 timer.owner = fountain;
 469                 timer.skin = 10;
 470         }
 471         else
 472                 setmodel(fountain, MDL_Null);
 473 }
 474
 475 void nade_translocate_boom(entity this)
 476 {
 477         if(this.realowner.vehicle)
 478                 return;
 479
 480         vector locout = this.origin + '0 0 1' * (1 - this.realowner.mins.z - 24);
 481         tracebox(locout, this.realowner.mins, this.realowner.maxs, locout, MOVE_NOMONSTERS, this.realowner);
 482         locout = trace_endpos;
 483
 484         makevectors(this.realowner.angles);
 485
 486         MUTATOR_CALLHOOK(PortalTeleport, this.realowner);
 487
 488         TeleportPlayer(this, this.realowner, locout, this.realowner.angles, v_forward * vlen(this.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 489 }
 490
 491 void nade_spawn_boom(entity this)
 492 {
 493         entity spawnloc = spawn();
 494         setorigin(spawnloc, this.origin);
 495         setsize(spawnloc, this.realowner.mins, this.realowner.maxs);
 496         set_movetype(spawnloc, MOVETYPE_NONE);
 497         spawnloc.solid = SOLID_NOT;
 498         spawnloc.drawonlytoclient = this.realowner;
 499         spawnloc.effects = EF_STARDUST;
 500         spawnloc.cnt = autocvar_g_nades_spawn_count;
 501
 502         if(this.realowner.nade_spawnloc)
 503         {
 504                 delete(this.realowner.nade_spawnloc);
 505                 this.realowner.nade_spawnloc = NULL;
 506         }
 507
 508         this.realowner.nade_spawnloc = spawnloc;
 509 }
 510
 511 void nades_orb_think(entity this)
 512 {
 513         if(time >= this.ltime)
 514         {
 515                 delete(this);
 516                 return;
 517         }
 518
 519         this.nextthink = time;
 520
 521         if(time >= this.nade_special_time)
 522         {
 523                 this.nade_special_time = time+0.25;
 524                 this.nade_show_particles = 1;
 525         }
 526         else
 527                 this.nade_show_particles = 0;
 528 }
 529
 530 entity nades_spawn_orb(entity own, entity realown, vector org, float orb_ltime, float orb_rad)
 531 {
 532         // NOTE: this function merely places an orb
 533         // you must add a custom touch function to the returned entity if desired
 534         // also set .colormod if you wish to have it colorized
 535         entity orb = spawn(); // Net_LinkEntity sets the classname (TODO)
 536         orb.owner = own;
 537         orb.realowner = realown;
 538         setorigin(orb, org);
 539
 540         orb.orb_lifetime = orb_ltime; // required for timers
 541         orb.ltime = time + orb.orb_lifetime;
 542         orb.bot_dodge = false;
 543         orb.team = realown.team;
 544         orb.solid = SOLID_TRIGGER;
 545
 546         setmodel(orb, MDL_NADE_ORB);
 547         orb.skin = 1;
 548         orb.orb_radius = orb_rad; // required for fading
 549         vector size = '1 1 1' * orb.orb_radius / 2;
 550         setsize(orb, -size, size);
 551
 552         Net_LinkEntity(orb, true, 0, orb_send);
 553         orb.SendFlags |= 1;
 554
 555         setthink(orb, nades_orb_think);
 556         orb.nextthink = time;
 557
 558         return orb;
 559 }
 560
 561 void nade_entrap_touch(entity this, entity toucher)
 562 {
 563         if(DIFF_TEAM(toucher, this.realowner)) // TODO: what if realowner changes team or disconnects?
 564         {
 565                 if (!isPushable(toucher))
 566                         return;
 567
 568                 float pushdeltatime = time - toucher.lastpushtime;
 569                 if (pushdeltatime > 0.15) pushdeltatime = 0;
 570                 toucher.lastpushtime = time;
 571                 if(!pushdeltatime) return;
 572
 573                 // div0: ticrate independent, 1 = identity (not 20)
 574                 toucher.velocity = toucher.velocity * pow(autocvar_g_nades_entrap_strength, pushdeltatime);
 575
 576         #ifdef SVQC
 577                 UpdateCSQCProjectile(toucher);
 578         #endif
 579         }
 580
 581         if ( IS_REAL_CLIENT(toucher) || IS_VEHICLE(toucher) || IS_MONSTER(toucher) )
 582         {
 583                 entity show_tint = (IS_VEHICLE(toucher)) ? toucher.owner : toucher;
 584                 STAT(ENTRAP_ORB, show_tint) = time + 0.1;
 585
 586                 float tint_alpha = 0.75;
 587                 if(SAME_TEAM(toucher, this.realowner))
 588                         tint_alpha = 0.45;
 589                 STAT(ENTRAP_ORB_ALPHA, show_tint) = tint_alpha * (this.ltime - time) / this.orb_lifetime;
 590         }
 591 }
 592
 593 void nade_entrap_boom(entity this)
 594 {
 595         entity orb = nades_spawn_orb(this.owner, this.realowner, this.origin, autocvar_g_nades_entrap_time, autocvar_g_nades_entrap_radius);
 596
 597         settouch(orb, nade_entrap_touch);
 598         orb.colormod = NADE_TYPE_ENTRAP.m_color;
 599 }
 600
 601 void nade_heal_touch(entity this, entity toucher)
 602 {
 603         float maxhealth;
 604         float health_factor;
 605         if(IS_PLAYER(toucher) || IS_MONSTER(toucher))
 606         if(!IS_DEAD(toucher))
 607         if(!STAT(FROZEN, toucher))
 608         {
 609                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 610                 if ( toucher != this.realowner )
 611                 {
 612                         if ( SAME_TEAM(toucher,this) )
 613                                 health_factor *= autocvar_g_nades_heal_friend;
 614                         else
 615                                 health_factor *= autocvar_g_nades_heal_foe;
 616                 }
 617                 if ( health_factor > 0 )
 618                 {
 619                         maxhealth = (IS_MONSTER(toucher)) ? toucher.max_health : g_pickup_healthmega_max;
 620                         if ( toucher.health < maxhealth )
 621                         {
 622                                 if ( this.nade_show_particles )
 623                                         Send_Effect(EFFECT_HEALING, toucher.origin, '0 0 0', 1);
 624                                 toucher.health = min(toucher.health+health_factor, maxhealth);
 625                         }
 626                         toucher.pauserothealth_finished = max(toucher.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 627                 }
 628                 else if ( health_factor < 0 )
 629                 {
 630                         Damage(toucher,this,this.realowner,-health_factor,DEATH_NADE_HEAL.m_id,toucher.origin,'0 0 0');
 631                 }
 632
 633         }
 634
 635         if ( IS_REAL_CLIENT(toucher) || IS_VEHICLE(toucher) )
 636         {
 637                 entity show_red = (IS_VEHICLE(toucher)) ? toucher.owner : toucher;
 638                 show_red.stat_healing_orb = time+0.1;
 639                 show_red.stat_healing_orb_alpha = 0.75 * (this.ltime - time) / this.orb_lifetime;
 640         }
 641 }
 642
 643 void nade_heal_boom(entity this)
 644 {
 645         entity orb = nades_spawn_orb(this.owner, this.realowner, this.origin, autocvar_g_nades_heal_time, autocvar_g_nades_nade_radius);
 646
 647         settouch(orb, nade_heal_touch);
 648         orb.colormod = '1 0 0';
 649 }
 650
 651 void nade_monster_boom(entity this)
 652 {
 653         entity e = spawnmonster(this.pokenade_type, 0, this.realowner, this.realowner, this.origin, false, false, 1);
 654
 655         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 656                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 657         e.monster_skill = MONSTER_SKILL_INSANE;
 658 }
 659
 660 void nade_boom(entity this)
 661 {
 662         entity expef = NULL;
 663         bool nade_blast = true;
 664
 665         switch ( Nades_from(this.nade_type) )
 666         {
 667                 case NADE_TYPE_NAPALM:
 668                         nade_blast = autocvar_g_nades_napalm_blast;
 669                         expef = EFFECT_EXPLOSION_MEDIUM;
 670                         break;
 671                 case NADE_TYPE_ICE:
 672                         nade_blast = false;
 673                         expef = EFFECT_ELECTRO_COMBO; // hookbomb_explode electro_combo bigplasma_impact
 674                         break;
 675                 case NADE_TYPE_TRANSLOCATE:
 676                         nade_blast = false;
 677                         break;
 678                 case NADE_TYPE_MONSTER:
 679                 case NADE_TYPE_SPAWN:
 680                         nade_blast = false;
 681                         switch(this.realowner.team)
 682                         {
 683                                 case NUM_TEAM_1: expef = EFFECT_SPAWN_RED; break;
 684                                 case NUM_TEAM_2: expef = EFFECT_SPAWN_BLUE; break;
 685                                 case NUM_TEAM_3: expef = EFFECT_SPAWN_YELLOW; break;
 686                                 case NUM_TEAM_4: expef = EFFECT_SPAWN_PINK; break;
 687                                 default: expef = EFFECT_SPAWN_NEUTRAL; break;
 688                         }
 689                         break;
 690                 case NADE_TYPE_HEAL:
 691                         nade_blast = false;
 692                         expef = EFFECT_SPAWN_RED;
 693                         break;
 694
 695                 case NADE_TYPE_ENTRAP:
 696                         nade_blast = false;
 697                         expef = EFFECT_SPAWN_YELLOW;
 698                         break;
 699
 700                 default:
 701                 case NADE_TYPE_NORMAL:
 702                         expef = EFFECT_NADE_EXPLODE(this.realowner.team);
 703                         break;
 704         }
 705
 706         if(expef)
 707                 Send_Effect(expef, findbetterlocation(this.origin, 8), '0 0 0', 1);
 708
 709         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 710         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 711
 712         this.event_damage = func_null; // prevent somehow calling damage in the next call
 713
 714         if(nade_blast)
 715         {
 716                 RadiusDamage(this, this.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 717                                  autocvar_g_nades_nade_radius, this, NULL, autocvar_g_nades_nade_force, this.projectiledeathtype, this.enemy);
 718                 Damage_DamageInfo(this.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, this.projectiledeathtype, 0, this);
 719         }
 720
 721         if(this.takedamage)
 722         switch ( Nades_from(this.nade_type) )
 723         {
 724                 case NADE_TYPE_NAPALM: nade_napalm_boom(this); break;
 725                 case NADE_TYPE_ICE: nade_ice_boom(this); break;
 726                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(this); break;
 727                 case NADE_TYPE_SPAWN: nade_spawn_boom(this); break;
 728                 case NADE_TYPE_HEAL: nade_heal_boom(this); break;
 729                 case NADE_TYPE_MONSTER: nade_monster_boom(this); break;
 730                 case NADE_TYPE_ENTRAP: nade_entrap_boom(this); break;
 731         }
 732
 733         FOREACH_ENTITY_ENT(aiment, this,
 734         {
 735                 if(it.classname == "grapplinghook")
 736                         RemoveGrapplingHook(it.realowner);
 737         });
 738
 739         delete(this);
 740 }
 741
 742 void spawn_held_nade(entity player, entity nowner, float ntime, int ntype, string pntype);
 743 void nade_pickup(entity this, entity thenade)
 744 {
 745         spawn_held_nade(this, thenade.realowner, autocvar_g_nades_pickup_time, thenade.nade_type, thenade.pokenade_type);
 746
 747         // set refire so player can't even
 748         this.nade_refire = time + autocvar_g_nades_nade_refire;
 749         this.nade_timer = 0;
 750
 751         if(this.nade)
 752                 this.nade.nade_time_primed = thenade.nade_time_primed;
 753 }
 754
 755 bool CanThrowNade(entity this);
 756 void nade_touch(entity this, entity toucher)
 757 {
 758         if(toucher)
 759                 UpdateCSQCProjectile(this);
 760
 761         if(toucher == this.realowner)
 762                 return; // no this impacts
 763
 764         if(autocvar_g_nades_pickup)
 765         if(time >= this.spawnshieldtime)
 766         if(!toucher.nade && this.health == this.max_health) // no boosted shot pickups, thank you very much
 767         if(!STAT(FROZEN, toucher))
 768         if(CanThrowNade(toucher)) // prevent some obvious things, like dead players
 769         if(IS_REAL_CLIENT(toucher)) // above checks for IS_PLAYER, don't need to do it here
 770         {
 771                 nade_pickup(toucher, this);
 772                 sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 773                 delete(this);
 774                 return;
 775         }
 776         /*float is_weapclip = 0;
 777         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 778         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 779         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 780                 is_weapclip = 1;*/
 781         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
 782         {
 783                 FOREACH_ENTITY_ENT(aiment, this,
 784                 {
 785                         if(it.classname == "grapplinghook")
 786                                 RemoveGrapplingHook(it.realowner);
 787                 });
 788                 delete(this);
 789                 return;
 790         }
 791
 792         PROJECTILE_TOUCH(this, toucher);
 793
 794         //setsize(this, '-2 -2 -2', '2 2 2');
 795         //UpdateCSQCProjectile(this);
 796         if(this.health == this.max_health)
 797         {
 798                 spamsound(this, CH_SHOTS, SND(GRENADE_BOUNCE_RANDOM()), VOL_BASE, ATTEN_NORM);
 799                 return;
 800         }
 801
 802         this.enemy = toucher;
 803         nade_boom(this);
 804 }
 805
 806 void nade_beep(entity this)
 807 {
 808         sound(this, CH_SHOTS_SINGLE, SND_NADE_BEEP, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 809         setthink(this, nade_boom);
 810         this.nextthink = max(this.wait, time);
 811 }
 812
 813 void nade_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 814 {
 815         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 816         {
 817                 this.takedamage = DAMAGE_NO;
 818                 nade_boom(this);
 819                 return;
 820         }
 821
 822         if(this.nade_type == NADE_TYPE_TRANSLOCATE.m_id || this.nade_type == NADE_TYPE_SPAWN.m_id)
 823                 return;
 824
 825         if (MUTATOR_CALLHOOK(Nade_Damage, this, DEATH_WEAPONOF(deathtype), force, damage)) {}
 826         else if(DEATH_ISWEAPON(deathtype, WEP_BLASTER))
 827         {
 828                 force *= 1.5;
 829                 damage = 0;
 830         }
 831         else if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) && (deathtype & HITTYPE_SECONDARY))
 832         {
 833                 force *= 0.5; // too much
 834                 damage = 0;
 835         }
 836         else if(DEATH_ISWEAPON(deathtype, WEP_VORTEX) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 837         {
 838                 force *= 6;
 839                 damage = this.max_health * 0.55;
 840         }
 841         else if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 842                 damage = this.max_health * 0.1;
 843         else if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN)) // WEAPONTODO
 844         {
 845                 if(deathtype & HITTYPE_SECONDARY)
 846                 {
 847                         damage = this.max_health * 0.1;
 848                         force *= 10;
 849                 }
 850                 else
 851                         damage = this.max_health * 1.15;
 852         }
 853
 854         this.velocity += force;
 855         UpdateCSQCProjectile(this);
 856
 857         if(damage <= 0 || ((IS_ONGROUND(this)) && IS_PLAYER(attacker)))
 858                 return;
 859
 860         if(this.health == this.max_health)
 861         {
 862                 sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 863                 this.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
 864                 setthink(this, nade_beep);
 865         }
 866
 867         this.health -= damage;
 868
 869         if ( this.nade_type != NADE_TYPE_HEAL.m_id || IS_PLAYER(attacker) )
 870                 this.realowner = attacker;
 871
 872         if(this.health <= 0)
 873                 W_PrepareExplosionByDamage(this, attacker, nade_boom);
 874         else
 875                 nade_burn_spawn(this);
 876 }
 877
 878 void toss_nade(entity e, bool set_owner, vector _velocity, float _time)
 879 {
 880         if(e.nade == NULL)
 881                 return;
 882
 883         entity _nade = e.nade;
 884         e.nade = NULL;
 885
 886         delete(e.fake_nade);
 887         e.fake_nade = NULL;
 888
 889         makevectors(e.v_angle);
 890
 891         // NOTE: always throw from first weapon entity?
 892         W_SetupShot(e, weaponentities[0], false, false, SND_Null, CH_WEAPON_A, 0);
 893
 894         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER, CPID_NADES);
 895
 896         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
 897                                   + (v_right * autocvar_g_nades_throw_offset.y)
 898                                   + (v_up * autocvar_g_nades_throw_offset.z);
 899         if(autocvar_g_nades_throw_offset == '0 0 0')
 900                 offset = '0 0 0';
 901
 902         setorigin(_nade, w_shotorg + offset + (v_right * 25) * -1);
 903         //setmodel(_nade, MDL_PROJECTILE_NADE);
 904         //setattachment(_nade, NULL, "");
 905         PROJECTILE_MAKETRIGGER(_nade);
 906         if(STAT(NADES_SMALL, e))
 907                 setsize(_nade, '-8 -8 -8', '8 8 8');
 908         else
 909                 setsize(_nade, '-16 -16 -16', '16 16 16');
 910         set_movetype(_nade, MOVETYPE_BOUNCE);
 911
 912         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
 913         if (trace_startsolid)
 914                 setorigin(_nade, e.origin);
 915
 916         if(e.v_angle.x >= 70 && e.v_angle.x <= 110 && PHYS_INPUT_BUTTON_CROUCH(e))
 917                 _nade.velocity = '0 0 100';
 918         else if(autocvar_g_nades_nade_newton_style == 1)
 919                 _nade.velocity = e.velocity + _velocity;
 920         else if(autocvar_g_nades_nade_newton_style == 2)
 921                 _nade.velocity = _velocity;
 922         else
 923                 _nade.velocity = W_CalculateProjectileVelocity(e, e.velocity, _velocity, true);
 924
 925         if(set_owner)
 926                 _nade.realowner = e;
 927
 928         settouch(_nade, nade_touch);
 929         _nade.spawnshieldtime = time + 0.1; // prevent instantly picking up again
 930         _nade.health = autocvar_g_nades_nade_health;
 931         _nade.max_health = _nade.health;
 932         _nade.takedamage = DAMAGE_AIM;
 933         _nade.event_damage = nade_damage;
 934         setcefc(_nade, func_null);
 935         _nade.exteriormodeltoclient = NULL;
 936         _nade.traileffectnum = 0;
 937         _nade.teleportable = true;
 938         _nade.pushable = true;
 939         _nade.gravity = 1;
 940         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 941         _nade.damagedbycontents = true;
 942         IL_PUSH(g_damagedbycontents, _nade);
 943         _nade.angles = vectoangles(_nade.velocity);
 944         _nade.flags = FL_PROJECTILE;
 945         IL_PUSH(g_projectiles, _nade);
 946         _nade.projectiledeathtype = DEATH_NADE.m_id;
 947         _nade.toss_time = time;
 948         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 949
 950         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE.m_id || _nade.nade_type == NADE_TYPE_SPAWN.m_id)
 951                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 952         else
 953                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 954
 955         nade_spawn(_nade);
 956
 957         if(_time)
 958         {
 959                 setthink(_nade, nade_boom);
 960                 _nade.nextthink = _time;
 961         }
 962
 963         e.nade_refire = time + autocvar_g_nades_nade_refire;
 964         e.nade_timer = 0;
 965 }
 966
 967 void nades_GiveBonus(entity player, float score)
 968 {
 969         if (autocvar_g_nades)
 970         if (autocvar_g_nades_bonus)
 971         if (IS_REAL_CLIENT(player))
 972         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 973         if (STAT(FROZEN, player) == 0)
 974         if (!IS_DEAD(player))
 975         {
 976                 if ( player.bonus_nade_score < 1 )
 977                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 978
 979                 if ( player.bonus_nade_score >= 1 )
 980                 {
 981                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 982                         play2(player, SND(KH_ALARM));
 983                         player.bonus_nades++;
 984                         player.bonus_nade_score -= 1;
 985                 }
 986         }
 987 }
 988
 989 /** Remove all bonus nades from a player */
 990 void nades_RemoveBonus(entity player)
 991 {
 992         player.bonus_nades = player.bonus_nade_score = 0;
 993 }
 994
 995 MUTATOR_HOOKFUNCTION(nades, PutClientInServer)
 996 {
 997     entity player = M_ARGV(0, entity);
 998
 999         nades_RemoveBonus(player);
1000 }
1001
1002 bool nade_customize(entity this, entity client)
1003 {
1004         //if(IS_SPEC(client)) { return false; }
1005         if(client == this.exteriormodeltoclient || (IS_SPEC(client) && client.enemy == this.exteriormodeltoclient))
1006         {
1007                 // somewhat hide the model, but keep the glow
1008                 //this.effects = 0;
1009                 if(this.traileffectnum)
1010                         this.traileffectnum = 0;
1011                 this.alpha = -1;
1012         }
1013         else
1014         {
1015                 //this.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
1016                 if(!this.traileffectnum)
1017                         this.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(this.nade_type).m_projectile[false], this.team).eent_eff_name);
1018                 this.alpha = 1;
1019         }
1020
1021         return true;
1022 }
1023
1024 void spawn_held_nade(entity player, entity nowner, float ntime, int ntype, string pntype)
1025 {
1026         entity n = new(nade), fn = new(fake_nade);
1027
1028         n.nade_type = max(1, ntype);
1029         n.pokenade_type = pntype;
1030
1031         if(Nades_from(n.nade_type) == NADE_TYPE_Null)
1032                 n.nade_type = NADE_TYPE_NORMAL.m_id;
1033
1034         setmodel(n, MDL_PROJECTILE_NADE);
1035         //setattachment(n, player, "bip01 l hand");
1036         n.exteriormodeltoclient = player;
1037         setcefc(n, nade_customize);
1038         n.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(n.nade_type).m_projectile[false], player.team).eent_eff_name);
1039         n.colormod = Nades_from(n.nade_type).m_color;
1040         n.realowner = nowner;
1041         n.colormap = player.colormap;
1042         n.glowmod = player.glowmod;
1043         n.wait = time + max(0, ntime);
1044         n.nade_time_primed = time;
1045         setthink(n, nade_beep);
1046         n.nextthink = max(n.wait - 3, time);
1047         n.projectiledeathtype = DEATH_NADE.m_id;
1048
1049         setmodel(fn, MDL_NADE_VIEW);
1050         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
1051         setattachment(fn, player.(weaponentity), "");
1052         fn.realowner = fn.owner = player;
1053         fn.colormod = Nades_from(n.nade_type).m_color;
1054         fn.colormap = player.colormap;
1055         fn.glowmod = player.glowmod;
1056         setthink(fn, SUB_Remove);
1057         fn.nextthink = n.wait;
1058
1059         player.nade = n;
1060         player.fake_nade = fn;
1061 }
1062
1063 void nade_prime(entity this)
1064 {
1065         if(autocvar_g_nades_bonus_only)
1066         if(!this.bonus_nades)
1067                 return; // only allow bonus nades
1068
1069         if(this.nade)
1070                 delete(this.nade);
1071
1072         if(this.fake_nade)
1073                 delete(this.fake_nade);
1074
1075         int ntype;
1076         string pntype = this.pokenade_type;
1077
1078         if(this.items & ITEM_Strength.m_itemid && autocvar_g_nades_bonus_onstrength)
1079                 ntype = this.nade_type;
1080         else if (this.bonus_nades >= 1)
1081         {
1082                 ntype = this.nade_type;
1083                 pntype = this.pokenade_type;
1084                 this.bonus_nades -= 1;
1085         }
1086         else
1087         {
1088                 ntype = ((autocvar_g_nades_client_select) ? this.cvar_cl_nade_type : autocvar_g_nades_nade_type);
1089                 pntype = ((autocvar_g_nades_client_select) ? this.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
1090         }
1091
1092         spawn_held_nade(this, this, autocvar_g_nades_nade_lifetime, ntype, pntype);
1093 }
1094
1095 bool CanThrowNade(entity this)
1096 {
1097         if(this.vehicle)
1098                 return false;
1099
1100         if(gameover)
1101                 return false;
1102
1103         if(IS_DEAD(this))
1104                 return false;
1105
1106         if (!autocvar_g_nades)
1107                 return false; // allow turning them off mid match
1108
1109         if(forbidWeaponUse(this))
1110                 return false;
1111
1112         if (!IS_PLAYER(this))
1113                 return false;
1114
1115         return true;
1116 }
1117
1118 .bool nade_altbutton;
1119
1120 void nades_CheckThrow(entity this)
1121 {
1122         if(!CanThrowNade(this))
1123                 return;
1124
1125         entity held_nade = this.nade;
1126         if (!held_nade)
1127         {
1128                 this.nade_altbutton = true;
1129                 if(time > this.nade_refire)
1130                 {
1131                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_NADE_THROW);
1132                         nade_prime(this);
1133                         this.nade_refire = time + autocvar_g_nades_nade_refire;
1134                 }
1135         }
1136         else
1137         {
1138                 this.nade_altbutton = false;
1139                 if (time >= held_nade.nade_time_primed + 1) {
1140                         makevectors(this.v_angle);
1141                         float _force = time - held_nade.nade_time_primed;
1142                         _force /= autocvar_g_nades_nade_lifetime;
1143                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1144                         vector dir = (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05);
1145                         dir = W_CalculateSpread(dir, autocvar_g_nades_spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
1146                         toss_nade(this, true, dir * _force, 0);
1147                 }
1148         }
1149 }
1150
1151 void nades_Clear(entity player)
1152 {
1153         if(player.nade)
1154                 delete(player.nade);
1155         if(player.fake_nade)
1156                 delete(player.fake_nade);
1157
1158         player.nade = player.fake_nade = NULL;
1159         player.nade_timer = 0;
1160 }
1161
1162 MUTATOR_HOOKFUNCTION(nades, VehicleEnter)
1163 {
1164         entity player = M_ARGV(0, entity);
1165
1166         if(player.nade)
1167                 toss_nade(player, true, '0 0 100', max(player.nade.wait, time + 0.05));
1168 }
1169
1170 CLASS(NadeOffhand, OffhandWeapon)
1171     METHOD(NadeOffhand, offhand_think, void(NadeOffhand this, entity player, bool key_pressed))
1172     {
1173         entity held_nade = player.nade;
1174                 if (held_nade)
1175                 {
1176                         player.nade_timer = bound(0, (time - held_nade.nade_time_primed) / autocvar_g_nades_nade_lifetime, 1);
1177                         // LOG_TRACEF("%d %d", player.nade_timer, time - held_nade.nade_time_primed);
1178                         makevectors(player.angles);
1179                         held_nade.velocity = player.velocity;
1180                         setorigin(held_nade, player.origin + player.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
1181                         held_nade.angles_y = player.angles.y;
1182
1183                         if (time + 0.1 >= held_nade.wait)
1184                                 toss_nade(player, false, '0 0 0', time + 0.05);
1185                 }
1186
1187         if (!CanThrowNade(player)) return;
1188         if (!(time > player.nade_refire)) return;
1189                 if (key_pressed) {
1190                         if (!held_nade) {
1191                                 nade_prime(player);
1192                                 held_nade = player.nade;
1193                         }
1194                 } else if (time >= held_nade.nade_time_primed + 1) {
1195                         if (held_nade) {
1196                                 makevectors(player.v_angle);
1197                                 float _force = time - held_nade.nade_time_primed;
1198                                 _force /= autocvar_g_nades_nade_lifetime;
1199                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1200                                 vector dir = (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1);
1201                                 dir = W_CalculateSpread(dir, autocvar_g_nades_spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
1202                                 toss_nade(player, false, dir * _force, 0);
1203                         }
1204                 }
1205     }
1206 ENDCLASS(NadeOffhand)
1207 NadeOffhand OFFHAND_NADE; STATIC_INIT(OFFHAND_NADE) { OFFHAND_NADE = NEW(NadeOffhand); }
1208
1209 MUTATOR_HOOKFUNCTION(nades, ForbidThrowCurrentWeapon, CBC_ORDER_LAST)
1210 {
1211     entity player = M_ARGV(0, entity);
1212
1213         if (player.offhand != OFFHAND_NADE || (player.weapons & WEPSET(HOOK)) || autocvar_g_nades_override_dropweapon) {
1214                 nades_CheckThrow(player);
1215                 return true;
1216         }
1217 }
1218
1219 MUTATOR_HOOKFUNCTION(nades, PlayerPreThink)
1220 {
1221         entity player = M_ARGV(0, entity);
1222
1223         if (!IS_PLAYER(player)) { return; }
1224
1225         if (player.nade && (player.offhand != OFFHAND_NADE || (player.weapons & WEPSET(HOOK)))) OFFHAND_NADE.offhand_think(OFFHAND_NADE, player, player.nade_altbutton);
1226
1227         if(IS_PLAYER(player))
1228         {
1229                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
1230                 {
1231                         entity key;
1232                         float key_count = 0;
1233                         FOR_EACH_KH_KEY(key) if(key.owner == player) { ++key_count; }
1234
1235                         float time_score;
1236                         if(player.flagcarried || player.ballcarried) // this player is important
1237                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
1238                         else
1239                                 time_score = autocvar_g_nades_bonus_score_time;
1240
1241                         if(key_count)
1242                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
1243
1244                         if(autocvar_g_nades_bonus_client_select)
1245                         {
1246                                 player.nade_type = player.cvar_cl_nade_type;
1247                                 player.pokenade_type = player.cvar_cl_pokenade_type;
1248                         }
1249                         else
1250                         {
1251                                 player.nade_type = autocvar_g_nades_bonus_type;
1252                                 player.pokenade_type = autocvar_g_nades_pokenade_monster_type;
1253                         }
1254
1255                         player.nade_type = bound(1, player.nade_type, Nades_COUNT);
1256
1257                         if(player.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
1258                                 nades_GiveBonus(player, time_score / autocvar_g_nades_bonus_score_max);
1259                 }
1260                 else
1261                 {
1262                         player.bonus_nades = player.bonus_nade_score = 0;
1263                 }
1264         }
1265
1266         float n = 0;
1267         entity o = NULL;
1268         if(player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
1269                 n = -1;
1270         else
1271         {
1272                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1273                 n = 0;
1274                 FOREACH_CLIENT(IS_PLAYER(it) && it != player, LAMBDA(
1275                         if(!IS_DEAD(it))
1276                         if(STAT(FROZEN, it) == 0)
1277                         if(SAME_TEAM(it, player))
1278                         if(boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
1279                         {
1280                                 if(!o)
1281                                         o = it;
1282                                 if(STAT(FROZEN, player) == 1)
1283                                         it.reviving = true;
1284                                 ++n;
1285                         }
1286                 ));
1287         }
1288
1289         if(n && STAT(FROZEN, player) == 3) // OK, there is at least one teammate reviving us
1290         {
1291                 player.revive_progress = bound(0, player.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1292                 player.health = max(1, player.revive_progress * start_health);
1293
1294                 if(player.revive_progress >= 1)
1295                 {
1296                         Unfreeze(player);
1297
1298                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1299                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
1300                 }
1301
1302                 FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, LAMBDA(
1303                         it.revive_progress = player.revive_progress;
1304                         it.reviving = false;
1305                 ));
1306         }
1307 }
1308
1309 MUTATOR_HOOKFUNCTION(nades, PlayerPhysics)
1310 {
1311         entity player = M_ARGV(0, entity);
1312
1313         if (STAT(ENTRAP_ORB, player) > time)
1314         {
1315                 player.stat_sv_maxspeed *= autocvar_g_nades_entrap_speed;
1316                 player.stat_sv_airspeedlimit_nonqw *= autocvar_g_nades_entrap_speed;
1317         }
1318 }
1319
1320 MUTATOR_HOOKFUNCTION(nades, MonsterMove)
1321 {
1322     entity mon = M_ARGV(0, entity);
1323
1324         if (STAT(ENTRAP_ORB, mon) > time)
1325         {
1326                 M_ARGV(1, float) *= autocvar_g_nades_entrap_speed; // run speed
1327                 M_ARGV(2, float) *= autocvar_g_nades_entrap_speed; // walk speed
1328         }
1329 }
1330
1331 MUTATOR_HOOKFUNCTION(nades, PlayerSpawn)
1332 {
1333         entity player = M_ARGV(0, entity);
1334
1335         if(autocvar_g_nades_spawn)
1336                 player.nade_refire = time + autocvar_g_spawnshieldtime;
1337         else
1338                 player.nade_refire  = time + autocvar_g_nades_nade_refire;
1339
1340         if(autocvar_g_nades_bonus_client_select)
1341                 player.nade_type = player.cvar_cl_nade_type;
1342
1343         player.nade_timer = 0;
1344
1345         if (!player.offhand) player.offhand = OFFHAND_NADE;
1346
1347         if(player.nade_spawnloc)
1348         {
1349                 setorigin(player, player.nade_spawnloc.origin);
1350                 player.nade_spawnloc.cnt -= 1;
1351
1352                 if(player.nade_spawnloc.cnt <= 0)
1353                 {
1354                         delete(player.nade_spawnloc);
1355                         player.nade_spawnloc = NULL;
1356                 }
1357         }
1358 }
1359
1360 MUTATOR_HOOKFUNCTION(nades, PlayerDies, CBC_ORDER_LAST)
1361 {
1362         entity frag_attacker = M_ARGV(1, entity);
1363         entity frag_target = M_ARGV(2, entity);
1364
1365         if(frag_target.nade)
1366         if(!STAT(FROZEN, frag_target) || !autocvar_g_freezetag_revive_nade)
1367                 toss_nade(frag_target, true, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1368
1369         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1370
1371         if(IS_PLAYER(frag_attacker))
1372         {
1373                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1374                         nades_RemoveBonus(frag_attacker);
1375                 else if(frag_target.flagcarried)
1376                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1377                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1378                 {
1379                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1380                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1381                         switch(frag_attacker.killcount)
1382                         {
1383                                 KILL_SPREE_LIST
1384                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1385                         }
1386                         #undef SPREE_ITEM
1387                 }
1388                 else
1389                         nades_GiveBonus(frag_attacker, killcount_bonus);
1390         }
1391
1392         nades_RemoveBonus(frag_target);
1393 }
1394
1395 MUTATOR_HOOKFUNCTION(nades, PlayerDamage_Calculate)
1396 {
1397         entity frag_inflictor = M_ARGV(0, entity);
1398         entity frag_attacker = M_ARGV(1, entity);
1399         entity frag_target = M_ARGV(2, entity);
1400         float frag_deathtype = M_ARGV(3, float);
1401
1402         if(STAT(FROZEN, frag_target))
1403         if(autocvar_g_freezetag_revive_nade)
1404         if(frag_attacker == frag_target)
1405         if(frag_deathtype == DEATH_NADE.m_id)
1406         if(time - frag_inflictor.toss_time <= 0.1)
1407         {
1408                 Unfreeze(frag_target);
1409                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1410                 Send_Effect(EFFECT_ICEORGLASS, frag_target.origin, '0 0 0', 3);
1411                 M_ARGV(4, float) = 0;
1412                 M_ARGV(6, vector) = '0 0 0';
1413                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1414                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1415         }
1416 }
1417
1418 MUTATOR_HOOKFUNCTION(nades, MonsterDies)
1419 {
1420         entity frag_target = M_ARGV(0, entity);
1421         entity frag_attacker = M_ARGV(1, entity);
1422
1423         if(IS_PLAYER(frag_attacker))
1424         if(DIFF_TEAM(frag_attacker, frag_target))
1425         if(!(frag_target.spawnflags & MONSTERFLAG_SPAWNED))
1426                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1427 }
1428
1429 MUTATOR_HOOKFUNCTION(nades, DropSpecialItems)
1430 {
1431         entity frag_target = M_ARGV(0, entity);
1432
1433         if(frag_target.nade)
1434                 toss_nade(frag_target, true, '0 0 0', time + 0.05);
1435 }
1436
1437 void nades_RemovePlayer(entity this)
1438 {
1439         nades_Clear(this);
1440         nades_RemoveBonus(this);
1441 }
1442
1443 MUTATOR_HOOKFUNCTION(nades, MakePlayerObserver) { entity player = M_ARGV(0, entity); nades_RemovePlayer(player); }
1444 MUTATOR_HOOKFUNCTION(nades, ClientDisconnect) { entity player = M_ARGV(0, entity); nades_RemovePlayer(player); }
1445 MUTATOR_HOOKFUNCTION(nades, reset_map_global)
1446 {
1447         FOREACH_CLIENT(IS_PLAYER(it),
1448         {
1449                 nades_RemovePlayer(it);
1450         });
1451 }
1452
1453 MUTATOR_HOOKFUNCTION(nades, SpectateCopy)
1454 {
1455         entity spectatee = M_ARGV(0, entity);
1456         entity client = M_ARGV(1, entity);
1457
1458         client.nade_timer = spectatee.nade_timer;
1459         client.nade_type = spectatee.nade_type;
1460         client.pokenade_type = spectatee.pokenade_type;
1461         client.bonus_nades = spectatee.bonus_nades;
1462         client.bonus_nade_score = spectatee.bonus_nade_score;
1463         client.stat_healing_orb = spectatee.stat_healing_orb;
1464         client.stat_healing_orb_alpha = spectatee.stat_healing_orb_alpha;
1465         STAT(ENTRAP_ORB, client) = STAT(ENTRAP_ORB, spectatee);
1466         STAT(ENTRAP_ORB_ALPHA, client) = STAT(ENTRAP_ORB_ALPHA, spectatee);
1467 }
1468
1469 REPLICATE(cvar_cl_nade_type, int, "cl_nade_type");
1470 REPLICATE(cvar_cl_pokenade_type, string, "cl_pokenade_type");
1471
1472 MUTATOR_HOOKFUNCTION(nades, BuildMutatorsString)
1473 {
1474         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Nades");
1475 }
1476
1477 MUTATOR_HOOKFUNCTION(nades, BuildMutatorsPrettyString)
1478 {
1479         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Nades");
1480 }
1481
1482 MUTATOR_HOOKFUNCTION(nades, BuildGameplayTipsString)
1483 {
1484         M_ARGV(0, string) = strcat(M_ARGV(0, string), "\n\n^3nades^8 are enabled, press 'g' to use them\n");
1485 }
1486
1487 #endif