Makefile: use `-I.`
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mutators / mutator / nades / nades.qc
1 #include "nades.qh"
2
3 #ifdef IMPLEMENTATION
4
5 #ifndef MENUQC
6 entity Nade_TrailEffect(int proj, int nade_team)
7 {
8     switch (proj)
9     {
10         case PROJECTILE_NADE:       return EFFECT_NADE_TRAIL(nade_team);
11         case PROJECTILE_NADE_BURN:  return EFFECT_NADE_TRAIL_BURN(nade_team);
12     }
13
14     FOREACH(Nades, true, LAMBDA(
15         for (int j = 0; j < 2; j++)
16         {
17             if (it.m_projectile[j] == proj)
18             {
19                 string trail = it.m_trail[j].eent_eff_name;
20                 if (trail) return it.m_trail[j];
21                 break;
22             }
23         }
24     ));
25
26     return EFFECT_Null;
27 }
28 #endif
29
30 #ifdef CSQC
31 REGISTER_MUTATOR(cl_nades, true);
32 MUTATOR_HOOKFUNCTION(cl_nades, HUD_Draw_overlay)
33 {
34         if (STAT(HEALING_ORB) <= time) return false;
35         MUTATOR_ARGV(0, vector) = NADE_TYPE_HEAL.m_color;
36         MUTATOR_ARGV(0, float) = STAT(HEALING_ORB_ALPHA);
37         return true;
38 }
39 MUTATOR_HOOKFUNCTION(cl_nades, Ent_Projectile)
40 {
41         if (self.cnt == PROJECTILE_NAPALM_FOUNTAIN)
42         {
43                 self.modelindex = 0;
44                 self.traileffect = EFFECT_FIREBALL.m_id;
45                 return true;
46         }
47         if (Nade_FromProjectile(self.cnt) != NADE_TYPE_Null)
48         {
49                 setmodel(self, MDL_PROJECTILE_NADE);
50                 entity trail = Nade_TrailEffect(self.cnt, self.team);
51                 if (trail.eent_eff_name) self.traileffect = trail.m_id;
52                 return true;
53         }
54 }
55 MUTATOR_HOOKFUNCTION(cl_nades, EditProjectile)
56 {
57         if (self.cnt == PROJECTILE_NAPALM_FOUNTAIN)
58         {
59                 loopsound(self, CH_SHOTS_SINGLE, SND(FIREBALL_FLY2), VOL_BASE, ATTEN_NORM);
60                 self.mins = '-16 -16 -16';
61                 self.maxs = '16 16 16';
62         }
63
64         entity nade_type = Nade_FromProjectile(self.cnt);
65         if (nade_type == NADE_TYPE_Null) return;
66         self.mins = '-16 -16 -16';
67         self.maxs = '16 16 16';
68         self.colormod = nade_type.m_color;
69         self.move_movetype = MOVETYPE_BOUNCE;
70         self.move_touch = func_null;
71         self.scale = 1.5;
72         self.avelocity = randomvec() * 720;
73
74         if (nade_type == NADE_TYPE_TRANSLOCATE || nade_type == NADE_TYPE_SPAWN)
75                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
76         else
77                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
78 }
79 bool Projectile_isnade(int p)
80 {
81         return Nade_FromProjectile(p) != NADE_TYPE_Null;
82 }
83 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
84 {
85         float bonusNades    = STAT(NADE_BONUS);
86         float bonusProgress = STAT(NADE_BONUS_SCORE);
87         float bonusType     = STAT(NADE_BONUS_TYPE);
88         Nade def = Nades_from(bonusType);
89         vector nadeColor    = def.m_color;
90         string nadeIcon     = def.m_icon;
91
92         vector iconPos, textPos;
93
94         if(autocvar_hud_panel_ammo_iconalign)
95         {
96                 iconPos = myPos + eX * 2 * mySize.y;
97                 textPos = myPos;
98         }
99         else
100         {
101                 iconPos = myPos;
102                 textPos = myPos + eX * mySize.y;
103         }
104
105         if(bonusNades > 0 || bonusProgress > 0)
106         {
107                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
108
109                 if(autocvar_hud_panel_ammo_text)
110                         drawstring_aspect(textPos, ftos(bonusNades), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
111
112                 if(draw_expanding)
113                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
114
115                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
116         }
117 }
118 #endif
119
120 #ifdef SVQC
121
122 #include <common/gamemodes/all.qh>
123 #include <common/monsters/spawn.qh>
124 #include <common/monsters/sv_monsters.qh>
125 #include <server/g_subs.qh>
126
127 REGISTER_MUTATOR(nades, cvar("g_nades"));
128
129 .float nade_time_primed;
130
131 .entity nade_spawnloc;
132
133 void nade_timer_think()
134 {SELFPARAM();
135         self.skin = 8 - (self.owner.wait - time) / (autocvar_g_nades_nade_lifetime / 10);
136         self.nextthink = time;
137         if(!self.owner || wasfreed(self.owner))
138                 remove(self);
139 }
140
141 void nade_burn_spawn(entity _nade)
142 {
143         CSQCProjectile(_nade, true, Nades_from(_nade.nade_type).m_projectile[true], true);
144 }
145
146 void nade_spawn(entity _nade)
147 {
148         entity timer = new(nade_timer);
149         setmodel(timer, MDL_NADE_TIMER);
150         setattachment(timer, _nade, "");
151         timer.colormap = _nade.colormap;
152         timer.glowmod = _nade.glowmod;
153         timer.think = nade_timer_think;
154         timer.nextthink = time;
155         timer.wait = _nade.wait;
156         timer.owner = _nade;
157         timer.skin = 10;
158
159         _nade.effects |= EF_LOWPRECISION;
160
161         CSQCProjectile(_nade, true, Nades_from(_nade.nade_type).m_projectile[false], true);
162 }
163
164 void napalm_damage(float dist, float damage, float edgedamage, float burntime)
165 {SELFPARAM();
166         entity e;
167         float d;
168         vector p;
169
170         if ( damage < 0 )
171                 return;
172
173         RandomSelection_Init();
174         for(e = WarpZone_FindRadius(self.origin, dist, true); e; e = e.chain)
175                 if(e.takedamage == DAMAGE_AIM)
176                 if(self.realowner != e || autocvar_g_nades_napalm_selfdamage)
177                 if(!IS_PLAYER(e) || !self.realowner || DIFF_TEAM(e, self))
178                 if(!e.frozen)
179                 {
180                         p = e.origin;
181                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
182                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
183                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
184                         d = vlen(WarpZone_UnTransformOrigin(e, self.origin) - p);
185                         if(d < dist)
186                         {
187                                 e.fireball_impactvec = p;
188                                 RandomSelection_Add(e, 0, string_null, 1 / (1 + d), !Fire_IsBurning(e));
189                         }
190                 }
191         if(RandomSelection_chosen_ent)
192         {
193                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, self.origin) - RandomSelection_chosen_ent.fireball_impactvec);
194                 d = damage + (edgedamage - damage) * (d / dist);
195                 Fire_AddDamage(RandomSelection_chosen_ent, self.realowner, d * burntime, burntime, self.projectiledeathtype | HITTYPE_BOUNCE);
196                 //trailparticles(self, particleeffectnum(EFFECT_FIREBALL_LASER), self.origin, RandomSelection_chosen_ent.fireball_impactvec);
197                 Send_Effect(EFFECT_FIREBALL_LASER, self.origin, RandomSelection_chosen_ent.fireball_impactvec - self.origin, 1);
198         }
199 }
200
201
202 void napalm_ball_think()
203 {SELFPARAM();
204         if(round_handler_IsActive())
205         if(!round_handler_IsRoundStarted())
206         {
207                 remove(self);
208                 return;
209         }
210
211         if(time > self.pushltime)
212         {
213                 remove(self);
214                 return;
215         }
216
217         vector midpoint = ((self.absmin + self.absmax) * 0.5);
218         if(pointcontents(midpoint) == CONTENT_WATER)
219         {
220                 self.velocity = self.velocity * 0.5;
221
222                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
223                         { self.velocity_z = 200; }
224         }
225
226         self.angles = vectoangles(self.velocity);
227
228         napalm_damage(autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
229                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
230
231         self.nextthink = time + 0.1;
232 }
233
234
235 void nade_napalm_ball()
236 {SELFPARAM();
237         entity proj;
238         vector kick;
239
240         spamsound(self, CH_SHOTS, SND(FIREBALL_FIRE), VOL_BASE, ATTEN_NORM);
241
242         proj = new(grenade);
243         proj.owner = self.owner;
244         proj.realowner = self.realowner;
245         proj.team = self.owner.team;
246         proj.bot_dodge = true;
247         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
248         proj.movetype = MOVETYPE_BOUNCE;
249         proj.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
250         PROJECTILE_MAKETRIGGER(proj);
251         setmodel(proj, MDL_Null);
252         proj.scale = 1;//0.5;
253         setsize(proj, '-4 -4 -4', '4 4 4');
254         setorigin(proj, self.origin);
255         proj.think = napalm_ball_think;
256         proj.nextthink = time;
257         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
258         proj.effects = EF_LOWPRECISION | EF_FLAME;
259
260         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
261         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
262         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
263         proj.velocity = kick;
264
265         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
266
267         proj.angles = vectoangles(proj.velocity);
268         proj.flags = FL_PROJECTILE;
269         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
270
271         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
272 }
273
274
275 void napalm_fountain_think()
276 {SELFPARAM();
277
278         if(round_handler_IsActive())
279         if(!round_handler_IsRoundStarted())
280         {
281                 remove(self);
282                 return;
283         }
284
285         if(time >= self.ltime)
286         {
287                 remove(self);
288                 return;
289         }
290
291         vector midpoint = ((self.absmin + self.absmax) * 0.5);
292         if(pointcontents(midpoint) == CONTENT_WATER)
293         {
294                 self.velocity = self.velocity * 0.5;
295
296                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
297                         { self.velocity_z = 200; }
298
299                 UpdateCSQCProjectile(self);
300         }
301
302         napalm_damage(autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
303                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
304
305         self.nextthink = time + 0.1;
306         if(time >= self.nade_special_time)
307         {
308                 self.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
309                 nade_napalm_ball();
310         }
311 }
312
313 void nade_napalm_boom()
314 {SELFPARAM();
315         entity fountain;
316         int c;
317         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
318                 nade_napalm_ball();
319
320
321         fountain = spawn();
322         fountain.owner = self.owner;
323         fountain.realowner = self.realowner;
324         fountain.origin = self.origin;
325         setorigin(fountain, fountain.origin);
326         fountain.think = napalm_fountain_think;
327         fountain.nextthink = time;
328         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
329         fountain.pushltime = fountain.ltime;
330         fountain.team = self.team;
331         fountain.movetype = MOVETYPE_TOSS;
332         fountain.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
333         fountain.bot_dodge = true;
334         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
335         fountain.nade_special_time = time;
336         setsize(fountain, '-16 -16 -16', '16 16 16');
337         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
338 }
339
340 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
341 {
342         frost_target.frozen_by = freezefield.realowner;
343         Send_Effect(EFFECT_ELECTRO_IMPACT, frost_target.origin, '0 0 0', 1);
344         Freeze(frost_target, 1/freeze_time, 3, false);
345
346         Drop_Special_Items(frost_target);
347 }
348
349 void nade_ice_think()
350 {SELFPARAM();
351
352         if(round_handler_IsActive())
353         if(!round_handler_IsRoundStarted())
354         {
355                 remove(self);
356                 return;
357         }
358
359         if(time >= self.ltime)
360         {
361                 if ( autocvar_g_nades_ice_explode )
362                 {
363                         entity expef = EFFECT_NADE_EXPLODE(self.realowner.team);
364                         Send_Effect(expef, self.origin + '0 0 1', '0 0 0', 1);
365                         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
366
367                         RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
368                                 autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
369                         Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
370                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
371                 }
372                 remove(self);
373                 return;
374         }
375
376
377         self.nextthink = time+0.1;
378
379         // gaussian
380         float randomr;
381         randomr = random();
382         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
383         float randomw;
384         randomw = random()*M_PI*2;
385         vector randomp;
386         randomp.x = randomr*cos(randomw);
387         randomp.y = randomr*sin(randomw);
388         randomp.z = 1;
389         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, self.origin + randomp, '0 0 0', 1);
390
391         if(time >= self.nade_special_time)
392         {
393                 self.nade_special_time = time+0.7;
394
395                 Send_Effect(EFFECT_ELECTRO_IMPACT, self.origin, '0 0 0', 1);
396                 Send_Effect(EFFECT_ICEFIELD, self.origin, '0 0 0', 1);
397         }
398
399
400         float current_freeze_time = self.ltime - time - 0.1;
401
402         entity e;
403         for(e = findradius(self.origin, autocvar_g_nades_nade_radius); e; e = e.chain)
404         if(e != self)
405         if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(e, self.realowner) || e == self.realowner))
406         if(e.takedamage && e.deadflag == DEAD_NO)
407         if(e.health > 0)
408         if(!e.revival_time || ((time - e.revival_time) >= 1.5))
409         if(!e.frozen)
410         if(current_freeze_time > 0)
411                 nade_ice_freeze(self, e, current_freeze_time);
412 }
413
414 void nade_ice_boom()
415 {SELFPARAM();
416         entity fountain;
417         fountain = spawn();
418         fountain.owner = self.owner;
419         fountain.realowner = self.realowner;
420         fountain.origin = self.origin;
421         setorigin(fountain, fountain.origin);
422         fountain.think = nade_ice_think;
423         fountain.nextthink = time;
424         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
425         fountain.pushltime = fountain.wait = fountain.ltime;
426         fountain.team = self.team;
427         fountain.movetype = MOVETYPE_TOSS;
428         fountain.projectiledeathtype = DEATH_NADE_ICE.m_id;
429         fountain.bot_dodge = false;
430         setsize(fountain, '-16 -16 -16', '16 16 16');
431         fountain.nade_special_time = time+0.3;
432         fountain.angles = self.angles;
433
434         if ( autocvar_g_nades_ice_explode )
435         {
436                 setmodel(fountain, MDL_PROJECTILE_GRENADE);
437                 entity timer = new(nade_timer);
438                 setmodel(timer, MDL_NADE_TIMER);
439                 setattachment(timer, fountain, "");
440                 timer.colormap = self.colormap;
441                 timer.glowmod = self.glowmod;
442                 timer.think = nade_timer_think;
443                 timer.nextthink = time;
444                 timer.wait = fountain.ltime;
445                 timer.owner = fountain;
446                 timer.skin = 10;
447         }
448         else
449                 setmodel(fountain, MDL_Null);
450 }
451
452 void nade_translocate_boom()
453 {SELFPARAM();
454         if(self.realowner.vehicle)
455                 return;
456
457         vector locout = self.origin + '0 0 1' * (1 - self.realowner.mins.z - 24);
458         tracebox(locout, self.realowner.mins, self.realowner.maxs, locout, MOVE_NOMONSTERS, self.realowner);
459         locout = trace_endpos;
460
461         makevectors(self.realowner.angles);
462
463         MUTATOR_CALLHOOK(PortalTeleport, self.realowner);
464
465         TeleportPlayer(self, self.realowner, locout, self.realowner.angles, v_forward * vlen(self.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
466 }
467
468 void nade_spawn_boom()
469 {SELFPARAM();
470         entity spawnloc = spawn();
471         setorigin(spawnloc, self.origin);
472         setsize(spawnloc, self.realowner.mins, self.realowner.maxs);
473         spawnloc.movetype = MOVETYPE_NONE;
474         spawnloc.solid = SOLID_NOT;
475         spawnloc.drawonlytoclient = self.realowner;
476         spawnloc.effects = EF_STARDUST;
477         spawnloc.cnt = autocvar_g_nades_spawn_count;
478
479         if(self.realowner.nade_spawnloc)
480         {
481                 remove(self.realowner.nade_spawnloc);
482                 self.realowner.nade_spawnloc = world;
483         }
484
485         self.realowner.nade_spawnloc = spawnloc;
486 }
487
488 void nade_heal_think()
489 {SELFPARAM();
490         if(time >= self.ltime)
491         {
492                 remove(self);
493                 return;
494         }
495
496         self.nextthink = time;
497
498         if(time >= self.nade_special_time)
499         {
500                 self.nade_special_time = time+0.25;
501                 self.nade_show_particles = 1;
502         }
503         else
504                 self.nade_show_particles = 0;
505 }
506
507 void nade_heal_touch()
508 {SELFPARAM();
509         float maxhealth;
510         float health_factor;
511         if(IS_PLAYER(other) || IS_MONSTER(other))
512         if(other.deadflag == DEAD_NO)
513         if(!other.frozen)
514         {
515                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
516                 if ( other != self.realowner )
517                 {
518                         if ( SAME_TEAM(other,self) )
519                                 health_factor *= autocvar_g_nades_heal_friend;
520                         else
521                                 health_factor *= autocvar_g_nades_heal_foe;
522                 }
523                 if ( health_factor > 0 )
524                 {
525                         maxhealth = (IS_MONSTER(other)) ? other.max_health : g_pickup_healthmega_max;
526                         if ( other.health < maxhealth )
527                         {
528                                 if ( self.nade_show_particles )
529                                         Send_Effect(EFFECT_HEALING, other.origin, '0 0 0', 1);
530                                 other.health = min(other.health+health_factor, maxhealth);
531                         }
532                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
533                 }
534                 else if ( health_factor < 0 )
535                 {
536                         Damage(other,self,self.realowner,-health_factor,DEATH_NADE_HEAL.m_id,other.origin,'0 0 0');
537                 }
538
539         }
540
541         if ( IS_REAL_CLIENT(other) || IS_VEHICLE(other) )
542         {
543                 entity show_red = (IS_VEHICLE(other)) ? other.owner : other;
544                 show_red.stat_healing_orb = time+0.1;
545                 show_red.stat_healing_orb_alpha = 0.75 * (self.ltime - time) / self.healer_lifetime;
546         }
547 }
548
549 void nade_heal_boom()
550 {SELFPARAM();
551         entity healer;
552         healer = spawn();
553         healer.owner = self.owner;
554         healer.realowner = self.realowner;
555         setorigin(healer, self.origin);
556         healer.healer_lifetime = autocvar_g_nades_heal_time; // save the cvar
557         healer.ltime = time + healer.healer_lifetime;
558         healer.team = self.realowner.team;
559         healer.bot_dodge = false;
560         healer.solid = SOLID_TRIGGER;
561         healer.touch = nade_heal_touch;
562
563         setmodel(healer, MDL_NADE_HEAL);
564         healer.healer_radius = autocvar_g_nades_nade_radius;
565         vector size = '1 1 1' * healer.healer_radius / 2;
566         setsize(healer,-size,size);
567
568         Net_LinkEntity(healer, true, 0, healer_send);
569
570         healer.think = nade_heal_think;
571         healer.nextthink = time;
572         healer.SendFlags |= 1;
573 }
574
575 void nade_monster_boom()
576 {SELFPARAM();
577         entity e = spawnmonster(self.pokenade_type, 0, self.realowner, self.realowner, self.origin, false, false, 1);
578
579         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
580                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
581         e.monster_skill = MONSTER_SKILL_INSANE;
582 }
583
584 void nade_boom()
585 {SELFPARAM();
586         entity expef = NULL;
587         bool nade_blast = true;
588
589         switch ( Nades_from(self.nade_type) )
590         {
591                 case NADE_TYPE_NAPALM:
592                         nade_blast = autocvar_g_nades_napalm_blast;
593                         expef = EFFECT_EXPLOSION_MEDIUM;
594                         break;
595                 case NADE_TYPE_ICE:
596                         nade_blast = false;
597                         expef = EFFECT_ELECTRO_COMBO; // hookbomb_explode electro_combo bigplasma_impact
598                         break;
599                 case NADE_TYPE_TRANSLOCATE:
600                         nade_blast = false;
601                         break;
602                 case NADE_TYPE_MONSTER:
603                 case NADE_TYPE_SPAWN:
604                         nade_blast = false;
605                         switch(self.realowner.team)
606                         {
607                                 case NUM_TEAM_1: expef = EFFECT_SPAWN_RED; break;
608                                 case NUM_TEAM_2: expef = EFFECT_SPAWN_BLUE; break;
609                                 case NUM_TEAM_3: expef = EFFECT_SPAWN_YELLOW; break;
610                                 case NUM_TEAM_4: expef = EFFECT_SPAWN_PINK; break;
611                                 default: expef = EFFECT_SPAWN_NEUTRAL; break;
612                         }
613                         break;
614                 case NADE_TYPE_HEAL:
615                         nade_blast = false;
616                         expef = EFFECT_SPAWN_RED;
617                         break;
618
619                 default:
620                 case NADE_TYPE_NORMAL:
621                         expef = EFFECT_NADE_EXPLODE(self.realowner.team);
622                         break;
623         }
624
625         if(expef)
626                 Send_Effect(expef, findbetterlocation(self.origin, 8), '0 0 0', 1);
627
628         sound(self, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
629         sound(self, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
630
631         self.event_damage = func_null; // prevent somehow calling damage in the next call
632
633         if(nade_blast)
634         {
635                 RadiusDamage(self, self.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
636                                  autocvar_g_nades_nade_radius, self, world, autocvar_g_nades_nade_force, self.projectiledeathtype, self.enemy);
637                 Damage_DamageInfo(self.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, self.projectiledeathtype, 0, self);
638         }
639
640         if(self.takedamage)
641         switch ( Nades_from(self.nade_type) )
642         {
643                 case NADE_TYPE_NAPALM: nade_napalm_boom(); break;
644                 case NADE_TYPE_ICE: nade_ice_boom(); break;
645                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(); break;
646                 case NADE_TYPE_SPAWN: nade_spawn_boom(); break;
647                 case NADE_TYPE_HEAL: nade_heal_boom(); break;
648                 case NADE_TYPE_MONSTER: nade_monster_boom(); break;
649         }
650
651         entity head;
652         for(head = world; (head = find(head, classname, "grapplinghook")); )
653         if(head.aiment == self)
654                 RemoveGrapplingHook(head.realowner);
655
656         remove(self);
657 }
658
659 void nade_touch()
660 {SELFPARAM();
661         if(other)
662                 UpdateCSQCProjectile(self);
663
664         if(other == self.realowner)
665                 return; // no self impacts
666         /*float is_weapclip = 0;
667         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
668         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
669         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
670                 is_weapclip = 1;*/
671         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
672         {
673                 entity head;
674                 for(head = world; (head = find(head, classname, "grapplinghook")); )
675                 if(head.aiment == self)
676                         RemoveGrapplingHook(head.realowner);
677                 remove(self);
678                 return;
679         }
680
681         PROJECTILE_TOUCH;
682
683         //setsize(self, '-2 -2 -2', '2 2 2');
684         //UpdateCSQCProjectile(self);
685         if(self.health == self.max_health)
686         {
687                 spamsound(self, CH_SHOTS, SND(GRENADE_BOUNCE_RANDOM()), VOL_BASE, ATTEN_NORM);
688                 return;
689         }
690
691         self.enemy = other;
692         nade_boom();
693 }
694
695 void nade_beep()
696 {SELFPARAM();
697         sound(self, CH_SHOTS_SINGLE, SND_NADE_BEEP, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
698         self.think = nade_boom;
699         self.nextthink = max(self.wait, time);
700 }
701
702 void nade_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
703 {SELFPARAM();
704         if(ITEM_DAMAGE_NEEDKILL(deathtype))
705         {
706                 self.takedamage = DAMAGE_NO;
707                 nade_boom();
708                 return;
709         }
710
711         if(self.nade_type == NADE_TYPE_TRANSLOCATE.m_id || self.nade_type == NADE_TYPE_SPAWN.m_id)
712                 return;
713
714         if (MUTATOR_CALLHOOK(Nade_Damage, DEATH_WEAPONOF(deathtype), force, damage)) {}
715         else if(DEATH_ISWEAPON(deathtype, WEP_BLASTER))
716         {
717                 force *= 1.5;
718                 damage = 0;
719         }
720         else if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) && (deathtype & HITTYPE_SECONDARY))
721         {
722                 force *= 0.5; // too much
723                 damage = 0;
724         }
725         else if(DEATH_ISWEAPON(deathtype, WEP_VORTEX) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
726         {
727                 force *= 6;
728                 damage = self.max_health * 0.55;
729         }
730         else if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
731                 damage = self.max_health * 0.1;
732         else if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN)) // WEAPONTODO
733         {
734                 if(deathtype & HITTYPE_SECONDARY)
735                 {
736                         damage = self.max_health * 0.1;
737                         force *= 10;
738                 }
739                 else
740                         damage = self.max_health * 1.15;
741         }
742
743         self.velocity += force;
744         UpdateCSQCProjectile(self);
745
746         if(damage <= 0 || ((IS_ONGROUND(self)) && IS_PLAYER(attacker)))
747                 return;
748
749         if(self.health == self.max_health)
750         {
751                 sound(self, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
752                 self.nextthink = max(time + autocvar_g_nades_nade_lifetime, time);
753                 self.think = nade_beep;
754         }
755
756         self.health -= damage;
757
758         if ( self.nade_type != NADE_TYPE_HEAL.m_id || IS_PLAYER(attacker) )
759                 self.realowner = attacker;
760
761         if(self.health <= 0)
762                 W_PrepareExplosionByDamage(attacker, nade_boom);
763         else
764                 nade_burn_spawn(self);
765 }
766
767 void toss_nade(entity e, vector _velocity, float _time)
768 {SELFPARAM();
769         if(e.nade == world)
770                 return;
771
772         entity _nade = e.nade;
773         e.nade = world;
774
775         remove(e.fake_nade);
776         e.fake_nade = world;
777
778         makevectors(e.v_angle);
779
780         W_SetupShot(e, false, false, "", CH_WEAPON_A, 0);
781
782         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER_CPID, CPID_NADES);
783
784         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
785                                   + (v_right * autocvar_g_nades_throw_offset.y)
786                                   + (v_up * autocvar_g_nades_throw_offset.z);
787         if(autocvar_g_nades_throw_offset == '0 0 0')
788                 offset = '0 0 0';
789
790         setorigin(_nade, w_shotorg + offset + (v_right * 25) * -1);
791         //setmodel(_nade, MDL_PROJECTILE_NADE);
792         //setattachment(_nade, world, "");
793         PROJECTILE_MAKETRIGGER(_nade);
794         setsize(_nade, '-16 -16 -16', '16 16 16');
795         _nade.movetype = MOVETYPE_BOUNCE;
796
797         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, false, _nade);
798         if (trace_startsolid)
799                 setorigin(_nade, e.origin);
800
801         if(self.v_angle.x >= 70 && self.v_angle.x <= 110 && self.BUTTON_CROUCH)
802                 _nade.velocity = '0 0 100';
803         else if(autocvar_g_nades_nade_newton_style == 1)
804                 _nade.velocity = e.velocity + _velocity;
805         else if(autocvar_g_nades_nade_newton_style == 2)
806                 _nade.velocity = _velocity;
807         else
808                 _nade.velocity = W_CalculateProjectileVelocity(e.velocity, _velocity, true);
809
810         _nade.touch = nade_touch;
811         _nade.health = autocvar_g_nades_nade_health;
812         _nade.max_health = _nade.health;
813         _nade.takedamage = DAMAGE_AIM;
814         _nade.event_damage = nade_damage;
815         _nade.customizeentityforclient = func_null;
816         _nade.exteriormodeltoclient = world;
817         _nade.traileffectnum = 0;
818         _nade.teleportable = true;
819         _nade.pushable = true;
820         _nade.gravity = 1;
821         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
822         _nade.damagedbycontents = true;
823         _nade.angles = vectoangles(_nade.velocity);
824         _nade.flags = FL_PROJECTILE;
825         _nade.projectiledeathtype = DEATH_NADE.m_id;
826         _nade.toss_time = time;
827         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
828
829         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE.m_id || _nade.nade_type == NADE_TYPE_SPAWN.m_id)
830                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
831         else
832                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
833
834         nade_spawn(_nade);
835
836         if(_time)
837         {
838                 _nade.think = nade_boom;
839                 _nade.nextthink = _time;
840         }
841
842         e.nade_refire = time + autocvar_g_nades_nade_refire;
843         e.nade_timer = 0;
844 }
845
846 void nades_GiveBonus(entity player, float score)
847 {
848         if (autocvar_g_nades)
849         if (autocvar_g_nades_bonus)
850         if (IS_REAL_CLIENT(player))
851         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
852         if (player.frozen == 0)
853         if (player.deadflag == DEAD_NO)
854         {
855                 if ( player.bonus_nade_score < 1 )
856                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
857
858                 if ( player.bonus_nade_score >= 1 )
859                 {
860                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
861                         play2(player, SND(KH_ALARM));
862                         player.bonus_nades++;
863                         player.bonus_nade_score -= 1;
864                 }
865         }
866 }
867
868 /** Remove all bonus nades from a player */
869 void nades_RemoveBonus(entity player)
870 {
871         player.bonus_nades = player.bonus_nade_score = 0;
872 }
873
874 MUTATOR_HOOKFUNCTION(nades, PutClientInServer)
875 {
876         nades_RemoveBonus(self);
877 }
878
879 float nade_customize()
880 {SELFPARAM();
881         //if(IS_SPEC(other)) { return false; }
882         if(other == self.realowner || (IS_SPEC(other) && other.enemy == self.realowner))
883         {
884                 // somewhat hide the model, but keep the glow
885                 //self.effects = 0;
886                 if(self.traileffectnum)
887                         self.traileffectnum = 0;
888                 self.alpha = -1;
889         }
890         else
891         {
892                 //self.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
893                 if(!self.traileffectnum)
894                         self.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(self.nade_type).m_projectile[false], self.team).eent_eff_name);
895                 self.alpha = 1;
896         }
897
898         return true;
899 }
900
901 void nade_prime()
902 {SELFPARAM();
903         if(autocvar_g_nades_bonus_only)
904         if(!self.bonus_nades)
905                 return; // only allow bonus nades
906
907         if(self.nade)
908                 remove(self.nade);
909
910         if(self.fake_nade)
911                 remove(self.fake_nade);
912
913         entity n = new(nade), fn = new(fake_nade);
914
915         if(self.items & ITEM_Strength.m_itemid && autocvar_g_nades_bonus_onstrength)
916                 n.nade_type = self.nade_type;
917         else if (self.bonus_nades >= 1)
918         {
919                 n.nade_type = self.nade_type;
920                 n.pokenade_type = self.pokenade_type;
921                 self.bonus_nades -= 1;
922         }
923         else
924         {
925                 n.nade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_nade_type : autocvar_g_nades_nade_type);
926                 n.pokenade_type = ((autocvar_g_nades_client_select) ? self.cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
927         }
928
929         n.nade_type = bound(1, n.nade_type, Nades_COUNT);
930
931         setmodel(n, MDL_PROJECTILE_NADE);
932         //setattachment(n, self, "bip01 l hand");
933         n.exteriormodeltoclient = self;
934         n.customizeentityforclient = nade_customize;
935         n.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(n.nade_type).m_projectile[false], self.team).eent_eff_name);
936         n.colormod = Nades_from(n.nade_type).m_color;
937         n.realowner = self;
938         n.colormap = self.colormap;
939         n.glowmod = self.glowmod;
940         n.wait = time + autocvar_g_nades_nade_lifetime;
941         n.nade_time_primed = time;
942         n.think = nade_beep;
943         n.nextthink = max(n.wait - 3, time);
944         n.projectiledeathtype = DEATH_NADE.m_id;
945
946         setmodel(fn, MDL_NADE_VIEW);
947         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
948         setattachment(fn, self.(weaponentity), "");
949         fn.realowner = fn.owner = self;
950         fn.colormod = Nades_from(n.nade_type).m_color;
951         fn.colormap = self.colormap;
952         fn.glowmod = self.glowmod;
953         fn.think = SUB_Remove_self;
954         fn.nextthink = n.wait;
955
956         self.nade = n;
957         self.fake_nade = fn;
958 }
959
960 float CanThrowNade()
961 {SELFPARAM();
962         if(self.vehicle)
963                 return false;
964
965         if(gameover)
966                 return false;
967
968         if(self.deadflag != DEAD_NO)
969                 return false;
970
971         if (!autocvar_g_nades)
972                 return false; // allow turning them off mid match
973
974         if(forbidWeaponUse(self))
975                 return false;
976
977         if (!IS_PLAYER(self))
978                 return false;
979
980         return true;
981 }
982
983 .bool nade_altbutton;
984
985 void nades_CheckThrow()
986 {SELFPARAM();
987         if(!CanThrowNade())
988                 return;
989
990         entity held_nade = self.nade;
991         if (!held_nade)
992         {
993                 self.nade_altbutton = true;
994                 if(time > self.nade_refire)
995                 {
996                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_NADE_THROW);
997                         nade_prime();
998                         self.nade_refire = time + autocvar_g_nades_nade_refire;
999                 }
1000         }
1001         else
1002         {
1003                 self.nade_altbutton = false;
1004                 if (time >= held_nade.nade_time_primed + 1) {
1005                         makevectors(self.v_angle);
1006                         float _force = time - held_nade.nade_time_primed;
1007                         _force /= autocvar_g_nades_nade_lifetime;
1008                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1009                         toss_nade(self, (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05) * _force, 0);
1010                 }
1011         }
1012 }
1013
1014 void nades_Clear(entity player)
1015 {
1016         if(player.nade)
1017                 remove(player.nade);
1018         if(player.fake_nade)
1019                 remove(player.fake_nade);
1020
1021         player.nade = player.fake_nade = world;
1022         player.nade_timer = 0;
1023 }
1024
1025 MUTATOR_HOOKFUNCTION(nades, VehicleEnter)
1026 {
1027         if(vh_player.nade)
1028                 toss_nade(vh_player, '0 0 100', max(vh_player.nade.wait, time + 0.05));
1029
1030         return false;
1031 }
1032
1033 CLASS(NadeOffhand, OffhandWeapon)
1034     METHOD(NadeOffhand, offhand_think, void(NadeOffhand this, entity player, bool key_pressed))
1035     {
1036         entity held_nade = player.nade;
1037                 if (held_nade)
1038                 {
1039                         player.nade_timer = bound(0, (time - held_nade.nade_time_primed) / autocvar_g_nades_nade_lifetime, 1);
1040                         // LOG_TRACEF("%d %d\n", player.nade_timer, time - held_nade.nade_time_primed);
1041                         makevectors(player.angles);
1042                         held_nade.velocity = player.velocity;
1043                         setorigin(held_nade, player.origin + player.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
1044                         held_nade.angles_y = player.angles.y;
1045
1046                         if (time + 0.1 >= held_nade.wait)
1047                                 toss_nade(player, '0 0 0', time + 0.05);
1048                 }
1049
1050         if (!CanThrowNade()) return;
1051         if (!(time > player.nade_refire)) return;
1052                 if (key_pressed) {
1053                         if (!held_nade) {
1054                                 nade_prime();
1055                                 held_nade = player.nade;
1056                         }
1057                 } else if (time >= held_nade.nade_time_primed + 1) {
1058                         if (held_nade) {
1059                                 makevectors(player.v_angle);
1060                                 float _force = time - held_nade.nade_time_primed;
1061                                 _force /= autocvar_g_nades_nade_lifetime;
1062                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1063                                 toss_nade(player, (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1) * _force, 0);
1064                         }
1065                 }
1066     }
1067 ENDCLASS(NadeOffhand)
1068 NadeOffhand OFFHAND_NADE; STATIC_INIT(OFFHAND_NADE) { OFFHAND_NADE = NEW(NadeOffhand); }
1069
1070 MUTATOR_HOOKFUNCTION(nades, ForbidThrowCurrentWeapon, CBC_ORDER_LAST)
1071 {
1072         if (self.offhand != OFFHAND_NADE || (self.weapons & WEPSET(HOOK)) || autocvar_g_nades_override_dropweapon) {
1073                 nades_CheckThrow();
1074                 return true;
1075         }
1076         return false;
1077 }
1078
1079 MUTATOR_HOOKFUNCTION(nades, PlayerPreThink)
1080 {SELFPARAM();
1081         if (!IS_PLAYER(self)) { return false; }
1082
1083         if (self.nade && (self.offhand != OFFHAND_NADE || (self.weapons & WEPSET(HOOK)))) OFFHAND_NADE.offhand_think(OFFHAND_NADE, self, self.nade_altbutton);
1084
1085         if(IS_PLAYER(self))
1086         {
1087                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
1088                 {
1089                         entity key;
1090                         float key_count = 0;
1091                         FOR_EACH_KH_KEY(key) if(key.owner == self) { ++key_count; }
1092
1093                         float time_score;
1094                         if(self.flagcarried || self.ballcarried) // this player is important
1095                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
1096                         else
1097                                 time_score = autocvar_g_nades_bonus_score_time;
1098
1099                         if(key_count)
1100                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
1101
1102                         if(autocvar_g_nades_bonus_client_select)
1103                         {
1104                                 self.nade_type = self.cvar_cl_nade_type;
1105                                 self.pokenade_type = self.cvar_cl_pokenade_type;
1106                         }
1107                         else
1108                         {
1109                                 self.nade_type = autocvar_g_nades_bonus_type;
1110                                 self.pokenade_type = autocvar_g_nades_pokenade_monster_type;
1111                         }
1112
1113                         self.nade_type = bound(1, self.nade_type, Nades_COUNT);
1114
1115                         if(self.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
1116                                 nades_GiveBonus(self, time_score / autocvar_g_nades_bonus_score_max);
1117                 }
1118                 else
1119                 {
1120                         self.bonus_nades = self.bonus_nade_score = 0;
1121                 }
1122         }
1123
1124         float n = 0;
1125         entity o = world;
1126         if(self.freezetag_frozen_timeout > 0 && time >= self.freezetag_frozen_timeout)
1127                 n = -1;
1128         else
1129         {
1130                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1131                 n = 0;
1132                 FOREACH_CLIENT(IS_PLAYER(it) && it != self, LAMBDA(
1133                         if(it.deadflag == DEAD_NO)
1134                         if(it.frozen == 0)
1135                         if(SAME_TEAM(it, self))
1136                         if(boxesoverlap(self.absmin - revive_extra_size, self.absmax + revive_extra_size, it.absmin, it.absmax))
1137                         {
1138                                 if(!o)
1139                                         o = it;
1140                                 if(self.frozen == 1)
1141                                         it.reviving = true;
1142                                 ++n;
1143                         }
1144                 ));
1145         }
1146
1147         if(n && self.frozen == 3) // OK, there is at least one teammate reviving us
1148         {
1149                 self.revive_progress = bound(0, self.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1150                 self.health = max(1, self.revive_progress * start_health);
1151
1152                 if(self.revive_progress >= 1)
1153                 {
1154                         Unfreeze(self);
1155
1156                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1157                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, self.netname);
1158                 }
1159
1160                 FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, LAMBDA(
1161                         other.revive_progress = self.revive_progress;
1162                         other.reviving = false;
1163                 ));
1164         }
1165
1166         return false;
1167 }
1168
1169 MUTATOR_HOOKFUNCTION(nades, PlayerSpawn)
1170 {SELFPARAM();
1171         if(autocvar_g_nades_spawn)
1172                 self.nade_refire = time + autocvar_g_spawnshieldtime;
1173         else
1174                 self.nade_refire  = time + autocvar_g_nades_nade_refire;
1175
1176         if(autocvar_g_nades_bonus_client_select)
1177                 self.nade_type = self.cvar_cl_nade_type;
1178
1179         self.nade_timer = 0;
1180
1181         if (!self.offhand) self.offhand = OFFHAND_NADE;
1182
1183         if(self.nade_spawnloc)
1184         {
1185                 setorigin(self, self.nade_spawnloc.origin);
1186                 self.nade_spawnloc.cnt -= 1;
1187
1188                 if(self.nade_spawnloc.cnt <= 0)
1189                 {
1190                         remove(self.nade_spawnloc);
1191                         self.nade_spawnloc = world;
1192                 }
1193         }
1194
1195         return false;
1196 }
1197
1198 MUTATOR_HOOKFUNCTION(nades, PlayerDies, CBC_ORDER_LAST)
1199 {
1200         if(frag_target.nade)
1201         if(!frag_target.frozen || !autocvar_g_freezetag_revive_nade)
1202                 toss_nade(frag_target, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1203
1204         float killcount_bonus = ((frag_attacker.killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * frag_attacker.killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1205
1206         if(IS_PLAYER(frag_attacker))
1207         {
1208                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1209                         nades_RemoveBonus(frag_attacker);
1210                 else if(frag_target.flagcarried)
1211                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1212                 else if(autocvar_g_nades_bonus_score_spree && frag_attacker.killcount > 1)
1213                 {
1214                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1215                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1216                         switch(frag_attacker.killcount)
1217                         {
1218                                 KILL_SPREE_LIST
1219                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1220                         }
1221                         #undef SPREE_ITEM
1222                 }
1223                 else
1224                         nades_GiveBonus(frag_attacker, killcount_bonus);
1225         }
1226
1227         nades_RemoveBonus(frag_target);
1228
1229         return false;
1230 }
1231
1232 MUTATOR_HOOKFUNCTION(nades, PlayerDamage_Calculate)
1233 {
1234         if(frag_target.frozen)
1235         if(autocvar_g_freezetag_revive_nade)
1236         if(frag_attacker == frag_target)
1237         if(frag_deathtype == DEATH_NADE.m_id)
1238         if(time - frag_inflictor.toss_time <= 0.1)
1239         {
1240                 Unfreeze(frag_target);
1241                 frag_target.health = autocvar_g_freezetag_revive_nade_health;
1242                 Send_Effect(EFFECT_ICEORGLASS, frag_target.origin, '0 0 0', 3);
1243                 frag_damage = 0;
1244                 frag_force = '0 0 0';
1245                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1246                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1247         }
1248
1249         return false;
1250 }
1251
1252 MUTATOR_HOOKFUNCTION(nades, MonsterDies)
1253 {SELFPARAM();
1254         if(IS_PLAYER(frag_attacker))
1255         if(DIFF_TEAM(frag_attacker, self))
1256         if(!(self.spawnflags & MONSTERFLAG_SPAWNED))
1257                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1258
1259         return false;
1260 }
1261
1262 MUTATOR_HOOKFUNCTION(nades, DropSpecialItems)
1263 {
1264         if(frag_target.nade)
1265                 toss_nade(frag_target, '0 0 0', time + 0.05);
1266
1267         return false;
1268 }
1269
1270 bool nades_RemovePlayer()
1271 {SELFPARAM();
1272         nades_Clear(self);
1273         nades_RemoveBonus(self);
1274         return false;
1275 }
1276
1277 MUTATOR_HOOKFUNCTION(nades, MakePlayerObserver) { nades_RemovePlayer(); }
1278 MUTATOR_HOOKFUNCTION(nades, ClientDisconnect) { nades_RemovePlayer(); }
1279 MUTATOR_HOOKFUNCTION(nades, reset_map_global) { nades_RemovePlayer(); }
1280
1281 MUTATOR_HOOKFUNCTION(nades, SpectateCopy)
1282 {SELFPARAM();
1283         self.nade_timer = other.nade_timer;
1284         self.nade_type = other.nade_type;
1285         self.pokenade_type = other.pokenade_type;
1286         self.bonus_nades = other.bonus_nades;
1287         self.bonus_nade_score = other.bonus_nade_score;
1288         self.stat_healing_orb = other.stat_healing_orb;
1289         self.stat_healing_orb_alpha = other.stat_healing_orb_alpha;
1290         return false;
1291 }
1292
1293 MUTATOR_HOOKFUNCTION(nades, GetCvars)
1294 {
1295         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_nade_type, "cl_nade_type");
1296         GetCvars_handleString(get_cvars_s, get_cvars_f, cvar_cl_pokenade_type, "cl_pokenade_type");
1297
1298         return false;
1299 }
1300
1301 MUTATOR_HOOKFUNCTION(nades, BuildMutatorsString)
1302 {
1303         ret_string = strcat(ret_string, ":Nades");
1304         return false;
1305 }
1306
1307 MUTATOR_HOOKFUNCTION(nades, BuildMutatorsPrettyString)
1308 {
1309         ret_string = strcat(ret_string, ", Nades");
1310         return false;
1311 }
1312
1313 MUTATOR_HOOKFUNCTION(nades, BuildGameplayTipsString)
1314 {
1315         ret_string = strcat(ret_string, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
1316         return false;
1317 }
1318
1319 #endif
1320 #endif