qcsrc/common/mutators/mutator/nades/nades.qc

   1 #include "nades.qh"
   2
   3 #ifdef SVQC
   4 bool autocvar_g_nades_nade_small;
   5 float autocvar_g_nades_spread = 0.04;
   6 #endif
   7
   8 REGISTER_STAT(NADES_SMALL, int, autocvar_g_nades_nade_small)
   9
  10 #ifdef GAMEQC
  11 entity Nade_TrailEffect(int proj, int nade_team)
  12 {
  13     switch (proj)
  14     {
  15         case PROJECTILE_NADE:       return EFFECT_NADE_TRAIL(nade_team);
  16         case PROJECTILE_NADE_BURN:  return EFFECT_NADE_TRAIL_BURN(nade_team);
  17     }
  18
  19     FOREACH(Nades, true, {
  20         for (int j = 0; j < 2; j++)
  21         {
  22             if (it.m_projectile[j] == proj)
  23             {
  24                 string trail = it.m_trail[j].eent_eff_name;
  25                 if (trail) return it.m_trail[j];
  26                 break;
  27             }
  28         }
  29     });
  30
  31     return EFFECT_Null;
  32 }
  33 #endif
  34
  35 #ifdef CSQC
  36 REGISTER_MUTATOR(cl_nades, true);
  37 MUTATOR_HOOKFUNCTION(cl_nades, HUD_Draw_overlay)
  38 {
  39         if (STAT(HEALING_ORB) > time)
  40         {
  41                 M_ARGV(0, vector) = NADE_TYPE_HEAL.m_color;
  42                 M_ARGV(1, float) = STAT(HEALING_ORB_ALPHA);
  43                 return true;
  44         }
  45         if (STAT(ENTRAP_ORB) > time)
  46         {
  47                 M_ARGV(0, vector) = NADE_TYPE_ENTRAP.m_color;
  48                 M_ARGV(1, float) = STAT(ENTRAP_ORB_ALPHA);
  49                 return true;
  50         }
  51         return false;
  52 }
  53 MUTATOR_HOOKFUNCTION(cl_nades, Ent_Projectile)
  54 {
  55         entity proj = M_ARGV(0, entity);
  56
  57         if (proj.cnt == PROJECTILE_NAPALM_FOUNTAIN)
  58         {
  59                 proj.modelindex = 0;
  60                 proj.traileffect = EFFECT_FIREBALL.m_id;
  61                 return true;
  62         }
  63         if (Nade_FromProjectile(proj.cnt) != NADE_TYPE_Null)
  64         {
  65                 setmodel(proj, MDL_PROJECTILE_NADE);
  66                 entity trail = Nade_TrailEffect(proj.cnt, proj.team);
  67                 if (trail.eent_eff_name) proj.traileffect = trail.m_id;
  68                 return true;
  69         }
  70 }
  71 MUTATOR_HOOKFUNCTION(cl_nades, EditProjectile)
  72 {
  73         entity proj = M_ARGV(0, entity);
  74
  75         if (proj.cnt == PROJECTILE_NAPALM_FOUNTAIN)
  76         {
  77                 loopsound(proj, CH_SHOTS_SINGLE, SND_FIREBALL_FLY2, VOL_BASE, ATTEN_NORM);
  78                 proj.mins = '-16 -16 -16';
  79                 proj.maxs = '16 16 16';
  80         }
  81
  82         entity nade_type = Nade_FromProjectile(proj.cnt);
  83         if (nade_type == NADE_TYPE_Null) return;
  84         if(STAT(NADES_SMALL, NULL))
  85         {
  86                 proj.mins = '-8 -8 -8';
  87                 proj.maxs = '8 8 8';
  88         }
  89         else
  90         {
  91                 proj.mins = '-16 -16 -16';
  92                 proj.maxs = '16 16 16';
  93         }
  94         proj.colormod = nade_type.m_color;
  95         set_movetype(proj, MOVETYPE_BOUNCE);
  96         settouch(proj, func_null);
  97         proj.scale = 1.5;
  98         proj.avelocity = randomvec() * 720;
  99
 100         if (nade_type == NADE_TYPE_TRANSLOCATE || nade_type == NADE_TYPE_SPAWN)
 101                 proj.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 102         else
 103                 proj.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 104 }
 105 bool Projectile_isnade(int p)
 106 {
 107         return Nade_FromProjectile(p) != NADE_TYPE_Null;
 108 }
 109 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 110 {
 111         float bonusNades    = STAT(NADE_BONUS);
 112         float bonusProgress = STAT(NADE_BONUS_SCORE);
 113         float bonusType     = STAT(NADE_BONUS_TYPE);
 114         Nade def = Nades_from(bonusType);
 115         vector nadeColor    = def.m_color;
 116         string nadeIcon     = def.m_icon;
 117
 118         vector iconPos, textPos;
 119
 120         if(autocvar_hud_panel_ammo_iconalign)
 121         {
 122                 iconPos = myPos + eX * 2 * mySize.y;
 123                 textPos = myPos;
 124         }
 125         else
 126         {
 127                 iconPos = myPos;
 128                 textPos = myPos + eX * mySize.y;
 129         }
 130
 131         if(bonusNades > 0 || bonusProgress > 0)
 132         {
 133                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
 134
 135                 if(autocvar_hud_panel_ammo_text)
 136                         drawstring_aspect(textPos, ftos(bonusNades), vec2((2/3) * mySize.x, mySize.y), '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 137
 138                 if(draw_expanding)
 139                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
 140
 141                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 142         }
 143 }
 144 #endif
 145
 146 #ifdef SVQC
 147
 148 #include <common/gamemodes/_mod.qh>
 149 #include <common/monsters/sv_spawn.qh>
 150 #include <common/monsters/sv_monsters.qh>
 151 #include <server/g_subs.qh>
 152
 153 REGISTER_MUTATOR(nades, cvar("g_nades"));
 154
 155 .float nade_time_primed;
 156 .float nade_lifetime;
 157
 158 .entity nade_spawnloc;
 159
 160
 161 void nade_timer_think(entity this)
 162 {
 163         this.skin = 8 - (this.owner.wait - time) / (this.owner.nade_lifetime / 10);
 164         this.nextthink = time;
 165         if(!this.owner || wasfreed(this.owner))
 166                 delete(this);
 167 }
 168
 169 void nade_burn_spawn(entity _nade)
 170 {
 171         CSQCProjectile(_nade, true, Nades_from(_nade.nade_type).m_projectile[true], true);
 172 }
 173
 174 void nade_spawn(entity _nade)
 175 {
 176         entity timer = new(nade_timer);
 177         setmodel(timer, MDL_NADE_TIMER);
 178         setattachment(timer, _nade, "");
 179         timer.colormap = _nade.colormap;
 180         timer.glowmod = _nade.glowmod;
 181         setthink(timer, nade_timer_think);
 182         timer.nextthink = time;
 183         timer.wait = _nade.wait;
 184         timer.owner = _nade;
 185         timer.skin = 10;
 186
 187         _nade.effects |= EF_LOWPRECISION;
 188
 189         CSQCProjectile(_nade, true, Nades_from(_nade.nade_type).m_projectile[false], true);
 190 }
 191
 192 void napalm_damage(entity this, float dist, float damage, float edgedamage, float burntime)
 193 {
 194         entity e;
 195         float d;
 196         vector p;
 197
 198         if ( damage < 0 )
 199                 return;
 200
 201         RandomSelection_Init();
 202         for(e = WarpZone_FindRadius(this.origin, dist, true); e; e = e.chain)
 203                 if(e.takedamage == DAMAGE_AIM)
 204                 if(this.realowner != e || autocvar_g_nades_napalm_selfdamage)
 205                 if(!IS_PLAYER(e) || !this.realowner || DIFF_TEAM(e, this))
 206                 if(!STAT(FROZEN, e))
 207                 {
 208                         p = e.origin;
 209                         p.x += e.mins.x + random() * (e.maxs.x - e.mins.x);
 210                         p.y += e.mins.y + random() * (e.maxs.y - e.mins.y);
 211                         p.z += e.mins.z + random() * (e.maxs.z - e.mins.z);
 212                         d = vlen(WarpZone_UnTransformOrigin(e, this.origin) - p);
 213                         if(d < dist)
 214                         {
 215                                 e.fireball_impactvec = p;
 216                                 RandomSelection_AddEnt(e, 1 / (1 + d), !Fire_IsBurning(e));
 217                         }
 218                 }
 219         if(RandomSelection_chosen_ent)
 220         {
 221                 d = vlen(WarpZone_UnTransformOrigin(RandomSelection_chosen_ent, this.origin) - RandomSelection_chosen_ent.fireball_impactvec);
 222                 d = damage + (edgedamage - damage) * (d / dist);
 223                 Fire_AddDamage(RandomSelection_chosen_ent, this.realowner, d * burntime, burntime, this.projectiledeathtype);
 224                 //trailparticles(this, particleeffectnum(EFFECT_FIREBALL_LASER), this.origin, RandomSelection_chosen_ent.fireball_impactvec);
 225                 Send_Effect(EFFECT_FIREBALL_LASER, this.origin, RandomSelection_chosen_ent.fireball_impactvec - this.origin, 1);
 226         }
 227 }
 228
 229
 230 void napalm_ball_think(entity this)
 231 {
 232         if(round_handler_IsActive())
 233         if(!round_handler_IsRoundStarted())
 234         {
 235                 delete(this);
 236                 return;
 237         }
 238
 239         if(time > this.pushltime)
 240         {
 241                 delete(this);
 242                 return;
 243         }
 244
 245         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 246         if(pointcontents(midpoint) == CONTENT_WATER)
 247         {
 248                 this.velocity = this.velocity * 0.5;
 249
 250                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 251                         { this.velocity_z = 200; }
 252         }
 253
 254         this.angles = vectoangles(this.velocity);
 255
 256         napalm_damage(this, autocvar_g_nades_napalm_ball_radius,autocvar_g_nades_napalm_ball_damage,
 257                                   autocvar_g_nades_napalm_ball_damage,autocvar_g_nades_napalm_burntime);
 258
 259         this.nextthink = time + 0.1;
 260 }
 261
 262
 263 void nade_napalm_ball(entity this)
 264 {
 265         entity proj;
 266         vector kick;
 267
 268         spamsound(this, CH_SHOTS, SND_FIREBALL_FIRE, VOL_BASE, ATTEN_NORM);
 269
 270         proj = new(grenade);
 271         proj.owner = this.owner;
 272         proj.realowner = this.realowner;
 273         proj.team = this.owner.team;
 274         proj.bot_dodge = true;
 275         proj.bot_dodgerating = autocvar_g_nades_napalm_ball_damage;
 276         set_movetype(proj, MOVETYPE_BOUNCE);
 277         proj.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
 278         PROJECTILE_MAKETRIGGER(proj);
 279         setmodel(proj, MDL_Null);
 280         proj.scale = 1;//0.5;
 281         setsize(proj, '-4 -4 -4', '4 4 4');
 282         setorigin(proj, this.origin);
 283         setthink(proj, napalm_ball_think);
 284         proj.nextthink = time;
 285         proj.damageforcescale = autocvar_g_nades_napalm_ball_damageforcescale;
 286         proj.effects = EF_LOWPRECISION | EF_FLAME;
 287
 288         kick.x =(random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 289         kick.y = (random() - 0.5) * 2 * autocvar_g_nades_napalm_ball_spread;
 290         kick.z = (random()/2+0.5) * autocvar_g_nades_napalm_ball_spread;
 291         proj.velocity = kick;
 292
 293         proj.pushltime = time + autocvar_g_nades_napalm_ball_lifetime;
 294
 295         proj.angles = vectoangles(proj.velocity);
 296         proj.flags = FL_PROJECTILE;
 297         IL_PUSH(g_projectiles, proj);
 298         IL_PUSH(g_bot_dodge, proj);
 299         proj.missile_flags = MIF_SPLASH | MIF_PROXY | MIF_ARC;
 300
 301         //CSQCProjectile(proj, true, PROJECTILE_NAPALM_FIRE, true);
 302 }
 303
 304
 305 void napalm_fountain_think(entity this)
 306 {
 307
 308         if(round_handler_IsActive())
 309         if(!round_handler_IsRoundStarted())
 310         {
 311                 delete(this);
 312                 return;
 313         }
 314
 315         if(time >= this.ltime)
 316         {
 317                 delete(this);
 318                 return;
 319         }
 320
 321         vector midpoint = ((this.absmin + this.absmax) * 0.5);
 322         if(pointcontents(midpoint) == CONTENT_WATER)
 323         {
 324                 this.velocity = this.velocity * 0.5;
 325
 326                 if(pointcontents(midpoint + '0 0 16') == CONTENT_WATER)
 327                         { this.velocity_z = 200; }
 328
 329                 UpdateCSQCProjectile(this);
 330         }
 331
 332         napalm_damage(this, autocvar_g_nades_napalm_fountain_radius, autocvar_g_nades_napalm_fountain_damage,
 333                 autocvar_g_nades_napalm_fountain_edgedamage, autocvar_g_nades_napalm_burntime);
 334
 335         this.nextthink = time + 0.1;
 336         if(time >= this.nade_special_time)
 337         {
 338                 this.nade_special_time = time + autocvar_g_nades_napalm_fountain_delay;
 339                 nade_napalm_ball(this);
 340         }
 341 }
 342
 343 void nade_napalm_boom(entity this)
 344 {
 345         entity fountain;
 346         int c;
 347         for (c = 0; c < autocvar_g_nades_napalm_ball_count; c++)
 348                 nade_napalm_ball(this);
 349
 350
 351         fountain = spawn();
 352         fountain.owner = this.owner;
 353         fountain.realowner = this.realowner;
 354         fountain.origin = this.origin;
 355         fountain.flags = FL_PROJECTILE;
 356         IL_PUSH(g_projectiles, fountain);
 357         IL_PUSH(g_bot_dodge, fountain);
 358         setorigin(fountain, fountain.origin);
 359         setthink(fountain, napalm_fountain_think);
 360         fountain.nextthink = time;
 361         fountain.ltime = time + autocvar_g_nades_napalm_fountain_lifetime;
 362         fountain.pushltime = fountain.ltime;
 363         fountain.team = this.team;
 364         set_movetype(fountain, MOVETYPE_TOSS);
 365         fountain.projectiledeathtype = DEATH_NADE_NAPALM.m_id;
 366         fountain.bot_dodge = true;
 367         fountain.bot_dodgerating = autocvar_g_nades_napalm_fountain_damage;
 368         fountain.nade_special_time = time;
 369         setsize(fountain, '-16 -16 -16', '16 16 16');
 370         CSQCProjectile(fountain, true, PROJECTILE_NAPALM_FOUNTAIN, true);
 371 }
 372
 373 void nade_ice_freeze(entity freezefield, entity frost_target, float freeze_time)
 374 {
 375         frost_target.frozen_by = freezefield.realowner;
 376         Send_Effect(EFFECT_ELECTRO_IMPACT, frost_target.origin, '0 0 0', 1);
 377         Freeze(frost_target, 1/freeze_time, 3, false);
 378
 379         Drop_Special_Items(frost_target);
 380 }
 381
 382 void nade_ice_think(entity this)
 383 {
 384         if(round_handler_IsActive())
 385         if(!round_handler_IsRoundStarted())
 386         {
 387                 delete(this);
 388                 return;
 389         }
 390
 391         if(time >= this.ltime)
 392         {
 393                 if ( autocvar_g_nades_ice_explode )
 394                 {
 395                         entity expef = EFFECT_NADE_EXPLODE(this.realowner.team);
 396                         Send_Effect(expef, this.origin + '0 0 1', '0 0 0', 1);
 397                         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 398
 399                         RadiusDamage(this, this.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 400                                 autocvar_g_nades_nade_radius, this, NULL, autocvar_g_nades_nade_force, this.projectiledeathtype, this.enemy);
 401                         Damage_DamageInfo(this.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 402                                 autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, this.projectiledeathtype, 0, this);
 403                 }
 404                 delete(this);
 405                 return;
 406         }
 407
 408
 409         this.nextthink = time+0.1;
 410
 411         // gaussian
 412         float randomr;
 413         randomr = random();
 414         randomr = exp(-5*randomr*randomr)*autocvar_g_nades_nade_radius;
 415         float randomw;
 416         randomw = random()*M_PI*2;
 417         vector randomp;
 418         randomp.x = randomr*cos(randomw);
 419         randomp.y = randomr*sin(randomw);
 420         randomp.z = 1;
 421         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, this.origin + randomp, '0 0 0', 1);
 422
 423         if(time >= this.nade_special_time)
 424         {
 425                 this.nade_special_time = time+0.7;
 426
 427                 Send_Effect(EFFECT_ELECTRO_IMPACT, this.origin, '0 0 0', 1);
 428                 Send_Effect(EFFECT_ICEFIELD, this.origin, '0 0 0', 1);
 429         }
 430
 431
 432         float current_freeze_time = this.ltime - time - 0.1;
 433
 434         FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_nades_nade_radius, it != this && it.takedamage && !IS_DEAD(it) && GetResourceAmount(it, RESOURCE_HEALTH) > 0 && current_freeze_time > 0,
 435         {
 436                 if(!autocvar_g_nades_ice_teamcheck || (DIFF_TEAM(it, this.realowner) || it == this.realowner))
 437                 if(!it.revival_time || ((time - it.revival_time) >= 1.5))
 438                 if(!STAT(FROZEN, it))
 439                         nade_ice_freeze(this, it, current_freeze_time);
 440         });
 441 }
 442
 443 void nade_ice_boom(entity this)
 444 {
 445         entity fountain;
 446         fountain = spawn();
 447         fountain.owner = this.owner;
 448         fountain.realowner = this.realowner;
 449         fountain.origin = this.origin;
 450         setorigin(fountain, fountain.origin);
 451         setthink(fountain, nade_ice_think);
 452         fountain.nextthink = time;
 453         fountain.ltime = time + autocvar_g_nades_ice_freeze_time;
 454         fountain.pushltime = fountain.wait = fountain.ltime;
 455         fountain.team = this.team;
 456         set_movetype(fountain, MOVETYPE_TOSS);
 457         fountain.projectiledeathtype = DEATH_NADE_ICE.m_id;
 458         fountain.bot_dodge = false;
 459         setsize(fountain, '-16 -16 -16', '16 16 16');
 460         fountain.nade_special_time = time+0.3;
 461         fountain.angles = this.angles;
 462
 463         if ( autocvar_g_nades_ice_explode )
 464         {
 465                 setmodel(fountain, MDL_PROJECTILE_GRENADE);
 466                 entity timer = new(nade_timer);
 467                 setmodel(timer, MDL_NADE_TIMER);
 468                 setattachment(timer, fountain, "");
 469                 timer.colormap = this.colormap;
 470                 timer.glowmod = this.glowmod;
 471                 setthink(timer, nade_timer_think);
 472                 timer.nextthink = time;
 473                 timer.wait = fountain.ltime;
 474                 timer.owner = fountain;
 475                 timer.skin = 10;
 476         }
 477         else
 478                 setmodel(fountain, MDL_Null);
 479 }
 480
 481 void nade_translocate_boom(entity this)
 482 {
 483         if(this.realowner.vehicle)
 484                 return;
 485
 486         vector locout = this.origin + '0 0 1' * (1 - this.realowner.mins.z - 24);
 487         tracebox(locout, this.realowner.mins, this.realowner.maxs, locout, MOVE_NOMONSTERS, this.realowner);
 488         locout = trace_endpos;
 489
 490         makevectors(this.realowner.angles);
 491
 492         MUTATOR_CALLHOOK(PortalTeleport, this.realowner);
 493
 494         TeleportPlayer(this, this.realowner, locout, this.realowner.angles, v_forward * vlen(this.realowner.velocity), '0 0 0', '0 0 0', TELEPORT_FLAGS_TELEPORTER);
 495 }
 496
 497 void nade_spawn_boom(entity this)
 498 {
 499         entity spawnloc = spawn();
 500         setorigin(spawnloc, this.origin);
 501         setsize(spawnloc, this.realowner.mins, this.realowner.maxs);
 502         set_movetype(spawnloc, MOVETYPE_NONE);
 503         spawnloc.solid = SOLID_NOT;
 504         spawnloc.drawonlytoclient = this.realowner;
 505         spawnloc.effects = EF_STARDUST;
 506         spawnloc.cnt = autocvar_g_nades_spawn_count;
 507
 508         if(this.realowner.nade_spawnloc)
 509         {
 510                 delete(this.realowner.nade_spawnloc);
 511                 this.realowner.nade_spawnloc = NULL;
 512         }
 513
 514         this.realowner.nade_spawnloc = spawnloc;
 515 }
 516
 517 void nades_orb_think(entity this)
 518 {
 519         if(time >= this.ltime)
 520         {
 521                 delete(this);
 522                 return;
 523         }
 524
 525         this.nextthink = time;
 526
 527         if(time >= this.nade_special_time)
 528         {
 529                 this.nade_special_time = time+0.25;
 530                 this.nade_show_particles = 1;
 531         }
 532         else
 533                 this.nade_show_particles = 0;
 534 }
 535
 536 entity nades_spawn_orb(entity own, entity realown, vector org, float orb_ltime, float orb_rad)
 537 {
 538         // NOTE: this function merely places an orb
 539         // you must add a custom touch function to the returned entity if desired
 540         // also set .colormod if you wish to have it colorized
 541         entity orb = spawn(); // Net_LinkEntity sets the classname (TODO)
 542         orb.owner = own;
 543         orb.realowner = realown;
 544         setorigin(orb, org);
 545
 546         orb.orb_lifetime = orb_ltime; // required for timers
 547         orb.ltime = time + orb.orb_lifetime;
 548         orb.bot_dodge = false;
 549         orb.team = realown.team;
 550         orb.solid = SOLID_TRIGGER;
 551
 552         setmodel(orb, MDL_NADE_ORB);
 553         orb.skin = 1;
 554         orb.orb_radius = orb_rad; // required for fading
 555         vector size = '1 1 1' * orb.orb_radius / 2;
 556         setsize(orb, -size, size);
 557
 558         Net_LinkEntity(orb, true, 0, orb_send);
 559         orb.SendFlags |= 1;
 560
 561         setthink(orb, nades_orb_think);
 562         orb.nextthink = time;
 563
 564         return orb;
 565 }
 566
 567 void nade_entrap_touch(entity this, entity toucher)
 568 {
 569         if(DIFF_TEAM(toucher, this.realowner)) // TODO: what if realowner changes team or disconnects?
 570         {
 571                 if (!isPushable(toucher))
 572                         return;
 573
 574                 float pushdeltatime = time - toucher.lastpushtime;
 575                 if (pushdeltatime > 0.15) pushdeltatime = 0;
 576                 toucher.lastpushtime = time;
 577                 if(!pushdeltatime) return;
 578
 579                 // div0: ticrate independent, 1 = identity (not 20)
 580                 toucher.velocity = toucher.velocity * (autocvar_g_nades_entrap_strength ** pushdeltatime);
 581
 582         #ifdef SVQC
 583                 UpdateCSQCProjectile(toucher);
 584         #endif
 585         }
 586
 587         if ( IS_REAL_CLIENT(toucher) || IS_VEHICLE(toucher) || IS_MONSTER(toucher) )
 588         {
 589                 entity show_tint = (IS_VEHICLE(toucher)) ? toucher.owner : toucher;
 590                 STAT(ENTRAP_ORB, show_tint) = time + 0.1;
 591
 592                 float tint_alpha = 0.75;
 593                 if(SAME_TEAM(toucher, this.realowner))
 594                         tint_alpha = 0.45;
 595                 STAT(ENTRAP_ORB_ALPHA, show_tint) = tint_alpha * (this.ltime - time) / this.orb_lifetime;
 596         }
 597 }
 598
 599 void nade_entrap_boom(entity this)
 600 {
 601         entity orb = nades_spawn_orb(this.owner, this.realowner, this.origin, autocvar_g_nades_entrap_time, autocvar_g_nades_entrap_radius);
 602
 603         settouch(orb, nade_entrap_touch);
 604         orb.colormod = NADE_TYPE_ENTRAP.m_color;
 605 }
 606
 607 void nade_heal_touch(entity this, entity toucher)
 608 {
 609         float maxhealth;
 610         float health_factor;
 611         if(IS_PLAYER(toucher) || IS_MONSTER(toucher))
 612         if(!IS_DEAD(toucher))
 613         if(!STAT(FROZEN, toucher))
 614         {
 615                 health_factor = autocvar_g_nades_heal_rate*frametime/2;
 616                 if ( toucher != this.realowner )
 617                 {
 618                         if ( SAME_TEAM(toucher,this) )
 619                                 health_factor *= autocvar_g_nades_heal_friend;
 620                         else
 621                                 health_factor *= autocvar_g_nades_heal_foe;
 622                 }
 623                 if ( health_factor > 0 )
 624                 {
 625                         maxhealth = (IS_MONSTER(toucher)) ? toucher.max_health : g_pickup_healthmega_max;
 626                         float hp = GetResourceAmount(toucher, RESOURCE_HEALTH);
 627                         if (hp < maxhealth)
 628                         {
 629                                 if (this.nade_show_particles)
 630                                 {
 631                                         Send_Effect(EFFECT_HEALING, toucher.origin, '0 0 0', 1);
 632                                 }
 633                                 GiveResourceWithLimit(toucher, RESOURCE_HEALTH, health_factor, maxhealth);
 634                         }
 635                 }
 636                 else if ( health_factor < 0 )
 637                 {
 638                         Damage(toucher,this,this.realowner,-health_factor,DEATH_NADE_HEAL.m_id,toucher.origin,'0 0 0');
 639                 }
 640
 641         }
 642
 643         if ( IS_REAL_CLIENT(toucher) || IS_VEHICLE(toucher) )
 644         {
 645                 entity show_red = (IS_VEHICLE(toucher)) ? toucher.owner : toucher;
 646                 show_red.stat_healing_orb = time+0.1;
 647                 show_red.stat_healing_orb_alpha = 0.75 * (this.ltime - time) / this.orb_lifetime;
 648         }
 649 }
 650
 651 void nade_heal_boom(entity this)
 652 {
 653         entity orb = nades_spawn_orb(this.owner, this.realowner, this.origin, autocvar_g_nades_heal_time, autocvar_g_nades_nade_radius);
 654
 655         settouch(orb, nade_heal_touch);
 656         orb.colormod = '1 0 0';
 657 }
 658
 659 void nade_monster_boom(entity this)
 660 {
 661         entity e = spawnmonster(spawn(), this.pokenade_type, 0, this.realowner, this.realowner, this.origin, false, false, 1);
 662
 663         if(autocvar_g_nades_pokenade_monster_lifetime > 0)
 664                 e.monster_lifetime = time + autocvar_g_nades_pokenade_monster_lifetime;
 665         e.monster_skill = MONSTER_SKILL_INSANE;
 666 }
 667
 668 void nade_boom(entity this)
 669 {
 670         entity expef = NULL;
 671         bool nade_blast = true;
 672
 673         switch ( Nades_from(this.nade_type) )
 674         {
 675                 case NADE_TYPE_NAPALM:
 676                         nade_blast = autocvar_g_nades_napalm_blast;
 677                         expef = EFFECT_EXPLOSION_MEDIUM;
 678                         break;
 679                 case NADE_TYPE_ICE:
 680                         nade_blast = false;
 681                         expef = EFFECT_ELECTRO_COMBO; // hookbomb_explode electro_combo bigplasma_impact
 682                         break;
 683                 case NADE_TYPE_TRANSLOCATE:
 684                         nade_blast = false;
 685                         break;
 686                 case NADE_TYPE_MONSTER:
 687                 case NADE_TYPE_SPAWN:
 688                         nade_blast = false;
 689                         switch(this.realowner.team)
 690                         {
 691                                 case NUM_TEAM_1: expef = EFFECT_SPAWN_RED; break;
 692                                 case NUM_TEAM_2: expef = EFFECT_SPAWN_BLUE; break;
 693                                 case NUM_TEAM_3: expef = EFFECT_SPAWN_YELLOW; break;
 694                                 case NUM_TEAM_4: expef = EFFECT_SPAWN_PINK; break;
 695                                 default: expef = EFFECT_SPAWN_NEUTRAL; break;
 696                         }
 697                         break;
 698                 case NADE_TYPE_HEAL:
 699                         nade_blast = false;
 700                         expef = EFFECT_SPAWN_RED;
 701                         break;
 702
 703                 case NADE_TYPE_ENTRAP:
 704                         nade_blast = false;
 705                         expef = EFFECT_SPAWN_YELLOW;
 706                         break;
 707
 708                 default:
 709                 case NADE_TYPE_NORMAL:
 710                         expef = EFFECT_NADE_EXPLODE(this.realowner.team);
 711                         break;
 712         }
 713
 714         if(expef)
 715                 Send_Effect(expef, findbetterlocation(this.origin, 8), '0 0 0', 1);
 716
 717         sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, ATTEN_NORM);
 718         sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 719
 720         this.event_damage = func_null; // prevent somehow calling damage in the next call
 721
 722         if(nade_blast)
 723         {
 724                 RadiusDamage(this, this.realowner, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage,
 725                                  autocvar_g_nades_nade_radius, this, NULL, autocvar_g_nades_nade_force, this.projectiledeathtype, this.enemy);
 726                 Damage_DamageInfo(this.origin, autocvar_g_nades_nade_damage, autocvar_g_nades_nade_edgedamage, autocvar_g_nades_nade_radius, '1 1 1' * autocvar_g_nades_nade_force, this.projectiledeathtype, 0, this);
 727         }
 728
 729         if(this.takedamage)
 730         switch ( Nades_from(this.nade_type) )
 731         {
 732                 case NADE_TYPE_NAPALM: nade_napalm_boom(this); break;
 733                 case NADE_TYPE_ICE: nade_ice_boom(this); break;
 734                 case NADE_TYPE_TRANSLOCATE: nade_translocate_boom(this); break;
 735                 case NADE_TYPE_SPAWN: nade_spawn_boom(this); break;
 736                 case NADE_TYPE_HEAL: nade_heal_boom(this); break;
 737                 case NADE_TYPE_MONSTER: nade_monster_boom(this); break;
 738                 case NADE_TYPE_ENTRAP: nade_entrap_boom(this); break;
 739         }
 740
 741         IL_EACH(g_projectiles, it.classname == "grapplinghook" && it.aiment == this,
 742         {
 743                 RemoveHook(it);
 744         });
 745
 746         delete(this);
 747 }
 748
 749 void spawn_held_nade(entity player, entity nowner, float ntime, int ntype, string pntype);
 750 void nade_pickup(entity this, entity thenade)
 751 {
 752         spawn_held_nade(this, thenade.realowner, autocvar_g_nades_pickup_time, thenade.nade_type, thenade.pokenade_type);
 753
 754         // set refire so player can't even
 755         this.nade_refire = time + autocvar_g_nades_nade_refire;
 756         this.nade_timer = 0;
 757
 758         if(this.nade)
 759                 this.nade.nade_time_primed = thenade.nade_time_primed;
 760 }
 761
 762 bool CanThrowNade(entity this);
 763 void nade_touch(entity this, entity toucher)
 764 {
 765         if(toucher)
 766                 UpdateCSQCProjectile(this);
 767
 768         if(toucher == this.realowner)
 769                 return; // no this impacts
 770
 771         if(autocvar_g_nades_pickup)
 772         if(time >= this.spawnshieldtime)
 773         if(!toucher.nade && GetResourceAmount(this, RESOURCE_HEALTH) == this.max_health) // no boosted shot pickups, thank you very much
 774         if(CanThrowNade(toucher)) // prevent some obvious things, like dead players
 775         if(IS_REAL_CLIENT(toucher)) // above checks for IS_PLAYER, don't need to do it here
 776         {
 777                 nade_pickup(toucher, this);
 778                 sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 779                 delete(this);
 780                 return;
 781         }
 782         /*float is_weapclip = 0;
 783         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 784         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 785         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 786                 is_weapclip = 1;*/
 787         if(ITEM_TOUCH_NEEDKILL()) // || is_weapclip)
 788         {
 789                 IL_EACH(g_projectiles, it.classname == "grapplinghook" && it.aiment == this,
 790                 {
 791                         RemoveHook(it);
 792                 });
 793                 delete(this);
 794                 return;
 795         }
 796
 797         PROJECTILE_TOUCH(this, toucher);
 798
 799         //setsize(this, '-2 -2 -2', '2 2 2');
 800         //UpdateCSQCProjectile(this);
 801         if(GetResourceAmount(this, RESOURCE_HEALTH) == this.max_health)
 802         {
 803                 spamsound(this, CH_SHOTS, SND_GRENADE_BOUNCE_RANDOM(), VOL_BASE, ATTEN_NORM);
 804                 return;
 805         }
 806
 807         this.enemy = toucher;
 808         nade_boom(this);
 809 }
 810
 811 void nade_beep(entity this)
 812 {
 813         sound(this, CH_SHOTS_SINGLE, SND_NADE_BEEP, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 814         setthink(this, nade_boom);
 815         this.nextthink = max(this.wait, time);
 816 }
 817
 818 void nade_damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 819 {
 820         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 821         {
 822                 this.takedamage = DAMAGE_NO;
 823                 nade_boom(this);
 824                 return;
 825         }
 826
 827         if(this.nade_type == NADE_TYPE_TRANSLOCATE.m_id || this.nade_type == NADE_TYPE_SPAWN.m_id)
 828                 return;
 829
 830         if (MUTATOR_CALLHOOK(Nade_Damage, this, DEATH_WEAPONOF(deathtype), force, damage)) {}
 831         else if(DEATH_ISWEAPON(deathtype, WEP_BLASTER))
 832         {
 833                 force *= 1.5;
 834                 damage = 0;
 835         }
 836         else if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER) && (deathtype & HITTYPE_SECONDARY))
 837         {
 838                 force *= 0.5; // too much
 839                 damage = 0;
 840         }
 841         else if(DEATH_ISWEAPON(deathtype, WEP_VORTEX) || DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 842         {
 843                 force *= 6;
 844                 damage = this.max_health * 0.55;
 845         }
 846         else if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 847                 damage = this.max_health * 0.1;
 848         else if(DEATH_ISWEAPON(deathtype, WEP_SHOCKWAVE) || DEATH_ISWEAPON(deathtype, WEP_SHOTGUN)) // WEAPONTODO
 849         {
 850                 if(deathtype & HITTYPE_SECONDARY)
 851                 {
 852                         damage = this.max_health * 0.1;
 853                         force *= 10;
 854                 }
 855                 else
 856                         damage = this.max_health * 1.15;
 857         }
 858
 859         this.velocity += force;
 860         UpdateCSQCProjectile(this);
 861
 862         if(damage <= 0 || ((IS_ONGROUND(this)) && IS_PLAYER(attacker)))
 863                 return;
 864
 865         float hp = GetResourceAmount(this, RESOURCE_HEALTH);
 866         if(hp == this.max_health)
 867         {
 868                 sound(this, CH_SHOTS_SINGLE, SND_Null, VOL_BASE, 0.5 *(ATTEN_LARGE + ATTEN_MAX));
 869                 this.nextthink = max(time + this.nade_lifetime, time);
 870                 setthink(this, nade_beep);
 871         }
 872
 873         hp -= damage;
 874         SetResourceAmount(this, RESOURCE_HEALTH, hp);
 875
 876
 877         if ( this.nade_type != NADE_TYPE_HEAL.m_id || IS_PLAYER(attacker) )
 878                 this.realowner = attacker;
 879
 880         if(hp <= 0)
 881                 W_PrepareExplosionByDamage(this, attacker, nade_boom);
 882         else
 883                 nade_burn_spawn(this);
 884 }
 885
 886 void toss_nade(entity e, bool set_owner, vector _velocity, float _time)
 887 {
 888         if(e.nade == NULL)
 889                 return;
 890
 891         entity _nade = e.nade;
 892         e.nade = NULL;
 893
 894         delete(e.fake_nade);
 895         e.fake_nade = NULL;
 896
 897         Kill_Notification(NOTIF_ONE_ONLY, e, MSG_CENTER, CPID_NADES);
 898
 899         makevectors(e.v_angle);
 900
 901         // NOTE: always throw from first weapon entity?
 902         W_SetupShot(e, _nade.weaponentity_fld, false, false, SND_Null, CH_WEAPON_A, 0);
 903
 904         vector offset = (v_forward * autocvar_g_nades_throw_offset.x)
 905                       + (v_right * autocvar_g_nades_throw_offset.y)
 906                       + (v_up * autocvar_g_nades_throw_offset.z);
 907
 908         setorigin(_nade, w_shotorg + offset);
 909         //setmodel(_nade, MDL_PROJECTILE_NADE);
 910         //setattachment(_nade, NULL, "");
 911         PROJECTILE_MAKETRIGGER(_nade);
 912         if(STAT(NADES_SMALL, e))
 913                 setsize(_nade, '-8 -8 -8', '8 8 8');
 914         else
 915                 setsize(_nade, '-16 -16 -16', '16 16 16');
 916         set_movetype(_nade, MOVETYPE_BOUNCE);
 917
 918         tracebox(_nade.origin, _nade.mins, _nade.maxs, _nade.origin, MOVE_NOMONSTERS, _nade);
 919         if (trace_startsolid)
 920                 setorigin(_nade, e.origin);
 921
 922         if(e.v_angle.x >= 70 && e.v_angle.x <= 110 && PHYS_INPUT_BUTTON_CROUCH(e))
 923                 _nade.velocity = '0 0 100';
 924         else if(autocvar_g_nades_nade_newton_style == 1)
 925                 _nade.velocity = e.velocity + _velocity;
 926         else if(autocvar_g_nades_nade_newton_style == 2)
 927                 _nade.velocity = _velocity;
 928         else
 929                 _nade.velocity = W_CalculateProjectileVelocity(e, e.velocity, _velocity, true);
 930
 931         if(set_owner)
 932                 _nade.realowner = e;
 933
 934         settouch(_nade, nade_touch);
 935         _nade.spawnshieldtime = time + 0.1; // prevent instantly picking up again
 936         SetResourceAmount(_nade, RESOURCE_HEALTH, autocvar_g_nades_nade_health);
 937         _nade.max_health = _nade.health;
 938         _nade.takedamage = DAMAGE_AIM;
 939         _nade.event_damage = nade_damage;
 940         setcefc(_nade, func_null);
 941         _nade.exteriormodeltoclient = NULL;
 942         _nade.traileffectnum = 0;
 943         _nade.teleportable = true;
 944         _nade.pushable = true;
 945         _nade.gravity = 1;
 946         _nade.missile_flags = MIF_SPLASH | MIF_ARC;
 947         _nade.damagedbycontents = true;
 948         IL_PUSH(g_damagedbycontents, _nade);
 949         _nade.angles = vectoangles(_nade.velocity);
 950         _nade.flags = FL_PROJECTILE;
 951         IL_PUSH(g_projectiles, _nade);
 952         IL_PUSH(g_bot_dodge, _nade);
 953         _nade.projectiledeathtype = DEATH_NADE.m_id;
 954         _nade.toss_time = time;
 955         _nade.solid = SOLID_CORPSE; //((_nade.nade_type == NADE_TYPE_TRANSLOCATE) ? SOLID_CORPSE : SOLID_BBOX);
 956
 957         if(_nade.nade_type == NADE_TYPE_TRANSLOCATE.m_id || _nade.nade_type == NADE_TYPE_SPAWN.m_id)
 958                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 959         else
 960                 _nade.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 961
 962         nade_spawn(_nade);
 963
 964         if(_time)
 965         {
 966                 setthink(_nade, nade_boom);
 967                 _nade.nextthink = _time;
 968         }
 969
 970         e.nade_refire = time + autocvar_g_nades_nade_refire;
 971         e.nade_timer = 0;
 972 }
 973
 974 void nades_GiveBonus(entity player, float score)
 975 {
 976         if (autocvar_g_nades)
 977         if (autocvar_g_nades_bonus)
 978         if (IS_REAL_CLIENT(player))
 979         if (IS_PLAYER(player) && player.bonus_nades < autocvar_g_nades_bonus_max)
 980         if (STAT(FROZEN, player) == 0)
 981         if (!IS_DEAD(player))
 982         {
 983                 if ( player.bonus_nade_score < 1 )
 984                         player.bonus_nade_score += score/autocvar_g_nades_bonus_score_max;
 985
 986                 if ( player.bonus_nade_score >= 1 )
 987                 {
 988                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_NADE_BONUS);
 989                         play2(player, SND(KH_ALARM));
 990                         player.bonus_nades++;
 991                         player.bonus_nade_score -= 1;
 992                 }
 993         }
 994 }
 995
 996 /** Remove all bonus nades from a player */
 997 void nades_RemoveBonus(entity player)
 998 {
 999         player.bonus_nades = player.bonus_nade_score = 0;
1000 }
1001
1002 MUTATOR_HOOKFUNCTION(nades, PutClientInServer)
1003 {
1004     entity player = M_ARGV(0, entity);
1005
1006         nades_RemoveBonus(player);
1007 }
1008
1009 bool nade_customize(entity this, entity client)
1010 {
1011         //if(IS_SPEC(client)) { return false; }
1012         if(client == this.exteriormodeltoclient || (IS_SPEC(client) && client.enemy == this.exteriormodeltoclient))
1013         {
1014                 // somewhat hide the model, but keep the glow
1015                 //this.effects = 0;
1016                 if(this.traileffectnum)
1017                         this.traileffectnum = 0;
1018                 this.alpha = -1;
1019         }
1020         else
1021         {
1022                 //this.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
1023                 if(!this.traileffectnum)
1024                         this.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(this.nade_type).m_projectile[false], this.team).eent_eff_name);
1025                 this.alpha = 1;
1026         }
1027
1028         return true;
1029 }
1030
1031 void spawn_held_nade(entity player, entity nowner, float ntime, int ntype, string pntype)
1032 {
1033         entity n = new(nade), fn = new(fake_nade);
1034
1035         n.nade_type = max(1, ntype);
1036         n.pokenade_type = pntype;
1037
1038         if(Nades_from(n.nade_type) == NADE_TYPE_Null)
1039                 n.nade_type = NADE_TYPE_NORMAL.m_id;
1040
1041         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
1042
1043         setmodel(n, MDL_PROJECTILE_NADE);
1044         //setattachment(n, player, "bip01 l hand");
1045         n.exteriormodeltoclient = player;
1046         setcefc(n, nade_customize);
1047         n.traileffectnum = _particleeffectnum(Nade_TrailEffect(Nades_from(n.nade_type).m_projectile[false], player.team).eent_eff_name);
1048         n.colormod = Nades_from(n.nade_type).m_color;
1049         n.realowner = nowner;
1050         n.colormap = player.colormap;
1051         n.glowmod = player.glowmod;
1052         n.wait = time + max(0, ntime);
1053         n.nade_time_primed = time;
1054         setthink(n, nade_beep);
1055         n.nextthink = max(n.wait - 3, time);
1056         n.projectiledeathtype = DEATH_NADE.m_id;
1057         n.weaponentity_fld = weaponentity;
1058         n.nade_lifetime = ntime;
1059
1060         setmodel(fn, MDL_NADE_VIEW);
1061         setattachment(fn, player.(weaponentity), "");
1062         fn.realowner = fn.owner = player;
1063         fn.colormod = Nades_from(n.nade_type).m_color;
1064         fn.colormap = player.colormap;
1065         fn.glowmod = player.glowmod;
1066         setthink(fn, SUB_Remove);
1067         fn.nextthink = n.wait;
1068         fn.weaponentity_fld = weaponentity;
1069
1070         player.nade = n;
1071         player.fake_nade = fn;
1072 }
1073
1074 void nade_prime(entity this)
1075 {
1076         if(autocvar_g_nades_bonus_only)
1077         if(!this.bonus_nades)
1078                 return; // only allow bonus nades
1079
1080         if(this.nade)
1081                 delete(this.nade);
1082
1083         if(this.fake_nade)
1084                 delete(this.fake_nade);
1085
1086         int ntype;
1087         string pntype = this.pokenade_type;
1088
1089         if(this.items & ITEM_Strength.m_itemid && autocvar_g_nades_bonus_onstrength)
1090                 ntype = this.nade_type;
1091         else if (this.bonus_nades >= 1)
1092         {
1093                 ntype = this.nade_type;
1094                 pntype = this.pokenade_type;
1095                 this.bonus_nades -= 1;
1096         }
1097         else
1098         {
1099                 ntype = ((autocvar_g_nades_client_select) ? CS(this).cvar_cl_nade_type : autocvar_g_nades_nade_type);
1100                 pntype = ((autocvar_g_nades_client_select) ? CS(this).cvar_cl_pokenade_type : autocvar_g_nades_pokenade_monster_type);
1101         }
1102
1103         spawn_held_nade(this, this, autocvar_g_nades_nade_lifetime, ntype, pntype);
1104 }
1105
1106 bool CanThrowNade(entity this)
1107 {
1108         if(this.vehicle)
1109                 return false;
1110
1111         if(IS_DEAD(this))
1112                 return false;
1113
1114         if (!autocvar_g_nades)
1115                 return false; // allow turning them off mid match
1116
1117         if(forbidWeaponUse(this))
1118                 return false;
1119
1120         if (!IS_PLAYER(this))
1121                 return false;
1122
1123         return true;
1124 }
1125
1126 .bool nade_altbutton;
1127
1128 void nades_CheckThrow(entity this)
1129 {
1130         if(!CanThrowNade(this))
1131                 return;
1132
1133         entity held_nade = this.nade;
1134         if (!held_nade)
1135         {
1136                 this.nade_altbutton = true;
1137                 if(time > this.nade_refire)
1138                 {
1139                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_NADE_THROW);
1140                         nade_prime(this);
1141                         this.nade_refire = time + autocvar_g_nades_nade_refire;
1142                 }
1143         }
1144         else
1145         {
1146                 this.nade_altbutton = false;
1147                 if (time >= held_nade.nade_time_primed + 1) {
1148                         makevectors(this.v_angle);
1149                         float _force = time - held_nade.nade_time_primed;
1150                         _force /= autocvar_g_nades_nade_lifetime;
1151                         _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1152                         vector dir = (v_forward * 0.75 + v_up * 0.2 + v_right * 0.05);
1153                         dir = W_CalculateSpread(dir, autocvar_g_nades_spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
1154                         toss_nade(this, true, dir * _force, 0);
1155                 }
1156         }
1157 }
1158
1159 void nades_Clear(entity player)
1160 {
1161         if(player.nade)
1162                 delete(player.nade);
1163         if(player.fake_nade)
1164                 delete(player.fake_nade);
1165
1166         player.nade = player.fake_nade = NULL;
1167         player.nade_timer = 0;
1168 }
1169
1170 MUTATOR_HOOKFUNCTION(nades, VehicleEnter)
1171 {
1172         entity player = M_ARGV(0, entity);
1173
1174         if(player.nade)
1175                 toss_nade(player, true, '0 0 100', max(player.nade.wait, time + 0.05));
1176 }
1177
1178 CLASS(NadeOffhand, OffhandWeapon)
1179     METHOD(NadeOffhand, offhand_think, void(NadeOffhand this, entity player, bool key_pressed))
1180     {
1181         entity held_nade = player.nade;
1182
1183         if (!CanThrowNade(player)) return;
1184         if (!(time > player.nade_refire)) return;
1185                 if (key_pressed) {
1186                         if (!held_nade) {
1187                                 nade_prime(player);
1188                                 held_nade = player.nade;
1189                         }
1190                 } else if (time >= held_nade.nade_time_primed + 1) {
1191                         if (held_nade) {
1192                                 makevectors(player.v_angle);
1193                                 float _force = time - held_nade.nade_time_primed;
1194                                 _force /= autocvar_g_nades_nade_lifetime;
1195                                 _force = autocvar_g_nades_nade_minforce + (_force * (autocvar_g_nades_nade_maxforce - autocvar_g_nades_nade_minforce));
1196                                 vector dir = (v_forward * 0.7 + v_up * 0.2 + v_right * 0.1);
1197                                 dir = W_CalculateSpread(dir, autocvar_g_nades_spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
1198                                 toss_nade(player, false, dir * _force, 0);
1199                         }
1200                 }
1201     }
1202 ENDCLASS(NadeOffhand)
1203 NadeOffhand OFFHAND_NADE; STATIC_INIT(OFFHAND_NADE) { OFFHAND_NADE = NEW(NadeOffhand); }
1204
1205 MUTATOR_HOOKFUNCTION(nades, ForbidThrowCurrentWeapon, CBC_ORDER_LAST)
1206 {
1207     entity player = M_ARGV(0, entity);
1208
1209         if (player.offhand != OFFHAND_NADE || (player.weapons & WEPSET(HOOK)) || autocvar_g_nades_override_dropweapon) {
1210                 nades_CheckThrow(player);
1211                 return true;
1212         }
1213 }
1214
1215 MUTATOR_HOOKFUNCTION(nades, PlayerPreThink)
1216 {
1217         entity player = M_ARGV(0, entity);
1218
1219         if (!IS_PLAYER(player)) { return; }
1220
1221         if (player.nade && (player.offhand != OFFHAND_NADE || (player.weapons & WEPSET(HOOK)))) OFFHAND_NADE.offhand_think(OFFHAND_NADE, player, player.nade_altbutton);
1222
1223         entity held_nade = player.nade;
1224         if (held_nade)
1225         {
1226                 player.nade_timer = bound(0, (time - held_nade.nade_time_primed) / held_nade.nade_lifetime, 1);
1227                 // LOG_TRACEF("%d %d", player.nade_timer, time - held_nade.nade_time_primed);
1228                 makevectors(player.angles);
1229                 held_nade.velocity = player.velocity;
1230                 setorigin(held_nade, player.origin + player.view_ofs + v_forward * 8 + v_right * -8 + v_up * 0);
1231                 held_nade.angles_y = player.angles.y;
1232
1233                 if (time + 0.1 >= held_nade.wait)
1234                         toss_nade(player, false, '0 0 0', time + 0.05);
1235         }
1236
1237         if(IS_PLAYER(player))
1238         {
1239                 if ( autocvar_g_nades_bonus && autocvar_g_nades )
1240                 {
1241                         entity key;
1242                         float key_count = 0;
1243                         FOR_EACH_KH_KEY(key) if(key.owner == player) { ++key_count; }
1244
1245                         float time_score;
1246                         if(GameRules_scoring_is_vip(player))
1247                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier;
1248                         else
1249                                 time_score = autocvar_g_nades_bonus_score_time;
1250
1251                         if(key_count)
1252                                 time_score = autocvar_g_nades_bonus_score_time_flagcarrier * key_count; // multiply by the number of keys the player is holding
1253
1254                         if(autocvar_g_nades_bonus_client_select)
1255                         {
1256                                 player.nade_type = CS(player).cvar_cl_nade_type;
1257                                 player.pokenade_type = CS(player).cvar_cl_pokenade_type;
1258                         }
1259                         else
1260                         {
1261                                 player.nade_type = autocvar_g_nades_bonus_type;
1262                                 player.pokenade_type = autocvar_g_nades_pokenade_monster_type;
1263                         }
1264
1265                         player.nade_type = bound(1, player.nade_type, Nades_COUNT);
1266
1267                         if(player.bonus_nade_score >= 0 && autocvar_g_nades_bonus_score_max)
1268                                 nades_GiveBonus(player, time_score / autocvar_g_nades_bonus_score_max);
1269                 }
1270                 else
1271                 {
1272                         player.bonus_nades = player.bonus_nade_score = 0;
1273                 }
1274         }
1275
1276         float n = 0;
1277         entity o = NULL;
1278         if(player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
1279                 n = -1;
1280         else
1281         {
1282                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
1283                 n = 0;
1284                 FOREACH_CLIENT(IS_PLAYER(it) && it != player, {
1285                         if(!IS_DEAD(it))
1286                         if(STAT(FROZEN, it) == 0)
1287                         if(SAME_TEAM(it, player))
1288                         if(boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
1289                         {
1290                                 if(!o)
1291                                         o = it;
1292                                 if(STAT(FROZEN, player) == 1)
1293                                         it.reviving = true;
1294                                 ++n;
1295                         }
1296                 });
1297         }
1298
1299         if(n && STAT(FROZEN, player) == 3) // OK, there is at least one teammate reviving us
1300         {
1301                 player.revive_progress = bound(0, player.revive_progress + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
1302                 SetResourceAmount(player, RESOURCE_HEALTH, max(1, player.revive_progress * start_health));
1303
1304                 if(player.revive_progress >= 1)
1305                 {
1306                         Unfreeze(player);
1307
1308                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, o.netname);
1309                         Send_Notification(NOTIF_ONE, o, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
1310                 }
1311
1312                 FOREACH_CLIENT(IS_PLAYER(it) && it.reviving, {
1313                         it.revive_progress = player.revive_progress;
1314                         it.reviving = false;
1315                 });
1316         }
1317 }
1318
1319 MUTATOR_HOOKFUNCTION(nades, PlayerPhysics)
1320 {
1321         entity player = M_ARGV(0, entity);
1322
1323         if (STAT(ENTRAP_ORB, player) > time)
1324         {
1325                 player.stat_sv_maxspeed *= autocvar_g_nades_entrap_speed;
1326                 player.stat_sv_airspeedlimit_nonqw *= autocvar_g_nades_entrap_speed;
1327         }
1328 }
1329
1330 MUTATOR_HOOKFUNCTION(nades, MonsterMove)
1331 {
1332     entity mon = M_ARGV(0, entity);
1333
1334         if (STAT(ENTRAP_ORB, mon) > time)
1335         {
1336                 M_ARGV(1, float) *= autocvar_g_nades_entrap_speed; // run speed
1337                 M_ARGV(2, float) *= autocvar_g_nades_entrap_speed; // walk speed
1338         }
1339 }
1340
1341 MUTATOR_HOOKFUNCTION(nades, PlayerSpawn)
1342 {
1343         entity player = M_ARGV(0, entity);
1344
1345         if(autocvar_g_nades_spawn)
1346                 player.nade_refire = time + autocvar_g_spawnshieldtime;
1347         else
1348                 player.nade_refire  = time + autocvar_g_nades_nade_refire;
1349
1350         if(autocvar_g_nades_bonus_client_select)
1351                 player.nade_type = CS(player).cvar_cl_nade_type;
1352
1353         player.nade_timer = 0;
1354
1355         if (!player.offhand) player.offhand = OFFHAND_NADE;
1356
1357         if(player.nade_spawnloc)
1358         {
1359                 setorigin(player, player.nade_spawnloc.origin);
1360                 player.nade_spawnloc.cnt -= 1;
1361
1362                 if(player.nade_spawnloc.cnt <= 0)
1363                 {
1364                         delete(player.nade_spawnloc);
1365                         player.nade_spawnloc = NULL;
1366                 }
1367         }
1368 }
1369
1370 MUTATOR_HOOKFUNCTION(nades, PlayerDies, CBC_ORDER_LAST)
1371 {
1372         entity frag_attacker = M_ARGV(1, entity);
1373         entity frag_target = M_ARGV(2, entity);
1374
1375         if(frag_target.nade)
1376         if(!STAT(FROZEN, frag_target) || !autocvar_g_freezetag_revive_nade)
1377                 toss_nade(frag_target, true, '0 0 100', max(frag_target.nade.wait, time + 0.05));
1378
1379         if(IS_PLAYER(frag_attacker))
1380         {
1381                 float killcount_bonus = ((CS(frag_attacker).killcount >= 1) ? bound(0, autocvar_g_nades_bonus_score_minor * CS(frag_attacker).killcount, autocvar_g_nades_bonus_score_medium) : autocvar_g_nades_bonus_score_minor);
1382
1383                 if (SAME_TEAM(frag_attacker, frag_target) || frag_attacker == frag_target)
1384                         nades_RemoveBonus(frag_attacker);
1385                 else if(GameRules_scoring_is_vip(frag_target))
1386                         nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_medium);
1387                 else if(autocvar_g_nades_bonus_score_spree && CS(frag_attacker).killcount > 1)
1388                 {
1389                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
1390                                 case counta: { nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_spree); break; }
1391                         switch(CS(frag_attacker).killcount)
1392                         {
1393                                 KILL_SPREE_LIST
1394                                 default: nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor); break;
1395                         }
1396                         #undef SPREE_ITEM
1397                 }
1398                 else
1399                         nades_GiveBonus(frag_attacker, killcount_bonus);
1400         }
1401
1402         nades_RemoveBonus(frag_target);
1403 }
1404
1405 MUTATOR_HOOKFUNCTION(nades, Damage_Calculate)
1406 {
1407         entity frag_inflictor = M_ARGV(0, entity);
1408         entity frag_attacker = M_ARGV(1, entity);
1409         entity frag_target = M_ARGV(2, entity);
1410         float frag_deathtype = M_ARGV(3, float);
1411
1412         if(STAT(FROZEN, frag_target))
1413         if(autocvar_g_freezetag_revive_nade)
1414         if(frag_attacker == frag_target)
1415         if(frag_deathtype == DEATH_NADE.m_id)
1416         if(time - frag_inflictor.toss_time <= 0.1)
1417         {
1418                 Unfreeze(frag_target);
1419                 SetResourceAmount(frag_target, RESOURCE_HEALTH, autocvar_g_freezetag_revive_nade_health);
1420                 Send_Effect(EFFECT_ICEORGLASS, frag_target.origin, '0 0 0', 3);
1421                 M_ARGV(4, float) = 0;
1422                 M_ARGV(6, vector) = '0 0 0';
1423                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED_NADE, frag_target.netname);
1424                 Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_REVIVE_SELF);
1425         }
1426 }
1427
1428 MUTATOR_HOOKFUNCTION(nades, MonsterDies)
1429 {
1430         entity frag_target = M_ARGV(0, entity);
1431         entity frag_attacker = M_ARGV(1, entity);
1432
1433         if(IS_PLAYER(frag_attacker))
1434         if(DIFF_TEAM(frag_attacker, frag_target))
1435         if(!(frag_target.spawnflags & MONSTERFLAG_SPAWNED))
1436                 nades_GiveBonus(frag_attacker, autocvar_g_nades_bonus_score_minor);
1437 }
1438
1439 MUTATOR_HOOKFUNCTION(nades, DropSpecialItems)
1440 {
1441         entity frag_target = M_ARGV(0, entity);
1442
1443         if(frag_target.nade)
1444                 toss_nade(frag_target, true, '0 0 0', time + 0.05);
1445 }
1446
1447 void nades_RemovePlayer(entity this)
1448 {
1449         nades_Clear(this);
1450         nades_RemoveBonus(this);
1451 }
1452
1453 MUTATOR_HOOKFUNCTION(nades, MakePlayerObserver) { entity player = M_ARGV(0, entity); nades_RemovePlayer(player); }
1454 MUTATOR_HOOKFUNCTION(nades, ClientDisconnect) { entity player = M_ARGV(0, entity); nades_RemovePlayer(player); }
1455 MUTATOR_HOOKFUNCTION(nades, reset_map_global)
1456 {
1457         FOREACH_CLIENT(IS_PLAYER(it),
1458         {
1459                 nades_RemovePlayer(it);
1460         });
1461 }
1462
1463 MUTATOR_HOOKFUNCTION(nades, SpectateCopy)
1464 {
1465         entity spectatee = M_ARGV(0, entity);
1466         entity client = M_ARGV(1, entity);
1467
1468         client.nade_timer = spectatee.nade_timer;
1469         client.nade_type = spectatee.nade_type;
1470         client.pokenade_type = spectatee.pokenade_type;
1471         client.bonus_nades = spectatee.bonus_nades;
1472         client.bonus_nade_score = spectatee.bonus_nade_score;
1473         client.stat_healing_orb = spectatee.stat_healing_orb;
1474         client.stat_healing_orb_alpha = spectatee.stat_healing_orb_alpha;
1475         STAT(ENTRAP_ORB, client) = STAT(ENTRAP_ORB, spectatee);
1476         STAT(ENTRAP_ORB_ALPHA, client) = STAT(ENTRAP_ORB_ALPHA, spectatee);
1477 }
1478
1479 REPLICATE(cvar_cl_nade_type, int, "cl_nade_type");
1480 REPLICATE(cvar_cl_pokenade_type, string, "cl_pokenade_type");
1481
1482 MUTATOR_HOOKFUNCTION(nades, BuildMutatorsString)
1483 {
1484         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":Nades");
1485 }
1486
1487 MUTATOR_HOOKFUNCTION(nades, BuildGameplayTipsString)
1488 {
1489         M_ARGV(0, string) = strcat(M_ARGV(0, string), "\n\n^3nades^8 are enabled, press 'g' to use them\n");
1490 }
1491
1492 #endif