qcsrc/common/mutators/mutator/overkill/hmg.qc

   1 #include "hmg.qh"
   2
   3 #ifdef SVQC
   4
   5 REGISTER_MUTATOR(hmg_nadesupport, true);
   6 MUTATOR_HOOKFUNCTION(hmg_nadesupport, Nade_Damage)
   7 {
   8         if (M_ARGV(1, entity) != WEP_HMG) return;
   9         return = true;
  10         M_ARGV(3, float) /* damage */ = (M_ARGV(0, entity)).max_health * 0.1;
  11 }
  12
  13 void W_HeavyMachineGun_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  14 {
  15         if (!PHYS_INPUT_BUTTON_ATCK(actor))
  16         {
  17                 w_ready(thiswep, actor, weaponentity, fire);
  18                 return;
  19         }
  20
  21         if((!thiswep.wr_checkammo1(thiswep, actor, weaponentity) && !(actor.items & IT_UNLIMITED_WEAPON_AMMO)) || (!(actor.items & IT_SUPERWEAPON) && !(actor.items & IT_UNLIMITED_SUPERWEAPONS)))
  22         {
  23                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
  24                 w_ready(thiswep, actor, weaponentity, fire);
  25                 return;
  26         }
  27
  28         W_DecreaseAmmo(WEP_HMG, actor, WEP_CVAR(hmg, ammo), weaponentity);
  29
  30         W_SetupShot (actor, weaponentity, true, 0, SND_UZI_FIRE, CH_WEAPON_A, WEP_CVAR(hmg, damage), WEP_HMG.m_id);
  31
  32         if(!autocvar_g_norecoil)
  33         {
  34                 actor.punchangle_x = random () - 0.5;
  35                 actor.punchangle_y = random () - 0.5;
  36         }
  37
  38         float hmg_spread = bound(WEP_CVAR(hmg, spread_min), WEP_CVAR(hmg, spread_min) + (WEP_CVAR(hmg, spread_add) * actor.(weaponentity).misc_bulletcounter), WEP_CVAR(hmg, spread_max));
  39         fireBullet(actor, weaponentity, w_shotorg, w_shotdir, hmg_spread, WEP_CVAR(hmg, solidpenetration), WEP_CVAR(hmg, damage), WEP_CVAR(hmg, force), WEP_HMG.m_id, 0);
  40
  41         actor.(weaponentity).misc_bulletcounter = actor.(weaponentity).misc_bulletcounter + 1;
  42
  43         Send_Effect(EFFECT_MACHINEGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
  44
  45         W_MachineGun_MuzzleFlash(actor, weaponentity);
  46         W_AttachToShotorg(actor, weaponentity, actor.(weaponentity).muzzle_flash, '5 0 0');
  47
  48         if (autocvar_g_casings >= 2) // casing code
  49         {
  50                 makevectors(actor.v_angle); // for some reason, this is lost
  51                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
  52         }
  53
  54         int slot = weaponslot(weaponentity);
  55         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR(hmg, refire) * W_WeaponRateFactor(actor);
  56         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(hmg, refire), W_HeavyMachineGun_Attack_Auto);
  57 }
  58
  59 METHOD(HeavyMachineGun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  60 {
  61     if(vdist(actor.origin - actor.enemy.origin, <, 3000 - bound(0, skill, 10) * 200))
  62         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  63     else
  64         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  65 }
  66
  67 METHOD(HeavyMachineGun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
  68 {
  69     if(WEP_CVAR(hmg, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR(hmg, ammo)) { // forced reload
  70         thiswep.wr_reload(thiswep, actor, weaponentity);
  71     } else
  72     {
  73         if (fire & 1)
  74         if (weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
  75         {
  76             actor.(weaponentity).misc_bulletcounter = 0;
  77             W_HeavyMachineGun_Attack_Auto(thiswep, actor, weaponentity, fire);
  78         }
  79     }
  80 }
  81
  82 METHOD(HeavyMachineGun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
  83 {
  84     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(hmg, ammo);
  85
  86     if(autocvar_g_balance_hmg_reload_ammo)
  87         ammo_amount += actor.(weaponentity).(weapon_load[WEP_HMG.m_id]) >= WEP_CVAR(hmg, ammo);
  88
  89     return ammo_amount;
  90 }
  91
  92 METHOD(HeavyMachineGun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
  93 {
  94     float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR(hmg, ammo);
  95
  96     if(autocvar_g_balance_hmg_reload_ammo)
  97         ammo_amount += actor.(weaponentity).(weapon_load[WEP_HMG.m_id]) >= WEP_CVAR(hmg, ammo);
  98
  99     return ammo_amount;
 100 }
 101
 102 METHOD(HeavyMachineGun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 103 {
 104     W_Reload(actor, weaponentity, WEP_CVAR(hmg, ammo), SND_RELOAD);
 105 }
 106
 107 METHOD(HeavyMachineGun, wr_suicidemessage, Notification(entity thiswep))
 108 {
 109     return WEAPON_THINKING_WITH_PORTALS;
 110 }
 111
 112 METHOD(HeavyMachineGun, wr_killmessage, Notification(entity thiswep))
 113 {
 114     if(w_deathtype & HITTYPE_SECONDARY)
 115         return WEAPON_HMG_MURDER_SNIPE;
 116     else
 117         return WEAPON_HMG_MURDER_SPRAY;
 118 }
 119
 120 #endif
 121 #ifdef CSQC
 122
 123 METHOD(HeavyMachineGun, wr_impacteffect, void(entity thiswep, entity actor))
 124 {
 125     vector org2;
 126     org2 = w_org + w_backoff * 2;
 127     pointparticles(EFFECT_MACHINEGUN_IMPACT, org2, w_backoff * 1000, 1);
 128     if(!w_issilent)
 129         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 130 }
 131
 132 #endif