qcsrc/common/mutators/mutator/overkill/hmg.qc

   1 #include "hmg.qh"
   2
   3 #ifdef SVQC
   4
   5 REGISTER_MUTATOR(hmg_nadesupport, true);
   6 MUTATOR_HOOKFUNCTION(hmg_nadesupport, Nade_Damage)
   7 {
   8         if (M_ARGV(1, entity) != WEP_HMG) return;
   9         return = true;
  10         M_ARGV(3, float) /* damage */ = (M_ARGV(0, entity)).max_health * 0.1;
  11 }
  12
  13 void W_HeavyMachineGun_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  14 {
  15         if (!PHYS_INPUT_BUTTON_ATCK(actor))
  16         {
  17                 w_ready(thiswep, actor, weaponentity, fire);
  18                 return;
  19         }
  20
  21         if((!thiswep.wr_checkammo1(thiswep, actor, weaponentity) && !(actor.items & IT_UNLIMITED_WEAPON_AMMO)) || (!(actor.items & IT_SUPERWEAPON) && !(actor.items & IT_UNLIMITED_SUPERWEAPONS)))
  22         {
  23                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
  24                 w_ready(thiswep, actor, weaponentity, fire);
  25                 return;
  26         }
  27
  28         W_DecreaseAmmo(WEP_HMG, actor, WEP_CVAR_PRI(hmg, ammo), weaponentity);
  29
  30         W_SetupShot (actor, weaponentity, true, 0, SND_UZI_FIRE, CH_WEAPON_A, WEP_CVAR_PRI(hmg, damage));
  31
  32         if(!autocvar_g_norecoil)
  33         {
  34                 actor.punchangle_x = random () - 0.5;
  35                 actor.punchangle_y = random () - 0.5;
  36         }
  37
  38         float hmg_spread = bound(WEP_CVAR_PRI(hmg, spread_min), WEP_CVAR_PRI(hmg, spread_min) + (WEP_CVAR_PRI(hmg, spread_add) * actor.(weaponentity).misc_bulletcounter), WEP_CVAR_PRI(hmg, spread_max));
  39         fireBullet(actor, weaponentity, w_shotorg, w_shotdir, hmg_spread, WEP_CVAR_PRI(hmg, solidpenetration), WEP_CVAR_PRI(hmg, damage), WEP_CVAR_PRI(hmg, force), WEP_HMG.m_id, 0);
  40
  41         actor.(weaponentity).misc_bulletcounter = actor.(weaponentity).misc_bulletcounter + 1;
  42
  43         Send_Effect(EFFECT_MACHINEGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
  44
  45         W_MachineGun_MuzzleFlash(actor, weaponentity);
  46         W_AttachToShotorg(actor, weaponentity, actor.(weaponentity).muzzle_flash, '5 0 0');
  47
  48         if (autocvar_g_casings >= 2) // casing code
  49         {
  50                 makevectors(actor.v_angle); // for some reason, this is lost
  51                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
  52         }
  53
  54         int slot = weaponslot(weaponentity);
  55         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR_PRI(hmg, refire) * W_WeaponRateFactor(actor);
  56         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(hmg, refire), W_HeavyMachineGun_Attack_Auto);
  57 }
  58
  59 METHOD(HeavyMachineGun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  60 {
  61     if(vdist(actor.origin - actor.enemy.origin, <, 3000 - bound(0, skill, 10) * 200))
  62         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  63     else
  64         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  65 }
  66
  67 METHOD(HeavyMachineGun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
  68 {
  69         if ((WEP_CVAR_SEC(hmg, refire_type) == 1) && (fire & 2) && (time >= actor.jump_interval))
  70         {
  71                 // Secondary uses it's own refire timer if refire_type is 1.
  72                 actor.jump_interval = time + WEP_CVAR_SEC(hmg, refire) * W_WeaponRateFactor(actor);
  73                 // Ugly hack to reuse the fire mode of the blaster.
  74                 makevectors(actor.v_angle);
  75                 Weapon oldwep = actor.(weaponentity).m_weapon; // we can't avoid this hack
  76                 actor.(weaponentity).m_weapon = WEP_BLASTER;
  77                 W_Blaster_Attack(
  78                         actor,
  79                         weaponentity,
  80                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
  81                         WEP_CVAR_SEC(hmg, shotangle),
  82                         WEP_CVAR_SEC(hmg, damage),
  83                         WEP_CVAR_SEC(hmg, edgedamage),
  84                         WEP_CVAR_SEC(hmg, radius),
  85                         WEP_CVAR_SEC(hmg, force),
  86                         WEP_CVAR_SEC(hmg, speed),
  87                         WEP_CVAR_SEC(hmg, spread),
  88                         WEP_CVAR_SEC(hmg, delay),
  89                         WEP_CVAR_SEC(hmg, lifetime)
  90                 );
  91                 actor.(weaponentity).m_weapon = oldwep;
  92                 if ((actor.(weaponentity).wframe == WFRAME_IDLE) ||
  93                         (actor.(weaponentity).wframe == WFRAME_FIRE2))
  94                 {
  95                         // Set secondary fire animation.
  96                         vector a = '0 0 0';
  97                         actor.(weaponentity).wframe = WFRAME_FIRE2;
  98                         a = actor.(weaponentity).anim_fire2;
  99                         a.z *= g_weaponratefactor;
 100                         FOREACH_CLIENT(true, LAMBDA(
 101                                 if (it == actor || (IS_SPEC(it) && it.enemy == actor))
 102                                 {
 103                                         wframe_send(it, actor.(weaponentity), a, true);
 104                                 }
 105                         ));
 106                         animdecide_setaction(actor, ANIMACTION_SHOOT, true);
 107                 }
 108         }
 109     if (WEP_CVAR(hmg, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(hmg, ammo))
 110         {
 111                 // Forced reload.
 112         thiswep.wr_reload(thiswep, actor, weaponentity);
 113                 return;
 114         }
 115         if (fire & 1) // Primary attack
 116         {
 117                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
 118                 {
 119                         return;
 120                 }
 121                 actor.(weaponentity).misc_bulletcounter = 0;
 122                 W_HeavyMachineGun_Attack_Auto(thiswep, actor, weaponentity, fire);
 123                 return;
 124         }
 125         if ((fire & 2) && (WEP_CVAR_SEC(hmg, refire_type) == 0)) // Secondary attack
 126         {
 127                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(hmg, refire)))
 128                 {
 129                         return;
 130                 }
 131                 // ugly instagib hack to reuse the fire mode of the laser
 132                 makevectors(actor.v_angle);
 133                 Weapon oldwep = actor.(weaponentity).m_weapon; // we can't avoid this hack
 134                 actor.(weaponentity).m_weapon = WEP_BLASTER;
 135                 W_Blaster_Attack(
 136                         actor,
 137                         weaponentity,
 138                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 139                         WEP_CVAR_SEC(hmg, shotangle),
 140                         WEP_CVAR_SEC(hmg, damage),
 141                         WEP_CVAR_SEC(hmg, edgedamage),
 142                         WEP_CVAR_SEC(hmg, radius),
 143                         WEP_CVAR_SEC(hmg, force),
 144                         WEP_CVAR_SEC(hmg, speed),
 145                         WEP_CVAR_SEC(hmg, spread),
 146                         WEP_CVAR_SEC(hmg, delay),
 147                         WEP_CVAR_SEC(hmg, lifetime)
 148                 );
 149                 actor.(weaponentity).m_weapon = oldwep;
 150                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(hmg, animtime), w_ready);
 151         }
 152 }
 153
 154 METHOD(HeavyMachineGun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 155 {
 156         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(hmg, ammo);
 157         if (autocvar_g_balance_hmg_reload_ammo)
 158         {
 159                 ammo_amount += actor.(weaponentity).(weapon_load[WEP_HMG.m_id]) >= WEP_CVAR_PRI(hmg, ammo);
 160         }
 161         return ammo_amount;
 162 }
 163
 164 METHOD(HeavyMachineGun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 165 {
 166         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(hmg, ammo);
 167         if (autocvar_g_balance_hmg_reload_ammo)
 168         {
 169                 ammo_amount += actor.(weaponentity).(weapon_load[WEP_HMG.m_id]) >= WEP_CVAR_SEC(hmg, ammo);
 170         }
 171         return ammo_amount;
 172 }
 173
 174 METHOD(HeavyMachineGun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 175 {
 176     W_Reload(actor, weaponentity, WEP_CVAR_PRI(hmg, ammo), SND_RELOAD);
 177 }
 178
 179 METHOD(HeavyMachineGun, wr_suicidemessage, Notification(entity thiswep))
 180 {
 181     return WEAPON_THINKING_WITH_PORTALS;
 182 }
 183
 184 METHOD(HeavyMachineGun, wr_killmessage, Notification(entity thiswep))
 185 {
 186     if(w_deathtype & HITTYPE_SECONDARY)
 187         return WEAPON_HMG_MURDER_SNIPE;
 188     else
 189         return WEAPON_HMG_MURDER_SPRAY;
 190 }
 191
 192 #endif
 193 #ifdef CSQC
 194
 195 METHOD(HeavyMachineGun, wr_impacteffect, void(entity thiswep, entity actor))
 196 {
 197     vector org2;
 198     org2 = w_org + w_backoff * 2;
 199     pointparticles(EFFECT_MACHINEGUN_IMPACT, org2, w_backoff * 1000, 1);
 200     if(!w_issilent)
 201         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 202 }
 203
 204 #endif