qcsrc/common/mutators/mutator/overkill/okhmg.qc

   1 #include "okhmg.qh"
   2
   3 #ifdef SVQC
   4
   5 REGISTER_MUTATOR(okhmg_nadesupport, true);
   6 MUTATOR_HOOKFUNCTION(okhmg_nadesupport, Nade_Damage)
   7 {
   8         if (M_ARGV(1, entity) != WEP_OVERKILL_HMG) return;
   9         return = true;
  10         M_ARGV(3, float) /* damage */ = (M_ARGV(0, entity)).max_health * 0.1;
  11 }
  12
  13 void W_OverkillHeavyMachineGun_Attack_Auto(Weapon thiswep, entity actor, .entity weaponentity, int fire)
  14 {
  15         if (!PHYS_INPUT_BUTTON_ATCK(actor))
  16         {
  17                 w_ready(thiswep, actor, weaponentity, fire);
  18                 return;
  19         }
  20
  21         if((!thiswep.wr_checkammo1(thiswep, actor, weaponentity) && !(actor.items & IT_UNLIMITED_WEAPON_AMMO)) || (!(actor.items & IT_SUPERWEAPON) && !(actor.items & IT_UNLIMITED_SUPERWEAPONS)))
  22         {
  23                 W_SwitchWeapon_Force(actor, w_getbestweapon(actor, weaponentity), weaponentity);
  24                 w_ready(thiswep, actor, weaponentity, fire);
  25                 return;
  26         }
  27
  28         W_DecreaseAmmo(WEP_OVERKILL_HMG, actor, WEP_CVAR_PRI(okhmg, ammo), weaponentity);
  29
  30         W_SetupShot(actor, weaponentity, true, 0, SND_UZI_FIRE, CH_WEAPON_A, WEP_CVAR_PRI(okhmg, damage), WEP_OVERKILL_HMG.m_id);
  31
  32         if(!autocvar_g_norecoil)
  33         {
  34                 actor.punchangle_x = random () - 0.5;
  35                 actor.punchangle_y = random () - 0.5;
  36         }
  37
  38         float okhmg_spread = bound(WEP_CVAR_PRI(okhmg, spread_min), WEP_CVAR_PRI(okhmg, spread_min) + (WEP_CVAR_PRI(okhmg, spread_add) * actor.(weaponentity).misc_bulletcounter), WEP_CVAR_PRI(okhmg, spread_max));
  39         fireBullet(actor, weaponentity, w_shotorg, w_shotdir, okhmg_spread, WEP_CVAR_PRI(okhmg, solidpenetration), WEP_CVAR_PRI(okhmg, damage), WEP_CVAR_PRI(okhmg, force), WEP_OVERKILL_HMG.m_id, 0);
  40
  41         actor.(weaponentity).misc_bulletcounter = actor.(weaponentity).misc_bulletcounter + 1;
  42
  43         Send_Effect(EFFECT_MACHINEGUN_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
  44
  45         W_MachineGun_MuzzleFlash(actor, weaponentity);
  46         W_AttachToShotorg(actor, weaponentity, actor.(weaponentity).muzzle_flash, '5 0 0');
  47
  48         if (autocvar_g_casings >= 2) // casing code
  49         {
  50                 makevectors(actor.v_angle); // for some reason, this is lost
  51                 SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 70) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 3, actor, weaponentity);
  52         }
  53
  54         int slot = weaponslot(weaponentity);
  55         ATTACK_FINISHED(actor, slot) = time + WEP_CVAR_PRI(okhmg, refire) * W_WeaponRateFactor(actor);
  56         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(okhmg, refire), W_OverkillHeavyMachineGun_Attack_Auto);
  57 }
  58
  59 METHOD(OverkillHeavyMachineGun, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
  60 {
  61     if(vdist(actor.origin - actor.enemy.origin, <, 3000 - bound(0, skill, 10) * 200))
  62         PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  63     else
  64         PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false);
  65 }
  66
  67 METHOD(OverkillHeavyMachineGun, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
  68 {
  69         if ((WEP_CVAR_SEC(okhmg, refire_type) == 1) && (fire & 2) && (time >= actor.jump_interval))
  70         {
  71                 // Secondary uses it's own refire timer if refire_type is 1.
  72                 actor.jump_interval = time + WEP_CVAR_SEC(okhmg, refire) * W_WeaponRateFactor(actor);
  73                 BLASTER_SECONDARY_ATTACK(okhmg, actor, weaponentity);
  74                 if ((actor.(weaponentity).wframe == WFRAME_IDLE) ||
  75                         (actor.(weaponentity).wframe == WFRAME_FIRE2))
  76                 {
  77                         // Set secondary fire animation.
  78                         vector a = '0 0 0';
  79                         actor.(weaponentity).wframe = WFRAME_FIRE2;
  80                         a = actor.(weaponentity).anim_fire2;
  81                         a.z *= g_weaponratefactor;
  82                         FOREACH_CLIENT(true, LAMBDA(
  83                                 if (it == actor || (IS_SPEC(it) && it.enemy == actor))
  84                                 {
  85                                         wframe_send(it, actor.(weaponentity), a, true);
  86                                 }
  87                         ));
  88                         animdecide_setaction(actor, ANIMACTION_SHOOT, true);
  89                 }
  90         }
  91     if (WEP_CVAR(okhmg, reload_ammo) && actor.(weaponentity).clip_load < WEP_CVAR_PRI(okhmg, ammo))
  92         {
  93                 // Forced reload.
  94         thiswep.wr_reload(thiswep, actor, weaponentity);
  95                 return;
  96         }
  97         if (fire & 1) // Primary attack
  98         {
  99                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, 0))
 100                 {
 101                         return;
 102                 }
 103                 actor.(weaponentity).misc_bulletcounter = 0;
 104                 W_OverkillHeavyMachineGun_Attack_Auto(thiswep, actor, weaponentity, fire);
 105                 return;
 106         }
 107         if ((fire & 2) && (WEP_CVAR_SEC(okhmg, refire_type) == 0)) // Secondary attack
 108         {
 109                 if (!weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_SEC(okhmg, refire)))
 110                 {
 111                         return;
 112                 }
 113                 BLASTER_SECONDARY_ATTACK(okhmg, actor, weaponentity);
 114                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(okhmg, animtime), w_ready);
 115         }
 116 }
 117
 118 METHOD(OverkillHeavyMachineGun, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
 119 {
 120         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_PRI(okhmg, ammo);
 121         if (autocvar_g_balance_okhmg_reload_ammo)
 122         {
 123                 ammo_amount += actor.(weaponentity).(weapon_load[WEP_OVERKILL_HMG.m_id]) >= WEP_CVAR_PRI(okhmg, ammo);
 124         }
 125         return ammo_amount;
 126 }
 127
 128 METHOD(OverkillHeavyMachineGun, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
 129 {
 130         float ammo_amount = GetResourceAmount(actor, thiswep.ammo_type) >= WEP_CVAR_SEC(okhmg, ammo);
 131         if (autocvar_g_balance_okhmg_reload_ammo)
 132         {
 133                 ammo_amount += actor.(weaponentity).(weapon_load[WEP_OVERKILL_HMG.m_id]) >= WEP_CVAR_SEC(okhmg, ammo);
 134         }
 135         return ammo_amount;
 136 }
 137
 138 METHOD(OverkillHeavyMachineGun, wr_reload, void(entity thiswep, entity actor, .entity weaponentity))
 139 {
 140     W_Reload(actor, weaponentity, WEP_CVAR_PRI(okhmg, ammo), SND_RELOAD);
 141 }
 142
 143 METHOD(OverkillHeavyMachineGun, wr_suicidemessage, Notification(entity thiswep))
 144 {
 145     return WEAPON_THINKING_WITH_PORTALS;
 146 }
 147
 148 METHOD(OverkillHeavyMachineGun, wr_killmessage, Notification(entity thiswep))
 149 {
 150     if(w_deathtype & HITTYPE_SECONDARY)
 151         return WEAPON_OVERKILL_HMG_MURDER_SNIPE;
 152     else
 153         return WEAPON_OVERKILL_HMG_MURDER_SPRAY;
 154 }
 155
 156 #endif
 157 #ifdef CSQC
 158
 159 METHOD(OverkillHeavyMachineGun, wr_impacteffect, void(entity thiswep, entity actor))
 160 {
 161     vector org2;
 162     org2 = w_org + w_backoff * 2;
 163     pointparticles(EFFECT_MACHINEGUN_IMPACT, org2, w_backoff * 1000, 1);
 164     if(!w_issilent)
 165         sound(actor, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 166 }
 167
 168 #endif