qcsrc/common/mutators/mutator/overkill/overkill.qc

   1 #ifdef IMPLEMENTATION
   2 bool autocvar_g_overkill_powerups_replace;
   3 float autocvar_g_overkill_superguns_respawn_time;
   4 bool autocvar_g_overkill_100h_anyway;
   5 bool autocvar_g_overkill_100a_anyway;
   6 bool autocvar_g_overkill_ammo_charge;
   7 float autocvar_g_overkill_ammo_charge_notice;
   8 float autocvar_g_overkill_ammo_charge_limit;
   9
  10 .vector ok_deathloc;
  11 .float ok_spawnsys_timer;
  12 .float ok_lastwep;
  13 .float ok_item;
  14
  15 .float ok_notice_time;
  16 .float ammo_charge[Weapons_MAX];
  17 .float ok_use_ammocharge = _STAT(OK_AMMO_CHARGE);
  18 .float ok_ammo_charge = _STAT(OK_AMMO_CHARGEPOOL);
  19
  20 .float ok_pauseregen_finished;
  21
  22 void(entity ent, float wep) ok_DecreaseCharge;
  23
  24 void ok_Initialize();
  25
  26 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  27 {
  28         MUTATOR_ONADD
  29         {
  30                 ok_Initialize();
  31         }
  32
  33         MUTATOR_ONREMOVE
  34         {
  35                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  36                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  37         }
  38
  39         return false;
  40 }
  41
  42 MUTATOR_HOOKFUNCTION(ok, W_DecreaseAmmo)
  43 {
  44         entity actor = M_ARGV(0, entity);
  45         if (actor.ok_use_ammocharge)
  46         {
  47                 ok_DecreaseCharge(actor, PS(actor).m_weapon.m_id);
  48                 return true;
  49         }
  50 }
  51
  52 MUTATOR_HOOKFUNCTION(ok, W_Reload)
  53 {
  54         entity actor = M_ARGV(0, entity);
  55         return actor.ok_use_ammocharge;
  56 }
  57
  58 void W_Blaster_Attack(entity, float, float, float, float, float, float, float, float, float, float);
  59 spawnfunc(weapon_hmg);
  60 spawnfunc(weapon_rpc);
  61
  62 void ok_DecreaseCharge(entity ent, int wep)
  63 {
  64         if(!ent.ok_use_ammocharge) return;
  65
  66         entity wepent = Weapons_from(wep);
  67
  68         if (wepent == WEP_Null) return;  // dummy
  69
  70         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  71 }
  72
  73 void ok_IncreaseCharge(entity ent, int wep)
  74 {
  75         entity wepent = Weapons_from(wep);
  76
  77         if (wepent == WEP_Null) return;  // dummy
  78
  79         if(ent.ok_use_ammocharge)
  80         if(!PHYS_INPUT_BUTTON_ATCK(ent)) // not while attacking?
  81                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  82 }
  83
  84 float ok_CheckWeaponCharge(entity ent, int wep)
  85 {
  86         if(!ent.ok_use_ammocharge) return true;
  87
  88         entity wepent = Weapons_from(wep);
  89
  90         if(wepent == WEP_Null) return 0;  // dummy
  91
  92         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  93 }
  94
  95 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_Calculate, CBC_ORDER_LAST)
  96 {
  97         entity frag_attacker = M_ARGV(1, entity);
  98         entity frag_target = M_ARGV(2, entity);
  99         float frag_deathtype = M_ARGV(3, float);
 100         float frag_damage = M_ARGV(4, float);
 101         vector frag_force = M_ARGV(6, vector);
 102
 103         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
 104         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
 105         {
 106                 frag_damage = 0;
 107
 108                 if(frag_attacker != frag_target)
 109                 if(frag_target.health > 0)
 110                 if(STAT(FROZEN, frag_target) == 0)
 111                 if(!IS_DEAD(frag_target))
 112                 {
 113                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
 114                         frag_force = '0 0 0';
 115                 }
 116
 117                 M_ARGV(4, float) = frag_damage;
 118                 M_ARGV(6, vector) = frag_force;
 119         }
 120
 121         return false;
 122 }
 123
 124 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_SplitHealthArmor)
 125 {
 126         entity frag_target = M_ARGV(2, entity);
 127         float damage_take = M_ARGV(4, float);
 128
 129         if(damage_take)
 130                 frag_target.ok_pauseregen_finished = max(frag_target.ok_pauseregen_finished, time + 2);
 131 }
 132
 133 void ok_DropItem(entity this, entity targ)
 134 {
 135         entity e = new(droppedweapon); // hax
 136         e.ok_item = true;
 137         e.noalign = true;
 138         e.pickup_anyway = true;
 139         e.spawnfunc_checked = true;
 140         WITHSELF(e, spawnfunc_item_armor_small(e));
 141         if (!wasfreed(e)) { // might have been blocked by a mutator
 142         e.movetype = MOVETYPE_TOSS;
 143         e.gravity = 1;
 144         e.reset = SUB_Remove;
 145         setorigin(e, this.origin + '0 0 32');
 146         e.velocity = '0 0 200' + normalize(targ.origin - this.origin) * 500;
 147         SUB_SetFade(e, time + 5, 1);
 148         }
 149 }
 150
 151 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
 152 {
 153         entity frag_attacker = M_ARGV(1, entity);
 154         entity frag_target = M_ARGV(2, entity);
 155
 156         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 157
 158         ok_DropItem(frag_target, targ);
 159
 160         frag_target.ok_lastwep = PS(frag_target).m_switchweapon.m_id;
 161 }
 162
 163 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
 164 {
 165         entity mon = M_ARGV(0, entity);
 166         entity olditem = M_ARGV(1, entity);
 167         entity frag_attacker = M_ARGV(2, entity);
 168
 169         remove(olditem);
 170
 171         M_ARGV(1, entity) = NULL;
 172
 173         ok_DropItem(mon, frag_attacker);
 174 }
 175
 176 MUTATOR_HOOKFUNCTION(ok, PlayerRegen)
 177 {SELFPARAM();
 178         // overkill's values are different, so use custom regen
 179         if(!STAT(FROZEN, self))
 180         {
 181                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 182                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 183
 184                 float minf, maxf, limitf;
 185
 186                 maxf = autocvar_g_balance_fuel_rotstable;
 187                 minf = autocvar_g_balance_fuel_regenstable;
 188                 limitf = autocvar_g_balance_fuel_limit;
 189
 190                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 191         }
 192         return true; // return true anyway, as frozen uses no regen
 193 }
 194
 195 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 196 {
 197         return true;
 198 }
 199
 200 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 201 {SELFPARAM();
 202         if(intermission_running || gameover)
 203                 return false;
 204
 205         if(IS_DEAD(self) || !IS_PLAYER(self) || STAT(FROZEN, self))
 206                 return false;
 207
 208         if(self.ok_lastwep)
 209         {
 210                 Weapon newwep = Weapons_from(self.ok_lastwep);
 211                 if(self.ok_lastwep == WEP_HMG.m_id)
 212                         newwep = WEP_MACHINEGUN;
 213                 if(self.ok_lastwep == WEP_RPC.m_id)
 214                         newwep = WEP_VORTEX;
 215                 PS(self).m_switchweapon = newwep;
 216                 self.ok_lastwep = 0;
 217         }
 218
 219         ok_IncreaseCharge(self, PS(self).m_weapon.m_id);
 220
 221         if(PHYS_INPUT_BUTTON_ATCK2(self))
 222         if(!forbidWeaponUse(self) || self.weapon_blocked) // allow if weapon is blocked
 223         if(time >= self.jump_interval)
 224         {
 225                 self.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor(this);
 226                 makevectors(self.v_angle);
 227
 228                 Weapon oldwep = PS(self).m_weapon;
 229                 PS(self).m_weapon = WEP_BLASTER;
 230                 W_Blaster_Attack(
 231                         self,
 232                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 233                         WEP_CVAR_SEC(vaporizer, shotangle),
 234                         WEP_CVAR_SEC(vaporizer, damage),
 235                         WEP_CVAR_SEC(vaporizer, edgedamage),
 236                         WEP_CVAR_SEC(vaporizer, radius),
 237                         WEP_CVAR_SEC(vaporizer, force),
 238                         WEP_CVAR_SEC(vaporizer, speed),
 239                         WEP_CVAR_SEC(vaporizer, spread),
 240                         WEP_CVAR_SEC(vaporizer, delay),
 241                         WEP_CVAR_SEC(vaporizer, lifetime)
 242                 );
 243                 PS(self).m_weapon = oldwep;
 244         }
 245
 246         self.weapon_blocked = false;
 247
 248         self.ok_ammo_charge = self.ammo_charge[PS(self).m_weapon.m_id];
 249
 250         if(self.ok_use_ammocharge)
 251         if(!ok_CheckWeaponCharge(self, PS(self).m_weapon.m_id))
 252         {
 253                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && PHYS_INPUT_BUTTON_ATCK(self) && IS_REAL_CLIENT(self) && PS(self).m_weapon == PS(self).m_switchweapon)
 254                 {
 255                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 256                         self.ok_notice_time = time + 2;
 257                         play2(self, SND(DRYFIRE));
 258                 }
 259                 Weapon wpn = PS(self).m_weapon;
 260                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 261                 if(self.(weaponentity).state != WS_CLEAR)
 262                         w_ready(wpn, self, weaponentity, PHYS_INPUT_BUTTON_ATCK(self) | (PHYS_INPUT_BUTTON_ATCK2(self) << 1));
 263
 264                 self.weapon_blocked = true;
 265         }
 266
 267         PHYS_INPUT_BUTTON_ATCK2(self) = false;
 268
 269         return false;
 270 }
 271
 272 MUTATOR_HOOKFUNCTION(ok, PlayerSpawn)
 273 {
 274         entity player = M_ARGV(0, entity);
 275
 276         if(autocvar_g_overkill_ammo_charge)
 277         {
 278                 FOREACH(Weapons, it != WEP_Null, LAMBDA(player.ammo_charge[it.m_id] = autocvar_g_overkill_ammo_charge_limit));
 279
 280                 player.ok_use_ammocharge = 1;
 281                 player.ok_notice_time = time;
 282         }
 283         else
 284                 player.ok_use_ammocharge = 0;
 285
 286         // if player changed their weapon while dead, don't switch to their death weapon
 287         if(player.impulse)
 288                 player.ok_lastwep = 0;
 289
 290         player.ok_pauseregen_finished = time + 2;
 291
 292         return false;
 293 }
 294
 295 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 296 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 297
 298 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 299 {
 300         entity ent = M_ARGV(0, entity);
 301
 302         if(autocvar_g_powerups)
 303         if(autocvar_g_overkill_powerups_replace)
 304         {
 305                 if(ent.classname == "item_strength")
 306                 {
 307                         entity wep = new(weapon_hmg);
 308                         setorigin(wep, ent.origin);
 309                         setmodel(wep, MDL_OK_HMG);
 310                         wep.ok_item = true;
 311                         wep.noalign = ent.noalign;
 312                         wep.cnt = ent.cnt;
 313                         wep.team = ent.team;
 314                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 315                         wep.pickup_anyway = true;
 316                         wep.spawnfunc_checked = true;
 317                         setthink(wep, self_spawnfunc_weapon_hmg);
 318                         wep.nextthink = time + 0.1;
 319                         return true;
 320                 }
 321
 322                 if(ent.classname == "item_invincible")
 323                 {
 324                         entity wep = new(weapon_rpc);
 325                         setorigin(wep, ent.origin);
 326                         setmodel(wep, MDL_OK_RPC);
 327                         wep.ok_item = true;
 328                         wep.noalign = ent.noalign;
 329                         wep.cnt = ent.cnt;
 330                         wep.team = ent.team;
 331                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 332                         wep.pickup_anyway = true;
 333                         wep.spawnfunc_checked = true;
 334                         setthink(wep, self_spawnfunc_weapon_rpc);
 335                         wep.nextthink = time + 0.1;
 336                         return true;
 337                 }
 338         }
 339
 340         return false;
 341 }
 342
 343 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 344 {
 345         entity item = M_ARGV(0, entity);
 346
 347         if(item.ok_item)
 348                 return false;
 349
 350         switch(item.items)
 351         {
 352                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 353                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 354         }
 355
 356         return true;
 357 }
 358
 359 MUTATOR_HOOKFUNCTION(ok, SpectateCopy)
 360 {
 361         entity spectatee = M_ARGV(0, entity);
 362         entity client = M_ARGV(1, entity);
 363
 364         client.ammo_charge[PS(client).m_weapon.m_id] = spectatee.ammo_charge[PS(spectatee).m_weapon.m_id];
 365         client.ok_use_ammocharge = spectatee.ok_use_ammocharge;
 366 }
 367
 368 MUTATOR_HOOKFUNCTION(ok, SetStartItems)
 369 {
 370         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 371
 372         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 373         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 374
 375         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 376         start_weapons = warmup_start_weapons = ok_start_items;
 377
 378         return false;
 379 }
 380
 381 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 382 {
 383         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 384 }
 385
 386 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 387 {
 388         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 389 }
 390
 391 MUTATOR_HOOKFUNCTION(ok, SetModname)
 392 {
 393         M_ARGV(0, string) = "Overkill";
 394         return true;
 395 }
 396
 397 void ok_SetCvars()
 398 {
 399         // hack to force overkill playermodels
 400         cvar_settemp("sv_defaultcharacter", "1");
 401         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 402         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 403         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 404 }
 405
 406 void ok_Initialize()
 407 {
 408         ok_SetCvars();
 409
 410         precache_all_playermodels("models/ok_player/*.dpm");
 411
 412         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 413         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 414
 415         WEP_SHOTGUN.mdl = "ok_shotgun";
 416         WEP_MACHINEGUN.mdl = "ok_mg";
 417         WEP_VORTEX.mdl = "ok_sniper";
 418 }
 419 #endif