qcsrc/common/mutators/mutator/overkill/overkill.qc

   1 #ifdef IMPLEMENTATION
   2 bool autocvar_g_overkill_powerups_replace;
   3 float autocvar_g_overkill_superguns_respawn_time;
   4 bool autocvar_g_overkill_100h_anyway;
   5 bool autocvar_g_overkill_100a_anyway;
   6 bool autocvar_g_overkill_ammo_charge;
   7 float autocvar_g_overkill_ammo_charge_notice;
   8 float autocvar_g_overkill_ammo_charge_limit;
   9
  10 .vector ok_deathloc;
  11 .float ok_spawnsys_timer;
  12 .float ok_lastwep;
  13 .float ok_item;
  14
  15 .float ok_notice_time;
  16 .float ammo_charge[Weapons_MAX];
  17 .float ok_use_ammocharge = _STAT(OK_AMMO_CHARGE);
  18 .float ok_ammo_charge = _STAT(OK_AMMO_CHARGEPOOL);
  19
  20 .float ok_pauseregen_finished;
  21
  22 void(entity ent, float wep) ok_DecreaseCharge;
  23
  24 void ok_Initialize();
  25
  26 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  27 {
  28         MUTATOR_ONADD
  29         {
  30                 ok_Initialize();
  31         }
  32
  33         MUTATOR_ONREMOVE
  34         {
  35                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  36                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  37         }
  38
  39         return false;
  40 }
  41
  42 MUTATOR_HOOKFUNCTION(ok, W_DecreaseAmmo)
  43 {
  44         entity actor = M_ARGV(0, entity);
  45         if (actor.ok_use_ammocharge)
  46         {
  47                 ok_DecreaseCharge(actor, PS(actor).m_weapon.m_id);
  48                 return true;
  49         }
  50 }
  51
  52 MUTATOR_HOOKFUNCTION(ok, W_Reload)
  53 {
  54         entity actor = M_ARGV(0, entity);
  55         return actor.ok_use_ammocharge;
  56 }
  57
  58 void W_Blaster_Attack(entity, float, float, float, float, float, float, float, float, float, float);
  59 spawnfunc(weapon_hmg);
  60 spawnfunc(weapon_rpc);
  61
  62 void ok_DecreaseCharge(entity ent, int wep)
  63 {
  64         if(!ent.ok_use_ammocharge) return;
  65
  66         entity wepent = Weapons_from(wep);
  67
  68         if (wepent == WEP_Null) return;  // dummy
  69
  70         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  71 }
  72
  73 void ok_IncreaseCharge(entity ent, int wep)
  74 {
  75         entity wepent = Weapons_from(wep);
  76
  77         if (wepent == WEP_Null) return;  // dummy
  78
  79         if(ent.ok_use_ammocharge)
  80         if(!PHYS_INPUT_BUTTON_ATCK(ent)) // not while attacking?
  81                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  82 }
  83
  84 float ok_CheckWeaponCharge(entity ent, int wep)
  85 {
  86         if(!ent.ok_use_ammocharge) return true;
  87
  88         entity wepent = Weapons_from(wep);
  89
  90         if(wepent == WEP_Null) return 0;  // dummy
  91
  92         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  93 }
  94
  95 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_Calculate, CBC_ORDER_LAST)
  96 {
  97         entity frag_attacker = M_ARGV(1, entity);
  98         entity frag_target = M_ARGV(2, entity);
  99         float frag_deathtype = M_ARGV(3, float);
 100         float frag_damage = M_ARGV(4, float);
 101         vector frag_force = M_ARGV(6, vector);
 102
 103         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
 104         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
 105         {
 106                 frag_damage = 0;
 107
 108                 if(frag_attacker != frag_target)
 109                 if(frag_target.health > 0)
 110                 if(STAT(FROZEN, frag_target) == 0)
 111                 if(!IS_DEAD(frag_target))
 112                 {
 113                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
 114                         frag_force = '0 0 0';
 115                 }
 116
 117                 M_ARGV(4, float) = frag_damage;
 118                 M_ARGV(6, vector) = frag_force;
 119         }
 120
 121         return false;
 122 }
 123
 124 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_SplitHealthArmor)
 125 {
 126         if(damage_take)
 127                 frag_target.ok_pauseregen_finished = max(frag_target.ok_pauseregen_finished, time + 2);
 128         return false;
 129 }
 130
 131 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
 132 {
 133         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 134
 135         if(IS_MONSTER(frag_target))
 136         {
 137                 remove(other); // remove default item
 138                 other = NULL;
 139         }
 140
 141         entity e = new(droppedweapon); // hax
 142         e.ok_item = true;
 143         e.noalign = true;
 144         e.pickup_anyway = true;
 145         e.spawnfunc_checked = true;
 146         spawnfunc_item_armor_small(e);
 147         if (!wasfreed(e)) { // might have been blocked by a mutator
 148         e.movetype = MOVETYPE_TOSS;
 149         e.gravity = 1;
 150         e.reset = SUB_Remove;
 151         setorigin(e, frag_target.origin + '0 0 32');
 152         e.velocity = '0 0 200' + normalize(targ.origin - frag_target.origin) * 500;
 153         SUB_SetFade(e, time + 5, 1);
 154         }
 155
 156         frag_target.ok_lastwep = PS(frag_target).m_switchweapon.m_id;
 157
 158         return false;
 159 }
 160 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem) { ok_PlayerDies(); }
 161
 162 MUTATOR_HOOKFUNCTION(ok, PlayerRegen)
 163 {SELFPARAM();
 164         // overkill's values are different, so use custom regen
 165         if(!STAT(FROZEN, self))
 166         {
 167                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 168                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 169
 170                 float minf, maxf, limitf;
 171
 172                 maxf = autocvar_g_balance_fuel_rotstable;
 173                 minf = autocvar_g_balance_fuel_regenstable;
 174                 limitf = autocvar_g_balance_fuel_limit;
 175
 176                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 177         }
 178         return true; // return true anyway, as frozen uses no regen
 179 }
 180
 181 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 182 {
 183         return true;
 184 }
 185
 186 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 187 {SELFPARAM();
 188         if(intermission_running || gameover)
 189                 return false;
 190
 191         if(IS_DEAD(self) || !IS_PLAYER(self) || STAT(FROZEN, self))
 192                 return false;
 193
 194         if(self.ok_lastwep)
 195         {
 196                 Weapon newwep = Weapons_from(self.ok_lastwep);
 197                 if(self.ok_lastwep == WEP_HMG.m_id)
 198                         newwep = WEP_MACHINEGUN;
 199                 if(self.ok_lastwep == WEP_RPC.m_id)
 200                         newwep = WEP_VORTEX;
 201                 PS(self).m_switchweapon = newwep;
 202                 self.ok_lastwep = 0;
 203         }
 204
 205         ok_IncreaseCharge(self, PS(self).m_weapon.m_id);
 206
 207         if(PHYS_INPUT_BUTTON_ATCK2(self))
 208         if(!forbidWeaponUse(self) || self.weapon_blocked) // allow if weapon is blocked
 209         if(time >= self.jump_interval)
 210         {
 211                 self.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor();
 212                 makevectors(self.v_angle);
 213
 214                 Weapon oldwep = PS(self).m_weapon;
 215                 PS(self).m_weapon = WEP_BLASTER;
 216                 W_Blaster_Attack(
 217                         self,
 218                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 219                         WEP_CVAR_SEC(vaporizer, shotangle),
 220                         WEP_CVAR_SEC(vaporizer, damage),
 221                         WEP_CVAR_SEC(vaporizer, edgedamage),
 222                         WEP_CVAR_SEC(vaporizer, radius),
 223                         WEP_CVAR_SEC(vaporizer, force),
 224                         WEP_CVAR_SEC(vaporizer, speed),
 225                         WEP_CVAR_SEC(vaporizer, spread),
 226                         WEP_CVAR_SEC(vaporizer, delay),
 227                         WEP_CVAR_SEC(vaporizer, lifetime)
 228                 );
 229                 PS(self).m_weapon = oldwep;
 230         }
 231
 232         self.weapon_blocked = false;
 233
 234         self.ok_ammo_charge = self.ammo_charge[PS(self).m_weapon.m_id];
 235
 236         if(self.ok_use_ammocharge)
 237         if(!ok_CheckWeaponCharge(self, PS(self).m_weapon.m_id))
 238         {
 239                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && PHYS_INPUT_BUTTON_ATCK(self) && IS_REAL_CLIENT(self) && PS(self).m_weapon == PS(self).m_switchweapon)
 240                 {
 241                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 242                         self.ok_notice_time = time + 2;
 243                         play2(self, SND(DRYFIRE));
 244                 }
 245                 Weapon wpn = PS(self).m_weapon;
 246                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 247                 if(self.(weaponentity).state != WS_CLEAR)
 248                         w_ready(wpn, self, weaponentity, PHYS_INPUT_BUTTON_ATCK(self) | (PHYS_INPUT_BUTTON_ATCK2(self) << 1));
 249
 250                 self.weapon_blocked = true;
 251         }
 252
 253         PHYS_INPUT_BUTTON_ATCK2(self) = false;
 254
 255         return false;
 256 }
 257
 258 MUTATOR_HOOKFUNCTION(ok, PlayerSpawn)
 259 {
 260         entity player = M_ARGV(0, entity);
 261
 262         if(autocvar_g_overkill_ammo_charge)
 263         {
 264                 FOREACH(Weapons, it != WEP_Null, LAMBDA(player.ammo_charge[it.m_id] = autocvar_g_overkill_ammo_charge_limit));
 265
 266                 player.ok_use_ammocharge = 1;
 267                 player.ok_notice_time = time;
 268         }
 269         else
 270                 player.ok_use_ammocharge = 0;
 271
 272         // if player changed their weapon while dead, don't switch to their death weapon
 273         if(player.impulse)
 274                 player.ok_lastwep = 0;
 275
 276         player.ok_pauseregen_finished = time + 2;
 277
 278         return false;
 279 }
 280
 281 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 282 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 283
 284 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 285 {SELFPARAM();
 286         if(autocvar_g_powerups)
 287         if(autocvar_g_overkill_powerups_replace)
 288         {
 289                 if(self.classname == "item_strength")
 290                 {
 291                         entity wep = new(weapon_hmg);
 292                         setorigin(wep, self.origin);
 293                         setmodel(wep, MDL_OK_HMG);
 294                         wep.ok_item = true;
 295                         wep.noalign = self.noalign;
 296                         wep.cnt = self.cnt;
 297                         wep.team = self.team;
 298                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 299                         wep.pickup_anyway = true;
 300                         wep.spawnfunc_checked = true;
 301                         setthink(wep, self_spawnfunc_weapon_hmg);
 302                         wep.nextthink = time + 0.1;
 303                         return true;
 304                 }
 305
 306                 if(self.classname == "item_invincible")
 307                 {
 308                         entity wep = new(weapon_rpc);
 309                         setorigin(wep, self.origin);
 310                         setmodel(wep, MDL_OK_RPC);
 311                         wep.ok_item = true;
 312                         wep.noalign = self.noalign;
 313                         wep.cnt = self.cnt;
 314                         wep.team = self.team;
 315                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 316                         wep.pickup_anyway = true;
 317                         wep.spawnfunc_checked = true;
 318                         setthink(wep, self_spawnfunc_weapon_rpc);
 319                         wep.nextthink = time + 0.1;
 320                         return true;
 321                 }
 322         }
 323
 324         return false;
 325 }
 326
 327 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 328 {SELFPARAM();
 329         if(self.ok_item)
 330                 return false;
 331
 332         switch(self.items)
 333         {
 334                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 335                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 336         }
 337
 338         return true;
 339 }
 340
 341 MUTATOR_HOOKFUNCTION(ok, SpectateCopy)
 342 {SELFPARAM();
 343         self.ammo_charge[PS(self).m_weapon.m_id] = other.ammo_charge[PS(other).m_weapon.m_id];
 344         self.ok_use_ammocharge = other.ok_use_ammocharge;
 345
 346         return false;
 347 }
 348
 349 MUTATOR_HOOKFUNCTION(ok, SetStartItems)
 350 {
 351         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 352
 353         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 354         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 355
 356         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 357         start_weapons = warmup_start_weapons = ok_start_items;
 358
 359         return false;
 360 }
 361
 362 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 363 {
 364         ret_string = strcat(ret_string, ":OK");
 365         return false;
 366 }
 367
 368 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 369 {
 370         ret_string = strcat(ret_string, ", Overkill");
 371         return false;
 372 }
 373
 374 MUTATOR_HOOKFUNCTION(ok, SetModname)
 375 {
 376         modname = "Overkill";
 377         return true;
 378 }
 379
 380 void ok_SetCvars()
 381 {
 382         // hack to force overkill playermodels
 383         cvar_settemp("sv_defaultcharacter", "1");
 384         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 385         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 386         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 387 }
 388
 389 void ok_Initialize()
 390 {
 391         ok_SetCvars();
 392
 393         precache_all_playermodels("models/ok_player/*.dpm");
 394
 395         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 396         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 397
 398         WEP_SHOTGUN.mdl = "ok_shotgun";
 399         WEP_MACHINEGUN.mdl = "ok_mg";
 400         WEP_VORTEX.mdl = "ok_sniper";
 401 }
 402 #endif