qcsrc/common/mutators/mutator/overkill/overkill.qc

   1 #ifdef IMPLEMENTATION
   2 bool autocvar_g_overkill_powerups_replace;
   3 float autocvar_g_overkill_superguns_respawn_time;
   4 bool autocvar_g_overkill_100h_anyway;
   5 bool autocvar_g_overkill_100a_anyway;
   6 bool autocvar_g_overkill_ammo_charge;
   7 float autocvar_g_overkill_ammo_charge_notice;
   8 float autocvar_g_overkill_ammo_charge_limit;
   9
  10 .vector ok_deathloc;
  11 .float ok_spawnsys_timer;
  12 .float ok_lastwep;
  13 .float ok_item;
  14
  15 .float ok_notice_time;
  16 .float ammo_charge[Weapons_MAX];
  17 .float ok_use_ammocharge = _STAT(OK_AMMO_CHARGE);
  18 .float ok_ammo_charge = _STAT(OK_AMMO_CHARGEPOOL);
  19
  20 .float ok_pauseregen_finished;
  21
  22 void(entity ent, float wep) ok_DecreaseCharge;
  23
  24 void ok_Initialize();
  25
  26 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  27 {
  28         MUTATOR_ONADD
  29         {
  30                 ok_Initialize();
  31         }
  32
  33         MUTATOR_ONREMOVE
  34         {
  35                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  36                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  37         }
  38
  39         return false;
  40 }
  41
  42 MUTATOR_HOOKFUNCTION(ok, W_DecreaseAmmo)
  43 {
  44         entity actor = MUTATOR_ARGV(0, entity);
  45         if (actor.ok_use_ammocharge)
  46         {
  47                 ok_DecreaseCharge(actor, PS(actor).m_weapon.m_id);
  48                 return true;
  49         }
  50 }
  51
  52 MUTATOR_HOOKFUNCTION(ok, W_Reload)
  53 {
  54         entity actor = MUTATOR_ARGV(0, entity);
  55         return actor.ok_use_ammocharge;
  56 }
  57
  58 void W_Blaster_Attack(entity, float, float, float, float, float, float, float, float, float, float);
  59 spawnfunc(weapon_hmg);
  60 spawnfunc(weapon_rpc);
  61
  62 void ok_DecreaseCharge(entity ent, int wep)
  63 {
  64         if(!ent.ok_use_ammocharge) return;
  65
  66         entity wepent = Weapons_from(wep);
  67
  68         if (wepent == WEP_Null) return;  // dummy
  69
  70         ent.ammo_charge[wep] -= max(0, cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  71 }
  72
  73 void ok_IncreaseCharge(entity ent, int wep)
  74 {
  75         entity wepent = Weapons_from(wep);
  76
  77         if (wepent == WEP_Null) return;  // dummy
  78
  79         if(ent.ok_use_ammocharge)
  80         if(!PHYS_INPUT_BUTTON_ATCK(ent)) // not while attacking?
  81                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  82 }
  83
  84 float ok_CheckWeaponCharge(entity ent, int wep)
  85 {
  86         if(!ent.ok_use_ammocharge) return true;
  87
  88         entity wepent = Weapons_from(wep);
  89
  90         if(wepent == WEP_Null) return 0;  // dummy
  91
  92         return (ent.ammo_charge[wep] >= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  93 }
  94
  95 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_Calculate, CBC_ORDER_LAST)
  96 {
  97         if(IS_PLAYER(frag_attacker) && IS_PLAYER(frag_target))
  98         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  99         {
 100                 frag_damage = 0;
 101
 102                 if(frag_attacker != frag_target)
 103                 if(frag_target.health > 0)
 104                 if(STAT(FROZEN, frag_target) == 0)
 105                 if(!IS_DEAD(frag_target))
 106                 {
 107                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
 108                         frag_force = '0 0 0';
 109                 }
 110         }
 111
 112         return false;
 113 }
 114
 115 MUTATOR_HOOKFUNCTION(ok, PlayerDamage_SplitHealthArmor)
 116 {
 117         if(damage_take)
 118                 frag_target.ok_pauseregen_finished = max(frag_target.ok_pauseregen_finished, time + 2);
 119         return false;
 120 }
 121
 122 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
 123 {
 124         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
 125
 126         if(IS_MONSTER(frag_target))
 127         {
 128                 remove(other); // remove default item
 129                 other = NULL;
 130         }
 131
 132         entity e = new(droppedweapon); // hax
 133         e.ok_item = true;
 134         e.noalign = true;
 135         e.pickup_anyway = true;
 136         e.spawnfunc_checked = true;
 137         spawnfunc_item_armor_small(e);
 138         if (!wasfreed(e)) { // might have been blocked by a mutator
 139         e.movetype = MOVETYPE_TOSS;
 140         e.gravity = 1;
 141         e.reset = SUB_Remove;
 142         setorigin(e, frag_target.origin + '0 0 32');
 143         e.velocity = '0 0 200' + normalize(targ.origin - frag_target.origin) * 500;
 144         SUB_SetFade(e, time + 5, 1);
 145         }
 146
 147         frag_target.ok_lastwep = PS(frag_target).m_switchweapon.m_id;
 148
 149         return false;
 150 }
 151 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem) { ok_PlayerDies(); }
 152
 153 MUTATOR_HOOKFUNCTION(ok, PlayerRegen)
 154 {SELFPARAM();
 155         // overkill's values are different, so use custom regen
 156         if(!STAT(FROZEN, self))
 157         {
 158                 self.armorvalue = CalcRotRegen(self.armorvalue, autocvar_g_balance_armor_regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 1 * frametime * (time > self.ok_pauseregen_finished), 0, 0, 1, 1 * frametime * (time > self.pauserotarmor_finished), autocvar_g_balance_armor_limit);
 159                 self.health = CalcRotRegen(self.health, autocvar_g_balance_health_regenstable, 0, 100, 1 * frametime * (time > self.ok_pauseregen_finished), 200, 0, autocvar_g_balance_health_rotlinear, 1 * frametime * (time > self.pauserothealth_finished), autocvar_g_balance_health_limit);
 160
 161                 float minf, maxf, limitf;
 162
 163                 maxf = autocvar_g_balance_fuel_rotstable;
 164                 minf = autocvar_g_balance_fuel_regenstable;
 165                 limitf = autocvar_g_balance_fuel_limit;
 166
 167                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
 168         }
 169         return true; // return true anyway, as frozen uses no regen
 170 }
 171
 172 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 173 {
 174         return true;
 175 }
 176
 177 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 178 {SELFPARAM();
 179         if(intermission_running || gameover)
 180                 return false;
 181
 182         if(IS_DEAD(self) || !IS_PLAYER(self) || STAT(FROZEN, self))
 183                 return false;
 184
 185         if(self.ok_lastwep)
 186         {
 187                 Weapon newwep = Weapons_from(self.ok_lastwep);
 188                 if(self.ok_lastwep == WEP_HMG.m_id)
 189                         newwep = WEP_MACHINEGUN;
 190                 if(self.ok_lastwep == WEP_RPC.m_id)
 191                         newwep = WEP_VORTEX;
 192                 PS(self).m_switchweapon = newwep;
 193                 self.ok_lastwep = 0;
 194         }
 195
 196         ok_IncreaseCharge(self, PS(self).m_weapon.m_id);
 197
 198         if(PHYS_INPUT_BUTTON_ATCK2(self))
 199         if(!forbidWeaponUse(self) || self.weapon_blocked) // allow if weapon is blocked
 200         if(time >= self.jump_interval)
 201         {
 202                 self.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor();
 203                 makevectors(self.v_angle);
 204
 205                 Weapon oldwep = PS(self).m_weapon;
 206                 PS(self).m_weapon = WEP_BLASTER;
 207                 W_Blaster_Attack(
 208                         self,
 209                         WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 210                         WEP_CVAR_SEC(vaporizer, shotangle),
 211                         WEP_CVAR_SEC(vaporizer, damage),
 212                         WEP_CVAR_SEC(vaporizer, edgedamage),
 213                         WEP_CVAR_SEC(vaporizer, radius),
 214                         WEP_CVAR_SEC(vaporizer, force),
 215                         WEP_CVAR_SEC(vaporizer, speed),
 216                         WEP_CVAR_SEC(vaporizer, spread),
 217                         WEP_CVAR_SEC(vaporizer, delay),
 218                         WEP_CVAR_SEC(vaporizer, lifetime)
 219                 );
 220                 PS(self).m_weapon = oldwep;
 221         }
 222
 223         self.weapon_blocked = false;
 224
 225         self.ok_ammo_charge = self.ammo_charge[PS(self).m_weapon.m_id];
 226
 227         if(self.ok_use_ammocharge)
 228         if(!ok_CheckWeaponCharge(self, PS(self).m_weapon.m_id))
 229         {
 230                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && PHYS_INPUT_BUTTON_ATCK(self) && IS_REAL_CLIENT(self) && PS(self).m_weapon == PS(self).m_switchweapon)
 231                 {
 232                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 233                         self.ok_notice_time = time + 2;
 234                         play2(self, SND(DRYFIRE));
 235                 }
 236                 Weapon wpn = PS(self).m_weapon;
 237                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 238                 if(self.(weaponentity).state != WS_CLEAR)
 239                         w_ready(wpn, self, weaponentity, PHYS_INPUT_BUTTON_ATCK(self) | (PHYS_INPUT_BUTTON_ATCK2(self) << 1));
 240
 241                 self.weapon_blocked = true;
 242         }
 243
 244         PHYS_INPUT_BUTTON_ATCK2(self) = false;
 245
 246         return false;
 247 }
 248
 249 MUTATOR_HOOKFUNCTION(ok, PlayerSpawn)
 250 {SELFPARAM();
 251         if(autocvar_g_overkill_ammo_charge)
 252         {
 253                 FOREACH(Weapons, it != WEP_Null, LAMBDA(self.ammo_charge[it.m_id] = autocvar_g_overkill_ammo_charge_limit));
 254
 255                 self.ok_use_ammocharge = 1;
 256                 self.ok_notice_time = time;
 257         }
 258         else
 259                 self.ok_use_ammocharge = 0;
 260
 261         // if player changed their weapon while dead, don't switch to their death weapon
 262         if(self.impulse)
 263                 self.ok_lastwep = 0;
 264
 265         self.ok_pauseregen_finished = time + 2;
 266
 267         return false;
 268 }
 269
 270 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 271 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 272
 273 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 274 {SELFPARAM();
 275         if(autocvar_g_powerups)
 276         if(autocvar_g_overkill_powerups_replace)
 277         {
 278                 if(self.classname == "item_strength")
 279                 {
 280                         entity wep = new(weapon_hmg);
 281                         setorigin(wep, self.origin);
 282                         setmodel(wep, MDL_OK_HMG);
 283                         wep.ok_item = true;
 284                         wep.noalign = self.noalign;
 285                         wep.cnt = self.cnt;
 286                         wep.team = self.team;
 287                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 288                         wep.pickup_anyway = true;
 289                         wep.spawnfunc_checked = true;
 290                         setthink(wep, self_spawnfunc_weapon_hmg);
 291                         wep.nextthink = time + 0.1;
 292                         return true;
 293                 }
 294
 295                 if(self.classname == "item_invincible")
 296                 {
 297                         entity wep = new(weapon_rpc);
 298                         setorigin(wep, self.origin);
 299                         setmodel(wep, MDL_OK_RPC);
 300                         wep.ok_item = true;
 301                         wep.noalign = self.noalign;
 302                         wep.cnt = self.cnt;
 303                         wep.team = self.team;
 304                         wep.respawntime = autocvar_g_overkill_superguns_respawn_time;
 305                         wep.pickup_anyway = true;
 306                         wep.spawnfunc_checked = true;
 307                         setthink(wep, self_spawnfunc_weapon_rpc);
 308                         wep.nextthink = time + 0.1;
 309                         return true;
 310                 }
 311         }
 312
 313         return false;
 314 }
 315
 316 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 317 {SELFPARAM();
 318         if(self.ok_item)
 319                 return false;
 320
 321         switch(self.items)
 322         {
 323                 case ITEM_HealthMega.m_itemid: return !(autocvar_g_overkill_100h_anyway);
 324                 case ITEM_ArmorMega.m_itemid: return !(autocvar_g_overkill_100a_anyway);
 325         }
 326
 327         return true;
 328 }
 329
 330 MUTATOR_HOOKFUNCTION(ok, SpectateCopy)
 331 {SELFPARAM();
 332         self.ammo_charge[PS(self).m_weapon.m_id] = other.ammo_charge[PS(other).m_weapon.m_id];
 333         self.ok_use_ammocharge = other.ok_use_ammocharge;
 334
 335         return false;
 336 }
 337
 338 MUTATOR_HOOKFUNCTION(ok, SetStartItems)
 339 {
 340         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 341
 342         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 343         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 344
 345         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 346         start_weapons = warmup_start_weapons = ok_start_items;
 347
 348         return false;
 349 }
 350
 351 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 352 {
 353         ret_string = strcat(ret_string, ":OK");
 354         return false;
 355 }
 356
 357 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 358 {
 359         ret_string = strcat(ret_string, ", Overkill");
 360         return false;
 361 }
 362
 363 MUTATOR_HOOKFUNCTION(ok, SetModname)
 364 {
 365         modname = "Overkill";
 366         return true;
 367 }
 368
 369 void ok_SetCvars()
 370 {
 371         // hack to force overkill playermodels
 372         cvar_settemp("sv_defaultcharacter", "1");
 373         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 374         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 375         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 376 }
 377
 378 void ok_Initialize()
 379 {
 380         ok_SetCvars();
 381
 382         precache_all_playermodels("models/ok_player/*.dpm");
 383
 384         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 385         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 386
 387         WEP_SHOTGUN.mdl = "ok_shotgun";
 388         WEP_MACHINEGUN.mdl = "ok_mg";
 389         WEP_VORTEX.mdl = "ok_sniper";
 390 }
 391 #endif