Give W_SetupShot a deathtype parameter, fixes some ugly hacks
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mutators / mutator / overkill / sv_overkill.qc
1 #include "sv_overkill.qh"
2
3 #include "hmg.qh"
4 #include "rpc.qh"
5
6 string autocvar_g_overkill;
7
8 bool autocvar_g_overkill_powerups_replace;
9
10 bool autocvar_g_overkill_itemwaypoints = true;
11
12 .Weapon ok_lastwep[MAX_WEAPONSLOTS];
13
14 REGISTER_MUTATOR(ok, expr_evaluate(autocvar_g_overkill) && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
15 {
16         MUTATOR_ONADD
17         {
18                 precache_all_playermodels("models/ok_player/*.dpm");
19
20                 if (autocvar_g_overkill_filter_healthmega)
21                 {
22                         ITEM_HealthMega.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
23                 }
24                 if (autocvar_g_overkill_filter_armormedium)
25                 {
26                         ITEM_ArmorMedium.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
27                 }
28                 if (autocvar_g_overkill_filter_armorbig)
29                 {
30                         ITEM_ArmorBig.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
31                 }
32                 if (autocvar_g_overkill_filter_armormega)
33                 {
34                         ITEM_ArmorMega.spawnflags |= ITEM_FLAG_MUTATORBLOCKED;
35                 }
36
37                 WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
38                 WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
39
40                 WEP_SHOTGUN.mdl = "ok_shotgun";
41                 WEP_MACHINEGUN.mdl = "ok_mg";
42                 WEP_VORTEX.mdl = "ok_sniper";
43         }
44
45         MUTATOR_ONREMOVE
46         {
47                 ITEM_HealthMega.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
48                 ITEM_ArmorMedium.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
49                 ITEM_ArmorBig.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
50                 ITEM_ArmorMega.spawnflags &= ~ITEM_FLAG_MUTATORBLOCKED;
51
52                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
53                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
54         }
55 }
56
57 void W_Blaster_Attack(entity, .entity, float, float, float, float, float, float, float, float, float, float);
58
59 MUTATOR_HOOKFUNCTION(ok, Damage_Calculate, CBC_ORDER_LAST)
60 {
61         entity frag_attacker = M_ARGV(1, entity);
62         entity frag_target = M_ARGV(2, entity);
63         float frag_deathtype = M_ARGV(3, float);
64
65         if(IS_PLAYER(frag_attacker) && (IS_PLAYER(frag_target) || IS_VEHICLE(frag_target) || IS_TURRET(frag_target)))
66         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
67         {
68                 if(frag_attacker != frag_target)
69                 if(!STAT(FROZEN, frag_target))
70                 if(!IS_DEAD(frag_target))
71                 {
72                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
73                         M_ARGV(6, vector) = '0 0 0'; // force
74                 }
75
76                 M_ARGV(4, float) = 0; // damage
77         }
78 }
79
80 void ok_DropItem(entity this, entity targ)
81 {
82         entity e = spawn();
83         e.ok_item = true;
84         Item_InitializeLoot(e, "item_armor_small", this.origin + '0 0 32',
85                 '0 0 200' + normalize(targ.origin - this.origin) * 500, 5);
86 }
87
88 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
89 {
90         entity frag_attacker = M_ARGV(1, entity);
91         entity frag_target = M_ARGV(2, entity);
92
93         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
94
95         ok_DropItem(frag_target, targ);
96
97         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
98         {
99                 .entity weaponentity = weaponentities[slot];
100
101                 frag_target.ok_lastwep[slot] = frag_target.(weaponentity).m_switchweapon;
102         }
103 }
104
105 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
106 {
107         entity mon = M_ARGV(0, entity);
108         entity olditem = M_ARGV(1, entity);
109         entity frag_attacker = M_ARGV(2, entity);
110
111         delete(olditem);
112
113         M_ARGV(1, entity) = NULL;
114
115         ok_DropItem(mon, frag_attacker);
116 }
117
118 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
119 {
120         return true;
121 }
122
123 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
124 {
125         if(game_stopped)
126                 return;
127
128         entity player = M_ARGV(0, entity);
129
130         if(IS_DEAD(player) || !IS_PLAYER(player) || STAT(FROZEN, player))
131                 return;
132
133         if(PHYS_INPUT_BUTTON_ATCK2(player) && time >= player.jump_interval)
134         if( !forbidWeaponUse(player)
135                 || (round_handler_IsActive() && !round_handler_IsRoundStarted()) )
136         {
137                 player.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor(player);
138                 makevectors(player.v_angle);
139
140                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
141                 {
142                         .entity weaponentity = weaponentities[slot];
143
144                         if(player.(weaponentity).m_weapon == WEP_Null && slot != 0)
145                                 continue;
146
147                         W_Blaster_Attack(
148                                 player,
149                                 weaponentity,
150                                 WEP_BLASTER.m_id | HITTYPE_SECONDARY,
151                                 WEP_CVAR_SEC(vaporizer, shotangle),
152                                 WEP_CVAR_SEC(vaporizer, damage),
153                                 WEP_CVAR_SEC(vaporizer, edgedamage),
154                                 WEP_CVAR_SEC(vaporizer, radius),
155                                 WEP_CVAR_SEC(vaporizer, force),
156                                 WEP_CVAR_SEC(vaporizer, speed),
157                                 WEP_CVAR_SEC(vaporizer, spread),
158                                 WEP_CVAR_SEC(vaporizer, delay),
159                                 WEP_CVAR_SEC(vaporizer, lifetime)
160                         );
161                 }
162         }
163
164         PHYS_INPUT_BUTTON_ATCK2(player) = false;
165 }
166
167 MUTATOR_HOOKFUNCTION(ok, ForbidRandomStartWeapons)
168 {
169         return true;
170 }
171
172 MUTATOR_HOOKFUNCTION(ok, PlayerWeaponSelect)
173 {
174         entity player = M_ARGV(0, entity);
175
176         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
177         {
178                 .entity weaponentity = weaponentities[slot];
179                 entity thiswep = player.(weaponentity);
180
181                 if(player.ok_lastwep[slot] && player.ok_lastwep[slot] != WEP_Null)
182                 {
183                         Weapon newwep = player.ok_lastwep[slot];
184                         if(player.ok_lastwep[slot] == WEP_HMG)
185                                 newwep = WEP_MACHINEGUN;
186                         if(player.ok_lastwep[slot] == WEP_RPC)
187                                 newwep = WEP_VORTEX;
188                         thiswep.m_switchweapon = newwep;
189                         player.ok_lastwep[slot] = WEP_Null;
190                 }
191         }
192 }
193
194 bool ok_HandleItemWaypoints(entity e)
195 {
196         if(!autocvar_g_overkill_itemwaypoints)
197                 return false; // don't handle it
198
199         switch(e.itemdef)
200         {
201                 case ITEM_HealthMega: return true;
202                 case ITEM_ArmorMedium: return true;
203                 case ITEM_ArmorBig: return true;
204                 case ITEM_ArmorMega: return true;
205         }
206
207         return false;
208 }
209
210 MUTATOR_HOOKFUNCTION(ok, Item_RespawnCountdown)
211 {
212         entity item = M_ARGV(0, entity);
213         return ok_HandleItemWaypoints(item);
214 }
215
216 MUTATOR_HOOKFUNCTION(ok, Item_ScheduleRespawn)
217 {
218         entity item = M_ARGV(0, entity);
219         return ok_HandleItemWaypoints(item);
220 }
221
222 MUTATOR_HOOKFUNCTION(ok, FilterItem)
223 {
224         entity item = M_ARGV(0, entity);
225
226         if (item.ok_item)
227         {
228                 return false;
229         }
230         switch(item.itemdef)
231         {
232                 case ITEM_HealthMega: return autocvar_g_overkill_filter_healthmega;
233                 case ITEM_ArmorMedium: return autocvar_g_overkill_filter_armormedium;
234                 case ITEM_ArmorBig: return autocvar_g_overkill_filter_armorbig;
235                 case ITEM_ArmorMega: return autocvar_g_overkill_filter_armormega;
236         }
237         if (!autocvar_g_powerups || !autocvar_g_overkill_powerups_replace)
238         {
239                 return true;
240         }
241         if (item.classname == "item_strength")
242         {
243                 entity wep = new(weapon_hmg);
244                 setorigin(wep, item.origin);
245                 wep.ok_item = true;
246                 wep.noalign = Item_ShouldKeepPosition(item);
247                 wep.cnt = item.cnt;
248                 wep.team = item.team;
249                 wep.respawntime = g_pickup_respawntime_superweapon;
250                 wep.pickup_anyway = true;
251                 wep.spawnfunc_checked = true;
252                 Item_Initialize(wep, "weapon_hmg");
253                 return true;
254         }
255         else if (item.classname == "item_shield")
256         {
257                 entity wep = new(weapon_rpc);
258                 setorigin(wep, item.origin);
259                 wep.ok_item = true;
260                 wep.noalign = Item_ShouldKeepPosition(item);
261                 wep.cnt = item.cnt;
262                 wep.team = item.team;
263                 wep.respawntime = g_pickup_respawntime_superweapon;
264                 wep.pickup_anyway = true;
265                 wep.spawnfunc_checked = true;
266                 Item_Initialize(wep, "weapon_rpc");
267                 return true;
268         }
269         return true;
270 }
271
272 MUTATOR_HOOKFUNCTION(ok, SetStartItems, CBC_ORDER_LAST)
273 {
274         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
275
276         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
277         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
278
279         start_items |= IT_UNLIMITED_WEAPON_AMMO;
280         start_weapons = warmup_start_weapons = ok_start_items;
281 }
282
283 MUTATOR_HOOKFUNCTION(ok, SetWeaponArena)
284 {
285         // turn weapon arena off
286         M_ARGV(0, string) = "off";
287 }
288
289 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
290 {
291         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
292 }
293
294 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
295 {
296         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
297 }
298
299 MUTATOR_HOOKFUNCTION(ok, SetModname)
300 {
301         M_ARGV(0, string) = "Overkill";
302         return true;
303 }