qcsrc/common/mutators/mutator/overkill/sv_overkill.qc

   1 #include "sv_overkill.qh"
   2
   3 #include "hmg.qh"
   4 #include "rpc.qh"
   5
   6 string autocvar_g_overkill;
   7
   8 bool autocvar_g_overkill_powerups_replace;
   9
  10 bool autocvar_g_overkill_itemwaypoints = true;
  11
  12 .Weapon ok_lastwep[MAX_WEAPONSLOTS];
  13
  14 void ok_Initialize();
  15
  16 REGISTER_MUTATOR(ok, expr_evaluate(autocvar_g_overkill) && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  17 {
  18         MUTATOR_ONADD
  19         {
  20                 ok_Initialize();
  21         }
  22
  23         MUTATOR_ONREMOVE
  24         {
  25                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  26                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  27         }
  28 }
  29
  30 void W_Blaster_Attack(entity, .entity, float, float, float, float, float, float, float, float, float, float);
  31
  32 MUTATOR_HOOKFUNCTION(ok, Damage_Calculate, CBC_ORDER_LAST)
  33 {
  34         entity frag_attacker = M_ARGV(1, entity);
  35         entity frag_target = M_ARGV(2, entity);
  36         float frag_deathtype = M_ARGV(3, float);
  37
  38         if(IS_PLAYER(frag_attacker) && (IS_PLAYER(frag_target) || IS_VEHICLE(frag_target) || IS_TURRET(frag_target)))
  39         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  40         {
  41                 if(frag_attacker != frag_target)
  42                 if(!STAT(FROZEN, frag_target))
  43                 if(!IS_DEAD(frag_target))
  44                 {
  45                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  46                         M_ARGV(6, vector) = '0 0 0'; // force
  47                 }
  48
  49                 M_ARGV(4, float) = 0; // damage
  50         }
  51 }
  52
  53 void ok_DropItem(entity this, entity targ)
  54 {
  55         entity e = spawn();
  56         e.ok_item = true;
  57         Item_InitializeLoot(e, "item_armor_small", this.origin + '0 0 32',
  58                 '0 0 200' + normalize(targ.origin - this.origin) * 500, 5);
  59 }
  60
  61 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
  62 {
  63         entity frag_attacker = M_ARGV(1, entity);
  64         entity frag_target = M_ARGV(2, entity);
  65
  66         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
  67
  68         ok_DropItem(frag_target, targ);
  69
  70         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  71         {
  72                 .entity weaponentity = weaponentities[slot];
  73
  74                 frag_target.ok_lastwep[slot] = frag_target.(weaponentity).m_switchweapon;
  75         }
  76 }
  77
  78 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
  79 {
  80         entity mon = M_ARGV(0, entity);
  81         entity olditem = M_ARGV(1, entity);
  82         entity frag_attacker = M_ARGV(2, entity);
  83
  84         delete(olditem);
  85
  86         M_ARGV(1, entity) = NULL;
  87
  88         ok_DropItem(mon, frag_attacker);
  89 }
  90
  91 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
  92 {
  93         return true;
  94 }
  95
  96 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
  97 {
  98         if(game_stopped)
  99                 return;
 100
 101         entity player = M_ARGV(0, entity);
 102
 103         if(IS_DEAD(player) || !IS_PLAYER(player) || STAT(FROZEN, player))
 104                 return;
 105
 106         if(PHYS_INPUT_BUTTON_ATCK2(player) && time >= player.jump_interval)
 107         if( !forbidWeaponUse(player)
 108                 || (round_handler_IsActive() && !round_handler_IsRoundStarted()) )
 109         {
 110                 player.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor(player);
 111                 makevectors(player.v_angle);
 112
 113                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 114                 {
 115                         .entity weaponentity = weaponentities[slot];
 116
 117                         if(player.(weaponentity).m_weapon == WEP_Null && slot != 0)
 118                                 continue;
 119
 120                         Weapon oldwep = player.(weaponentity).m_weapon;
 121                         player.(weaponentity).m_weapon = WEP_BLASTER;
 122                         W_Blaster_Attack(
 123                                 player,
 124                                 weaponentity,
 125                                 WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 126                                 WEP_CVAR_SEC(vaporizer, shotangle),
 127                                 WEP_CVAR_SEC(vaporizer, damage),
 128                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 129                                 WEP_CVAR_SEC(vaporizer, radius),
 130                                 WEP_CVAR_SEC(vaporizer, force),
 131                                 WEP_CVAR_SEC(vaporizer, speed),
 132                                 WEP_CVAR_SEC(vaporizer, spread),
 133                                 WEP_CVAR_SEC(vaporizer, delay),
 134                                 WEP_CVAR_SEC(vaporizer, lifetime)
 135                         );
 136                         player.(weaponentity).m_weapon = oldwep;
 137                 }
 138         }
 139
 140         PHYS_INPUT_BUTTON_ATCK2(player) = false;
 141 }
 142
 143 MUTATOR_HOOKFUNCTION(ok, PlayerWeaponSelect)
 144 {
 145         entity player = M_ARGV(0, entity);
 146
 147         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 148         {
 149                 .entity weaponentity = weaponentities[slot];
 150                 entity thiswep = player.(weaponentity);
 151
 152                 if(player.ok_lastwep[slot] && player.ok_lastwep[slot] != WEP_Null)
 153                 {
 154                         Weapon newwep = player.ok_lastwep[slot];
 155                         if(player.ok_lastwep[slot] == WEP_HMG)
 156                                 newwep = WEP_MACHINEGUN;
 157                         if(player.ok_lastwep[slot] == WEP_RPC)
 158                                 newwep = WEP_VORTEX;
 159                         thiswep.m_switchweapon = newwep;
 160                         player.ok_lastwep[slot] = WEP_Null;
 161                 }
 162         }
 163 }
 164
 165 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 166 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 167
 168 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 169 {
 170         entity ent = M_ARGV(0, entity);
 171
 172         if(autocvar_g_powerups)
 173         if(autocvar_g_overkill_powerups_replace)
 174         {
 175                 if(ent.classname == "item_strength")
 176                 {
 177                         entity wep = new(weapon_hmg);
 178                         setorigin(wep, ent.origin);
 179                         setmodel(wep, MDL_OK_HMG);
 180                         wep.ok_item = true;
 181                         wep.noalign = ent.noalign;
 182                         wep.cnt = ent.cnt;
 183                         wep.team = ent.team;
 184                         wep.respawntime = g_pickup_respawntime_superweapon;
 185                         wep.pickup_anyway = true;
 186                         wep.spawnfunc_checked = true;
 187                         setthink(wep, self_spawnfunc_weapon_hmg);
 188                         wep.nextthink = time + 0.1;
 189                         return true;
 190                 }
 191                 else if(ent.classname == "item_invincible")
 192                 {
 193                         entity wep = new(weapon_rpc);
 194                         setorigin(wep, ent.origin);
 195                         setmodel(wep, MDL_OK_RPC);
 196                         wep.ok_item = true;
 197                         wep.noalign = ent.noalign;
 198                         wep.cnt = ent.cnt;
 199                         wep.team = ent.team;
 200                         wep.respawntime = g_pickup_respawntime_superweapon;
 201                         wep.pickup_anyway = true;
 202                         wep.spawnfunc_checked = true;
 203                         setthink(wep, self_spawnfunc_weapon_rpc);
 204                         wep.nextthink = time + 0.1;
 205                         return true;
 206                 }
 207         }
 208 }
 209
 210 bool ok_HandleItemWaypoints(entity e)
 211 {
 212         if(!autocvar_g_overkill_itemwaypoints)
 213                 return false; // don't handle it
 214
 215         switch(e.itemdef)
 216         {
 217                 case ITEM_HealthMega: return true;
 218                 case ITEM_ArmorMedium: return true;
 219                 case ITEM_ArmorBig: return true;
 220                 case ITEM_ArmorMega: return true;
 221         }
 222
 223         return false;
 224 }
 225
 226 MUTATOR_HOOKFUNCTION(ok, Item_RespawnCountdown)
 227 {
 228         entity item = M_ARGV(0, entity);
 229         return ok_HandleItemWaypoints(item);
 230 }
 231
 232 MUTATOR_HOOKFUNCTION(ok, Item_ScheduleRespawn)
 233 {
 234         entity item = M_ARGV(0, entity);
 235         return ok_HandleItemWaypoints(item);
 236 }
 237
 238 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 239 {
 240         entity item = M_ARGV(0, entity);
 241
 242         if(item.ok_item)
 243                 return false;
 244
 245         switch(item.itemdef)
 246         {
 247                 case ITEM_HealthMega: return autocvar_g_overkill_filter_healthmega;
 248                 case ITEM_ArmorMedium: return autocvar_g_overkill_filter_armormedium;
 249                 case ITEM_ArmorBig: return autocvar_g_overkill_filter_armorbig;
 250                 case ITEM_ArmorMega: return autocvar_g_overkill_filter_armormega;
 251         }
 252
 253         return true;
 254 }
 255
 256 MUTATOR_HOOKFUNCTION(ok, SetStartItems, CBC_ORDER_LAST)
 257 {
 258         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 259
 260         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 261         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 262
 263         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 264         start_weapons = warmup_start_weapons = ok_start_items;
 265 }
 266
 267 MUTATOR_HOOKFUNCTION(ok, SetWeaponArena)
 268 {
 269         // turn weapon arena off
 270         M_ARGV(0, string) = "off";
 271 }
 272
 273 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 274 {
 275         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 276 }
 277
 278 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 279 {
 280         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 281 }
 282
 283 MUTATOR_HOOKFUNCTION(ok, SetModname)
 284 {
 285         M_ARGV(0, string) = "Overkill";
 286         return true;
 287 }
 288
 289 void ok_Initialize()
 290 {
 291         precache_all_playermodels("models/ok_player/*.dpm");
 292
 293         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 294         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 295
 296         WEP_SHOTGUN.mdl = "ok_shotgun";
 297         WEP_MACHINEGUN.mdl = "ok_mg";
 298         WEP_VORTEX.mdl = "ok_sniper";
 299 }