qcsrc/common/mutators/mutator/overkill/sv_overkill.qc

   1 #include "sv_overkill.qh"
   2
   3 #include "hmg.qh"
   4 #include "rpc.qh"
   5
   6 bool autocvar_g_overkill_powerups_replace;
   7
   8 bool autocvar_g_overkill_filter_healthmega;
   9 bool autocvar_g_overkill_filter_armormedium;
  10 bool autocvar_g_overkill_filter_armorbig;
  11 bool autocvar_g_overkill_filter_armormega;
  12
  13 .float ok_item;
  14
  15 .Weapon ok_lastwep[MAX_WEAPONSLOTS];
  16
  17 void ok_Initialize();
  18
  19 REGISTER_MUTATOR(ok, cvar("g_overkill") && !cvar("g_instagib") && !g_nexball && cvar_string("g_mod_balance") == "Overkill")
  20 {
  21         MUTATOR_ONADD
  22         {
  23                 ok_Initialize();
  24         }
  25
  26         MUTATOR_ONREMOVE
  27         {
  28                 WEP_RPC.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  29                 WEP_HMG.spawnflags |= WEP_FLAG_MUTATORBLOCKED;
  30         }
  31 }
  32
  33 void W_Blaster_Attack(entity, .entity, float, float, float, float, float, float, float, float, float, float);
  34 spawnfunc(weapon_hmg);
  35 spawnfunc(weapon_rpc);
  36
  37 MUTATOR_HOOKFUNCTION(ok, Damage_Calculate, CBC_ORDER_LAST)
  38 {
  39         entity frag_attacker = M_ARGV(1, entity);
  40         entity frag_target = M_ARGV(2, entity);
  41         float frag_deathtype = M_ARGV(3, float);
  42
  43         if(IS_PLAYER(frag_attacker) && (IS_PLAYER(frag_target) || IS_VEHICLE(frag_target) || IS_TURRET(frag_target)))
  44         if(DEATH_ISWEAPON(frag_deathtype, WEP_BLASTER))
  45         {
  46                 if(frag_attacker != frag_target)
  47                 if(!STAT(FROZEN, frag_target))
  48                 if(!IS_DEAD(frag_target))
  49                 {
  50                         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_SECONDARY_NODAMAGE);
  51                         M_ARGV(6, vector) = '0 0 0'; // force
  52                 }
  53
  54                 M_ARGV(4, float) = 0; // damage
  55         }
  56 }
  57
  58 void ok_DropItem(entity this, entity targ)
  59 {
  60         entity e = new(droppedweapon); // hax
  61         e.ok_item = true;
  62         e.noalign = true;
  63         e.pickup_anyway = true;
  64         e.spawnfunc_checked = true;
  65         spawnfunc_item_armor_small(e);
  66         if (!wasfreed(e)) { // might have been blocked by a mutator
  67         set_movetype(e, MOVETYPE_TOSS);
  68         e.gravity = 1;
  69         e.reset = SUB_Remove;
  70         setorigin(e, this.origin + '0 0 32');
  71         e.velocity = '0 0 200' + normalize(targ.origin - this.origin) * 500;
  72         SUB_SetFade(e, time + 5, 1);
  73         }
  74 }
  75
  76 MUTATOR_HOOKFUNCTION(ok, PlayerDies)
  77 {
  78         entity frag_attacker = M_ARGV(1, entity);
  79         entity frag_target = M_ARGV(2, entity);
  80
  81         entity targ = ((frag_attacker) ? frag_attacker : frag_target);
  82
  83         ok_DropItem(frag_target, targ);
  84
  85         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  86         {
  87                 .entity weaponentity = weaponentities[slot];
  88
  89                 frag_target.ok_lastwep[slot] = frag_target.(weaponentity).m_switchweapon;
  90         }
  91 }
  92
  93 MUTATOR_HOOKFUNCTION(ok, MonsterDropItem)
  94 {
  95         entity mon = M_ARGV(0, entity);
  96         entity olditem = M_ARGV(1, entity);
  97         entity frag_attacker = M_ARGV(2, entity);
  98
  99         delete(olditem);
 100
 101         M_ARGV(1, entity) = NULL;
 102
 103         ok_DropItem(mon, frag_attacker);
 104 }
 105
 106 MUTATOR_HOOKFUNCTION(ok, ForbidThrowCurrentWeapon)
 107 {
 108         return true;
 109 }
 110
 111 MUTATOR_HOOKFUNCTION(ok, PlayerPreThink)
 112 {
 113         if(game_stopped)
 114                 return;
 115
 116         entity player = M_ARGV(0, entity);
 117
 118         if(IS_DEAD(player) || !IS_PLAYER(player) || STAT(FROZEN, player))
 119                 return;
 120
 121         if(PHYS_INPUT_BUTTON_ATCK2(player))
 122         if( !forbidWeaponUse(player)
 123                 || (round_handler_IsActive() && !round_handler_IsRoundStarted()) )
 124         if(time >= player.jump_interval)
 125         {
 126                 player.jump_interval = time + WEP_CVAR_PRI(blaster, refire) * W_WeaponRateFactor(player);
 127                 makevectors(player.v_angle);
 128
 129                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 130                 {
 131                         .entity weaponentity = weaponentities[slot];
 132
 133                         if(player.(weaponentity).m_weapon == WEP_Null && slot != 0)
 134                                 continue;
 135
 136                         Weapon oldwep = player.(weaponentity).m_weapon;
 137                         player.(weaponentity).m_weapon = WEP_BLASTER;
 138                         W_Blaster_Attack(
 139                                 player,
 140                                 weaponentity,
 141                                 WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 142                                 WEP_CVAR_SEC(vaporizer, shotangle),
 143                                 WEP_CVAR_SEC(vaporizer, damage),
 144                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 145                                 WEP_CVAR_SEC(vaporizer, radius),
 146                                 WEP_CVAR_SEC(vaporizer, force),
 147                                 WEP_CVAR_SEC(vaporizer, speed),
 148                                 WEP_CVAR_SEC(vaporizer, spread),
 149                                 WEP_CVAR_SEC(vaporizer, delay),
 150                                 WEP_CVAR_SEC(vaporizer, lifetime)
 151                         );
 152                         player.(weaponentity).m_weapon = oldwep;
 153                 }
 154         }
 155
 156         PHYS_INPUT_BUTTON_ATCK2(player) = false;
 157 }
 158
 159 MUTATOR_HOOKFUNCTION(ok, PlayerWeaponSelect)
 160 {
 161         entity player = M_ARGV(0, entity);
 162
 163         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 164         {
 165                 .entity weaponentity = weaponentities[slot];
 166                 entity thiswep = player.(weaponentity);
 167
 168                 if(player.ok_lastwep[slot] && player.ok_lastwep[slot] != WEP_Null)
 169                 {
 170                         Weapon newwep = player.ok_lastwep[slot];
 171                         if(player.ok_lastwep[slot] == WEP_HMG)
 172                                 newwep = WEP_MACHINEGUN;
 173                         if(player.ok_lastwep[slot] == WEP_RPC)
 174                                 newwep = WEP_VORTEX;
 175                         thiswep.m_switchweapon = newwep;
 176                         player.ok_lastwep[slot] = WEP_Null;
 177                 }
 178         }
 179 }
 180
 181 void self_spawnfunc_weapon_hmg(entity this) { spawnfunc_weapon_hmg(this); }
 182 void self_spawnfunc_weapon_rpc(entity this) { spawnfunc_weapon_rpc(this); }
 183
 184 MUTATOR_HOOKFUNCTION(ok, OnEntityPreSpawn)
 185 {
 186         entity ent = M_ARGV(0, entity);
 187
 188         if(autocvar_g_powerups)
 189         if(autocvar_g_overkill_powerups_replace)
 190         {
 191                 if(ent.classname == "item_strength")
 192                 {
 193                         entity wep = new(weapon_hmg);
 194                         setorigin(wep, ent.origin);
 195                         setmodel(wep, MDL_OK_HMG);
 196                         wep.ok_item = true;
 197                         wep.noalign = ent.noalign;
 198                         wep.cnt = ent.cnt;
 199                         wep.team = ent.team;
 200                         wep.respawntime = g_pickup_respawntime_superweapon;
 201                         wep.pickup_anyway = true;
 202                         wep.spawnfunc_checked = true;
 203                         setthink(wep, self_spawnfunc_weapon_hmg);
 204                         wep.nextthink = time + 0.1;
 205                         return true;
 206                 }
 207                 else if(ent.classname == "item_invincible")
 208                 {
 209                         entity wep = new(weapon_rpc);
 210                         setorigin(wep, ent.origin);
 211                         setmodel(wep, MDL_OK_RPC);
 212                         wep.ok_item = true;
 213                         wep.noalign = ent.noalign;
 214                         wep.cnt = ent.cnt;
 215                         wep.team = ent.team;
 216                         wep.respawntime = g_pickup_respawntime_superweapon;
 217                         wep.pickup_anyway = true;
 218                         wep.spawnfunc_checked = true;
 219                         setthink(wep, self_spawnfunc_weapon_rpc);
 220                         wep.nextthink = time + 0.1;
 221                         return true;
 222                 }
 223         }
 224 }
 225
 226 MUTATOR_HOOKFUNCTION(ok, FilterItem)
 227 {
 228         entity item = M_ARGV(0, entity);
 229
 230         if(item.ok_item)
 231                 return false;
 232
 233         switch(item.itemdef)
 234         {
 235                 case ITEM_HealthMega: return autocvar_g_overkill_filter_healthmega;
 236                 case ITEM_ArmorMedium: return autocvar_g_overkill_filter_armormedium;
 237                 case ITEM_ArmorBig: return autocvar_g_overkill_filter_armorbig;
 238                 case ITEM_ArmorMega: return autocvar_g_overkill_filter_armormega;
 239         }
 240
 241         return true;
 242 }
 243
 244 MUTATOR_HOOKFUNCTION(ok, SetStartItems, CBC_ORDER_LAST)
 245 {
 246         WepSet ok_start_items = (WEPSET(MACHINEGUN) | WEPSET(VORTEX) | WEPSET(SHOTGUN));
 247
 248         if(WEP_RPC.weaponstart > 0) { ok_start_items |= WEPSET(RPC); }
 249         if(WEP_HMG.weaponstart > 0) { ok_start_items |= WEPSET(HMG); }
 250
 251         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 252         start_weapons = warmup_start_weapons = ok_start_items;
 253 }
 254
 255 MUTATOR_HOOKFUNCTION(ok, SetWeaponArena)
 256 {
 257         // turn weapon arena off
 258         M_ARGV(0, string) = "off";
 259 }
 260
 261 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsString)
 262 {
 263         M_ARGV(0, string) = strcat(M_ARGV(0, string), ":OK");
 264 }
 265
 266 MUTATOR_HOOKFUNCTION(ok, BuildMutatorsPrettyString)
 267 {
 268         M_ARGV(0, string) = strcat(M_ARGV(0, string), ", Overkill");
 269 }
 270
 271 MUTATOR_HOOKFUNCTION(ok, SetModname)
 272 {
 273         M_ARGV(0, string) = "Overkill";
 274         return true;
 275 }
 276
 277 void ok_SetCvars()
 278 {
 279         // hack to force overkill playermodels
 280         cvar_settemp("sv_defaultcharacter", "1");
 281         cvar_settemp("sv_defaultplayermodel", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 282         cvar_settemp("sv_defaultplayermodel_red", "models/ok_player/okrobot1.dpm models/ok_player/okrobot2.dpm models/ok_player/okrobot3.dpm models/ok_player/okrobot4.dpm");
 283         cvar_settemp("sv_defaultplayermodel_blue", "models/ok_player/okmale1.dpm models/ok_player/okmale2.dpm models/ok_player/okmale3.dpm models/ok_player/okmale4.dpm");
 284 }
 285
 286 void ok_Initialize()
 287 {
 288         ok_SetCvars();
 289
 290         precache_all_playermodels("models/ok_player/*.dpm");
 291
 292         WEP_RPC.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 293         WEP_HMG.spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 294
 295         WEP_SHOTGUN.mdl = "ok_shotgun";
 296         WEP_MACHINEGUN.mdl = "ok_mg";
 297         WEP_VORTEX.mdl = "ok_sniper";
 298 }