Remove SELFPARAM() from .think and .touch
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mutators / mutator / sandbox / sandbox.qc
1 #ifdef IMPLEMENTATION
2 int autocvar_g_sandbox_info;
3 bool autocvar_g_sandbox_readonly;
4 string autocvar_g_sandbox_storage_name;
5 float autocvar_g_sandbox_storage_autosave;
6 bool autocvar_g_sandbox_storage_autoload;
7 float autocvar_g_sandbox_editor_flood;
8 int autocvar_g_sandbox_editor_maxobjects;
9 int autocvar_g_sandbox_editor_free;
10 float autocvar_g_sandbox_editor_distance_spawn;
11 float autocvar_g_sandbox_editor_distance_edit;
12 float autocvar_g_sandbox_object_scale_min;
13 float autocvar_g_sandbox_object_scale_max;
14 float autocvar_g_sandbox_object_material_velocity_min;
15 float autocvar_g_sandbox_object_material_velocity_factor;
16
17 float autosave_time;
18 void sandbox_Database_Load();
19
20 REGISTER_MUTATOR(sandbox, cvar("g_sandbox"))
21 {
22         MUTATOR_ONADD
23         {
24                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
25                 if(autocvar_g_sandbox_storage_autoload)
26                         sandbox_Database_Load();
27         }
28
29         MUTATOR_ONROLLBACK_OR_REMOVE
30         {
31                 // nothing to roll back
32         }
33
34         MUTATOR_ONREMOVE
35         {
36                 // nothing to remove
37         }
38
39         return false;
40 }
41
42 const float MAX_STORAGE_ATTACHMENTS = 16;
43 float object_count;
44 .float object_flood;
45 .entity object_attach;
46 .string material;
47
48 .float touch_timer;
49 void sandbox_ObjectFunction_Touch(entity this)
50 {
51         // apply material impact effects
52
53         if(!self.material)
54                 return;
55         if(self.touch_timer > time)
56                 return; // don't execute each frame
57         self.touch_timer = time + 0.1;
58
59         // make particle count and sound volume depend on impact speed
60         float intensity;
61         intensity = vlen(self.velocity) + vlen(other.velocity);
62         if(intensity) // avoid divisions by 0
63                 intensity /= 2; // average the two velocities
64         if (!(intensity >= autocvar_g_sandbox_object_material_velocity_min))
65                 return; // impact not strong enough to do anything
66         // now offset intensity and apply it to the effects
67         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
68         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
69
70         _sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".wav"), VOL_BASE * intensity, ATTEN_NORM);
71         Send_Effect_(strcat("impact_", self.material), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
72 }
73
74 void sandbox_ObjectFunction_Think(entity this)
75 {
76         // decide if and how this object can be grabbed
77         if(autocvar_g_sandbox_readonly)
78                 self.grab = 0; // no grabbing
79         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
80                 self.grab = 1; // owner only
81         else
82                 self.grab = 3; // anyone
83
84         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
85         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
86         // since if the owning player disconnects, the object's owner should also be reset.
87
88         // bots can't have objects
89         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
90                 if(self.crypto_idfp == it.crypto_idfp)
91                 {
92                         self.realowner = it;
93                         break;
94                 }
95                 self.realowner = world;
96         ));
97
98         self.nextthink = time;
99
100         CSQCMODEL_AUTOUPDATE(self);
101 }
102
103 .float old_solid, old_movetype;
104 entity sandbox_ObjectEdit_Get(float permissions)
105 {SELFPARAM();
106         // Returns the traced entity if the player can edit it, and world if not.
107         // If permissions if false, the object is returned regardless of editing rights.
108         // Attached objects are SOLID_NOT and do not get traced.
109
110         crosshair_trace_plusvisibletriggers(self);
111         if(vdist(self.origin - trace_ent.origin, >, autocvar_g_sandbox_editor_distance_edit))
112                 return world; // out of trace range
113         if(trace_ent.classname != "object")
114                 return world; // entity is not an object
115         if(!permissions)
116                 return trace_ent; // don't check permissions, anyone can edit this object
117         if(trace_ent.crypto_idfp == "")
118                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
119         if (!(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2))
120                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
121         return world;
122 }
123
124 void sandbox_ObjectEdit_Scale(entity e, float f)
125 {
126         e.scale = f;
127         if(e.scale)
128         {
129                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
130                 _setmodel(e, e.model); // reset mins and maxs based on mesh
131                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
132         }
133 }
134
135 void sandbox_ObjectAttach_Remove(entity e);
136 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
137 {
138         // attaches e to parent on string s
139
140         // we can't attach to an attachment, for obvious reasons
141         sandbox_ObjectAttach_Remove(e);
142
143         e.old_solid = e.solid; // persist solidity
144         e.old_movetype = e.movetype; // persist physics
145         e.movetype = MOVETYPE_FOLLOW;
146         e.solid = SOLID_NOT;
147         e.takedamage = DAMAGE_NO;
148
149         setattachment(e, parent, s);
150         e.owner = parent;
151 }
152
153 void sandbox_ObjectAttach_Remove(entity e)
154 {
155         // detaches any object attached to e
156
157         entity head;
158         for(head = world; (head = find(head, classname, "object")); )
159         {
160                 if(head.owner == e)
161                 {
162                         vector org;
163                         org = gettaginfo(head, 0);
164                         setattachment(head, world, "");
165                         head.owner = world;
166
167                         // objects change origin and angles when detached, so apply previous position
168                         setorigin(head, org);
169                         head.angles = e.angles; // don't allow detached objects to spin or roll
170
171                         head.solid = head.old_solid; // restore persisted solidity
172                         head.movetype = head.old_movetype; // restore persisted physics
173                         head.takedamage = DAMAGE_AIM;
174                 }
175         }
176 }
177
178 entity sandbox_ObjectSpawn(float database)
179 {SELFPARAM();
180         // spawn a new object with default properties
181
182         entity e = new(object);
183         e.takedamage = DAMAGE_AIM;
184         e.damageforcescale = 1;
185         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
186         e.movetype = MOVETYPE_TOSS;
187         e.frame = 0;
188         e.skin = 0;
189         e.material = string_null;
190         settouch(e, sandbox_ObjectFunction_Touch);
191         setthink(e, sandbox_ObjectFunction_Think);
192         e.nextthink = time;
193         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
194
195         if(!database)
196         {
197                 // set the object's owner via player UID
198                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
199                 if(self.crypto_idfp != "")
200                         e.crypto_idfp = strzone(self.crypto_idfp);
201                 else
202                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
203
204                 // set public object information
205                 e.netname = strzone(self.netname); // name of the owner
206                 e.message = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // creation time
207                 e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S")); // last editing time
208
209                 // set origin and direction based on player position and view angle
210                 makevectors(self.v_angle);
211                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
212                 setorigin(e, trace_endpos);
213                 e.angles_y = self.v_angle.y;
214         }
215
216         CSQCMODEL_AUTOINIT(e);
217
218         object_count += 1;
219         return e;
220 }
221
222 void sandbox_ObjectRemove(entity e)
223 {
224         sandbox_ObjectAttach_Remove(e); // detach child objects
225
226         // if the object being removed has been selected for attachment by a player, unset it
227         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.object_attach == e, LAMBDA(it.object_attach = world));
228
229         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
230         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
231         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
232         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
233         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
234         remove(e);
235         e = world;
236
237         object_count -= 1;
238 }
239
240 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
241
242 string sandbox_ObjectPort_Save(entity e, float database)
243 {
244         // save object properties, and return them as a string
245         float i = 0;
246         string s;
247         entity head;
248
249         for(head = world; (head = find(head, classname, "object")); )
250         {
251                 // the main object needs to be first in the array [0] with attached objects following
252                 float slot, physics, solidity;
253                 if(head == e) // this is the main object, place it first
254                 {
255                         slot = 0;
256                         solidity = head.solid; // applied solidity is normal solidity for children
257                         physics = head.movetype; // applied physics are normal physics for parents
258                 }
259                 else if(head.owner == e) // child object, list them in order
260                 {
261                         i += 1; // children start from 1
262                         slot = i;
263                         solidity = head.old_solid; // persisted solidity is normal solidity for children
264                         physics = head.old_movetype; // persisted physics are normal physics for children
265                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
266                 }
267                 else
268                         continue;
269
270                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
271                 if(slot)
272                 {
273                         // properties stored only for child objects
274                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
275                 }
276                 else
277                 {
278                         // properties stored only for parent objects
279                         if(database)
280                         {
281                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
282                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
283                         }
284                 }
285                 // properties stored for all objects
286                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
287                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
288                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
289                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
290                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
291                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
292                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
293                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
294                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
295                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
296                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
297                 if(database)
298                 {
299                         // properties stored only for the database
300                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "\"\" "); // none
301                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
302                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
303                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
304                 }
305         }
306
307         // now apply the array to a simple string, with the ; symbol separating objects
308         s = "";
309         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
310         {
311                 if(port_string[i])
312                         s = strcat(s, port_string[i], "; ");
313                 port_string[i] = string_null; // fully clear the string
314         }
315
316         return s;
317 }
318
319 entity sandbox_ObjectPort_Load(string s, float database)
320 {
321         // load object properties, and spawn a new object with them
322         float n, i;
323         entity e = world, parent = world;
324
325         // separate objects between the ; symbols
326         n = tokenizebyseparator(s, "; ");
327         for(i = 0; i < n; ++i)
328                 port_string[i] = argv(i);
329
330         // now separate and apply the properties of each object
331         for(i = 0; i < n; ++i)
332         {
333                 float argv_num;
334                 string tagname = string_null;
335                 argv_num = 0;
336                 tokenize_console(port_string[i]);
337                 e = sandbox_ObjectSpawn(database);
338
339                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
340                 if(i)
341                 {
342                         // properties stored only for child objects
343                         if(argv(argv_num) != "")        tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
344                 }
345                 else
346                 {
347                         // properties stored only for parent objects
348                         if(database)
349                         {
350                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
351                                 e.angles = stov(argv(argv_num));        ++argv_num;
352                         }
353                         parent = e; // mark parent objects as such
354                 }
355                 // properties stored for all objects
356                 _setmodel(e, argv(argv_num));   ++argv_num;
357                 e.skin = stof(argv(argv_num));  ++argv_num;
358                 e.alpha = stof(argv(argv_num)); ++argv_num;
359                 e.colormod = stov(argv(argv_num));      ++argv_num;
360                 e.glowmod = stov(argv(argv_num));       ++argv_num;
361                 e.frame = stof(argv(argv_num)); ++argv_num;
362                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
363                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
364                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
365                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
366                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "")        e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
367                 if(database)
368                 {
369                         // properties stored only for the database
370                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "")        e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
371                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
372                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
373                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
374                 }
375
376                 // attach last
377                 if(i)
378                         sandbox_ObjectAttach_Set(e, parent, tagname);
379         }
380
381         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
382                 port_string[i] = string_null; // fully clear the string
383
384         return e;
385 }
386
387 void sandbox_Database_Save()
388 {
389         // saves all objects to the database file
390         entity head;
391         string file_name;
392         float file_get;
393
394         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
395         file_get = fopen(file_name, FILE_WRITE);
396         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(true, "%d-%m-%Y %H:%M:%S")));
397         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
398
399         for(head = world; (head = find(head, classname, "object")); )
400         {
401                 // attached objects are persisted separately, ignore them here
402                 if(head.owner != world)
403                         continue;
404
405                 // use a line of text for each object, listing all properties
406                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, true), "\n"));
407         }
408         fclose(file_get);
409 }
410
411 void sandbox_Database_Load()
412 {
413         // loads all objects from the database file
414         string file_read, file_name;
415         float file_get, i;
416
417         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
418         file_get = fopen(file_name, FILE_READ);
419         if(file_get < 0)
420         {
421                 if(autocvar_g_sandbox_info > 0)
422                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
423         }
424         else
425         {
426                 for (;;)
427                 {
428                         file_read = fgets(file_get);
429                         if(file_read == "")
430                                 break;
431                         if(substring(file_read, 0, 2) == "//")
432                                 continue;
433                         if(substring(file_read, 0, 1) == "#")
434                                 continue;
435
436                         entity e;
437                         e = sandbox_ObjectPort_Load(file_read, true);
438
439                         if(e.material)
440                         {
441                                 // since objects are being loaded for the first time, precache material sounds for each
442                                 for (i = 1; i <= 5; i++) // 5 sounds in total
443                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".wav"));
444                         }
445                 }
446                 if(autocvar_g_sandbox_info > 0)
447                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
448         }
449         fclose(file_get);
450 }
451
452 MUTATOR_HOOKFUNCTION(sandbox, SV_ParseClientCommand)
453 {SELFPARAM();
454         if(MUTATOR_RETURNVALUE) // command was already handled?
455                 return false;
456         if(cmd_name == "g_sandbox")
457         {
458                 if(autocvar_g_sandbox_readonly)
459                 {
460                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
461                         return true;
462                 }
463                 if(cmd_argc < 2)
464                 {
465                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
466                         return true;
467                 }
468
469                 switch(argv(1))
470                 {
471                         entity e;
472                         float i;
473                         string s;
474
475                         // ---------------- COMMAND: HELP ----------------
476                         case "help":
477                                 print_to(self, "You can use the following sandbox commands:");
478                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
479                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
480                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
481                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
482                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
483                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
484                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
485                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
486                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
487                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
488                                 print_to(self, "^3skin value ^7- changes the skin of the object");
489                                 print_to(self, "^3alpha value ^7- sets object transparency");
490                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
491                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
492                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
493                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
494                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
495                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
496                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
497                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
498                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
499                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
500                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
501                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
502                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
503                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
504                                 return true;
505
506                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
507                         case "object_spawn":
508                                 if(time < self.object_flood)
509                                 {
510                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
511                                         return true;
512                                 }
513                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
514                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
515                                 {
516                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
517                                         return true;
518                                 }
519                                 if(cmd_argc < 3)
520                                 {
521                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
522                                         return true;
523                                 }
524                                 if (!(fexists(argv(2))))
525                                 {
526                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
527                                         return true;
528                                 }
529
530                                 e = sandbox_ObjectSpawn(false);
531                                 _setmodel(e, argv(2));
532
533                                 if(autocvar_g_sandbox_info > 0)
534                                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
535                                 return true;
536
537                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
538                         case "object_remove":
539                                 e = sandbox_ObjectEdit_Get(true);
540                                 if(e != world)
541                                 {
542                                         if(autocvar_g_sandbox_info > 0)
543                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
544                                         sandbox_ObjectRemove(e);
545                                         return true;
546                                 }
547
548                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
549                                 return true;
550
551                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
552                         case "object_duplicate":
553                                 switch(argv(2))
554                                 {
555                                         case "copy":
556                                                 // copies customizable properties of the selected object to the clipboard cvar
557                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
558                                                 if(e != world)
559                                                 {
560                                                         s = sandbox_ObjectPort_Save(e, false);
561                                                         s = strreplace("\"", "\\\"", s);
562                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
563
564                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
565                                                         return true;
566                                                 }
567                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
568                                                 return true;
569
570                                         case "paste":
571                                                 // spawns a new object using the properties in the player's clipboard cvar
572                                                 if(time < self.object_flood)
573                                                 {
574                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
575                                                         return true;
576                                                 }
577                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
578                                                 if(argv(3) == "") // no object in clipboard
579                                                 {
580                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
581                                                         return true;
582                                                 }
583                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
584                                                 {
585                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
586                                                         return true;
587                                                 }
588                                                 e = sandbox_ObjectPort_Load(argv(3), false);
589
590                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
591                                                 if(autocvar_g_sandbox_info > 0)
592                                                         LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
593                                                 return true;
594                                 }
595                                 return true;
596
597                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
598                         case "object_attach":
599                                 switch(argv(2))
600                                 {
601                                         case "get":
602                                                 // select e as the object as meant to be attached
603                                                 e = sandbox_ObjectEdit_Get(true);
604                                                 if(e != world)
605                                                 {
606                                                         self.object_attach = e;
607                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
608                                                         return true;
609                                                 }
610                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
611                                                 return true;
612                                         case "set":
613                                                 if(self.object_attach == world)
614                                                 {
615                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
616                                                         return true;
617                                                 }
618
619                                                 // attaches the previously selected object to e
620                                                 e = sandbox_ObjectEdit_Get(true);
621                                                 if(e != world)
622                                                 {
623                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
624                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
625                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
626                                                         if(autocvar_g_sandbox_info > 1)
627                                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
628                                                         return true;
629                                                 }
630                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
631                                                 return true;
632                                         case "remove":
633                                                 // removes e if it was attached
634                                                 e = sandbox_ObjectEdit_Get(true);
635                                                 if(e != world)
636                                                 {
637                                                         sandbox_ObjectAttach_Remove(e);
638                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
639                                                         if(autocvar_g_sandbox_info > 1)
640                                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
641                                                         return true;
642                                                 }
643                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
644                                                 return true;
645                                 }
646                                 return true;
647
648                         // ---------------- COMMAND: OBJECT, EDIT ----------------
649                         case "object_edit":
650                                 if(argv(2) == "")
651                                 {
652                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
653                                         return true;
654                                 }
655
656                                 e = sandbox_ObjectEdit_Get(true);
657                                 if(e != world)
658                                 {
659                                         switch(argv(2))
660                                         {
661                                                 case "skin":
662                                                         e.skin = stof(argv(3));
663                                                         break;
664                                                 case "alpha":
665                                                         e.alpha = stof(argv(3));
666                                                         break;
667                                                 case "color_main":
668                                                         e.colormod = stov(argv(3));
669                                                         break;
670                                                 case "color_glow":
671                                                         e.glowmod = stov(argv(3));
672                                                         break;
673                                                 case "frame":
674                                                         e.frame = stof(argv(3));
675                                                         break;
676                                                 case "scale":
677                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
678                                                         break;
679                                                 case "solidity":
680                                                         switch(argv(3))
681                                                         {
682                                                                 case "0": // non-solid
683                                                                         e.solid = SOLID_TRIGGER;
684                                                                         break;
685                                                                 case "1": // solid
686                                                                         e.solid = SOLID_BBOX;
687                                                                         break;
688                                                                 default:
689                                                                         break;
690                                                         }
691                                                 case "physics":
692                                                         switch(argv(3))
693                                                         {
694                                                                 case "0": // static
695                                                                         e.movetype = MOVETYPE_NONE;
696                                                                         break;
697                                                                 case "1": // movable
698                                                                         e.movetype = MOVETYPE_TOSS;
699                                                                         break;
700                                                                 case "2": // physical
701                                                                         e.movetype = MOVETYPE_PHYSICS;
702                                                                         break;
703                                                                 default:
704                                                                         break;
705                                                         }
706                                                         break;
707                                                 case "force":
708                                                         e.damageforcescale = stof(argv(3));
709                                                         break;
710                                                 case "material":
711                                                         if(e.material)  strunzone(e.material);
712                                                         if(argv(3))
713                                                         {
714                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
715                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".wav"));
716                                                                 e.material = strzone(argv(3));
717                                                         }
718                                                         else
719                                                                 e.material = string_null; // no material
720                                                         break;
721                                                 default:
722                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
723                                                         return true;
724                                         }
725
726                                         // update last editing time
727                                         if(e.message2)  strunzone(e.message2);
728                                         e.message2 = strzone(strftime(true, "%d-%m-%Y %H:%M:%S"));
729
730                                         if(autocvar_g_sandbox_info > 1)
731                                                 LOG_INFO(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
732                                         return true;
733                                 }
734
735                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
736                                 return true;
737
738                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
739                         case "object_claim":
740                                 // if the player can edit an object but is not its owner, this can be used to claim that object
741                                 if(self.crypto_idfp == "")
742                                 {
743                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
744                                         return true;
745                                 }
746                                 e = sandbox_ObjectEdit_Get(true);
747                                 if(e != world)
748                                 {
749                                         // update the owner's name
750                                         // Do this before checking if you're already the owner and skipping if such, so we
751                                         // also update the player's nickname if he changed it (but has the same player UID)
752                                         if(e.netname != self.netname)
753                                         {
754                                                 if(e.netname)   strunzone(e.netname);
755                                                 e.netname = strzone(self.netname);
756                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
757                                         }
758
759                                         if(e.crypto_idfp == self.crypto_idfp)
760                                         {
761                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
762                                                 return true;
763                                         }
764
765                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
766                                         e.crypto_idfp = strzone(self.crypto_idfp);
767
768                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
769                                 }
770                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
771                                 return true;
772
773                         // ---------------- COMMAND: OBJECT, INFO ----------------
774                         case "object_info":
775                                 // prints public information about the object to the player
776                                 e = sandbox_ObjectEdit_Get(false);
777                                 if(e != world)
778                                 {
779                                         switch(argv(2))
780                                         {
781                                                 case "object":
782                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
783                                                         return true;
784                                                 case "mesh":
785                                                         s = "";
786                                                         FOR_EACH_TAG(e)
787                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
788                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
789                                                         return true;
790                                                 case "attachments":
791                                                         // this should show the same info as 'mesh' but for attachments
792                                                         s = "";
793                                                         entity head;
794                                                         i = 0;
795                                                         for(head = world; (head = find(head, classname, "object")); )
796                                                         {
797                                                                 if(head.owner == e)
798                                                                 {
799                                                                         ++i; // start from 1
800                                                                         gettaginfo(e, head.tag_index);
801                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
802                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
803                                                                 }
804                                                         }
805                                                         if(i) // object contains attachments
806                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
807                                                         else
808                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
809                                                         return true;
810                                         }
811                                 }
812                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
813                                 return true;
814
815                         // ---------------- COMMAND: DEFAULT ----------------
816                         default:
817                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
818                                 return true;
819                 }
820         }
821         return false;
822 }
823
824 MUTATOR_HOOKFUNCTION(sandbox, SV_StartFrame)
825 {
826         if(!autocvar_g_sandbox_storage_autosave)
827                 return false;
828         if(time < autosave_time)
829                 return false;
830         autosave_time = time + autocvar_g_sandbox_storage_autosave;
831
832         sandbox_Database_Save();
833
834         return true;
835 }
836 #endif