qcsrc/common/mutators/mutator/spawn_near_teammate/spawn_near_teammate.qc

   1 #ifdef IMPLEMENTATION
   2
   3 float autocvar_g_spawn_near_teammate_distance;
   4 int autocvar_g_spawn_near_teammate_ignore_spawnpoint;
   5 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
   6 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
   7 int autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health;
   8 bool autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath;
   9
  10 REGISTER_MUTATOR(spawn_near_teammate, cvar("g_spawn_near_teammate"));
  11
  12 .entity msnt_lookat;
  13
  14 .float msnt_timer;
  15 .vector msnt_deathloc;
  16
  17 .float cvar_cl_spawn_near_teammate;
  18
  19 MUTATOR_HOOKFUNCTION(spawn_near_teammate, Spawn_Score)
  20 {SELFPARAM();
  21         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && self.cvar_cl_spawn_near_teammate))
  22                 return 0;
  23
  24         spawn_spot.msnt_lookat = world;
  25
  26         if(!teamplay)
  27                 return 0;
  28
  29         RandomSelection_Init();
  30         FOREACH_CLIENT(IS_PLAYER(it) && it != self && SAME_TEAM(it, self) && !IS_DEAD(it), LAMBDA(
  31                 float l = vlen(spawn_spot.origin - it.origin);
  32                 if(l > autocvar_g_spawn_near_teammate_distance)
  33                         continue;
  34                 if(l < 48)
  35                         continue;
  36                 if(!checkpvs(spawn_spot.origin, it))
  37                         continue;
  38                 RandomSelection_Add(it, 0, string_null, 1, 1);
  39         ));
  40
  41         if(RandomSelection_chosen_ent)
  42         {
  43                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
  44                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
  45         }
  46         else if(self.team == spawn_spot.team)
  47                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
  48
  49         return 0;
  50 }
  51
  52 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerSpawn)
  53 {SELFPARAM();
  54         if(!teamplay) { return false; }
  55         // Note: when entering this, fixangle is already set.
  56         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && self.cvar_cl_spawn_near_teammate))
  57         {
  58                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
  59                         self.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
  60
  61                 entity best_mate = world;
  62                 vector best_spot = '0 0 0';
  63                 float pc = 0, best_dist = 0, dist = 0;
  64                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
  65                         if((autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health >= 0 && it.health >= autocvar_g_balance_health_regenstable) || autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health == 0)
  66                         if(!IS_DEAD(it))
  67                         if(it.msnt_timer < time)
  68                         if(SAME_TEAM(self, it))
  69                         if(time > it.spawnshieldtime) // spawn shielding
  70                         if(STAT(FROZEN, it) == 0)
  71                         if(it != self)
  72                         {
  73                                 tracebox(it.origin, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - '0 0 100', MOVE_WORLDONLY, it);
  74                                 if(trace_fraction != 1.0)
  75                                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
  76                                 {
  77                                         pc = pointcontents(trace_endpos + '0 0 1');
  78                                         if(pc == CONTENT_EMPTY)
  79                                         {
  80                                                 if(vdist(it.velocity, >, 5))
  81                                                         fixedmakevectors(vectoangles(it.velocity));
  82                                                 else
  83                                                         fixedmakevectors(it.angles);
  84
  85                                                 for(pc = 0; pc < 5; ++pc) // test 5 diffrent spots close to mate
  86                                                 {
  87                                                         switch(pc)
  88                                                         {
  89                                                                 case 0:
  90                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin + v_right * 128, MOVE_NORMAL, it);
  91                                                                         break;
  92                                                                 case 1:
  93                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_right * 128 , MOVE_NORMAL, it);
  94                                                                         break;
  95                                                                 case 2:
  96                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin + v_right * 64 - v_forward * 64, MOVE_NORMAL, it);
  97                                                                         break;
  98                                                                 case 3:
  99                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_right * 64 - v_forward * 64, MOVE_NORMAL, it);
 100                                                                         break;
 101                                                                 case 4:
 102                                                                         tracebox(it.origin , STAT(PL_MIN, NULL), STAT(PL_MAX, NULL), it.origin - v_forward * 128, MOVE_NORMAL, it);
 103                                                                         break;
 104                                                         }
 105
 106                                                         if(trace_fraction == 1.0)
 107                                                         {
 108                                                                 traceline(trace_endpos + '0 0 4', trace_endpos - '0 0 100', MOVE_NORMAL, it);
 109                                                                 if(trace_fraction != 1.0)
 110                                                                 {
 111                                                                         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 112                                                                         {
 113                                                                                 dist = vlen(trace_endpos - self.msnt_deathloc);
 114                                                                                 if(dist < best_dist || best_dist == 0)
 115                                                                                 {
 116                                                                                         best_dist = dist;
 117                                                                                         best_spot = trace_endpos;
 118                                                                                         best_mate = it;
 119                                                                                 }
 120                                                                         }
 121                                                                         else
 122                                                                         {
 123                                                                                 setorigin(self, trace_endpos);
 124                                                                                 self.angles = it.angles;
 125                                                                                 self.angles_z = 0; // never spawn tilted even if the spot says to
 126                                                                                 it.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 127                                                                                 return 0;
 128                                                                         }
 129                                                                 }
 130                                                         }
 131                                                 }
 132                                         }
 133                                 }
 134                         }
 135                 ));
 136
 137                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
 138                 if(best_dist)
 139                 {
 140                         setorigin(self, best_spot);
 141                         self.angles = best_mate.angles;
 142                         self.angles_z = 0; // never spawn tilted even if the spot says to
 143                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
 144                 }
 145         }
 146         else if(spawn_spot.msnt_lookat)
 147         {
 148                 self.angles = vectoangles(spawn_spot.msnt_lookat.origin - self.origin);
 149                 self.angles_x = -self.angles.x;
 150                 self.angles_z = 0; // never spawn tilted even if the spot says to
 151                 /*
 152                 sprint(self, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
 153                 sprint(self, "distance: ", vtos(spawn_spot.msnt_lookat.origin - self.origin), "\n");
 154                 sprint(self, "angles: ", vtos(self.angles), "\n");
 155                 */
 156         }
 157
 158         return 0;
 159 }
 160
 161 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerDies)
 162 {SELFPARAM();
 163         self.msnt_deathloc = self.origin;
 164         return 0;
 165 }
 166
 167 MUTATOR_HOOKFUNCTION(spawn_near_teammate, GetCvars)
 168 {
 169         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_spawn_near_teammate, "cl_spawn_near_teammate");
 170         return false;
 171 }
 172 #endif