Transifex autosync
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / mutators / mutator / spawn_near_teammate / sv_spawn_near_teammate.qc
1 #include "sv_spawn_near_teammate.qh"
2
3 #include <lib/float.qh>
4
5 string autocvar_g_spawn_near_teammate;
6 float autocvar_g_spawn_near_teammate_distance;
7 int autocvar_g_spawn_near_teammate_ignore_spawnpoint;
8 int autocvar_g_spawn_near_teammate_ignore_spawnpoint_max;
9 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
10 float autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
11 bool autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health;
12 bool autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath;
13
14 REGISTER_MUTATOR(spawn_near_teammate, expr_evaluate(autocvar_g_spawn_near_teammate));
15
16 .entity msnt_lookat;
17
18 .float msnt_timer;
19
20 .float cvar_cl_spawn_near_teammate;
21
22 MUTATOR_HOOKFUNCTION(spawn_near_teammate, Spawn_Score)
23 {
24         if (!teamplay) return;
25
26         entity player = M_ARGV(0, entity);
27         entity spawn_spot = M_ARGV(1, entity);
28         vector spawn_score = M_ARGV(2, vector);
29
30         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && CS(player).cvar_cl_spawn_near_teammate))
31                 return;
32
33         spawn_spot.msnt_lookat = NULL;
34
35         RandomSelection_Init();
36         FOREACH_CLIENT(IS_PLAYER(it) && it != player && SAME_TEAM(it, player) && !IS_DEAD(it), {
37                 if(vdist(spawn_spot.origin - it.origin, >, autocvar_g_spawn_near_teammate_distance))
38                         continue;
39                 if(vdist(spawn_spot.origin - it.origin, <, 48))
40                         continue;
41                 if(!checkpvs(spawn_spot.origin, it))
42                         continue;
43                 RandomSelection_AddEnt(it, 1, 1);
44         });
45
46         if(RandomSelection_chosen_ent)
47         {
48                 spawn_spot.msnt_lookat = RandomSelection_chosen_ent;
49                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_FOUND;
50         }
51         else if(player.team == spawn_spot.team)
52                 spawn_score.x += SPAWN_PRIO_NEAR_TEAMMATE_SAMETEAM; // prefer same team, if we can't find a spawn near teammate
53
54         M_ARGV(2, vector) = spawn_score;
55 }
56
57 MUTATOR_HOOKFUNCTION(spawn_near_teammate, PlayerSpawn)
58 {
59         if (!teamplay) return;
60
61         entity player = M_ARGV(0, entity);
62         entity spawn_spot = M_ARGV(1, entity);
63
64         int num_red = 0, num_blue = 0, num_yellow = 0, num_pink = 0;
65         FOREACH_CLIENT(IS_PLAYER(it),
66         {
67                 switch(it.team)
68                 {
69                         case NUM_TEAM_1: ++num_red; break;
70                         case NUM_TEAM_2: ++num_blue; break;
71                         case NUM_TEAM_3: ++num_yellow; break;
72                         case NUM_TEAM_4: ++num_pink; break;
73                 }
74         });
75
76         if(num_red == 1 || num_blue == 1 || num_yellow == 1 || num_pink == 1)
77                 return; // at least 1 team has only 1 player, let's not give the bigger team too much of an advantage!
78
79         // Note: when entering this, fixangle is already set.
80         if(autocvar_g_spawn_near_teammate_ignore_spawnpoint == 1 || (autocvar_g_spawn_near_teammate_ignore_spawnpoint == 2 && CS(player).cvar_cl_spawn_near_teammate))
81         {
82                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death)
83                         player.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay_death;
84
85                 entity best_mate = NULL;
86                 vector best_pos = '0 0 0';
87                 float best_dist2 = FLOAT_MAX;
88                 int tested = 0;
89                 FOREACH_CLIENT_RANDOM(IS_PLAYER(it), {
90                         if (autocvar_g_spawn_near_teammate_ignore_spawnpoint_max && tested >= autocvar_g_spawn_near_teammate_ignore_spawnpoint_max) break;
91
92                         if (PHYS_INPUT_BUTTON_CHAT(it)) continue;
93                         if (DIFF_TEAM(player, it)) continue;
94                         if (autocvar_g_spawn_near_teammate_ignore_spawnpoint_check_health && GetResource(it, RES_HEALTH) < autocvar_g_balance_health_regenstable) continue;
95                         if (IS_DEAD(it)) continue;
96                         if (time < it.msnt_timer) continue;
97                         if (time < it.spawnshieldtime) continue;
98                         if (weaponLocked(it)) continue;
99                         if (it == player) continue;
100
101                         tested++; // i consider a teammate to be available when he passes the checks above
102
103                         vector horiz_vel = vec2(it.velocity);
104                         // when walking slowly sideways, we assume the player wants a clear shot ahead - spawn behind him according to where he's looking
105                         // when running fast, spawn behind him according to his direction of movement to prevent colliding with the newly spawned player
106                         if (vdist(horiz_vel, >, autocvar_sv_maxspeed + 50))
107                                 fixedmakevectors(vectoangles(horiz_vel));
108                         else
109                                 fixedmakevectors(it.angles); // .angles is the angle of the model - usually/always 0 pitch
110
111                         // test different spots close to mate - trace upwards so it works on uneven surfaces
112                         // don't spawn in front of player or directly behind to avoid players shooting each other
113                         // test the potential spots in pairs (first pair is better than second and so on) but don't prefer one side
114                         RandomSelection_Init();
115                         for(int i = 0; i < 6; ++i)
116                         {
117                                 switch(i)
118                                 {
119                                         case 0:
120                                                 tracebox(it.origin, STAT(PL_MIN, player), STAT(PL_MAX, player), it.origin - v_forward * 64 + v_right * 128 + v_up * 64, MOVE_NOMONSTERS, it);
121                                                 break;
122                                         case 1:
123                                                 tracebox(it.origin, STAT(PL_MIN, player), STAT(PL_MAX, player), it.origin - v_forward * 64 - v_right * 128 + v_up * 64, MOVE_NOMONSTERS, it);
124                                                 break;
125                                         case 2:
126                                                 tracebox(it.origin, STAT(PL_MIN, player), STAT(PL_MAX, player), it.origin + v_right * 192 + v_up * 64, MOVE_NOMONSTERS, it);
127                                                 break;
128                                         case 3:
129                                                 tracebox(it.origin, STAT(PL_MIN, player), STAT(PL_MAX, player), it.origin - v_right * 192 + v_up * 64, MOVE_NOMONSTERS, it);
130                                                 break;
131                                         case 4:
132                                                 tracebox(it.origin, STAT(PL_MIN, player), STAT(PL_MAX, player), it.origin - v_forward * 128 + v_right * 64 + v_up * 64, MOVE_NOMONSTERS, it);
133                                                 break;
134                                         case 5:
135                                                 tracebox(it.origin, STAT(PL_MIN, player), STAT(PL_MAX, player), it.origin - v_forward * 128 - v_right * 64 + v_up * 64, MOVE_NOMONSTERS, it);
136                                                 break;
137                                 }
138
139                                 vector horizontal_trace_endpos = trace_endpos;
140                                 //te_lightning1(NULL, it.origin, horizontal_trace_endpos);
141                                 if (trace_fraction != 1.0) goto skip;
142
143                                 // 400 is about the height of a typical laser jump (in overkill)
144                                 // not traceline because we need space for the whole player, not just his origin
145                                 tracebox(horizontal_trace_endpos, STAT(PL_MIN, player), STAT(PL_MAX, player), horizontal_trace_endpos - '0 0 400', MOVE_NORMAL, it);
146                                 vector vectical_trace_endpos = trace_endpos;
147                                 //te_lightning1(NULL, horizontal_trace_endpos, vectical_trace_endpos);
148                                 if (trace_startsolid) goto skip; // inside another player
149                                 if (trace_fraction == 1.0) goto skip; // above void or too high
150                                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY) goto skip;
151                                 if (pointcontents(vectical_trace_endpos) != CONTENT_EMPTY) goto skip; // no lava or slime (or water which i assume would be annoying anyway)
152                                 if (tracebox_hits_trigger_hurt(horizontal_trace_endpos, STAT(PL_MIN, player), STAT(PL_MAX, player), vectical_trace_endpos)) goto skip;
153
154                                 // make sure the spawned player will have floor ahead (or at least a wall - he shouldn't fall as soon as he starts moving)
155                                 vector floor_test_start = vectical_trace_endpos + v_up * STAT(PL_MAX, player).z + v_forward * STAT(PL_MAX, player).x; // top front of player's bbox - highest point we know is not inside solid
156                                 traceline(floor_test_start, floor_test_start + v_forward * 100 - v_up * 128, MOVE_NOMONSTERS, it);
157                                 //te_beam(NULL, floor_test_start, trace_endpos);
158                                 if (trace_fraction == 1.0) goto skip;
159
160                                 if (autocvar_g_nades) {
161                                         bool nade_in_range = false;
162                                         IL_EACH(g_projectiles, it.classname == "nade",
163                                         {
164                                                 if (vdist(it.origin - vectical_trace_endpos, <, autocvar_g_nades_nade_radius)) {
165                                                         nade_in_range = true;
166                                                         goto skip;
167                                                 }
168                                         });
169                                         if (nade_in_range) goto skip;
170                                 }
171
172                                 // here, we know we found a good spot
173                                 RandomSelection_Add(it, 0, string_null, vectical_trace_endpos, 1, 1);
174                                 //te_lightning1(NULL, vectical_trace_endpos, vectical_trace_endpos + v_forward * 10);
175
176 LABEL(skip)
177                                 if (i % 2 == 1 && RandomSelection_chosen_ent)
178                                 {
179                                         if (autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
180                                         {
181                                                 float dist2 = vlen2(RandomSelection_chosen_ent.origin - player.death_origin);
182                                                 if (dist2 < best_dist2)
183                                                 {
184                                                         best_dist2 = dist2;
185                                                         best_pos = RandomSelection_chosen_vec;
186                                                         best_mate = RandomSelection_chosen_ent;
187                                                 }
188                                         }
189                                         else
190                                         {
191                                                 setorigin(player, RandomSelection_chosen_vec);
192                                                 player.angles = RandomSelection_chosen_ent.angles;
193                                                 player.angles_z = 0; // never spawn tilted even if the spot says to
194                                                 RandomSelection_chosen_ent.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
195                                                 return;
196                                         }
197                                         break; // don't test the other spots near this teammate, go to the next one
198                                 }
199                         }
200                 });
201
202                 if(autocvar_g_spawn_near_teammate_ignore_spawnpoint_closetodeath)
203                 if(best_mate)
204                 {
205                         setorigin(player, best_pos);
206                         player.angles = best_mate.angles;
207                         player.angles_z = 0; // never spawn tilted even if the spot says to
208                         best_mate.msnt_timer = time + autocvar_g_spawn_near_teammate_ignore_spawnpoint_delay;
209                 }
210         }
211         else if(spawn_spot.msnt_lookat)
212         {
213                 player.angles = vectoangles(spawn_spot.msnt_lookat.origin - player.origin);
214                 player.angles_x = -player.angles.x;
215                 player.angles_z = 0; // never spawn tilted even if the spot says to
216                 /*
217                 sprint(player, "You should be looking at ", spawn_spot.msnt_lookat.netname, "^7.\n");
218                 sprint(player, "distance: ", vtos(spawn_spot.msnt_lookat.origin - player.origin), "\n");
219                 sprint(player, "angles: ", vtos(player.angles), "\n");
220                 */
221         }
222 }
223
224 REPLICATE(cvar_cl_spawn_near_teammate, bool, "cl_spawn_near_teammate");