qcsrc/common/mutators/mutator/superspec/superspec.qc

   1 #ifdef IMPLEMENTATION
   2 REGISTER_MUTATOR(superspec, cvar("g_superspectate"));
   3
   4 #define _SSMAGIX "SUPERSPEC_OPTIONSFILE_V1"
   5 #define _ISLOCAL ((edict_num(1) == self) ? true : false)
   6
   7 const float ASF_STRENGTH                = BIT(0);
   8 const float ASF_SHIELD                  = BIT(1);
   9 const float ASF_MEGA_AR                 = BIT(2);
  10 const float ASF_MEGA_HP                 = BIT(3);
  11 const float ASF_FLAG_GRAB               = BIT(4);
  12 const float ASF_OBSERVER_ONLY   = BIT(5);
  13 const float ASF_SHOWWHAT                = BIT(6);
  14 const float ASF_SSIM                    = BIT(7);
  15 const float ASF_FOLLOWKILLER    = BIT(8);
  16 const float ASF_ALL                     = 0xFFFFFF;
  17 .float autospec_flags;
  18
  19 const float SSF_SILENT = 1;
  20 const float SSF_VERBOSE = 2;
  21 const float SSF_ITEMMSG = 4;
  22 .float superspec_flags;
  23
  24 .string superspec_itemfilter; //"classname1 classname2 ..."
  25
  26 bool superspec_Spectate(entity _player)
  27 {SELFPARAM();
  28         if(Spectate(_player) == 1)
  29             TRANSMUTE(Spectator, self);
  30
  31         return true;
  32 }
  33
  34 void superspec_save_client_conf()
  35 {SELFPARAM();
  36         string fn = "superspec-local.options";
  37         float fh;
  38
  39         if (!_ISLOCAL)
  40         {
  41                 if(self.crypto_idfp == "")
  42                         return;
  43
  44                 fn = sprintf("superspec-%s.options", uri_escape(self.crypto_idfp));
  45         }
  46
  47         fh = fopen(fn, FILE_WRITE);
  48         if(fh < 0)
  49         {
  50                 LOG_TRACE("^1ERROR: ^7 superspec can not open ", fn, " for writing.\n");
  51         }
  52         else
  53         {
  54                 fputs(fh, _SSMAGIX);
  55                 fputs(fh, "\n");
  56                 fputs(fh, ftos(self.autospec_flags));
  57                 fputs(fh, "\n");
  58                 fputs(fh, ftos(self.superspec_flags));
  59                 fputs(fh, "\n");
  60                 fputs(fh, self.superspec_itemfilter);
  61                 fputs(fh, "\n");
  62                 fclose(fh);
  63         }
  64 }
  65
  66 void superspec_msg(string _center_title, string _con_title, entity _to, string _msg, float _spamlevel)
  67 {
  68         sprint(_to, strcat(_con_title, _msg));
  69
  70         if(_to.superspec_flags & SSF_SILENT)
  71                 return;
  72
  73         if(_spamlevel > 1)
  74                 if (!(_to.superspec_flags & SSF_VERBOSE))
  75                         return;
  76
  77         centerprint(_to, strcat(_center_title, _msg));
  78 }
  79
  80 float superspec_filteritem(entity _for, entity _item)
  81 {
  82         float i;
  83
  84         if(_for.superspec_itemfilter == "")
  85                 return true;
  86
  87         if(_for.superspec_itemfilter == "")
  88                 return true;
  89
  90         float l = tokenize_console(_for.superspec_itemfilter);
  91         for(i = 0; i < l; ++i)
  92         {
  93                 if(argv(i) == _item.classname)
  94                         return true;
  95         }
  96
  97         return false;
  98 }
  99
 100 MUTATOR_HOOKFUNCTION(superspec, ItemTouch)
 101 {SELFPARAM();
 102         entity _item = self;
 103
 104         FOREACH_CLIENT(true, LAMBDA(
 105                 if(!IS_SPEC(it) && !IS_OBSERVER(it))
 106                         continue;
 107                 if(it.superspec_flags & SSF_ITEMMSG)
 108                         if(superspec_filteritem(it, _item))
 109                         {
 110                                 if(it.superspec_flags & SSF_VERBOSE)
 111                                         superspec_msg("", "", it, sprintf("Player %s^7 just picked up ^3%s\n", other.netname, _item.netname), 1);
 112                                 else
 113                                         superspec_msg("", "", it, sprintf("Player %s^7 just picked up ^3%s\n^8(%s^8)\n", other.netname, _item.netname, _item.classname), 1);
 114                                 if((it.autospec_flags & ASF_SSIM) && it.enemy != other)
 115                                 {
 116                                         WITHSELF(it, superspec_Spectate(other));
 117                                         return MUT_ITEMTOUCH_CONTINUE;
 118                                 }
 119                         }
 120
 121                 if((it.autospec_flags & ASF_SHIELD && _item.invincible_finished) ||
 122                         (it.autospec_flags & ASF_STRENGTH && _item.strength_finished) ||
 123                         (it.autospec_flags & ASF_MEGA_AR && _item.itemdef == ITEM_ArmorMega) ||
 124                         (it.autospec_flags & ASF_MEGA_HP && _item.itemdef == ITEM_HealthMega) ||
 125                         (it.autospec_flags & ASF_FLAG_GRAB && _item.classname == "item_flag_team"))
 126                 {
 127
 128                         if((it.enemy != other) || IS_OBSERVER(it))
 129                         {
 130                                 if(it.autospec_flags & ASF_OBSERVER_ONLY && !IS_OBSERVER(it))
 131                                 {
 132                                         if(it.superspec_flags & SSF_VERBOSE)
 133                                                 superspec_msg("", "", it, sprintf("^8Ignored that ^7%s^8 grabbed %s^8 since the observer_only option is ON\n", other.netname, _item.netname), 2);
 134                                 }
 135                                 else
 136                                 {
 137                                         if(it.autospec_flags & ASF_SHOWWHAT)
 138                                                 superspec_msg("", "", it, sprintf("^7Following %s^7 due to picking up %s\n", other.netname, _item.netname), 2);
 139
 140                                         WITHSELF(it, superspec_Spectate(other));
 141                                 }
 142                         }
 143                 }
 144         ));
 145
 146         return MUT_ITEMTOUCH_CONTINUE;
 147 }
 148
 149 MUTATOR_HOOKFUNCTION(superspec, SV_ParseClientCommand)
 150 {SELFPARAM();
 151 #define OPTIONINFO(flag,var,test,text,long,short) \
 152     var = strcat(var, ((flag & test) ? "^2[ON]  ^7" : "^1[OFF] ^7")); \
 153     var = strcat(var, text," ^7(^3 ", long, "^7 | ^3", short, " ^7)\n")
 154
 155         if(MUTATOR_RETURNVALUE) // command was already handled?
 156                 return false;
 157
 158         if(IS_PLAYER(self))
 159                 return false;
 160
 161         if(cmd_name == "superspec_itemfilter")
 162         {
 163                 if(argv(1) == "help")
 164                 {
 165                         string _aspeco;
 166                         _aspeco = "^7 superspec_itemfilter ^3\"item_classname1 item_classname2\"^7 only show thise items when ^2superspec ^3item_message^7 is on\n";
 167                         _aspeco = strcat(_aspeco, "^3 clear^7 Remove the filter (show all pickups)\n");
 168                         _aspeco = strcat(_aspeco, "^3 show ^7 Display current filter\n");
 169                         superspec_msg("^3superspec_itemfilter help:\n\n\n", "\n^3superspec_itemfilter help:\n", self, _aspeco, 1);
 170                 }
 171                 else if(argv(1) == "clear")
 172                 {
 173                         if(self.superspec_itemfilter != "")
 174                                 strunzone(self.superspec_itemfilter);
 175
 176                         self.superspec_itemfilter = "";
 177                 }
 178                 else if(argv(1) == "show" || argv(1) == "")
 179                 {
 180                         if(self.superspec_itemfilter == "")
 181                         {
 182                                 superspec_msg("^3superspec_itemfilter^7 is ^1not^7 set", "\n^3superspec_itemfilter^7 is ^1not^7 set\n", self, "", 1);
 183                                 return true;
 184                         }
 185                         float i;
 186                         float l = tokenize_console(self.superspec_itemfilter);
 187                         string _msg = "";
 188                         for(i = 0; i < l; ++i)
 189                                 _msg = strcat(_msg, "^3#", ftos(i), " ^7", argv(i), "\n");
 190                                 //_msg = sprintf("^3#%d^7 %s\n%s", i, _msg, argv(i));
 191
 192                         _msg = strcat(_msg,"\n");
 193
 194                         superspec_msg("^3superspec_itemfilter is:\n\n\n", "\n^3superspec_itemfilter is:\n", self, _msg, 1);
 195                 }
 196                 else
 197                 {
 198                         if(self.superspec_itemfilter != "")
 199                                 strunzone(self.superspec_itemfilter);
 200
 201                         self.superspec_itemfilter = strzone(argv(1));
 202                 }
 203
 204                 return true;
 205         }
 206
 207         if(cmd_name == "superspec")
 208         {
 209                 string _aspeco;
 210
 211                 if(cmd_argc > 1)
 212                 {
 213                         float i, _bits = 0, _start = 1;
 214                         if(argv(1) == "help")
 215                         {
 216                                 _aspeco = "use cmd superspec [option] [on|off] to set options\n\n";
 217                                 _aspeco = strcat(_aspeco, "^3 silent ^7(short^5 si^7) supresses ALL messages from superspectate.\n");
 218                                 _aspeco = strcat(_aspeco, "^3 verbose ^7(short^5 ve^7) makes superspectate print some additional information.\n");
 219                                 _aspeco = strcat(_aspeco, "^3 item_message ^7(short^5 im^7) makes superspectate print items that were picked up.\n");
 220                                 _aspeco = strcat(_aspeco, "^7    Use cmd superspec_itemfilter \"item_class1 item_class2\" to set up a filter of what to show with ^3item_message.\n");
 221                                 superspec_msg("^2Available Super Spectate ^3options:\n\n\n", "\n^2Available Super Spectate ^3options:\n", self, _aspeco, 1);
 222                                 return true;
 223                         }
 224
 225                         if(argv(1) == "clear")
 226                         {
 227                                 self.superspec_flags = 0;
 228                                 _start = 2;
 229                         }
 230
 231                         for(i = _start; i < cmd_argc; ++i)
 232                         {
 233                                 if(argv(i) == "on" || argv(i) == "1")
 234                                 {
 235                                         self.superspec_flags |= _bits;
 236                                         _bits = 0;
 237                                 }
 238                                 else if(argv(i) == "off" || argv(i) == "0")
 239                                 {
 240                                         if(_start == 1)
 241                                                 self.superspec_flags &= ~_bits;
 242
 243                                         _bits = 0;
 244                                 }
 245                                 else
 246                                 {
 247                                         if((argv(i) == "silent") || (argv(i) == "si")) _bits |= SSF_SILENT ;
 248                                         if((argv(i) == "verbose") || (argv(i) == "ve")) _bits |= SSF_VERBOSE;
 249                                         if((argv(i) == "item_message") || (argv(i) == "im")) _bits |= SSF_ITEMMSG;
 250                                 }
 251                         }
 252                 }
 253
 254                 _aspeco = "";
 255                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_SILENT, "Silent", "silent", "si");
 256                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_VERBOSE, "Verbose", "verbose", "ve");
 257                 OPTIONINFO(self.superspec_flags, _aspeco, SSF_ITEMMSG, "Item pickup messages", "item_message", "im");
 258
 259                 superspec_msg("^3Current Super Spectate options are:\n\n\n\n\n", "\n^3Current Super Spectate options are:\n", self, _aspeco, 1);
 260
 261                 return true;
 262         }
 263
 264 /////////////////////
 265
 266         if(cmd_name == "autospec")
 267         {
 268                 string _aspeco;
 269                 if(cmd_argc > 1)
 270                 {
 271                         if(argv(1) == "help")
 272                         {
 273                                 _aspeco = "use cmd autospec [option] [on|off] to set options\n\n";
 274                                 _aspeco = strcat(_aspeco, "^3 strength ^7(short^5 st^7) for automatic spectate on strength powerup\n");
 275                                 _aspeco = strcat(_aspeco, "^3 shield ^7(short^5 sh^7) for automatic spectate on shield powerup\n");
 276                                 _aspeco = strcat(_aspeco, "^3 mega_health ^7(short^5 mh^7) for automatic spectate on mega health\n");
 277                                 _aspeco = strcat(_aspeco, "^3 mega_armor ^7(short^5 ma^7) for automatic spectate on mega armor\n");
 278                                 _aspeco = strcat(_aspeco, "^3 flag_grab ^7(short^5 fg^7) for automatic spectate on CTF flag grab\n");
 279                                 _aspeco = strcat(_aspeco, "^3 observer_only ^7(short^5 oo^7) for automatic spectate only if in observer mode\n");
 280                                 _aspeco = strcat(_aspeco, "^3 show_what ^7(short^5 sw^7) to display what event triggered autospectate\n");
 281                                 _aspeco = strcat(_aspeco, "^3 item_msg ^7(short^5 im^7) to autospec when item_message in superspectate is triggered\n");
 282                                 _aspeco = strcat(_aspeco, "^3 followkiller ^7(short ^5fk^7) to autospec the killer/off\n");
 283                                 _aspeco = strcat(_aspeco, "^3 all ^7(short ^5aa^7) to turn everything on/off\n");
 284                                 superspec_msg("^2Available Auto Spectate ^3options:\n\n\n", "\n^2Available Auto Spectate ^3options:\n", self, _aspeco, 1);
 285                                 return true;
 286                         }
 287
 288                         float i, _bits = 0, _start = 1;
 289                         if(argv(1) == "clear")
 290                         {
 291                                 self.autospec_flags = 0;
 292                                 _start = 2;
 293                         }
 294
 295                         for(i = _start; i < cmd_argc; ++i)
 296                         {
 297                                 if(argv(i) == "on" || argv(i) == "1")
 298                                 {
 299                                         self.autospec_flags |= _bits;
 300                                         _bits = 0;
 301                                 }
 302                                 else if(argv(i) == "off" || argv(i) == "0")
 303                                 {
 304                                         if(_start == 1)
 305                                                 self.autospec_flags &= ~_bits;
 306
 307                                         _bits = 0;
 308                                 }
 309                                 else
 310                                 {
 311                                         if((argv(i) == "strength") || (argv(i) == "st")) _bits |= ASF_STRENGTH;
 312                                         if((argv(i) == "shield") || (argv(i) == "sh")) _bits |= ASF_SHIELD;
 313                                         if((argv(i) == "mega_health") || (argv(i) == "mh")) _bits |= ASF_MEGA_HP;
 314                                         if((argv(i) == "mega_armor") || (argv(i) == "ma")) _bits |= ASF_MEGA_AR;
 315                                         if((argv(i) == "flag_grab") || (argv(i) == "fg")) _bits |= ASF_FLAG_GRAB;
 316                                         if((argv(i) == "observer_only") || (argv(i) == "oo")) _bits |= ASF_OBSERVER_ONLY;
 317                                         if((argv(i) == "show_what") || (argv(i) == "sw")) _bits |= ASF_SHOWWHAT;
 318                                         if((argv(i) == "item_msg") || (argv(i) == "im")) _bits |= ASF_SSIM;
 319                                         if((argv(i) == "followkiller") || (argv(i) == "fk")) _bits |= ASF_FOLLOWKILLER;
 320                                         if((argv(i) == "all") || (argv(i) == "aa")) _bits |= ASF_ALL;
 321                                 }
 322                         }
 323                 }
 324
 325                 _aspeco = "";
 326                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_STRENGTH, "Strength", "strength", "st");
 327                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SHIELD, "Shield", "shield", "sh");
 328                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_MEGA_HP, "Mega Health", "mega_health", "mh");
 329                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_MEGA_AR, "Mega Armor", "mega_armor", "ma");
 330                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_FLAG_GRAB, "Flag grab", "flag_grab","fg");
 331                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_OBSERVER_ONLY, "Only switch if observer", "observer_only", "oo");
 332                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SHOWWHAT, "Show what item triggered spectate", "show_what", "sw");
 333                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_SSIM, "Switch on superspec item message", "item_msg", "im");
 334                 OPTIONINFO(self.autospec_flags, _aspeco, ASF_FOLLOWKILLER, "Followkiller", "followkiller", "fk");
 335
 336                 superspec_msg("^3Current auto spectate options are:\n\n\n\n\n", "\n^3Current auto spectate options are:\n", self, _aspeco, 1);
 337                 return true;
 338         }
 339
 340         if(cmd_name == "followpowerup")
 341         {
 342                 FOREACH_CLIENT(IS_PLAYER(it) && (it.strength_finished > time || it.invincible_finished > time), LAMBDA(return superspec_Spectate(it)));
 343
 344                 superspec_msg("", "", self, "No active powerup\n", 1);
 345                 return true;
 346         }
 347
 348         if(cmd_name == "followstrength")
 349         {
 350                 FOREACH_CLIENT(IS_PLAYER(it) && it.strength_finished > time, LAMBDA(return superspec_Spectate(it)));
 351
 352                 superspec_msg("", "", self, "No active Strength\n", 1);
 353                 return true;
 354         }
 355
 356         if(cmd_name == "followshield")
 357         {
 358                 FOREACH_CLIENT(IS_PLAYER(it) && it.invincible_finished > time, LAMBDA(return superspec_Spectate(it)));
 359
 360                 superspec_msg("", "", self, "No active Shield\n", 1);
 361                 return true;
 362         }
 363
 364         return false;
 365 #undef OPTIONINFO
 366 }
 367
 368 MUTATOR_HOOKFUNCTION(superspec, BuildMutatorsString)
 369 {
 370         ret_string = strcat(ret_string, ":SS");
 371         return 0;
 372 }
 373
 374 MUTATOR_HOOKFUNCTION(superspec, BuildMutatorsPrettyString)
 375 {
 376         ret_string = strcat(ret_string, ", Super Spectators");
 377         return 0;
 378 }
 379
 380 void superspec_hello(entity this)
 381 {
 382         if(self.enemy.crypto_idfp == "")
 383                 Send_Notification(NOTIF_ONE_ONLY, self.enemy, MSG_INFO, INFO_SUPERSPEC_MISSING_UID);
 384
 385         remove(self);
 386 }
 387
 388 MUTATOR_HOOKFUNCTION(superspec, ClientConnect)
 389 {SELFPARAM();
 390         if(!IS_REAL_CLIENT(self))
 391                 return false;
 392
 393         string fn = "superspec-local.options";
 394         float fh;
 395
 396         self.superspec_flags = SSF_VERBOSE;
 397         self.superspec_itemfilter = "";
 398
 399         entity _hello = spawn();
 400         _hello.enemy = self;
 401         setthink(_hello, superspec_hello);
 402         _hello.nextthink = time + 5;
 403
 404         if (!_ISLOCAL)
 405         {
 406                 if(self.crypto_idfp == "")
 407                         return false;
 408
 409                 fn = sprintf("superspec-%s.options", uri_escape(self.crypto_idfp));
 410         }
 411
 412         fh = fopen(fn, FILE_READ);
 413         if(fh < 0)
 414         {
 415                 LOG_TRACE("^1ERROR: ^7 superspec can not open ", fn, " for reading.\n");
 416         }
 417         else
 418         {
 419                 string _magic = fgets(fh);
 420                 if(_magic != _SSMAGIX)
 421                 {
 422                         LOG_TRACE("^1ERROR^7 While reading superspec options file: unknown magic\n");
 423                 }
 424                 else
 425                 {
 426                         self.autospec_flags = stof(fgets(fh));
 427                         self.superspec_flags = stof(fgets(fh));
 428                         self.superspec_itemfilter = strzone(fgets(fh));
 429                 }
 430                 fclose(fh);
 431         }
 432
 433         return false;
 434 }
 435
 436 MUTATOR_HOOKFUNCTION(superspec, PlayerDies)
 437 {
 438         FOREACH_CLIENT(IS_SPEC(it), LAMBDA(
 439                 if(it.autospec_flags & ASF_FOLLOWKILLER && IS_PLAYER(frag_attacker) && it.enemy == frag_target)
 440                 {
 441                         if(it.autospec_flags & ASF_SHOWWHAT)
 442                                 superspec_msg("", "", it, sprintf("^7Following %s^7 due to followkiller\n", frag_attacker.netname), 2);
 443
 444                         WITHSELF(it, superspec_Spectate(frag_attacker));
 445                 }
 446         ));
 447
 448         return false;
 449 }
 450
 451 MUTATOR_HOOKFUNCTION(superspec, ClientDisconnect)
 452 {
 453         superspec_save_client_conf();
 454         return false;
 455 }
 456 #endif