qcsrc/common/net_notice.qc

   1 #include "net_notice.qh"
   2
   3 #ifdef SVQC
   4 void sv_notice_join_think()
   5 {SELFPARAM();
   6     //NextLevel();
   7     float argc = tokenizebyseparator(autocvar_sv_join_notices, "|");
   8     if(argc > 0)
   9     {
  10         float i;
  11         for(i = argc - 1; i >= 0; --i)
  12             sv_notice_to(self.owner, argv(i), autocvar_sv_join_notices_time, false);
  13     }
  14     remove(self);
  15 }
  16
  17 void sv_notice_join()
  18 {SELFPARAM();
  19     // to-do: make sv_join_notices support per-entry times
  20     if(autocvar_sv_join_notices == "")
  21         return;
  22
  23     entity n = spawn();
  24     n.owner = self;
  25     n.think = sv_notice_join_think;
  26     n.nextthink = time + 1;
  27 }
  28
  29 void sv_notice_to(entity _to, string _notice, float _howlong, float _modal)
  30 {
  31         msg_entity = _to;
  32         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  33         WriteByte(MSG_ONE, TE_CSQC_SVNOTICE);
  34         WriteString(MSG_ONE, _notice);
  35         WriteLong(MSG_ONE, _howlong);
  36         WriteByte(MSG_ONE, _modal);
  37 }
  38
  39 void sv_notice_toall(string _notice, float _howlong, float _modal)
  40 {
  41     entity _head;
  42     FOR_EACH_REALCLIENT(_head)
  43         sv_notice_to(_head, _notice, _howlong, _modal);
  44
  45 }
  46
  47 #endif // SVQC
  48
  49 #ifdef CSQC
  50 void cl_notice_read()
  51 {
  52     //float _done;
  53     //float _modal;
  54     entity _notice = new(sv_notice);
  55     _notice.netname = strzone(ReadString());
  56     _notice.alpha = ReadLong() + time;
  57     _notice.skin = ReadByte();
  58 }
  59
  60 float cl_notice_run()
  61 {
  62     entity _notes;
  63     string _notice;
  64     float m = false;
  65
  66     _notes = findchain(classname, "sv_notice");
  67     if(!_notes)
  68         return false;
  69     #define M1 30
  70     #define M2 10
  71
  72     vector v1, v2 = '0 0 0', v3;
  73     v1 = '1 1 0' * M1;
  74     v2_x = vid_conwidth - (2 * M1);
  75     v2_y = vid_conheight - (2 * M1);
  76
  77     drawfill(v1, v2, '0 0 0', 0.5, DRAWFLAG_NORMAL);
  78     v1 = '1 1 0' * (M1 + M2);
  79     v2_x = vid_conwidth - (2 * (M1 + M2));
  80     v2_y = vid_conheight - (2 * (M1 + M2));
  81     drawfill(v1, v2, '0.5 0.5 0.5', 0.5, DRAWFLAG_NORMAL);
  82     v3 = v1 + '10 10 0';
  83
  84     #define OUT(s,z) drawcolorcodedstring(v3, s, '1 1 0' * z, 1, DRAWFLAG_NORMAL); v3_y += z + 4
  85
  86     OUT(_("^1Server notices:"), 32);
  87
  88     //drawcolorcodedstring(v1 + '5 5 0', "^1Server notices:", '32 32 0', 1, DRAWFLAG_NORMAL);
  89     while(_notes)
  90     {
  91
  92         _notice = sprintf(_("^7%s (^3%d sec left)"), _notes.netname , rint(_notes.alpha - time));
  93         OUT(_notice, 16);
  94
  95         if(_notes.skin)
  96             m = true;
  97
  98         if(_notes.alpha <= time)
  99         {
 100             _notes.think = SUB_Remove;
 101             _notes.nextthink = time;
 102         }
 103
 104         _notes = _notes.chain;
 105     }
 106
 107     #undef OUT
 108     #undef M1
 109     #undef M2
 110
 111     return m;
 112 }
 113
 114 #endif // CSQC