Fix compilation with gmqcc.
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / notifications.qc
1 // ================================================
2 //  Unified notification system, written by Samual
3 //  Last updated: August, 2013
4 // ================================================
5
6 string Get_Notif_TypeName(float net_type)
7 {
8         switch(net_type)
9         {
10                 case MSG_ANNCE: return "MSG_ANNCE";
11                 case MSG_INFO: return "MSG_INFO";
12                 case MSG_CENTER: return "MSG_CENTER";
13                 case MSG_CENTER_CPID: return "MSG_CENTER_CPID";
14                 case MSG_MULTI: return "MSG_MULTI";
15                 case MSG_CHOICE: return "MSG_CHOICE";
16         }
17         backtrace(sprintf("Get_Notif_TypeName(%d): Improper net type!\n", net_type));
18         return "";
19 }
20
21 entity Get_Notif_Ent(float net_type, float net_name)
22 {
23         switch(net_type)
24         {
25                 case MSG_ANNCE: return msg_annce_notifs[net_name - 1];
26                 case MSG_INFO: return msg_info_notifs[net_name - 1];
27                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
28                 case MSG_MULTI: return msg_multi_notifs[net_name - 1];
29                 case MSG_CHOICE: return msg_choice_notifs[net_name - 1];
30         }
31         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
32         return world;
33 }
34
35 #ifdef SVQC
36 #ifdef NOTIFICATIONS_DEBUG
37 string Get_Notif_BroadcastName(float broadcast)
38 {
39         switch(broadcast)
40         {
41                 case NOTIF_ONE: return "NOTIF_ONE";
42                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
43                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
44                 case NOTIF_ALL: return "NOTIF_ALL";
45                 case NOTIF_TEAM: return "NOTIF_TEAM";
46                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
47         }
48         backtrace(sprintf("Get_Notif_BroadcastName(%d): Improper broadcast!\n", broadcast));
49         return "";
50 }
51 #endif
52 #endif
53
54 string Notification_CheckArgs_TypeName(float net_type, float net_name)
55 {
56         // check supplied type and name for errors
57         string checkargs = "";
58         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
59                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
60                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
61         switch(net_type)
62         {
63                 CHECKARG_TYPENAME(ANNCE)
64                 CHECKARG_TYPENAME(INFO)
65                 CHECKARG_TYPENAME(CENTER)
66                 CHECKARG_TYPENAME(MULTI)
67                 CHECKARG_TYPENAME(CHOICE)
68                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
69         }
70         #undef CHECKARG_TYPENAME
71         return checkargs;
72 }
73
74 #ifdef SVQC
75 string Notification_CheckArgs(
76         float broadcast, entity client,
77         float net_type, float net_name)
78 {
79         // check supplied broadcast, target, type, and name for errors
80         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
81         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
82         switch(broadcast)
83         {
84                 case NOTIF_ONE:
85                 case NOTIF_ONE_ONLY:
86                 {
87                         if(IS_NOT_A_CLIENT(client))
88                                 { checkargs = sprintf("%sNo client provided!", checkargs); }
89                         break;
90                 }
91                 
92                 case NOTIF_ALL_EXCEPT:
93                 {
94                         if(IS_NOT_A_CLIENT(client))
95                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
96                         break;
97                 }
98                 
99                 case NOTIF_ALL:
100                 {
101                         if(client)
102                                 { checkargs = sprintf("%sEntity provided when world was required!", checkargs); }
103                         break;
104                 }
105                 
106                 case NOTIF_TEAM:
107                 {
108                         if not(teamplay)
109                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
110                         //else if not(client.team) { checkargs = sprintf("%sNo team provided!", checkargs); }
111                         break;
112                 }
113                 
114                 case NOTIF_TEAM_EXCEPT:
115                 {
116                         if not(teamplay)
117                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
118                         else if(IS_NOT_A_CLIENT(client))
119                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
120                         break;
121                 }
122                 
123                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
124         }
125         return checkargs;
126 }
127
128 float Notification_ShouldSend(float broadcast, entity to_client, entity other_client)
129 {
130         switch(broadcast)
131         {
132                 case NOTIF_ONE: // send to one client and their spectator
133                 {
134                         if(
135                                 (to_client == other_client)
136                                 ||
137                                 (
138                                         IS_SPEC(to_client)
139                                         &&
140                                         (to_client.enemy == other_client)
141                                 )
142                         ) { return TRUE; }
143                         break;
144                 }
145                 case NOTIF_ONE_ONLY: // send ONLY to one client
146                 {
147                         if(to_client == other_client) { return TRUE; }
148                         break;
149                 }
150                 case NOTIF_TEAM: // send only to X team and their spectators
151                 {
152                         if(
153                                 (to_client.team == other_client.team)
154                                 ||
155                                 (
156                                         IS_SPEC(to_client)
157                                         &&
158                                         (to_client.enemy.team == other_client.team)
159                                 )
160                         ) { return TRUE; }
161                         break;
162                 }
163                 case NOTIF_TEAM_EXCEPT: // send only to X team and their spectators, except for Y person and their spectators
164                 {
165                         if(
166                                 (to_client != other_client)
167                                 &&
168                                 (
169                                         (to_client.team == other_client.team)
170                                         ||
171                                         (
172                                                 IS_SPEC(to_client)
173                                                 &&
174                                                 (
175                                                         (to_client.enemy != other_client)
176                                                         &&
177                                                         (to_client.enemy.team == other_client.team)
178                                                 )
179                                         )
180                                 )
181                         ) { return TRUE; }
182                         break;
183                 }
184                 case NOTIF_ALL: // send to everyone
185                 {
186                         return TRUE;
187                 }
188                 case NOTIF_ALL_EXCEPT: // send to everyone except X person and their spectators
189                 {
190                         if(
191                                 (to_client != other_client)
192                                 &&
193                                 !(
194                                         IS_SPEC(to_client)
195                                         &&
196                                         (to_client.enemy == other_client)
197                                 )
198                         ) { return TRUE; }
199                         break;
200                 }
201         }
202         return FALSE;
203 }
204
205 #endif
206
207 // ===============================
208 //  Initialization Core Functions
209 // ===============================
210
211 // used by restartnotifs command to initialize notifications
212 void Destroy_Notification_Entity(entity notif)
213 {
214         if(notif.nent_name != "") { strunzone(notif.nent_name); }
215         if(notif.nent_snd != "") { strunzone(notif.nent_snd); }
216         if(notif.nent_args != "") { strunzone(notif.nent_args); }
217         if(notif.nent_hudargs != "") { strunzone(notif.nent_hudargs); }
218         if(notif.nent_icon != "") { strunzone(notif.nent_icon); }
219         if(notif.nent_durcnt != "") { strunzone(notif.nent_durcnt); }
220         if(notif.nent_string != "") { strunzone(notif.nent_string); }
221         remove(notif);
222 }
223
224 void Destroy_All_Notifications(void)
225 {
226         entity notif;
227         float i;
228         
229         #define DESTROY_LOOP(type,count) \
230                 for(i = 1; i <= count; ++i) \
231                 { \
232                         notif = Get_Notif_Ent(type, i); \
233                         if not(notif) { backtrace("Destroy_All_Notifications(): Missing notification entity!\n"); return; } \
234                         Destroy_Notification_Entity(notif); \
235                 }
236
237         // kill all networked notifications and centerprints
238         #ifdef SVQC
239         Kill_Notification(NOTIF_ALL, world, 0, 0);
240         #else
241         reset_centerprint_messages();
242         #endif
243
244         // kill all real notification entities
245         DESTROY_LOOP(MSG_ANNCE, NOTIF_ANNCE_COUNT)
246         DESTROY_LOOP(MSG_INFO, NOTIF_INFO_COUNT)
247         DESTROY_LOOP(MSG_CENTER, NOTIF_CENTER_COUNT)
248         DESTROY_LOOP(MSG_MULTI, NOTIF_MULTI_COUNT)
249         DESTROY_LOOP(MSG_CHOICE, NOTIF_CHOICE_COUNT)
250         #undef DESTROY_LOOP
251 }
252
253 string Process_Notif_Line(
254         float typeid,
255         float chat,
256         string input,
257         string notiftype,
258         string notifname,
259         string stringtype)
260 {
261         #ifdef CSQC
262         if(typeid == MSG_INFO)
263         {
264                 if((chat && autocvar_notification_allow_chatboxprint)
265                         || (autocvar_notification_allow_chatboxprint == 2))
266                 {
267                         // pass 1: add ETX char at beginning of line
268                         input = strcat("\{3}", input);
269
270                         // pass 2: add ETX char at end of each new line (so that
271                         // messages with multiple lines are put through chatbox too)
272                         input = strreplace("\n", "\n\{3}", input);
273
274                         // pass 3: strip trailing ETX char
275                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
276                                 { input = substring(input, 0, (strlen(input) - 1)); }
277                 }
278         }
279         #endif
280
281         // done to both MSG_INFO and MSG_CENTER
282         if(substring(input, (strlen(input) - 1), 1) == "\n")
283         {
284                 print(sprintf(
285                         strcat(
286                                 "^1TRAILING NEW LINE AT END OF NOTIFICATION: ",
287                                 "^7net_type = %s, net_name = %s, string = %s.\n"
288                         ),
289                         notiftype,
290                         notifname,
291                         stringtype
292                 ));
293                 notif_error = TRUE;
294                 input = substring(input, 1, (strlen(input) - 1));
295         }
296
297         return input;
298 }
299
300 string Process_Notif_Args(
301         float arg_type,
302         string args,
303         string notiftype,
304         string notifname)
305 {
306         string selected, remaining = args;
307         float sel_num = 0;
308
309         for(;(remaining != "");)
310         {
311                 selected = car(remaining); remaining = cdr(remaining);
312
313                 switch(arg_type)
314                 {
315                         case 1: // normal args
316                         {
317                                 if(sel_num == NOTIF_MAX_ARGS)
318                                 {
319                                         print(sprintf(
320                                                 strcat(
321                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
322                                                         "^7net_type = %s, net_name = %s, max args = %d.\n"
323                                                 ),
324                                                 notiftype,
325                                                 notifname,
326                                                 NOTIF_MAX_ARGS
327                                         ));
328                                         notif_error = TRUE;
329                                         break;
330                                 }
331
332                                 switch(strtolower(selected))
333                                 {
334                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { ++sel_num; break; }
335                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { ++sel_num; break; }
336                                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { ++sel_num; break; }
337                                         #define ARG_CASE_ARG_CS(selected,result)       case selected: { ++sel_num; break; }
338                                         #define ARG_CASE_ARG_SV(selected,result)       case selected: { ++sel_num; break; }
339                                         #define ARG_CASE_ARG_DC(selected,result)
340                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
341                                         NOTIF_ARGUMENT_LIST
342                                         #undef ARG_CASE
343                                         #undef ARG_CASE_ARG_DC
344                                         #undef ARG_CASE_ARG_SV
345                                         #undef ARG_CASE_ARG_CS
346                                         #undef ARG_CASE_ARG_CS_SV
347                                         #undef ARG_CASE_ARG_CS_SV_DC
348                                         #undef ARG_CASE_ARG_CS_SV_HA
349                                         default:
350                                         {
351                                                 print(sprintf(
352                                                         strcat(
353                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
354                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'.\n"
355                                                         ),
356                                                         notiftype,
357                                                         notifname,
358                                                         selected
359                                                 ));
360                                                 notif_error = TRUE;
361                                                 break;
362                                         }
363                                 }
364                                 break;
365                         }
366                         case 2: // hudargs
367                         {
368                                 if(sel_num == NOTIF_MAX_HUDARGS)
369                                 {
370                                         print(sprintf(
371                                                 strcat(
372                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
373                                                         "^7net_type = %s, net_name = %s, max hudargs = %d.\n"
374                                                 ),
375                                                 notiftype,
376                                                 notifname,
377                                                 NOTIF_MAX_HUDARGS
378                                         ));
379                                         notif_error = TRUE;
380                                         break;
381                                 }
382
383                                 switch(strtolower(selected))
384                                 {
385                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { ++sel_num; break; }
386                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
387                                         #define ARG_CASE_ARG_CS_SV(selected,result)
388                                         #define ARG_CASE_ARG_CS(selected,result)
389                                         #define ARG_CASE_ARG_SV(selected,result)
390                                         #define ARG_CASE_ARG_DC(selected,result)
391                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
392                                         NOTIF_ARGUMENT_LIST
393                                         #undef ARG_CASE
394                                         #undef ARG_CASE_ARG_DC
395                                         #undef ARG_CASE_ARG_SV
396                                         #undef ARG_CASE_ARG_CS
397                                         #undef ARG_CASE_ARG_CS_SV
398                                         #undef ARG_CASE_ARG_CS_SV_DC
399                                         #undef ARG_CASE_ARG_CS_SV_HA
400                                         default:
401                                         {
402                                                 print(sprintf(
403                                                         strcat(
404                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
405                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'.\n"
406                                                         ),
407                                                         notiftype,
408                                                         notifname,
409                                                         selected
410                                                 ));
411                                                 notif_error = TRUE;
412                                                 break;
413                                         }
414                                 }
415                                 break;
416                         }
417                         case 3: // durcnt 
418                         {
419                                 if(sel_num == NOTIF_MAX_DURCNT)
420                                 {
421                                         print(sprintf(
422                                                 strcat(
423                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
424                                                         "^7net_type = %s, net_name = %s, max durcnt = %d.\n"
425                                                 ),
426                                                 notiftype,
427                                                 notifname,
428                                                 NOTIF_MAX_DURCNT
429                                         ));
430                                         notif_error = TRUE;
431                                         break;
432                                 }
433
434                                 switch(strtolower(selected))
435                                 {
436                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
437                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { ++sel_num; break; }
438                                         #define ARG_CASE_ARG_CS_SV(selected,result)
439                                         #define ARG_CASE_ARG_CS(selected,result)
440                                         #define ARG_CASE_ARG_SV(selected,result)
441                                         #define ARG_CASE_ARG_DC(selected,result)       case selected: { ++sel_num; break; }
442                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
443                                         NOTIF_ARGUMENT_LIST
444                                         #undef ARG_CASE
445                                         #undef ARG_CASE_ARG_DC
446                                         #undef ARG_CASE_ARG_SV
447                                         #undef ARG_CASE_ARG_CS
448                                         #undef ARG_CASE_ARG_CS_SV
449                                         #undef ARG_CASE_ARG_CS_SV_DC
450                                         #undef ARG_CASE_ARG_CS_SV_HA
451                                         default:
452                                         {
453                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
454                                                 else
455                                                 {
456                                                         print(sprintf(
457                                                                 strcat(
458                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
459                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'.\n"
460                                                                 ),
461                                                                 notiftype,
462                                                                 notifname,
463                                                                 selected
464                                                         ));
465                                                         notif_error = TRUE;
466                                                 }
467                                                 break;
468                                         }
469                                 }
470                                 break;
471                         }
472                 }
473         }
474         return args;
475 }
476
477 void Create_Notification_Entity(
478         float var_default,
479         float var_cvar,
480         float typeid,
481         float nameid,
482         string namestring,
483         float strnum,
484         float flnum,
485         /* MSG_ANNCE */
486         float channel, 
487         string snd,
488         float vol,
489         float position,
490         /* MSG_INFO & MSG_CENTER */
491         string args,
492         string hudargs,
493         string icon,
494         float cpid,
495         string durcnt,
496         string normal,
497         string gentle,
498         /* MSG_MULTI */
499         float anncename,
500         float infoname,
501         float centername,
502         /* MSG_CHOICE */
503         float challow_def,
504         float challow_var,
505         float chtype,
506         float optiona,
507         float optionb)
508 {
509         // =====================
510         //  Global Entity Setup
511         // =====================
512         entity notif = spawn();
513         switch(typeid)
514         {
515                 case MSG_ANNCE:
516                 {
517                         msg_annce_notifs[nameid - 1] = notif;
518                         notif.classname = "msg_annce_notification";
519                         break;
520                 }
521                 case MSG_INFO:
522                 {
523                         msg_info_notifs[nameid - 1] = notif;
524                         notif.classname = "msg_info_notification";
525                         break;
526                 }
527                 case MSG_CENTER:
528                 {
529                         msg_center_notifs[nameid - 1] = notif;
530                         notif.classname = "msg_center_notification";
531                         break;
532                 }
533                 case MSG_MULTI:
534                 {
535                         msg_multi_notifs[nameid - 1] = notif;
536                         notif.classname = "msg_multi_notification";
537                         break;
538                 }
539                 case MSG_CHOICE:
540                 {
541                         msg_choice_notifs[nameid - 1] = notif;
542                         notif.classname = "msg_choice_notification";
543                         break;
544                 }
545
546                 default:
547                 {
548                         error(sprintf(
549                                 strcat(
550                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
551                                         "^7net_type = %d, net_name = %s.\n"
552                                 ),
553                                 typeid,
554                                 namestring
555                         ));
556                         return; // It's not possible to recover from this one
557                 }
558         }
559         notif.nent_default = var_default;
560         notif.nent_enabled = (1 <= var_cvar);
561         notif.nent_type = typeid;
562         notif.nent_id = nameid;
563         notif.nent_name = strzone(namestring);
564         
565         string typestring = Get_Notif_TypeName(typeid);
566
567         // Other pre-notif-setup requisites
568         notif_error = FALSE;
569
570         // ====================
571         //  Notification Setup
572         // ====================
573         switch(typeid)
574         {
575                 case MSG_ANNCE:
576                 {
577                         // Set MSG_ANNCE information and handle precaching
578                         #ifdef CSQC
579                         if not(GENTLE && (var_cvar == 1))
580                         {
581                                 if(snd != "")
582                                 {
583                                         if(notif.nent_enabled)
584                                         {
585                                                 precache_sound(sprintf("announcer/%s/%s.wav", autocvar_cl_announcer, snd));
586                                                 notif.nent_channel = channel;
587                                                 notif.nent_snd = strzone(snd);
588                                                 notif.nent_vol = vol;
589                                                 notif.nent_position = position;
590                                         }
591                                 }
592                                 else
593                                 {
594                                         print(sprintf(
595                                                 strcat(
596                                                         "^1NOTIFICATION WITH NO SOUND: ",
597                                                         "^7net_type = %s, net_name = %s.\n"
598                                                 ),
599                                                 typestring,
600                                                 namestring
601                                         ));
602                                         notif_error = TRUE;
603                                 }
604                         }
605                         else { notif.nent_enabled = FALSE; }
606                         #else
607                         notif.nent_enabled = FALSE;
608                         #endif
609
610                         break;
611                 }
612                 
613                 case MSG_INFO:
614                 case MSG_CENTER:
615                 {
616                         // Set MSG_INFO and MSG_CENTER string/float counts
617                         notif.nent_stringcount = strnum;
618                         notif.nent_floatcount = flnum;
619
620                         // Only initialize arguments if we're either a client or on a dedicated server
621                         #ifdef SVQC
622                         float should_process_args = server_is_dedicated;
623                         #else
624                         float should_process_args = TRUE;
625                         #endif
626
627                         if(should_process_args)
628                         {
629                                 // ========================
630                                 //  Process Main Arguments
631                                 // ========================
632                                 if(strnum + flnum)
633                                 {
634                                         if(args != "")
635                                         {
636                                                 notif.nent_args = strzone(
637                                                         Process_Notif_Args(1, args, typestring, namestring));
638                                         }
639                                         else if((hudargs == "") && (durcnt ==""))
640                                         {
641                                                 print(sprintf(
642                                                         strcat(
643                                                                 "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: ",
644                                                                 "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d\n"
645                                                         ),
646                                                         typestring,
647                                                         namestring,
648                                                         strnum,
649                                                         flnum
650                                                 ));
651                                                 notif_error = TRUE;
652                                         }
653                                 }
654                                 else if(args != "")
655                                 {
656                                         notif.nent_args = strzone(
657                                                 Process_Notif_Args(1, args, typestring, namestring));
658                                 }
659
660
661                                 // =======================================
662                                 //  Process HUD and Centerprint Arguments
663                                 //    Only processed on CSQC, as these
664                                 //    args are only for HUD features.
665                                 // =======================================
666                                 #ifdef CSQC
667                                 if(hudargs != "")
668                                 {
669                                         notif.nent_hudargs = strzone(
670                                                 Process_Notif_Args(2, hudargs, typestring, namestring));
671                                                 
672                                         if(icon != "") { notif.nent_icon = strzone(icon); }
673                                         else
674                                         {
675                                                 print(sprintf(
676                                                         strcat(
677                                                                 "^1NOTIFICATION HAS HUDARGS BUT NO ICON: ",
678                                                                 "^7net_type = %s, net_name = %s.\n"
679                                                         ),
680                                                         typestring,
681                                                         namestring
682                                                 ));
683                                                 notif_error = TRUE;
684                                         }
685                                 }
686                                 else if(icon != "")
687                                 {
688                                         print(sprintf(
689                                                 strcat(
690                                                         "^1NOTIFICATION HAS ICON BUT NO HUDARGS: ",
691                                                         "^7net_type = %s, net_name = %s.\n"
692                                                 ),
693                                                 typestring,
694                                                 namestring
695                                         ));
696                                         notif_error = TRUE;
697                                 }
698
699                                 if(durcnt != "")
700                                 {
701                                         notif.nent_durcnt = strzone(
702                                                 Process_Notif_Args(3, durcnt, typestring, namestring));
703                                                 
704                                         if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
705                                         else
706                                         {
707                                                 print(sprintf(
708                                                         strcat(
709                                                                 "^1NOTIFICATION HAS DURCNT BUT NO CPID: ",
710                                                                 "^7net_type = %s, net_name = %s.\n"
711                                                         ),
712                                                         typestring,
713                                                         namestring
714                                                 ));
715                                                 notif_error = TRUE;
716                                         }
717                                 } 
718                                 else if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
719                                 #endif
720
721
722                                 // ======================
723                                 //  Process Notif String
724                                 // ======================
725                                 #define SET_NOTIF_STRING(string,stringname) \
726                                         notif.nent_string = strzone(CCR( \
727                                                 Process_Notif_Line( \
728                                                         typeid, \
729                                                         (var_cvar > 1), \
730                                                         string, \
731                                                         typestring, \
732                                                         namestring, \
733                                                         stringname \
734                                                 )) \
735                                         );
736
737                                 if(GENTLE)
738                                 {
739                                         if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE") }
740                                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL") }
741                                 }
742                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL") }
743                                 
744                                 #undef SET_NOTIF_STRING
745
746                                 // Check to make sure a string was chosen
747                                 if(notif.nent_string == "")
748                                 {
749                                         print(sprintf(
750                                                 strcat(
751                                                         "^1EMPTY NOTIFICATION: ",
752                                                         "^7net_type = %s, net_name = %s.\n"
753                                                 ),
754                                                 typestring,
755                                                 namestring
756                                         ));
757                                         notif_error = TRUE;
758                                 }
759                         }
760
761                         break;
762                 }
763
764                 case MSG_MULTI:
765                 {
766                         // Set MSG_MULTI string/float counts
767                         if((anncename == NO_MSG) && (infoname == NO_MSG) && (centername == NO_MSG))
768                         {
769                                 print(sprintf(
770                                         strcat(
771                                                 "^1NOTIFICATION WITH NO SUBCALLS: ",
772                                                 "^7net_type = %s, net_name = %s.\n"
773                                         ),
774                                         typestring,
775                                         namestring
776                                 ));
777                                 notif_error = TRUE;
778                         }
779                         else
780                         {
781                                 // announcements don't actually need any arguments, so lets not even count them.
782                                 if(anncename != NO_MSG) { notif.nent_msgannce = msg_annce_notifs[anncename - 1]; }
783                                 
784                                 float infoname_stringcount = 0, infoname_floatcount = 0;
785                                 float centername_stringcount = 0, centername_floatcount = 0;
786                                 
787                                 if(infoname != NO_MSG)
788                                 {
789                                         notif.nent_msginfo = msg_info_notifs[infoname - 1];
790                                         infoname_stringcount = notif.nent_msginfo.nent_stringcount;
791                                         infoname_floatcount = notif.nent_msginfo.nent_floatcount;
792                                 }
793                                 
794                                 if(centername != NO_MSG)
795                                 {
796                                         notif.nent_msgcenter = msg_center_notifs[centername - 1];
797                                         centername_stringcount = notif.nent_msgcenter.nent_stringcount;
798                                         centername_floatcount = notif.nent_msgcenter.nent_floatcount;
799                                 }
800                                 
801                                 // set the requirements of THIS notification to the totals of its subcalls
802                                 notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
803                                 notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
804                         }
805                         
806                         break;
807                 }
808
809                 case MSG_CHOICE:
810                 {
811                         if((chtype == NO_MSG) || (optiona == NO_MSG) || (optionb == NO_MSG))
812                         {
813                                 print(sprintf(
814                                         strcat(
815                                                 "^1NOTIFICATION IS MISSING CHOICE PARAMS: ",
816                                                 "^7net_type = %s, net_name = %s.\n"
817                                         ),
818                                         typestring,
819                                         namestring
820                                 ));
821                                 notif_error = TRUE;
822                         }
823                         else
824                         {
825                                 switch(chtype)
826                                 {
827                                         case MSG_ANNCE:
828                                         {
829                                                 notif.nent_optiona = msg_annce_notifs[optiona - 1];
830                                                 notif.nent_optionb = msg_annce_notifs[optionb - 1];
831                                                 break;
832                                         }
833                                         case MSG_INFO:
834                                         {
835                                                 notif.nent_optiona = msg_info_notifs[optiona - 1];
836                                                 notif.nent_optionb = msg_info_notifs[optionb - 1];
837                                                 break;
838                                         }
839                                         case MSG_CENTER:
840                                         {
841                                                 notif.nent_optiona = msg_center_notifs[optiona - 1];
842                                                 notif.nent_optionb = msg_center_notifs[optionb - 1];
843                                                 break;
844                                         }
845                                         case MSG_MULTI:
846                                         {
847                                                 notif.nent_optiona = msg_multi_notifs[optiona - 1];
848                                                 notif.nent_optionb = msg_multi_notifs[optionb - 1];
849                                                 break;
850                                         }
851                                         case MSG_CHOICE: // should we REALLY allow nested options?... 
852                                         {
853                                                 notif.nent_optiona = msg_choice_notifs[optiona - 1];
854                                                 notif.nent_optionb = msg_choice_notifs[optionb - 1];
855                                                 break;
856                                         }
857
858                                         default:
859                                         {
860                                                 print(sprintf(
861                                                         strcat(
862                                                                 "^1NOTIFICATION WITH IMPROPER TYPE: ",
863                                                                 "^7net_type = %d, net_name = %s.\n"
864                                                         ),
865                                                         typeid,
866                                                         namestring
867                                                 ));
868                                                 notif_error = TRUE;
869                                                 break;
870                                         }
871                                 }
872                                 notif.nent_challow_def = challow_def; // 0: never allowed, 1: allowed in warmup, 2: always allowed
873                                 notif.nent_challow_var = challow_var; // 0: never allowed, 1: allowed in warmup, 2: always allowed
874                                 notif.nent_stringcount = max(notif.nent_optiona.nent_stringcount, notif.nent_optionb.nent_stringcount);
875                                 notif.nent_floatcount = max(notif.nent_optiona.nent_floatcount, notif.nent_optionb.nent_floatcount);
876                                 
877                                 /*#ifdef NOTIFICATIONS_DEBUG
878                                 Debug_Notification(sprintf(
879                                         "Create_Notification_Entity(...): MSG_CHOICE: %s\n%s\n%s\n",
880                                         notif.nent_name,
881                                         sprintf(
882                                                 "^ optiona: %s %s : %d %d",
883                                                 Get_Notif_TypeName(notif.nent_optiona.nent_type),
884                                                 notif.nent_optiona.nent_name,
885                                                 notif.nent_optiona.nent_stringcount,
886                                                 notif.nent_optiona.nent_floatcount
887                                         ),
888                                         sprintf(
889                                                 "^ optionb: %s %s : %d %d",
890                                                 Get_Notif_TypeName(notif.nent_optionb.nent_type),
891                                                 notif.nent_optionb.nent_name,
892                                                 notif.nent_optionb.nent_stringcount,
893                                                 notif.nent_optionb.nent_floatcount
894                                         )
895                                 ));
896                                 #endif*/
897                         }
898                         break;
899                 }
900                 
901                 default:
902                 {
903                         print(sprintf(
904                                 strcat(
905                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
906                                         "^7net_type = %d, net_name = %s.\n"
907                                 ),
908                                 typeid,
909                                 namestring
910                         ));
911                         notif_error = TRUE;
912                         break;
913                 }
914         }
915
916         // now check to see if any errors happened 
917         if(notif_error)
918         {
919                 notif.nent_enabled = FALSE; // disable the notification so it can't cause trouble
920                 notif_global_error = TRUE; // throw the red flag that an error happened on init
921         }
922 }
923
924
925 // ===============
926 //  Cvar Handling
927 // ===============
928
929 // used by MSG_CHOICE to build list of choices
930 #ifdef SVQC
931 void Notification_GetCvars(void)
932 {
933         float i;
934         for(i = 0; i <= NOTIF_CHOICE_COUNT; ++i)
935         {
936                 GetCvars_handleFloat(
937                         get_cvars_s,
938                         get_cvars_f,
939                         msg_choice_choices[i],
940                         sprintf("notification_%s", msg_choice_notifs[i].nent_name)
941                 );
942         }
943 }
944 #endif
945
946 // used to output notifications.cfg file
947 void Dump_Notifications(float fh, float alsoprint)
948 {
949         #define NOTIF_WRITE(a) { \
950                 fputs(fh, a); \
951                 if(alsoprint) { print(a); } }
952         #define NOTIF_WRITE_ENTITY(description) { \
953                 notif_msg = \
954                         sprintf( \
955                                 "seta notification_%s \"%d\" \"%s\"\n", \
956                                 e.nent_name, e.nent_default, description \
957                         ); \
958                 NOTIF_WRITE(notif_msg) }
959         #define NOTIF_WRITE_ENTITY_CHOICE(descriptiona,descriptionb) { \
960                 notif_msg = \
961                         sprintf( \
962                                 "seta notification_%s \"%d\" \"%s\"\n" \
963                                 "seta notification_%s_ALLOWED \"%d\" \"%s\"\n", \
964                                 e.nent_name, e.nent_default, descriptiona, \
965                                 e.nent_name, e.nent_challow_def, descriptionb \
966                         ); \
967                 NOTIF_WRITE(notif_msg) }
968         #define NOTIF_WRITE_HARDCODED(cvar,default,description) { \
969                 notif_msg = \
970                         sprintf( \
971                                 "seta notification_%s \"%s\" \"%s\"\n", \
972                                 cvar, default, description \
973                         ); \
974                 NOTIF_WRITE(notif_msg) }
975
976         string notif_msg;
977         float i;
978         entity e;
979
980         // Note: This warning only applies to the notifications.cfg file that is output...
981
982         // You ARE supposed to manually edit this function to add i.e. hard coded
983         // notification variables for mutators or game modes or such and then
984         // regenerate the notifications.cfg file from the new code.
985
986         NOTIF_WRITE("// ********************************************** //\n");
987         NOTIF_WRITE("// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n");
988         NOTIF_WRITE("// **                                          ** //\n");
989         NOTIF_WRITE("// **  This file is automatically generated    ** //\n");
990         NOTIF_WRITE("// **  by code with the command 'dumpnotifs'.  ** //\n");
991         NOTIF_WRITE("// **                                          ** //\n");
992         NOTIF_WRITE("// **  If you add a new notification, please   ** //\n");
993         NOTIF_WRITE("// **  regenerate this file with that command  ** //\n");
994         NOTIF_WRITE("// **  making sure that the output matches     ** //\n");
995         NOTIF_WRITE("// **  with the lists and defaults in code.    ** //\n");
996         NOTIF_WRITE("// **                                          ** //\n");
997         NOTIF_WRITE("// ********************************************** //\n");
998
999         // These notifications will also append their string as a comment...
1000         // This is not necessary, and does not matter if they vary between config versions,
1001         // it is just a semi-helpful tool for those who want to manually change their user settings.
1002
1003         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications (count = %d):\n", NOTIF_ANNCE_COUNT));
1004         for(i = 1; i <= NOTIF_ANNCE_COUNT; ++i)
1005         {
1006                 e = Get_Notif_Ent(MSG_ANNCE, i);
1007                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1008                 
1009                 NOTIF_WRITE_ENTITY(
1010                         "Notification control cvar: 0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled)"
1011                 );
1012         }
1013
1014         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
1015         for(i = 1; i <= NOTIF_INFO_COUNT; ++i)
1016         {
1017                 e = Get_Notif_Ent(MSG_INFO, i);
1018                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1019                 
1020                 NOTIF_WRITE_ENTITY(
1021                         "Notification control cvar: 0 = off, 1 = print to console, "
1022                         "2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)"
1023                 );
1024         }
1025
1026         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
1027         for(i = 1; i <= NOTIF_CENTER_COUNT; ++i)
1028         {
1029                 e = Get_Notif_Ent(MSG_CENTER, i);
1030                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1031                 
1032                 NOTIF_WRITE_ENTITY(
1033                         "Notification control cvar: 0 = off, 1 = centerprint"
1034                 );
1035         }
1036
1037         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications (count = %d):\n", NOTIF_MULTI_COUNT));
1038         for(i = 1; i <= NOTIF_MULTI_COUNT; ++i)
1039         {
1040                 e = Get_Notif_Ent(MSG_MULTI, i);
1041                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1042                 
1043                 NOTIF_WRITE_ENTITY(
1044                         "Notification control cvar: 0 = off, 1 = trigger subcalls"
1045                 );
1046         }
1047
1048         NOTIF_WRITE(sprintf("\n// MSG_CHOICE notifications (count = %d):\n", NOTIF_CHOICE_COUNT));
1049         for(i = 1; i <= NOTIF_CHOICE_COUNT; ++i)
1050         {
1051                 e = Get_Notif_Ent(MSG_CHOICE, i);
1052                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1053                 
1054                 NOTIF_WRITE_ENTITY_CHOICE(
1055                         "Notification control cvar: 0 = off, 1 = trigger option A subcall, 2 = trigger option B subcall",
1056                         "Notification control cvar: 0 = off, 1 = allowed in warmup mode, 2 = always allowed"
1057                 );
1058         }
1059
1060         // edit these to match whichever cvars are used for specific notification options
1061         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
1062         
1063         NOTIF_WRITE_HARDCODED(
1064                 "allow_chatboxprint", "1",
1065                 "Allow notifications to be printed to chat box by setting notification cvar to 2 "
1066                 "(You can also set this cvar to 2 to force ALL notifications to be printed to the chatbox)"
1067         );
1068         
1069         NOTIF_WRITE_HARDCODED(
1070                 "debug", "0",
1071                 "Print extra debug information on all notification function calls "
1072                 "(Requires -DNOTIFICATIONS_DEBUG flag to be enabled on QCSRC compilation)... "
1073                 "0 = disabled, 1 = dprint, 2 = print"
1074         );
1075         
1076         NOTIF_WRITE_HARDCODED(
1077                 "errors_are_fatal", "1",
1078                 "If a notification fails upon initialization, cause a Host_Error to stop the program"
1079         );
1080         
1081         NOTIF_WRITE_HARDCODED(
1082                 "item_centerprinttime", "1.5",
1083                 "How long to show item information centerprint messages (like 'You got the Electro' or such)"
1084         );
1085         
1086         NOTIF_WRITE_HARDCODED(
1087                 "lifetime_mapload", "10",
1088                 "Amount of time that notification entities last immediately at mapload (in seconds) "
1089                 "to help prevent notifications from being lost on early init (like gamestart countdown)"
1090         );
1091         
1092         NOTIF_WRITE_HARDCODED(
1093                 "lifetime_runtime", "0.5",
1094                 "Amount of time that notification entities last on the server during runtime (In seconds)"
1095         );
1096         
1097         NOTIF_WRITE_HARDCODED(
1098                 "server_allows_location", "1",
1099                 "Server side cvar for allowing death messages to show location information too"
1100         );
1101         
1102         NOTIF_WRITE_HARDCODED(
1103                 "show_location", "0",
1104                 "Append location information to MSG_INFO death/kill messages"
1105         );
1106         
1107         NOTIF_WRITE_HARDCODED(
1108                 "show_location_string", "",
1109                 "Replacement string piped into sprintf, "
1110                 "so you can do different messages like this: ' at the %s' or ' (near %s)'"
1111         );
1112         
1113         NOTIF_WRITE_HARDCODED(
1114                 "show_sprees", "1",
1115                 "Print information about sprees in death/kill messages"
1116         );
1117         
1118         NOTIF_WRITE_HARDCODED(
1119                 "show_sprees_center", "1",
1120                 "Show spree information in MSG_CENTER messages... "
1121                 "0 = off, 1 = target (but only for first victim) and attacker"
1122         );
1123         
1124         NOTIF_WRITE_HARDCODED(
1125                 "show_sprees_center_specialonly", "1",
1126                 "Don't show spree information in MSG_CENTER messages if it isn't an achievement"
1127         );
1128         
1129         NOTIF_WRITE_HARDCODED(
1130                 "show_sprees_info", "3",
1131                 "Show spree information in MSG_INFO messages... "
1132                 "0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker"
1133         );
1134         
1135         NOTIF_WRITE_HARDCODED(
1136                 "show_sprees_info_newline", "1",
1137                 "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself"
1138         );
1139         
1140         NOTIF_WRITE_HARDCODED(
1141                 "show_sprees_info_specialonly", "1",
1142                 "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement"
1143         );
1144
1145         NOTIF_WRITE(sprintf(
1146                 strcat(
1147                         "\n// Notification counts (total = %d): ",
1148                         "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
1149                 ),
1150                 (
1151                         NOTIF_ANNCE_COUNT +
1152                         NOTIF_INFO_COUNT +
1153                         NOTIF_CENTER_COUNT +
1154                         NOTIF_MULTI_COUNT +
1155                         NOTIF_CHOICE_COUNT
1156                 ),
1157                 NOTIF_ANNCE_COUNT,
1158                 NOTIF_INFO_COUNT,
1159                 NOTIF_CENTER_COUNT,
1160                 NOTIF_MULTI_COUNT,
1161                 NOTIF_CHOICE_COUNT
1162         ));
1163         
1164         return;
1165         #undef NOTIF_WRITE_HARDCODED
1166         #undef NOTIF_WRITE_ENTITY
1167         #undef NOTIF_WRITE
1168 }
1169
1170
1171 // ===============================
1172 //  Frontend Notification Pushing
1173 // ===============================
1174
1175 #ifdef NOTIFICATIONS_DEBUG
1176 void Debug_Notification(string input)
1177 {
1178         switch(autocvar_notification_debug)
1179         {
1180                 case 1: { dprint(input); break; }
1181                 case 2: { print(input); break; }
1182         }
1183 }
1184 #endif
1185
1186 string Local_Notification_sprintf(
1187         string input, string args, 
1188         string s1, string s2, string s3, string s4,
1189         float f1, float f2, float f3, float f4)
1190 {
1191         #ifdef NOTIFICATIONS_DEBUG
1192         Debug_Notification(sprintf(
1193                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
1194                 MakeConsoleSafe(input),
1195                 args,
1196                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1197                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1198         ));
1199         #endif
1200         
1201         string selected;
1202         float sel_num;
1203         for(sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
1204
1205         string tmp_s;
1206
1207         for(sel_num = 0;(args != "");)
1208         {
1209                 selected = car(args); args = cdr(args);
1210                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1211                 switch(strtolower(selected))
1212                 {
1213                         #ifdef CSQC
1214                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1215                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1216                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1217                         #define ARG_CASE_ARG_CS(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1218                         #define ARG_CASE_ARG_SV(selected,result)
1219                         #define ARG_CASE_ARG_DC(selected,result)
1220                         #else
1221                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1222                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1223                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1224                         #define ARG_CASE_ARG_CS(selected,result)
1225                         #define ARG_CASE_ARG_SV(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1226                         #define ARG_CASE_ARG_DC(selected,result)
1227                         #endif
1228                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1229                         NOTIF_ARGUMENT_LIST
1230                         #undef ARG_CASE
1231                         #undef ARG_CASE_ARG_DC
1232                         #undef ARG_CASE_ARG_SV
1233                         #undef ARG_CASE_ARG_CS
1234                         #undef ARG_CASE_ARG_CS_SV
1235                         #undef ARG_CASE_ARG_CS_SV_DC
1236                         #undef ARG_CASE_ARG_CS_SV_HA
1237                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1238                 }
1239         }
1240         return sprintf(
1241                 strcat(input, "\n"),
1242                 arg_slot[0],
1243                 arg_slot[1],
1244                 arg_slot[2],
1245                 arg_slot[3],
1246                 arg_slot[4],
1247                 arg_slot[5],
1248                 arg_slot[6]
1249         );
1250 }
1251
1252 #ifdef CSQC
1253 void Local_Notification_sound(
1254         float soundchannel, string soundfile,
1255         float soundvolume, float soundposition)
1256 {
1257         if((soundfile != prev_soundfile) || (time >= (prev_soundtime + autocvar_cl_announcer_antispam)))
1258         {
1259                 #ifdef NOTIFICATIONS_DEBUG
1260                 Debug_Notification(sprintf(
1261                         "Local_Notification_sound(world, %f, '%s', %f, %f);\n",
1262                         soundchannel,
1263                         sprintf(
1264                                 "announcer/%s/%s.wav",
1265                                 autocvar_cl_announcer,
1266                                 soundfile
1267                         ),
1268                         soundvolume,
1269                         soundposition
1270                 ));
1271                 #endif
1272                 
1273                 sound(
1274                         world,
1275                         soundchannel,
1276                         sprintf(
1277                                 "announcer/%s/%s.wav",
1278                                 autocvar_cl_announcer,
1279                                 soundfile
1280                         ),
1281                         soundvolume,
1282                         soundposition
1283                 );
1284                 
1285                 if(prev_soundfile) { strunzone(prev_soundfile); }
1286                 prev_soundfile = strzone(soundfile);
1287                 prev_soundtime = time;
1288         }
1289         else
1290         {
1291                 #ifdef NOTIFICATIONS_DEBUG
1292                 Debug_Notification(sprintf(
1293                         strcat(
1294                                 "Local_Notification_sound(world, %f, '%s', %f, %f) ",
1295                                 "^1BLOCKED BY ANTISPAM:^7 prevsnd: '%s', timediff: %f, limit: %f\n"
1296                          ),
1297                         soundchannel,
1298                         sprintf(
1299                                 "announcer/%s/%s.wav",
1300                                 autocvar_cl_announcer,
1301                                 soundfile
1302                         ),
1303                         soundvolume,
1304                         soundposition,
1305                         prev_soundfile,
1306                         (time - prev_soundtime),
1307                         autocvar_cl_announcer_antispam
1308                 ));
1309                 #endif
1310         }
1311 }
1312
1313 void Local_Notification_HUD_Notify_Push(
1314         string icon, string hudargs,
1315         string s1, string s2, string s3, string s4)
1316 {
1317         string selected;
1318         float sel_num;
1319         arg_slot[0] = ""; arg_slot[1] = "";
1320
1321         for(sel_num = 0;(hudargs != "");)
1322         {
1323                 selected = car(hudargs); hudargs = cdr(hudargs);
1324                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1325                 switch(strtolower(selected))
1326                 {
1327                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1328                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
1329                         #define ARG_CASE_ARG_CS_SV(selected,result)
1330                         #define ARG_CASE_ARG_CS(selected,result)
1331                         #define ARG_CASE_ARG_SV(selected,result)
1332                         #define ARG_CASE_ARG_DC(selected,result)
1333                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1334                         NOTIF_ARGUMENT_LIST
1335                         #undef ARG_CASE
1336                         #undef ARG_CASE_ARG_DC
1337                         #undef ARG_CASE_ARG_SV
1338                         #undef ARG_CASE_ARG_CS
1339                         #undef ARG_CASE_ARG_CS_SV
1340                         #undef ARG_CASE_ARG_CS_SV_DC
1341                         #undef ARG_CASE_ARG_CS_SV_HA
1342                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1343                 }
1344         }
1345         #ifdef NOTIFICATIONS_DEBUG
1346         Debug_Notification(sprintf(
1347                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s);\n",
1348                 icon,
1349                 hudargs,
1350                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1351                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
1352         ));
1353         #endif
1354         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
1355 }
1356
1357 void Local_Notification_centerprint_generic(
1358         string input, string durcnt,
1359         float cpid, float f1, float f2)
1360 {
1361         string selected;
1362         float sel_num;
1363         arg_slot[0] = ""; arg_slot[1] = "";
1364
1365         for(sel_num = 0;(durcnt != "");)
1366         {
1367                 selected = car(durcnt); durcnt = cdr(durcnt);
1368                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic")
1369                 switch(strtolower(selected))
1370                 {
1371                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
1372                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1373                         #define ARG_CASE_ARG_CS_SV(selected,result)
1374                         #define ARG_CASE_ARG_CS(selected,result)
1375                         #define ARG_CASE_ARG_SV(selected,result)
1376                         #define ARG_CASE_ARG_DC(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1377                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1378                         NOTIF_ARGUMENT_LIST
1379                         #undef ARG_CASE
1380                         #undef ARG_CASE_ARG_DC
1381                         #undef ARG_CASE_ARG_SV
1382                         #undef ARG_CASE_ARG_CS
1383                         #undef ARG_CASE_ARG_CS_SV
1384                         #undef ARG_CASE_ARG_CS_SV_DC
1385                         #undef ARG_CASE_ARG_CS_SV_HA
1386                         default:
1387                         {
1388                                 if(ftos(stof(selected)) != "") { arg_slot[sel_num] = selected; ++sel_num; }
1389                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic") }
1390                                 break;
1391                         }
1392                 }
1393         }
1394         #ifdef NOTIFICATIONS_DEBUG
1395         Debug_Notification(sprintf(
1396                 "Local_Notification_centerprint_generic('%s^7', '%s', %d, %d, %d, %d);\n",
1397                 MakeConsoleSafe(input),
1398                 durcnt,
1399                 f1, f2,
1400                 stof(arg_slot[0]),
1401                 stof(arg_slot[1])
1402         ));
1403         #endif
1404         centerprint_generic(cpid, input, stof(arg_slot[0]), stof(arg_slot[1]));
1405 }
1406 #endif
1407
1408 void Local_Notification(float net_type, float net_name, ...count)
1409 {
1410         // check if this should be aborted
1411         if(net_name == NOTIF_ABORT)
1412         {
1413                 #ifdef NOTIFICATIONS_DEBUG
1414                 Debug_Notification(sprintf(
1415                         "Local_Notification(%s, %s, ...);\n",
1416                         Get_Notif_TypeName(net_type),
1417                         "NOTIF_ABORT"
1418                 ));
1419                 #endif
1420                 return;
1421         }
1422         
1423         // check supplied type and name for errors
1424         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
1425         if(checkargs != "")
1426         {
1427                 #ifdef NOTIFICATIONS_DEBUG
1428                 Debug_Notification(sprintf(
1429                         "Local_Notification(%s, %d, ...);\n",
1430                         Get_Notif_TypeName(net_type),
1431                         Get_Notif_Ent(net_type, net_name).nent_name
1432                 ));
1433                 #endif
1434                 backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs));
1435                 return;
1436         }
1437
1438         // retreive entity of this notification
1439         entity notif = Get_Notif_Ent(net_type, net_name);
1440         if not(notif)
1441         {
1442                 #ifdef NOTIFICATIONS_DEBUG
1443                 Debug_Notification(sprintf(
1444                         "Local_Notification(%s, %d, ...);\n",
1445                         Get_Notif_TypeName(net_type),
1446                         net_name
1447                 ));
1448                 #endif
1449                 backtrace("Local_Notification: Could not find notification entity!\n");
1450                 return;
1451         }
1452
1453         // check if the notification is enabled
1454         if not(notif.nent_enabled)
1455         {
1456                 #ifdef NOTIFICATIONS_DEBUG
1457                 Debug_Notification(sprintf(
1458                         "Local_Notification(%s, %s, ...): Entity was disabled...\n",
1459                         Get_Notif_TypeName(net_type),
1460                         notif.nent_name
1461                 ));
1462                 #endif
1463                 return;
1464         }
1465
1466         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1467         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1468         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1469         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1470         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1471         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1472         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1473         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1474
1475         #ifdef NOTIFICATIONS_DEBUG
1476         Debug_Notification(sprintf(
1477                 "Local_Notification(%s, %s, %s, %s);\n",
1478                 Get_Notif_TypeName(net_type),
1479                 notif.nent_name,
1480                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1481                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1482         ));
1483         #endif
1484         
1485         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1486         {
1487                 backtrace(sprintf(
1488                         strcat(
1489                                 "Not enough arguments for Local_Notification(%s, %s, ...)! ",
1490                                 "stringcount(%d) + floatcount(%d) > count(%d)\n", 
1491                                 "Check the definition and function call for accuracy...?\n"
1492                         ),
1493                         Get_Notif_TypeName(net_type),
1494                         notif.nent_name,
1495                         notif.nent_stringcount,
1496                         notif.nent_floatcount,
1497                         count
1498                 ));
1499                 return;
1500         }
1501         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1502         {
1503                 backtrace(sprintf(
1504                         strcat(
1505                                 "Too many arguments for Local_Notification(%s, %s, ...)! ",
1506                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1507                                 "Check the definition and function call for accuracy...?\n"
1508                         ),
1509                         Get_Notif_TypeName(net_type),
1510                         notif.nent_name,
1511                         notif.nent_stringcount,
1512                         notif.nent_floatcount,
1513                         count
1514                 ));
1515                 return;
1516         }
1517         
1518         switch(net_type)
1519         {
1520                 case MSG_ANNCE:
1521                 {
1522                         #ifdef CSQC
1523                         Local_Notification_sound(
1524                                 notif.nent_channel,
1525                                 notif.nent_snd,
1526                                 notif.nent_vol,
1527                                 notif.nent_position
1528                         );
1529                         #else
1530                         backtrace("MSG_ANNCE on server?... Please notify Samual immediately!\n");
1531                         #endif
1532                         break;
1533                 }
1534                 
1535                 case MSG_INFO:
1536                 {
1537                         print(
1538                                 Local_Notification_sprintf(
1539                                         notif.nent_string,
1540                                         notif.nent_args, 
1541                                         s1, s2, s3, s4,
1542                                         f1, f2, f3, f4)
1543                         );
1544                         #ifdef CSQC 
1545                         if(notif.nent_icon != "")
1546                         {
1547                                 Local_Notification_HUD_Notify_Push(
1548                                         notif.nent_icon,
1549                                         notif.nent_hudargs,
1550                                         s1, s2, s3, s4);
1551                         } 
1552                         #endif 
1553                         break;
1554                 }
1555                 
1556                 #ifdef CSQC
1557                 case MSG_CENTER:
1558                 {
1559                         Local_Notification_centerprint_generic(
1560                                 Local_Notification_sprintf(
1561                                         notif.nent_string,
1562                                         notif.nent_args, 
1563                                         s1, s2, s3, s4,
1564                                         f1, f2, f3, f4),
1565                                 notif.nent_durcnt,
1566                                 notif.nent_cpid,
1567                                 f1, f2);
1568                         break;
1569                 }
1570                 #endif
1571                 
1572                 case MSG_MULTI:
1573                 {
1574                         if(notif.nent_msginfo)
1575                         if(notif.nent_msginfo.nent_enabled)
1576                         {
1577                                 Local_Notification_WOVA(
1578                                         MSG_INFO,
1579                                         notif.nent_msginfo.nent_id, 
1580                                         notif.nent_msginfo.nent_stringcount, 
1581                                         notif.nent_msginfo.nent_floatcount, 
1582                                         s1, s2, s3, s4,
1583                                         f1, f2, f3, f4);
1584                         }
1585                         #ifdef CSQC
1586                         if(notif.nent_msgannce)
1587                         if(notif.nent_msgannce.nent_enabled)
1588                         {
1589                                 Local_Notification_WOVA(
1590                                         MSG_ANNCE,
1591                                         notif.nent_msgannce.nent_id, 
1592                                         0, 0, 
1593                                         "", "", "", "",
1594                                         0, 0, 0, 0);
1595                         }
1596                         if(notif.nent_msgcenter)
1597                         if(notif.nent_msgcenter.nent_enabled)
1598                         {
1599                                 Local_Notification_WOVA(
1600                                         MSG_CENTER,
1601                                         notif.nent_msgcenter.nent_id, 
1602                                         notif.nent_msgcenter.nent_stringcount, 
1603                                         notif.nent_msgcenter.nent_floatcount, 
1604                                         s1, s2, s3, s4,
1605                                         f1, f2, f3, f4); 
1606                         }
1607                         #endif
1608                         break;
1609                 }
1610
1611                 case MSG_CHOICE:
1612                 {
1613                         entity found_choice;
1614                         
1615                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2)))
1616                         {
1617                                 switch(cvar_string(sprintf("notification_%s", notif.nent_name)))
1618                                 {
1619                                         case 1: found_choice = notif.nent_optiona; break;
1620                                         case 2: found_choice = notif.nent_optionb; break;
1621                                         default: return; // not enabled anyway
1622                                 }
1623                         }
1624                         else { found_choice = notif.nent_optiona; }
1625                         
1626                         Local_Notification_WOVA(
1627                                 found_choice.nent_type,
1628                                 found_choice.nent_id, 
1629                                 found_choice.nent_stringcount, 
1630                                 found_choice.nent_floatcount, 
1631                                 s1, s2, s3, s4,
1632                                 f1, f2, f3, f4); 
1633                 }
1634         }
1635 }
1636
1637 // WOVA = Without Variable Arguments 
1638 void Local_Notification_WOVA(
1639         float net_type, float net_name,
1640         float stringcount, float floatcount,
1641         string s1, string s2, string s3, string s4,
1642         float f1, float f2, float f3, float f4)
1643 {
1644         #define VARITEM(stringc,floatc,args) \
1645                 if((stringcount == stringc) && (floatcount == floatc)) \
1646                         { Local_Notification(net_type, net_name, args); return; }
1647         EIGHT_VARS_TO_VARARGS_VARLIST
1648         #undef VARITEM
1649         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1650 }
1651
1652
1653 // =========================
1654 //  Notification Networking
1655 // =========================
1656
1657 #ifdef CSQC
1658 void Read_Notification(float is_new)
1659 {
1660         float net_type = ReadByte();
1661         float net_name = ReadShort();
1662
1663         entity notif;
1664
1665         if(net_type == MSG_CENTER_CPID)
1666         {
1667                 #ifdef NOTIFICATIONS_DEBUG
1668                 Debug_Notification(sprintf(
1669                         "Read_Notification(%d) at %f: net_type = %s, net_name = %d\n",
1670                         is_new,
1671                         time,
1672                         Get_Notif_TypeName(net_type),
1673                         net_name
1674                 ));
1675                 #endif
1676                 
1677                 if(is_new)
1678                 {
1679                         if(net_name == 0) { reset_centerprint_messages(); }
1680                         else if(net_name != NO_CPID)
1681                         {
1682                                 // in this case, net_name IS the cpid we want to kill
1683                                 centerprint_generic(net_name, "", 0, 0);
1684                         }
1685                         else
1686                         {
1687                                 backtrace(sprintf(
1688                                         "Read_Notification(%d) at %f: ^1TRIED TO KILL NO_CPID CENTERPRINT!\n",
1689                                         is_new,
1690                                         time
1691                                 ));
1692                         } 
1693                 }
1694         }
1695         else
1696         {
1697                 notif = Get_Notif_Ent(net_type, net_name);
1698                 if not(notif) { backtrace("Read_Notification: Could not find notification entity!\n"); return; }
1699
1700                 #ifdef NOTIFICATIONS_DEBUG
1701                 Debug_Notification(sprintf(
1702                         "Read_Notification(%d) at %f: net_type = %s, net_name = %s\n",
1703                         is_new,
1704                         time,
1705                         Get_Notif_TypeName(net_type),
1706                         notif.nent_name
1707                 ));
1708                 #endif
1709
1710                 string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
1711                 string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
1712                 string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
1713                 string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
1714                 float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : 0);
1715                 float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : 0);
1716                 float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : 0);
1717                 float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : 0);
1718         
1719                 if(is_new)
1720                 {
1721                         Local_Notification_WOVA(
1722                                 net_type, net_name,
1723                                 notif.nent_stringcount,
1724                                 notif.nent_floatcount,
1725                                 s1, s2, s3, s4,
1726                                 f1, f2, f3, f4);
1727                 }
1728         }
1729 }
1730 #endif
1731
1732 #ifdef SVQC
1733 void Net_Notification_Remove()
1734 {
1735         if not(self) { backtrace(sprintf("Net_Notification_Remove() at %f: Missing self!?\n", time)); return; }
1736         
1737         #ifdef NOTIFICATIONS_DEBUG
1738         Debug_Notification(sprintf(
1739                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1740                 time,
1741                 ((self.nent_net_name == -1) ? "Killed" : "Removed"),
1742                 Get_Notif_TypeName(self.nent_net_type),
1743                 self.owner.nent_name
1744         ));
1745         #endif
1746         
1747         float i;
1748         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
1749         remove(self);
1750 }
1751
1752 float Net_Write_Notification(entity client, float sf)
1753 {
1754         if(Notification_ShouldSend(self.nent_broadcast, client, self.nent_client))
1755         {
1756                 float i;
1757                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1758                 WriteByte(MSG_ENTITY, self.nent_net_type);
1759                 WriteShort(MSG_ENTITY, self.nent_net_name);
1760                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); } 
1761                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
1762                 return TRUE;
1763         }
1764         else { return FALSE; }
1765 }
1766
1767 void Kill_Notification(
1768         float broadcast, entity client,
1769         float net_type, float net_name)
1770 {
1771         #ifdef NOTIFICATIONS_DEBUG
1772         Debug_Notification(sprintf(
1773                 "Kill_Notification(%s, '%s', %s, %d);\n",
1774                 Get_Notif_BroadcastName(broadcast),
1775                 client.netname,
1776                 (net_type ? Get_Notif_TypeName(net_type) : "0"),
1777                 net_name
1778         ));
1779         #endif
1780         
1781         string checkargs = Notification_CheckArgs(broadcast, client, 1, 1);
1782         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Kill_Notification: %s\n", checkargs)); return; }
1783
1784         entity notif, net_notif;
1785         float killed_cpid = NO_CPID;
1786         
1787         switch(net_type)
1788         {
1789                 case 0:
1790                 {
1791                         killed_cpid = 0; // kill ALL centerprints
1792                         break;
1793                 }
1794                 
1795                 case MSG_CENTER:
1796                 {
1797                         if(net_name)
1798                         {
1799                                 entity notif = Get_Notif_Ent(net_type, net_name);
1800                                 if not(notif) { backtrace("Kill_Notification: Could not find notification entity!\n"); return; }
1801                                 
1802                                 if(notif.nent_cpid)
1803                                         killed_cpid = notif.nent_cpid;
1804                                 else
1805                                         killed_cpid = NO_CPID;
1806                         }
1807                         else
1808                         {
1809                                 killed_cpid = 0; // kill ALL centerprints
1810                         }
1811                         break;
1812                 }
1813
1814                 case MSG_CENTER_CPID:
1815                 {
1816                         killed_cpid = net_name;
1817                         break;
1818                 }
1819         }
1820
1821         if(killed_cpid != NO_CPID)
1822         {
1823                 net_notif = spawn();
1824                 net_notif.classname = "net_kill_notification";
1825                 net_notif.nent_broadcast = broadcast;
1826                 net_notif.nent_client = client;
1827                 net_notif.nent_net_type = MSG_CENTER_CPID;
1828                 net_notif.nent_net_name = killed_cpid;
1829                 Net_LinkEntity(net_notif, FALSE, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1830         }
1831
1832         for(notif = world; (notif = find(notif, classname, "net_notification"));)
1833         {
1834                 if(net_type)
1835                 {
1836                         if((killed_cpid != NO_CPID) && (notif.nent_net_type == MSG_CENTER))
1837                         {
1838                                 if(notif.owner.nent_cpid == killed_cpid)
1839                                 {
1840                                         notif.nent_net_name = -1;
1841                                         notif.nextthink = time;
1842                                 }
1843                                 else { continue; } // we ARE looking for a specific CPID, don't kill everything else too
1844                         }
1845                         else if(notif.nent_net_type == net_type)
1846                         {
1847                                 if(net_name)
1848                                 {
1849                                         if(notif.nent_net_name == net_name) { notif.nent_net_name = -1; notif.nextthink = time; }
1850                                         else { continue; } // we ARE looking for a certain net_name, don't kill everything else too
1851                                 }
1852                                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1853                         }
1854                         else { continue; } // we ARE looking for a certain net_type, don't kill everything else too
1855                 }
1856                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1857         }
1858 }
1859
1860 void Send_Notification(
1861         float broadcast, entity client,
1862         float net_type, float net_name,
1863         ...count)
1864 {
1865         // check if this should be aborted
1866         if(net_name == NOTIF_ABORT)
1867         {
1868                 #ifdef NOTIFICATIONS_DEBUG
1869                 Debug_Notification(sprintf(
1870                         "Send_Notification(%s, '%s', %s, %s, ...);\n",
1871                         Get_Notif_BroadcastName(broadcast),
1872                         client.classname,
1873                         Get_Notif_TypeName(net_type),
1874                         "NOTIF_ABORT"
1875                 ));
1876                 #endif
1877                 return;
1878         }
1879         
1880         // check supplied broadcast, target, type, and name for errors
1881         string checkargs = Notification_CheckArgs(broadcast, client, net_type, net_name);
1882         if(checkargs != "")
1883         {
1884                 #ifdef NOTIFICATIONS_DEBUG
1885                 Debug_Notification(sprintf(
1886                         "Send_Notification(%s, '%s', %s, %s, ...);\n",
1887                         Get_Notif_BroadcastName(broadcast),
1888                         client.classname,
1889                         Get_Notif_TypeName(net_type),
1890                         Get_Notif_Ent(net_type, net_name).nent_name
1891                 ));
1892                 #endif
1893                 backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs));
1894                 return;
1895         }
1896
1897         // retreive entity of this notification
1898         entity notif = Get_Notif_Ent(net_type, net_name);
1899         if not(notif)
1900         {
1901                 #ifdef NOTIFICATIONS_DEBUG
1902                 Debug_Notification(sprintf(
1903                         "Send_Notification(%s, '%s', %s, %d, ...);\n",
1904                         Get_Notif_BroadcastName(broadcast),
1905                         client.classname,
1906                         Get_Notif_TypeName(net_type),
1907                         net_name
1908                 ));
1909                 #endif
1910                 backtrace("Send_Notification: Could not find notification entity!\n");
1911                 return;
1912         }
1913
1914         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1915         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1916         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1917         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1918         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1919         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1920         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1921         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1922
1923         #ifdef NOTIFICATIONS_DEBUG
1924         Debug_Notification(sprintf(
1925                 "Send_Notification(%s, %s, %s);\n",
1926                 sprintf(
1927                         "%s, '%s', %s, %s",
1928                         Get_Notif_BroadcastName(broadcast),
1929                         client.classname,
1930                         Get_Notif_TypeName(net_type),
1931                         notif.nent_name
1932                 ),
1933                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1934                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1935         ));
1936         #endif
1937
1938         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1939         {
1940                 backtrace(sprintf(
1941                         strcat(
1942                                 "Not enough arguments for Send_Notification(%s, ...)! ",
1943                                 "stringcount(%d) + floatcount(%d) > count(%d)\n", 
1944                                 "Check the definition and function call for accuracy...?\n"
1945                         ),
1946                         sprintf(
1947                                 #ifdef NOTIFICATIONS_DEBUG
1948                                 "%s, '%s', %s, %s",
1949                                 Get_Notif_BroadcastName(broadcast),
1950                                 #else
1951                                 "%d, '%s', %s, %s",
1952                                 broadcast,
1953                                 #endif
1954                                 client.classname,
1955                                 Get_Notif_TypeName(net_type),
1956                                 notif.nent_name
1957                         ),
1958                         notif.nent_stringcount,
1959                         notif.nent_floatcount,
1960                         count
1961                 ));
1962                 return;
1963         }
1964         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1965         {
1966                 backtrace(sprintf(
1967                         strcat(
1968                                 "Too many arguments for Send_Notification(%s, ...)! ",
1969                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1970                                 "Check the definition and function call for accuracy...?\n"
1971                         ),
1972                         sprintf(
1973                                 #ifdef NOTIFICATIONS_DEBUG
1974                                 "%s, '%s', %s, %s",
1975                                 Get_Notif_BroadcastName(broadcast),
1976                                 #else
1977                                 "%d, '%s', %s, %s",
1978                                 broadcast,
1979                                 #endif
1980                                 client.classname,
1981                                 Get_Notif_TypeName(net_type),
1982                                 notif.nent_name
1983                         ),
1984                         notif.nent_stringcount,
1985                         notif.nent_floatcount,
1986                         count
1987                 ));
1988                 return;
1989         }
1990
1991         if(
1992                 server_is_dedicated
1993                 &&
1994                 (
1995                         broadcast == NOTIF_ALL
1996                         ||
1997                         broadcast == NOTIF_ALL_EXCEPT
1998                 )
1999                 &&
2000                 !(
2001                         net_type == MSG_ANNCE
2002                         ||
2003                         net_type == MSG_CENTER
2004                 )
2005         )
2006         {
2007                 Local_Notification_WOVA(
2008                         net_type, net_name,
2009                         notif.nent_stringcount,
2010                         notif.nent_floatcount,
2011                         s1, s2, s3, s4,
2012                         f1, f2, f3, f4);
2013         }
2014
2015         if(net_type == MSG_CHOICE)
2016         {
2017                 // THIS GETS TRICKY... now we have to cycle through each possible player (checking broadcast)
2018                 // and then do an individual NOTIF_ONE_ONLY recursive call for each one depending on their option...
2019                 // It's slow, but it's better than the alternatives:
2020                 //   1. Constantly networking all info and letting client decide
2021                 //   2. Manually handling each separate call on per-usage basis (See old CTF usage of verbose)
2022                 entity found_choice; 
2023
2024                 #define RECURSE_FROM_CHOICE(ent,action) \
2025                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) \
2026                         { \
2027                                 switch(ent.msg_choice_choices[net_name]) \
2028                                 { \
2029                                         case 1: found_choice = notif.nent_optiona; break; \
2030                                         case 2: found_choice = notif.nent_optionb; break; \
2031                                         default: action; \
2032                                 } \
2033                         } \
2034                         else { found_choice = notif.nent_optiona; } \
2035                         Send_Notification_WOVA( \
2036                                 NOTIF_ONE_ONLY, \
2037                                 ent, \
2038                                 found_choice.nent_type, \
2039                                 found_choice.nent_id, \
2040                                 found_choice.nent_stringcount, \
2041                                 found_choice.nent_floatcount, \
2042                                 s1, s2, s3, s4, \
2043                                 f1, f2, f3, f4);
2044
2045                 switch(broadcast)
2046                 {
2047                         case NOTIF_ONE_ONLY: // we can potentially save processing power with this broadcast method
2048                         {
2049                                 if(IS_REAL_CLIENT(client))
2050                                         { RECURSE_FROM_CHOICE(client, return) }
2051                                 break;
2052                         }
2053                         default:
2054                         {
2055                                 entity to;
2056                                 FOR_EACH_REALCLIENT(to)
2057                                         { if(Notification_ShouldSend(broadcast, to, client))
2058                                                 { RECURSE_FROM_CHOICE(to, continue) } }
2059                                 break;
2060                         }
2061                 }
2062         }
2063         else
2064         {
2065                 entity net_notif = spawn();
2066                 net_notif.owner = notif;
2067                 net_notif.classname = "net_notification";
2068                 net_notif.nent_broadcast = broadcast;
2069                 net_notif.nent_client = client;
2070                 net_notif.nent_net_type = net_type;
2071                 net_notif.nent_net_name = net_name;
2072                 net_notif.nent_stringcount = notif.nent_stringcount;
2073                 net_notif.nent_floatcount = notif.nent_floatcount;
2074                 
2075                 float i;
2076                 for(i = 0; i < net_notif.nent_stringcount; ++i)
2077                         { net_notif.nent_strings[i] = strzone(...(i, string)); }
2078                 for(i = 0; i < net_notif.nent_floatcount; ++i)
2079                         { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
2080
2081                 net_notif.think = Net_Notification_Remove;
2082                 net_notif.nextthink =
2083                         ((time > autocvar_notification_lifetime_mapload)
2084                         ?
2085                                 (time + autocvar_notification_lifetime_runtime)
2086                                 :
2087                                 autocvar_notification_lifetime_mapload
2088                         ); 
2089
2090                 Net_LinkEntity(net_notif, FALSE, 0, Net_Write_Notification);
2091         }
2092 }
2093
2094 // WOVA = Without Variable Arguments 
2095 void Send_Notification_WOVA(
2096         float broadcast, entity client,
2097         float net_type, float net_name,
2098         float stringcount, float floatcount,
2099         string s1, string s2, string s3, string s4,
2100         float f1, float f2, float f3, float f4)
2101 {
2102         #ifdef NOTIFICATIONS_DEBUG
2103         entity notif = Get_Notif_Ent(net_type, net_name);
2104         Debug_Notification(sprintf(
2105                 "Send_Notification_WOVA(%s, %d, %d, %s, %s);\n",
2106                 sprintf(
2107                         "%s, '%s', %s, %s",
2108                         Get_Notif_BroadcastName(broadcast),
2109                         client.classname,
2110                         Get_Notif_TypeName(net_type),
2111                         notif.nent_name
2112                 ),
2113                 stringcount,
2114                 floatcount,
2115                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2116                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2117         ));
2118         #endif
2119         
2120         #define VARITEM(stringc,floatc,args) \
2121                 if((stringcount == stringc) && (floatcount == floatc)) \
2122                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2123         EIGHT_VARS_TO_VARARGS_VARLIST
2124         #undef VARITEM
2125         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2126 }
2127
2128 // WOCOVA = Without Counts Or Variable Arguments 
2129 void Send_Notification_WOCOVA(
2130         float broadcast, entity client,
2131         float net_type, float net_name,
2132         string s1, string s2, string s3, string s4,
2133         float f1, float f2, float f3, float f4)
2134 {
2135         entity notif = Get_Notif_Ent(net_type, net_name);
2136         
2137         #ifdef NOTIFICATIONS_DEBUG
2138         Debug_Notification(sprintf(
2139                 "Send_Notification_WOCOVA(%s, %s, %s);\n",
2140                 sprintf(
2141                         "%s, '%s', %s, %s",
2142                         Get_Notif_BroadcastName(broadcast),
2143                         client.classname,
2144                         Get_Notif_TypeName(net_type),
2145                         notif.nent_name
2146                 ),
2147                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2148                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2149         ));
2150         #endif
2151         
2152         #define VARITEM(stringc,floatc,args) \
2153                 if((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
2154                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2155         EIGHT_VARS_TO_VARARGS_VARLIST
2156         #undef VARITEM
2157         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2158 }
2159 #endif // ifdef SVQC