70a7fc1e1e8550c92475521ffab9d4292935276d
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / notifications.qc
1 // ================================================
2 //  Unified notification system, written by Samual
3 //  Last updated: August, 2013
4 // ================================================
5
6 string Get_Notif_TypeName(float net_type)
7 {
8         switch(net_type)
9         {
10                 case MSG_ANNCE: return "MSG_ANNCE";
11                 case MSG_INFO: return "MSG_INFO";
12                 case MSG_CENTER: return "MSG_CENTER";
13                 case MSG_CENTER_CPID: return "MSG_CENTER_CPID";
14                 case MSG_MULTI: return "MSG_MULTI";
15                 case MSG_CHOICE: return "MSG_CHOICE";
16         }
17         backtrace(sprintf("Get_Notif_TypeName(%d): Improper net type!\n", net_type));
18         return "";
19 }
20
21 entity Get_Notif_Ent(float net_type, float net_name)
22 {
23         switch(net_type)
24         {
25                 case MSG_ANNCE: return msg_annce_notifs[net_name - 1];
26                 case MSG_INFO: return msg_info_notifs[net_name - 1];
27                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
28                 case MSG_MULTI: return msg_multi_notifs[net_name - 1];
29                 case MSG_CHOICE: return msg_choice_notifs[net_name - 1];
30         }
31         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
32         return world;
33 }
34
35 #ifdef SVQC
36 #ifdef NOTIFICATIONS_DEBUG
37 string Get_Notif_BroadcastName(float broadcast)
38 {
39         switch(broadcast)
40         {
41                 case NOTIF_ONE: return "NOTIF_ONE";
42                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
43                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
44                 case NOTIF_ALL: return "NOTIF_ALL";
45                 case NOTIF_TEAM: return "NOTIF_TEAM";
46                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
47         }
48         backtrace(sprintf("Get_Notif_BroadcastName(%d): Improper broadcast!\n", broadcast));
49         return "";
50 }
51 #endif
52 #endif
53
54 string Notification_CheckArgs_TypeName(float net_type, float net_name)
55 {
56         // check supplied type and name for errors
57         string checkargs = "";
58         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
59                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
60                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
61         switch(net_type)
62         {
63                 CHECKARG_TYPENAME(ANNCE)
64                 CHECKARG_TYPENAME(INFO)
65                 CHECKARG_TYPENAME(CENTER)
66                 CHECKARG_TYPENAME(MULTI)
67                 CHECKARG_TYPENAME(CHOICE)
68                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
69         }
70         #undef CHECKARG_TYPENAME
71         return checkargs;
72 }
73
74 #ifdef SVQC
75 string Notification_CheckArgs(
76         float broadcast, entity client,
77         float net_type, float net_name)
78 {
79         // check supplied broadcast, target, type, and name for errors
80         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
81         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
82         switch(broadcast)
83         {
84                 case NOTIF_ONE:
85                 case NOTIF_ONE_ONLY:
86                 {
87                         if(IS_NOT_A_CLIENT(client))
88                                 { checkargs = sprintf("%sNo client provided!", checkargs); }
89                         break;
90                 }
91                 
92                 case NOTIF_ALL_EXCEPT:
93                 {
94                         if(IS_NOT_A_CLIENT(client))
95                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
96                         break;
97                 }
98                 
99                 case NOTIF_ALL:
100                 {
101                         if(client)
102                                 { checkargs = sprintf("%sEntity provided when world was required!", checkargs); }
103                         break;
104                 }
105                 
106                 case NOTIF_TEAM:
107                 {
108                         if not(teamplay)
109                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
110                         //else if not(client.team) { checkargs = sprintf("%sNo team provided!", checkargs); }
111                         break;
112                 }
113                 
114                 case NOTIF_TEAM_EXCEPT:
115                 {
116                         if not(teamplay)
117                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
118                         else if(IS_NOT_A_CLIENT(client))
119                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
120                         break;
121                 }
122                 
123                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
124         }
125         return checkargs;
126 }
127
128 float Notification_ShouldSend(float broadcast, entity to_client, entity other_client)
129 {
130         switch(broadcast)
131         {
132                 case NOTIF_ONE: // send to one client and their spectator
133                 {
134                         if(
135                                 (to_client == other_client)
136                                 ||
137                                 (
138                                         IS_SPEC(to_client)
139                                         &&
140                                         (to_client.enemy == other_client)
141                                 )
142                         ) { return TRUE; }
143                         break;
144                 }
145                 case NOTIF_ONE_ONLY: // send ONLY to one client
146                 {
147                         if(to_client == other_client) { return TRUE; }
148                         break;
149                 }
150                 case NOTIF_TEAM: // send only to X team and their spectators
151                 {
152                         if(
153                                 (to_client.team == other_client.team)
154                                 ||
155                                 (
156                                         IS_SPEC(to_client)
157                                         &&
158                                         (to_client.enemy.team == other_client.team)
159                                 )
160                         ) { return TRUE; }
161                         break;
162                 }
163                 case NOTIF_TEAM_EXCEPT: // send only to X team and their spectators, except for Y person and their spectators
164                 {
165                         if(
166                                 (to_client != other_client)
167                                 &&
168                                 (
169                                         (to_client.team == other_client.team)
170                                         ||
171                                         (
172                                                 IS_SPEC(to_client)
173                                                 &&
174                                                 (
175                                                         (to_client.enemy != other_client)
176                                                         &&
177                                                         (to_client.enemy.team == other_client.team)
178                                                 )
179                                         )
180                                 )
181                         ) { return TRUE; }
182                         break;
183                 }
184                 case NOTIF_ALL: // send to everyone
185                 {
186                         return TRUE;
187                 }
188                 case NOTIF_ALL_EXCEPT: // send to everyone except X person and their spectators
189                 {
190                         if(
191                                 (to_client != other_client)
192                                 &&
193                                 !(
194                                         IS_SPEC(to_client)
195                                         &&
196                                         (to_client.enemy == other_client)
197                                 )
198                         ) { return TRUE; }
199                         break;
200                 }
201         }
202         return FALSE;
203 }
204
205 #endif
206
207 // ===============================
208 //  Initialization Core Functions
209 // ===============================
210
211 // used by restartnotifs command to initialize notifications
212 void Destroy_Notification_Entity(entity notif)
213 {
214         if(notif.nent_name != "") { strunzone(notif.nent_name); }
215         if(notif.nent_snd != "") { strunzone(notif.nent_snd); }
216         if(notif.nent_args != "") { strunzone(notif.nent_args); }
217         if(notif.nent_hudargs != "") { strunzone(notif.nent_hudargs); }
218         if(notif.nent_icon != "") { strunzone(notif.nent_icon); }
219         if(notif.nent_durcnt != "") { strunzone(notif.nent_durcnt); }
220         if(notif.nent_string != "") { strunzone(notif.nent_string); }
221         remove(notif);
222 }
223
224 void Destroy_All_Notifications(void)
225 {
226         entity notif;
227         float i;
228         
229         #define DESTROY_LOOP(type,count) \
230                 for(i = 1; i <= count; ++i) \
231                 { \
232                         notif = Get_Notif_Ent(type, i); \
233                         if not(notif) { backtrace("Destroy_All_Notifications(): Missing notification entity!\n"); return; } \
234                         Destroy_Notification_Entity(notif); \
235                 }
236
237         // kill all networked notifications and centerprints
238         #ifdef SVQC
239         Kill_Notification(NOTIF_ALL, world, 0, 0);
240         #else
241         reset_centerprint_messages();
242         #endif
243
244         // kill all real notification entities
245         DESTROY_LOOP(MSG_ANNCE, NOTIF_ANNCE_COUNT)
246         DESTROY_LOOP(MSG_INFO, NOTIF_INFO_COUNT)
247         DESTROY_LOOP(MSG_CENTER, NOTIF_CENTER_COUNT)
248         DESTROY_LOOP(MSG_MULTI, NOTIF_MULTI_COUNT)
249         DESTROY_LOOP(MSG_CHOICE, NOTIF_CHOICE_COUNT)
250         #undef DESTROY_LOOP
251 }
252
253 string Process_Notif_Line(
254         float typeid,
255         float chat,
256         string input,
257         string notiftype,
258         string notifname,
259         string stringtype)
260 {
261         #ifdef CSQC
262         if(typeid == MSG_INFO)
263         {
264                 if((chat && autocvar_notification_allow_chatboxprint)
265                         || (autocvar_notification_allow_chatboxprint == 2))
266                 {
267                         // pass 1: add ETX char at beginning of line
268                         input = strcat("\{3}", input);
269
270                         // pass 2: add ETX char at end of each new line (so that
271                         // messages with multiple lines are put through chatbox too)
272                         input = strreplace("\n", "\n\{3}", input);
273
274                         // pass 3: strip trailing ETX char
275                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
276                                 { input = substring(input, 0, (strlen(input) - 1)); }
277                 }
278         }
279         #endif
280
281         // done to both MSG_INFO and MSG_CENTER
282         if(substring(input, (strlen(input) - 1), 1) == "\n")
283         {
284                 print(sprintf(
285                         strcat(
286                                 "^1TRAILING NEW LINE AT END OF NOTIFICATION: ",
287                                 "^7net_type = %s, net_name = %s, string = %s.\n"
288                         ),
289                         notiftype,
290                         notifname,
291                         stringtype
292                 ));
293                 notif_error = TRUE;
294                 input = substring(input, 1, (strlen(input) - 1));
295         }
296
297         return input;
298 }
299
300 string Process_Notif_Args(
301         float arg_type,
302         string args,
303         string notiftype,
304         string notifname)
305 {
306         string selected, remaining = args;
307         float sel_num = 0;
308
309         for(;(remaining != "");)
310         {
311                 selected = car(remaining); remaining = cdr(remaining);
312
313                 switch(arg_type)
314                 {
315                         case 1: // normal args
316                         {
317                                 if(sel_num == NOTIF_MAX_ARGS)
318                                 {
319                                         print(sprintf(
320                                                 strcat(
321                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
322                                                         "^7net_type = %s, net_name = %s, max args = %d.\n"
323                                                 ),
324                                                 notiftype,
325                                                 notifname,
326                                                 NOTIF_MAX_ARGS
327                                         ));
328                                         notif_error = TRUE;
329                                         break;
330                                 }
331
332                                 switch(strtolower(selected))
333                                 {
334                                         #define ARG_CASE(prog,selected,result) \
335                                                 #if (prog != ARG_DC) \
336                                                         case selected: { ++sel_num; break; } \
337                                                 #endif
338                                         NOTIF_ARGUMENT_LIST
339                                         #undef ARG_CASE
340                                         default:
341                                         {
342                                                 print(sprintf(
343                                                         strcat(
344                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
345                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'.\n"
346                                                         ),
347                                                         notiftype,
348                                                         notifname,
349                                                         selected
350                                                 ));
351                                                 notif_error = TRUE;
352                                                 break;
353                                         }
354                                 }
355                                 break;
356                         }
357                         case 2: // hudargs
358                         {
359                                 if(sel_num == NOTIF_MAX_HUDARGS)
360                                 {
361                                         print(sprintf(
362                                                 strcat(
363                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
364                                                         "^7net_type = %s, net_name = %s, max hudargs = %d.\n"
365                                                 ),
366                                                 notiftype,
367                                                 notifname,
368                                                 NOTIF_MAX_HUDARGS
369                                         ));
370                                         notif_error = TRUE;
371                                         break;
372                                 }
373
374                                 switch(strtolower(selected))
375                                 {
376                                         #define ARG_CASE(prog,selected,result) \
377                                                 #if (prog == ARG_CS_SV_HA) \
378                                                         case selected: { ++sel_num; break; } \
379                                                 #endif
380                                         NOTIF_ARGUMENT_LIST
381                                         #undef ARG_CASE
382                                         default:
383                                         {
384                                                 print(sprintf(
385                                                         strcat(
386                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
387                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'.\n"
388                                                         ),
389                                                         notiftype,
390                                                         notifname,
391                                                         selected
392                                                 ));
393                                                 notif_error = TRUE;
394                                                 break;
395                                         }
396                                 }
397                                 break;
398                         }
399                         case 3: // durcnt 
400                         {
401                                 if(sel_num == NOTIF_MAX_DURCNT)
402                                 {
403                                         print(sprintf(
404                                                 strcat(
405                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
406                                                         "^7net_type = %s, net_name = %s, max durcnt = %d.\n"
407                                                 ),
408                                                 notiftype,
409                                                 notifname,
410                                                 NOTIF_MAX_DURCNT
411                                         ));
412                                         notif_error = TRUE;
413                                         break;
414                                 }
415
416                                 switch(strtolower(selected))
417                                 {
418                                         #define ARG_CASE(prog,selected,result) \
419                                                 #if (prog == ARG_CS_SV_DC) || (prog == ARG_DC) \
420                                                         case selected: { ++sel_num; break; } \
421                                                 #endif
422                                         NOTIF_ARGUMENT_LIST
423                                         #undef ARG_CASE
424                                         default:
425                                         {
426                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
427                                                 else
428                                                 {
429                                                         print(sprintf(
430                                                                 strcat(
431                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
432                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'.\n"
433                                                                 ),
434                                                                 notiftype,
435                                                                 notifname,
436                                                                 selected
437                                                         ));
438                                                         notif_error = TRUE;
439                                                 }
440                                                 break;
441                                         }
442                                 }
443                                 break;
444                         }
445                 }
446         }
447         return args;
448 }
449
450 void Create_Notification_Entity(
451         float var_default,
452         float var_cvar,
453         float typeid,
454         float nameid,
455         string namestring,
456         float strnum,
457         float flnum,
458         /* MSG_ANNCE */
459         float channel, 
460         string snd,
461         float vol,
462         float position,
463         /* MSG_INFO & MSG_CENTER */
464         string args,
465         string hudargs,
466         string icon,
467         float cpid,
468         string durcnt,
469         string normal,
470         string gentle,
471         /* MSG_MULTI */
472         float anncename,
473         float infoname,
474         float centername,
475         /* MSG_CHOICE */
476         float challow_def,
477         float challow_var,
478         float chtype,
479         float optiona,
480         float optionb)
481 {
482         // =====================
483         //  Global Entity Setup
484         // =====================
485         entity notif = spawn();
486         switch(typeid)
487         {
488                 case MSG_ANNCE:
489                 {
490                         msg_annce_notifs[nameid - 1] = notif;
491                         notif.classname = "msg_annce_notification";
492                         break;
493                 }
494                 case MSG_INFO:
495                 {
496                         msg_info_notifs[nameid - 1] = notif;
497                         notif.classname = "msg_info_notification";
498                         break;
499                 }
500                 case MSG_CENTER:
501                 {
502                         msg_center_notifs[nameid - 1] = notif;
503                         notif.classname = "msg_center_notification";
504                         break;
505                 }
506                 case MSG_MULTI:
507                 {
508                         msg_multi_notifs[nameid - 1] = notif;
509                         notif.classname = "msg_multi_notification";
510                         break;
511                 }
512                 case MSG_CHOICE:
513                 {
514                         msg_choice_notifs[nameid - 1] = notif;
515                         notif.classname = "msg_choice_notification";
516                         break;
517                 }
518
519                 default:
520                 {
521                         error(sprintf(
522                                 strcat(
523                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
524                                         "^7net_type = %d, net_name = %s.\n"
525                                 ),
526                                 typeid,
527                                 namestring
528                         ));
529                         return; // It's not possible to recover from this one
530                 }
531         }
532         notif.nent_default = var_default;
533         notif.nent_enabled = (1 <= var_cvar);
534         notif.nent_type = typeid;
535         notif.nent_id = nameid;
536         notif.nent_name = strzone(namestring);
537         
538         string typestring = Get_Notif_TypeName(typeid);
539
540         // Other pre-notif-setup requisites
541         notif_error = FALSE;
542
543         // ====================
544         //  Notification Setup
545         // ====================
546         switch(typeid)
547         {
548                 case MSG_ANNCE:
549                 {
550                         // Set MSG_ANNCE information and handle precaching
551                         #ifdef CSQC
552                         if not(GENTLE && (var_cvar == 1))
553                         {
554                                 if(snd != "")
555                                 {
556                                         if(notif.nent_enabled)
557                                         {
558                                                 precache_sound(sprintf("announcer/%s/%s.wav", autocvar_cl_announcer, snd));
559                                                 notif.nent_channel = channel;
560                                                 notif.nent_snd = strzone(snd);
561                                                 notif.nent_vol = vol;
562                                                 notif.nent_position = position;
563                                         }
564                                 }
565                                 else
566                                 {
567                                         print(sprintf(
568                                                 strcat(
569                                                         "^1NOTIFICATION WITH NO SOUND: ",
570                                                         "^7net_type = %s, net_name = %s.\n"
571                                                 ),
572                                                 typestring,
573                                                 namestring
574                                         ));
575                                         notif_error = TRUE;
576                                 }
577                         }
578                         else { notif.nent_enabled = FALSE; }
579                         #else
580                         notif.nent_enabled = FALSE;
581                         #endif
582
583                         break;
584                 }
585                 
586                 case MSG_INFO:
587                 case MSG_CENTER:
588                 {
589                         // Set MSG_INFO and MSG_CENTER string/float counts
590                         notif.nent_stringcount = strnum;
591                         notif.nent_floatcount = flnum;
592
593                         // Only initialize arguments if we're either a client or on a dedicated server
594                         #ifdef SVQC
595                         float should_process_args = server_is_dedicated;
596                         #else
597                         float should_process_args = TRUE;
598                         #endif
599
600                         if(should_process_args)
601                         {
602                                 // ========================
603                                 //  Process Main Arguments
604                                 // ========================
605                                 if(strnum + flnum)
606                                 {
607                                         if(args != "")
608                                         {
609                                                 notif.nent_args = strzone(
610                                                         Process_Notif_Args(1, args, typestring, namestring));
611                                         }
612                                         else if((hudargs == "") && (durcnt ==""))
613                                         {
614                                                 print(sprintf(
615                                                         strcat(
616                                                                 "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: ",
617                                                                 "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d\n"
618                                                         ),
619                                                         typestring,
620                                                         namestring,
621                                                         strnum,
622                                                         flnum
623                                                 ));
624                                                 notif_error = TRUE;
625                                         }
626                                 }
627                                 else if(args != "")
628                                 {
629                                         notif.nent_args = strzone(
630                                                 Process_Notif_Args(1, args, typestring, namestring));
631                                 }
632
633
634                                 // =======================================
635                                 //  Process HUD and Centerprint Arguments
636                                 //    Only processed on CSQC, as these
637                                 //    args are only for HUD features.
638                                 // =======================================
639                                 #ifdef CSQC
640                                 if(hudargs != "")
641                                 {
642                                         notif.nent_hudargs = strzone(
643                                                 Process_Notif_Args(2, hudargs, typestring, namestring));
644                                                 
645                                         if(icon != "") { notif.nent_icon = strzone(icon); }
646                                         else
647                                         {
648                                                 print(sprintf(
649                                                         strcat(
650                                                                 "^1NOTIFICATION HAS HUDARGS BUT NO ICON: ",
651                                                                 "^7net_type = %s, net_name = %s.\n"
652                                                         ),
653                                                         typestring,
654                                                         namestring
655                                                 ));
656                                                 notif_error = TRUE;
657                                         }
658                                 }
659                                 else if(icon != "")
660                                 {
661                                         print(sprintf(
662                                                 strcat(
663                                                         "^1NOTIFICATION HAS ICON BUT NO HUDARGS: ",
664                                                         "^7net_type = %s, net_name = %s.\n"
665                                                 ),
666                                                 typestring,
667                                                 namestring
668                                         ));
669                                         notif_error = TRUE;
670                                 }
671
672                                 if(durcnt != "")
673                                 {
674                                         notif.nent_durcnt = strzone(
675                                                 Process_Notif_Args(3, durcnt, typestring, namestring));
676                                                 
677                                         if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
678                                         else
679                                         {
680                                                 print(sprintf(
681                                                         strcat(
682                                                                 "^1NOTIFICATION HAS DURCNT BUT NO CPID: ",
683                                                                 "^7net_type = %s, net_name = %s.\n"
684                                                         ),
685                                                         typestring,
686                                                         namestring
687                                                 ));
688                                                 notif_error = TRUE;
689                                         }
690                                 } 
691                                 else if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
692                                 #endif
693
694
695                                 // ======================
696                                 //  Process Notif String
697                                 // ======================
698                                 #define SET_NOTIF_STRING(string,stringname) \
699                                         notif.nent_string = strzone(CCR( \
700                                                 Process_Notif_Line( \
701                                                         typeid, \
702                                                         (var_cvar > 1), \
703                                                         string, \
704                                                         typestring, \
705                                                         namestring, \
706                                                         stringname \
707                                                 )) \
708                                         );
709
710                                 if(GENTLE)
711                                 {
712                                         if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE") }
713                                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL") }
714                                 }
715                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL") }
716                                 
717                                 #undef SET_NOTIF_STRING
718
719                                 // Check to make sure a string was chosen
720                                 if(notif.nent_string == "")
721                                 {
722                                         print(sprintf(
723                                                 strcat(
724                                                         "^1EMPTY NOTIFICATION: ",
725                                                         "^7net_type = %s, net_name = %s.\n"
726                                                 ),
727                                                 typestring,
728                                                 namestring
729                                         ));
730                                         notif_error = TRUE;
731                                 }
732                         }
733
734                         break;
735                 }
736
737                 case MSG_MULTI:
738                 {
739                         // Set MSG_MULTI string/float counts
740                         if((anncename == NO_MSG) && (infoname == NO_MSG) && (centername == NO_MSG))
741                         {
742                                 print(sprintf(
743                                         strcat(
744                                                 "^1NOTIFICATION WITH NO SUBCALLS: ",
745                                                 "^7net_type = %s, net_name = %s.\n"
746                                         ),
747                                         typestring,
748                                         namestring
749                                 ));
750                                 notif_error = TRUE;
751                         }
752                         else
753                         {
754                                 // announcements don't actually need any arguments, so lets not even count them.
755                                 if(anncename != NO_MSG) { notif.nent_msgannce = msg_annce_notifs[anncename - 1]; }
756                                 
757                                 float infoname_stringcount = 0, infoname_floatcount = 0;
758                                 float centername_stringcount = 0, centername_floatcount = 0;
759                                 
760                                 if(infoname != NO_MSG)
761                                 {
762                                         notif.nent_msginfo = msg_info_notifs[infoname - 1];
763                                         infoname_stringcount = notif.nent_msginfo.nent_stringcount;
764                                         infoname_floatcount = notif.nent_msginfo.nent_floatcount;
765                                 }
766                                 
767                                 if(centername != NO_MSG)
768                                 {
769                                         notif.nent_msgcenter = msg_center_notifs[centername - 1];
770                                         centername_stringcount = notif.nent_msgcenter.nent_stringcount;
771                                         centername_floatcount = notif.nent_msgcenter.nent_floatcount;
772                                 }
773                                 
774                                 // set the requirements of THIS notification to the totals of its subcalls
775                                 notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
776                                 notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
777                         }
778                         
779                         break;
780                 }
781
782                 case MSG_CHOICE:
783                 {
784                         if((chtype == NO_MSG) || (optiona == NO_MSG) || (optionb == NO_MSG))
785                         {
786                                 print(sprintf(
787                                         strcat(
788                                                 "^1NOTIFICATION IS MISSING CHOICE PARAMS: ",
789                                                 "^7net_type = %s, net_name = %s.\n"
790                                         ),
791                                         typestring,
792                                         namestring
793                                 ));
794                                 notif_error = TRUE;
795                         }
796                         else
797                         {
798                                 switch(chtype)
799                                 {
800                                         case MSG_ANNCE:
801                                         {
802                                                 notif.nent_optiona = msg_annce_notifs[optiona - 1];
803                                                 notif.nent_optionb = msg_annce_notifs[optionb - 1];
804                                                 break;
805                                         }
806                                         case MSG_INFO:
807                                         {
808                                                 notif.nent_optiona = msg_info_notifs[optiona - 1];
809                                                 notif.nent_optionb = msg_info_notifs[optionb - 1];
810                                                 break;
811                                         }
812                                         case MSG_CENTER:
813                                         {
814                                                 notif.nent_optiona = msg_center_notifs[optiona - 1];
815                                                 notif.nent_optionb = msg_center_notifs[optionb - 1];
816                                                 break;
817                                         }
818                                         case MSG_MULTI:
819                                         {
820                                                 notif.nent_optiona = msg_multi_notifs[optiona - 1];
821                                                 notif.nent_optionb = msg_multi_notifs[optionb - 1];
822                                                 break;
823                                         }
824                                         case MSG_CHOICE: // should we REALLY allow nested options?... 
825                                         {
826                                                 notif.nent_optiona = msg_choice_notifs[optiona - 1];
827                                                 notif.nent_optionb = msg_choice_notifs[optionb - 1];
828                                                 break;
829                                         }
830
831                                         default:
832                                         {
833                                                 error(sprintf(
834                                                         strcat(
835                                                                 "^1NOTIFICATION WITH IMPROPER TYPE: ",
836                                                                 "^7net_type = %d, net_name = %s.\n"
837                                                         ),
838                                                         typeid,
839                                                         namestring
840                                                 ));
841                                                 notif_error = TRUE;
842                                                 break;
843                                         }
844                                 }
845                                 notif.nent_challow_def = challow_def; // 0: never allowed, 1: allowed in warmup, 2: always allowed
846                                 notif.nent_challow_var = challow_var; // 0: never allowed, 1: allowed in warmup, 2: always allowed
847                                 notif.nent_stringcount = max(notif.nent_optiona.nent_stringcount, notif.nent_optionb.nent_stringcount);
848                                 notif.nent_floatcount = max(notif.nent_optiona.nent_floatcount, notif.nent_optionb.nent_floatcount);
849                                 
850                                 #ifdef NOTIFICATIONS_DEBUG
851                                 Debug_Notification(sprintf(
852                                         "Create_Notification_Entity(...): MSG_CHOICE: %s\n%s\n%s\n",
853                                         notif.nent_name,
854                                         sprintf(
855                                                 "^ optiona: %s %s : %d %d",
856                                                 Get_Notif_TypeName(notif.nent_optiona.nent_type),
857                                                 notif.nent_optiona.nent_name,
858                                                 notif.nent_optiona.nent_stringcount,
859                                                 notif.nent_optiona.nent_floatcount
860                                         ),
861                                         sprintf(
862                                                 "^ optionb: %s %s : %d %d",
863                                                 Get_Notif_TypeName(notif.nent_optionb.nent_type),
864                                                 notif.nent_optionb.nent_name,
865                                                 notif.nent_optionb.nent_stringcount,
866                                                 notif.nent_optionb.nent_floatcount
867                                         )
868                                 ));
869                                 #endif
870                         }
871                         break;
872                 }
873                 
874                 default: print("DAFUQ?\n"); notif_error = TRUE; break;
875         }
876
877         // now check to see if any errors happened 
878         if(notif_error)
879         {
880                 notif.nent_enabled = FALSE; // disable the notification so it can't cause trouble
881                 notif_global_error = TRUE; // throw the red flag that an error happened on init
882         }
883 }
884
885
886 // ===============
887 //  Cvar Handling
888 // ===============
889
890 // used by MSG_CHOICE to build list of choices
891 #ifdef SVQC
892 void Notification_GetCvars(void)
893 {
894         float i;
895         for(i = 0; i <= NOTIF_CHOICE_COUNT; ++i)
896         {
897                 GetCvars_handleFloat(
898                         get_cvars_s,
899                         get_cvars_f,
900                         msg_choice_choices[i],
901                         sprintf("notification_%s", msg_choice_notifs[i].nent_name)
902                 );
903         }
904
905         GetCvars_handleFloat(get_cvars_s, get_cvars_f, FRAG_VERBOSE, "notification_frag_verbose");
906 }
907 #endif
908
909 // used to output notifications.cfg file
910 void Dump_Notifications(float fh, float alsoprint)
911 {
912         #define NOTIF_WRITE(a) { \
913                 fputs(fh, a); \
914                 if(alsoprint) { print(a); } }
915         #define NOTIF_WRITE_ENTITY(description) { \
916                 notif_msg = \
917                         sprintf( \
918                                 "seta notification_%s \"%d\" \"%s\"\n", \
919                                 e.nent_name, e.nent_default, description \
920                         ); \
921                 NOTIF_WRITE(notif_msg) }
922         #define NOTIF_WRITE_ENTITY_CHOICE(descriptiona,descriptionb) { \
923                 notif_msg = \
924                         sprintf( \
925                                 "seta notification_%s \"%d\" \"%s\"\n" \
926                                 "seta notification_%s_ALLOWED \"%d\" \"%s\"\n", \
927                                 e.nent_name, e.nent_default, descriptiona, \
928                                 e.nent_name, e.nent_challow_def, descriptionb \
929                         ); \
930                 NOTIF_WRITE(notif_msg) }
931         #define NOTIF_WRITE_HARDCODED(cvar,default,description) { \
932                 notif_msg = \
933                         sprintf( \
934                                 "seta notification_%s \"%s\" \"%s\"\n", \
935                                 cvar, default, description \
936                         ); \
937                 NOTIF_WRITE(notif_msg) }
938
939         string notif_msg;
940         float i;
941         entity e;
942
943         // Note: This warning only applies to the notifications.cfg file that is output...
944
945         // You ARE supposed to manually edit this function to add i.e. hard coded
946         // notification variables for mutators or game modes or such and then
947         // regenerate the notifications.cfg file from the new code.
948
949         NOTIF_WRITE("// ********************************************** //\n");
950         NOTIF_WRITE("// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n");
951         NOTIF_WRITE("// **                                          ** //\n");
952         NOTIF_WRITE("// **  This file is automatically generated    ** //\n");
953         NOTIF_WRITE("// **  by code with the command 'dumpnotifs'.  ** //\n");
954         NOTIF_WRITE("// **                                          ** //\n");
955         NOTIF_WRITE("// **  If you add a new notification, please   ** //\n");
956         NOTIF_WRITE("// **  regenerate this file with that command  ** //\n");
957         NOTIF_WRITE("// **  making sure that the output matches     ** //\n");
958         NOTIF_WRITE("// **  with the lists and defaults in code.    ** //\n");
959         NOTIF_WRITE("// **                                          ** //\n");
960         NOTIF_WRITE("// ********************************************** //\n");
961
962         // These notifications will also append their string as a comment...
963         // This is not necessary, and does not matter if they vary between config versions,
964         // it is just a semi-helpful tool for those who want to manually change their user settings.
965
966         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications (count = %d):\n", NOTIF_ANNCE_COUNT));
967         for(i = 1; i <= NOTIF_ANNCE_COUNT; ++i)
968         {
969                 e = Get_Notif_Ent(MSG_ANNCE, i);
970                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
971                 
972                 NOTIF_WRITE_ENTITY(
973                         "Notification control cvar: 0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled)"
974                 );
975         }
976
977         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
978         for(i = 1; i <= NOTIF_INFO_COUNT; ++i)
979         {
980                 e = Get_Notif_Ent(MSG_INFO, i);
981                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
982                 
983                 NOTIF_WRITE_ENTITY(
984                         "Notification control cvar: 0 = off, 1 = print to console, "
985                         "2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)"
986                 );
987         }
988
989         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
990         for(i = 1; i <= NOTIF_CENTER_COUNT; ++i)
991         {
992                 e = Get_Notif_Ent(MSG_CENTER, i);
993                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
994                 
995                 NOTIF_WRITE_ENTITY(
996                         "Notification control cvar: 0 = off, 1 = centerprint"
997                 );
998         }
999
1000         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications (count = %d):\n", NOTIF_MULTI_COUNT));
1001         for(i = 1; i <= NOTIF_MULTI_COUNT; ++i)
1002         {
1003                 e = Get_Notif_Ent(MSG_MULTI, i);
1004                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1005                 
1006                 NOTIF_WRITE_ENTITY(
1007                         "Notification control cvar: 0 = off, 1 = trigger subcalls"
1008                 );
1009         }
1010
1011         NOTIF_WRITE(sprintf("\n// MSG_CHOICE notifications (count = %d):\n", NOTIF_CHOICE_COUNT));
1012         for(i = 1; i <= NOTIF_CHOICE_COUNT; ++i)
1013         {
1014                 e = Get_Notif_Ent(MSG_CHOICE, i);
1015                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1016                 
1017                 NOTIF_WRITE_ENTITY_CHOICE(
1018                         "Notification control cvar: 0 = off, 1 = trigger option A subcall, 2 = trigger option B subcall",
1019                         "Notification control cvar: 0 = off, 1 = allowed in warmup mode, 2 = always allowed"
1020                 );
1021         }
1022
1023         // edit these to match whichever cvars are used for specific notification options
1024         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
1025         
1026         NOTIF_WRITE_HARDCODED(
1027                 "allow_chatboxprint", "1",
1028                 "Allow notifications to be printed to chat box by setting notification cvar to 2 "
1029                 "(You can also set this cvar to 2 to force ALL notifications to be printed to the chatbox)"
1030         );
1031         
1032         NOTIF_WRITE_HARDCODED(
1033                 "debug", "0",
1034                 "Print extra debug information on all notification function calls "
1035                 "(Requires -DNOTIFICATIONS_DEBUG flag to be enabled on QCSRC compilation)... "
1036                 "0 = disabled, 1 = dprint, 2 = print"
1037         );
1038         
1039         NOTIF_WRITE_HARDCODED(
1040                 "errors_are_fatal", "1",
1041                 "If a notification fails upon initialization, cause a Host_Error to stop the program"
1042         );
1043         
1044         NOTIF_WRITE_HARDCODED(
1045                 "item_centerprinttime", "1.5",
1046                 "How long to show item information centerprint messages (like 'You got the Electro' or such)"
1047         );
1048         
1049         NOTIF_WRITE_HARDCODED(
1050                 "lifetime_mapload", "10",
1051                 "Amount of time that notification entities last immediately at mapload (in seconds) "
1052                 "to help prevent notifications from being lost on early init (like gamestart countdown)"
1053         );
1054         
1055         NOTIF_WRITE_HARDCODED(
1056                 "lifetime_runtime", "0.5",
1057                 "Amount of time that notification entities last on the server during runtime (In seconds)"
1058         );
1059         
1060         NOTIF_WRITE_HARDCODED(
1061                 "server_allows_location", "1",
1062                 "Server side cvar for allowing death messages to show location information too"
1063         );
1064         
1065         NOTIF_WRITE_HARDCODED(
1066                 "show_location", "0",
1067                 "Append location information to MSG_INFO death/kill messages"
1068         );
1069         
1070         NOTIF_WRITE_HARDCODED(
1071                 "show_location_string", "",
1072                 "Replacement string piped into sprintf, "
1073                 "so you can do different messages like this: ' at the %s' or ' (near %s)'"
1074         );
1075         
1076         NOTIF_WRITE_HARDCODED(
1077                 "show_sprees", "1",
1078                 "Print information about sprees in death/kill messages"
1079         );
1080         
1081         NOTIF_WRITE_HARDCODED(
1082                 "show_sprees_center", "1",
1083                 "Show spree information in MSG_CENTER messages... "
1084                 "0 = off, 1 = target (but only for first victim) and attacker"
1085         );
1086         
1087         NOTIF_WRITE_HARDCODED(
1088                 "show_sprees_center_specialonly", "1",
1089                 "Don't show spree information in MSG_CENTER messages if it isn't an achievement"
1090         );
1091         
1092         NOTIF_WRITE_HARDCODED(
1093                 "show_sprees_info", "3",
1094                 "Show spree information in MSG_INFO messages... "
1095                 "0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker"
1096         );
1097         
1098         NOTIF_WRITE_HARDCODED(
1099                 "show_sprees_info_newline", "1",
1100                 "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself"
1101         );
1102         
1103         NOTIF_WRITE_HARDCODED(
1104                 "show_sprees_info_specialonly", "1",
1105                 "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement"
1106         );
1107
1108         NOTIF_WRITE(sprintf(
1109                 strcat(
1110                         "\n// Notification counts (total = %d): ",
1111                         "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
1112                 ),
1113                 (
1114                         NOTIF_ANNCE_COUNT +
1115                         NOTIF_INFO_COUNT +
1116                         NOTIF_CENTER_COUNT +
1117                         NOTIF_MULTI_COUNT +
1118                         NOTIF_CHOICE_COUNT
1119                 ),
1120                 NOTIF_ANNCE_COUNT,
1121                 NOTIF_INFO_COUNT,
1122                 NOTIF_CENTER_COUNT,
1123                 NOTIF_MULTI_COUNT,
1124                 NOTIF_CHOICE_COUNT
1125         ));
1126         
1127         return;
1128         #undef NOTIF_WRITE_HARDCODED
1129         #undef NOTIF_WRITE_ENTITY
1130         #undef NOTIF_WRITE
1131 }
1132
1133
1134 // ===============================
1135 //  Frontend Notification Pushing
1136 // ===============================
1137
1138 #ifdef NOTIFICATIONS_DEBUG
1139 void Debug_Notification(string input)
1140 {
1141         switch(autocvar_notification_debug)
1142         {
1143                 case 1: { dprint(input); break; }
1144                 case 2: { print(input); break; }
1145         }
1146 }
1147 #endif
1148
1149 string Local_Notification_sprintf(
1150         string input, string args, 
1151         string s1, string s2, string s3, string s4,
1152         float f1, float f2, float f3, float f4)
1153 {
1154         #ifdef NOTIFICATIONS_DEBUG
1155         Debug_Notification(sprintf(
1156                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
1157                 MakeConsoleSafe(input),
1158                 args,
1159                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1160                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1161         ));
1162         #endif
1163         
1164         string selected;
1165         float sel_num;
1166         for(sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
1167
1168         string tmp_s;
1169
1170         for(sel_num = 0;(args != "");)
1171         {
1172                 selected = car(args); args = cdr(args);
1173                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1174                 switch(strtolower(selected))
1175                 {
1176                         #define ARG_CASE(prog,selected,result) \
1177                                 #ifdef CSQC \
1178                                         #if (prog != ARG_SV) && (prog != ARG_DC) \
1179                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
1180                                         #endif \
1181                                 #else \
1182                                         #if (prog != ARG_CS) && (prog != ARG_DC) \
1183                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
1184                                         #endif \
1185                                 #endif
1186                         NOTIF_ARGUMENT_LIST
1187                         #undef ARG_CASE
1188                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1189                 }
1190         }
1191         return sprintf(
1192                 strcat(input, "\n"),
1193                 arg_slot[0],
1194                 arg_slot[1],
1195                 arg_slot[2],
1196                 arg_slot[3],
1197                 arg_slot[4],
1198                 arg_slot[5],
1199                 arg_slot[6]
1200         );
1201 }
1202
1203 #ifdef CSQC
1204 void Local_Notification_sound(
1205         float soundchannel, string soundfile,
1206         float soundvolume, float soundposition)
1207 {
1208         if((soundfile != prev_soundfile) || (time >= (prev_soundtime + autocvar_cl_announcer_antispam)))
1209         {
1210                 #ifdef NOTIFICATIONS_DEBUG
1211                 Debug_Notification(sprintf(
1212                         "Local_Notification_sound(world, %f, '%s', %f, %f);\n",
1213                         soundchannel,
1214                         sprintf(
1215                                 "announcer/%s/%s.wav",
1216                                 autocvar_cl_announcer,
1217                                 soundfile
1218                         ),
1219                         soundvolume,
1220                         soundposition
1221                 ));
1222                 #endif
1223                 
1224                 sound(
1225                         world,
1226                         soundchannel,
1227                         sprintf(
1228                                 "announcer/%s/%s.wav",
1229                                 autocvar_cl_announcer,
1230                                 soundfile
1231                         ),
1232                         soundvolume,
1233                         soundposition
1234                 );
1235                 
1236                 if(prev_soundfile) { strunzone(prev_soundfile); }
1237                 prev_soundfile = strzone(soundfile);
1238                 prev_soundtime = time;
1239         }
1240         else
1241         {
1242                 #ifdef NOTIFICATIONS_DEBUG
1243                 Debug_Notification(sprintf(
1244                         strcat(
1245                                 "Local_Notification_sound(world, %f, '%s', %f, %f) ",
1246                                 "^1BLOCKED BY ANTISPAM:^7 prevsnd: '%s', timediff: %f, limit: %f\n"
1247                          ),
1248                         soundchannel,
1249                         sprintf(
1250                                 "announcer/%s/%s.wav",
1251                                 autocvar_cl_announcer,
1252                                 soundfile
1253                         ),
1254                         soundvolume,
1255                         soundposition,
1256                         prev_soundfile,
1257                         (time - prev_soundtime),
1258                         autocvar_cl_announcer_antispam
1259                 ));
1260                 #endif
1261         }
1262 }
1263
1264 void Local_Notification_HUD_Notify_Push(
1265         string icon, string hudargs,
1266         string s1, string s2, string s3, string s4)
1267 {
1268         string selected;
1269         float sel_num;
1270         arg_slot[0] = ""; arg_slot[1] = "";
1271
1272         for(sel_num = 0;(hudargs != "");)
1273         {
1274                 selected = car(hudargs); hudargs = cdr(hudargs);
1275                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1276                 switch(strtolower(selected))
1277                 {
1278                         #define ARG_CASE(prog,selected,result) \
1279                                 #if (prog == ARG_CS_SV_HA) \
1280                                         case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
1281                                 #endif
1282                         NOTIF_ARGUMENT_LIST
1283                         #undef ARG_CASE
1284                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1285                 }
1286         }
1287         #ifdef NOTIFICATIONS_DEBUG
1288         Debug_Notification(sprintf(
1289                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s);\n",
1290                 icon,
1291                 hudargs,
1292                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1293                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
1294         ));
1295         #endif
1296         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
1297 }
1298
1299 void Local_Notification_centerprint_generic(
1300         string input, string durcnt,
1301         float cpid, float f1, float f2)
1302 {
1303         string selected;
1304         float sel_num;
1305         arg_slot[0] = ""; arg_slot[1] = "";
1306
1307         for(sel_num = 0;(durcnt != "");)
1308         {
1309                 selected = car(durcnt); durcnt = cdr(durcnt);
1310                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic")
1311                 switch(strtolower(selected))
1312                 {
1313                         #define ARG_CASE(prog,selected,result) \
1314                                 #if (prog == ARG_CS_SV_DC) || (prog == ARG_DC) \
1315                                         case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
1316                                 #endif
1317                         NOTIF_ARGUMENT_LIST
1318                         #undef ARG_CASE
1319                         default:
1320                         {
1321                                 if(ftos(stof(selected)) != "") { arg_slot[sel_num] = selected; ++sel_num; }
1322                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic") }
1323                                 break;
1324                         }
1325                 }
1326         }
1327         #ifdef NOTIFICATIONS_DEBUG
1328         Debug_Notification(sprintf(
1329                 "Local_Notification_centerprint_generic('%s^7', '%s', %d, %d, %d, %d);\n",
1330                 MakeConsoleSafe(input),
1331                 durcnt,
1332                 f1, f2,
1333                 stof(arg_slot[0]),
1334                 stof(arg_slot[1])
1335         ));
1336         #endif
1337         centerprint_generic(cpid, input, stof(arg_slot[0]), stof(arg_slot[1]));
1338 }
1339 #endif
1340
1341 void Local_Notification(float net_type, float net_name, ...count)
1342 {
1343         // check supplied type and name for errors
1344         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
1345         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs)); return; }
1346
1347         entity notif = Get_Notif_Ent(net_type, net_name);
1348         if not(notif) { backtrace("Local_Notification: Could not find notification entity!\n"); return; }
1349         if not(notif.nent_enabled)
1350         {
1351                 #ifdef NOTIFICATIONS_DEBUG
1352                 Debug_Notification(sprintf(
1353                         "Local_Notification(%s, %s): Entity was disabled...\n",
1354                         Get_Notif_TypeName(net_type),
1355                         notif.nent_name
1356                 ));
1357                 #endif
1358                 return;
1359         }
1360         
1361         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1362         {
1363                 backtrace(sprintf(
1364                         strcat(
1365                                 "Not enough arguments for Local_Notification(%s, %s, ...)! ",
1366                                 "stringcount(%d) + floatcount(%d) > count(%d)\n", 
1367                                 "Check the definition and function call for accuracy...?\n"
1368                         ),
1369                         Get_Notif_TypeName(net_type),
1370                         notif.nent_name,
1371                         notif.nent_stringcount,
1372                         notif.nent_floatcount,
1373                         count
1374                 ));
1375                 return;
1376         }
1377         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1378         {
1379                 backtrace(sprintf(
1380                         strcat(
1381                                 "Too many arguments for Local_Notification(%s, %s, ...)! ",
1382                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1383                                 "Check the definition and function call for accuracy...?\n"
1384                         ),
1385                         Get_Notif_TypeName(net_type),
1386                         notif.nent_name,
1387                         notif.nent_stringcount,
1388                         notif.nent_floatcount,
1389                         count
1390                 ));
1391                 return;
1392         }
1393
1394         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1395         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1396         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1397         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1398         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1399         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1400         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1401         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1402
1403         #ifdef NOTIFICATIONS_DEBUG
1404         Debug_Notification(sprintf(
1405                 "Local_Notification(%s, %s, %s, %s);\n",
1406                 Get_Notif_TypeName(net_type),
1407                 notif.nent_name,
1408                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1409                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1410         ));
1411         #endif
1412         
1413         switch(net_type)
1414         {
1415                 case MSG_ANNCE:
1416                 {
1417                         #ifdef CSQC
1418                         Local_Notification_sound(
1419                                 notif.nent_channel,
1420                                 notif.nent_snd,
1421                                 notif.nent_vol,
1422                                 notif.nent_position
1423                         );
1424                         #else
1425                         backtrace("MSG_ANNCE on server?... Please notify Samual immediately!\n");
1426                         #endif
1427                         break;
1428                 }
1429                 
1430                 case MSG_INFO:
1431                 {
1432                         print(
1433                                 Local_Notification_sprintf(
1434                                         notif.nent_string,
1435                                         notif.nent_args, 
1436                                         s1, s2, s3, s4,
1437                                         f1, f2, f3, f4)
1438                         );
1439                         #ifdef CSQC 
1440                         if(notif.nent_icon != "")
1441                         {
1442                                 Local_Notification_HUD_Notify_Push(
1443                                         notif.nent_icon,
1444                                         notif.nent_hudargs,
1445                                         s1, s2, s3, s4);
1446                         } 
1447                         #endif 
1448                         break;
1449                 }
1450                 
1451                 #ifdef CSQC
1452                 case MSG_CENTER:
1453                 {
1454                         Local_Notification_centerprint_generic(
1455                                 Local_Notification_sprintf(
1456                                         notif.nent_string,
1457                                         notif.nent_args, 
1458                                         s1, s2, s3, s4,
1459                                         f1, f2, f3, f4),
1460                                 notif.nent_durcnt,
1461                                 notif.nent_cpid,
1462                                 f1, f2);
1463                         break;
1464                 }
1465                 #endif
1466                 
1467                 case MSG_MULTI:
1468                 {
1469                         if(notif.nent_msginfo)
1470                         if(notif.nent_msginfo.nent_enabled)
1471                         {
1472                                 Local_Notification_WOVA(
1473                                         MSG_INFO,
1474                                         notif.nent_msginfo.nent_id, 
1475                                         notif.nent_msginfo.nent_stringcount, 
1476                                         notif.nent_msginfo.nent_floatcount, 
1477                                         s1, s2, s3, s4,
1478                                         f1, f2, f3, f4);
1479                         }
1480                         #ifdef CSQC
1481                         if(notif.nent_msgannce)
1482                         if(notif.nent_msgannce.nent_enabled)
1483                         {
1484                                 Local_Notification_WOVA(
1485                                         MSG_ANNCE,
1486                                         notif.nent_msgannce.nent_id, 
1487                                         0, 0, 
1488                                         "", "", "", "",
1489                                         0, 0, 0, 0);
1490                         }
1491                         if(notif.nent_msgcenter)
1492                         if(notif.nent_msgcenter.nent_enabled)
1493                         {
1494                                 Local_Notification_WOVA(
1495                                         MSG_CENTER,
1496                                         notif.nent_msgcenter.nent_id, 
1497                                         notif.nent_msgcenter.nent_stringcount, 
1498                                         notif.nent_msgcenter.nent_floatcount, 
1499                                         s1, s2, s3, s4,
1500                                         f1, f2, f3, f4); 
1501                         }
1502                         #endif
1503                         break;
1504                 }
1505
1506                 case MSG_CHOICE:
1507                 {
1508                         entity found_choice;
1509                         
1510                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2)))
1511                         {
1512                                 switch(cvar_string(sprintf("notification_%s", notif.nent_name)))
1513                                 {
1514                                         case 1: found_choice = notif.nent_optiona; break;
1515                                         case 2: found_choice = notif.nent_optionb; break;
1516                                         default: return; // not enabled anyway
1517                                 }
1518                         }
1519                         else { found_choice = notif.nent_optiona; }
1520                         
1521                         Local_Notification_WOVA(
1522                                 found_choice.nent_type,
1523                                 found_choice.nent_id, 
1524                                 found_choice.nent_stringcount, 
1525                                 found_choice.nent_floatcount, 
1526                                 s1, s2, s3, s4,
1527                                 f1, f2, f3, f4); 
1528                 }
1529         }
1530 }
1531
1532 // WOVA = Without Variable Arguments 
1533 void Local_Notification_WOVA(
1534         float net_type, float net_name,
1535         float stringcount, float floatcount,
1536         string s1, string s2, string s3, string s4,
1537         float f1, float f2, float f3, float f4)
1538 {
1539         #define VARITEM(stringc,floatc,args) \
1540                 if((stringcount == stringc) && (floatcount == floatc)) \
1541                         { Local_Notification(net_type, net_name, args); return; }
1542         EIGHT_VARS_TO_VARARGS_VARLIST
1543         #undef VARITEM
1544         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1545 }
1546
1547
1548 // =========================
1549 //  Notification Networking
1550 // =========================
1551
1552 #ifdef CSQC
1553 void Read_Notification(float is_new)
1554 {
1555         float net_type = ReadByte();
1556         float net_name = ReadShort();
1557
1558         entity notif;
1559
1560         if(net_type == MSG_CENTER_CPID)
1561         {
1562                 #ifdef NOTIFICATIONS_DEBUG
1563                 Debug_Notification(sprintf(
1564                         "Read_Notification(%d) at %f: net_type = %s, net_name = %d\n",
1565                         is_new,
1566                         time,
1567                         Get_Notif_TypeName(net_type),
1568                         net_name
1569                 ));
1570                 #endif
1571                 
1572                 if(is_new)
1573                 {
1574                         if(net_name == 0) { reset_centerprint_messages(); }
1575                         else if(net_name != NO_CPID)
1576                         {
1577                                 // in this case, net_name IS the cpid we want to kill
1578                                 centerprint_generic(net_name, "", 0, 0);
1579                         }
1580                         else
1581                         {
1582                                 backtrace(sprintf(
1583                                         "Read_Notification(%d) at %f: ^1TRIED TO KILL NO_CPID CENTERPRINT!\n",
1584                                         is_new,
1585                                         time
1586                                 ));
1587                         } 
1588                 }
1589         }
1590         else
1591         {
1592                 notif = Get_Notif_Ent(net_type, net_name);
1593                 if not(notif) { backtrace("Read_Notification: Could not find notification entity!\n"); return; }
1594
1595                 #ifdef NOTIFICATIONS_DEBUG
1596                 Debug_Notification(sprintf(
1597                         "Read_Notification(%d) at %f: net_type = %s, net_name = %s\n",
1598                         is_new,
1599                         time,
1600                         Get_Notif_TypeName(net_type),
1601                         notif.nent_name
1602                 ));
1603                 #endif
1604
1605                 string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
1606                 string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
1607                 string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
1608                 string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
1609                 float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : 0);
1610                 float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : 0);
1611                 float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : 0);
1612                 float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : 0);
1613         
1614                 if(is_new)
1615                 {
1616                         Local_Notification_WOVA(
1617                                 net_type, net_name,
1618                                 notif.nent_stringcount,
1619                                 notif.nent_floatcount,
1620                                 s1, s2, s3, s4,
1621                                 f1, f2, f3, f4);
1622                 }
1623         }
1624 }
1625 #endif
1626
1627 #ifdef SVQC
1628 void Net_Notification_Remove()
1629 {
1630         if not(self) { backtrace(sprintf("Net_Notification_Remove() at %f: Missing self!?\n", time)); return; }
1631         
1632         #ifdef NOTIFICATIONS_DEBUG
1633         Debug_Notification(sprintf(
1634                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1635                 time,
1636                 ((self.nent_net_name == -1) ? "Killed" : "Removed"),
1637                 Get_Notif_TypeName(self.nent_net_type),
1638                 self.owner.nent_name
1639         ));
1640         #endif
1641         
1642         float i;
1643         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
1644         remove(self);
1645 }
1646
1647 float Net_Write_Notification(entity client, float sf)
1648 {
1649         if(Notification_ShouldSend(self.nent_broadcast, client, self.nent_client))
1650         {
1651                 float i;
1652                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1653                 WriteByte(MSG_ENTITY, self.nent_net_type);
1654                 WriteShort(MSG_ENTITY, self.nent_net_name);
1655                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); } 
1656                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
1657                 return TRUE;
1658         }
1659         else { return FALSE; }
1660 }
1661
1662 void Kill_Notification(
1663         float broadcast, entity client,
1664         float net_type, float net_name)
1665 {
1666         string checkargs = Notification_CheckArgs(broadcast, client, 1, 1);
1667         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Kill_Notification: %s\n", checkargs)); return; }
1668
1669         #ifdef NOTIFICATIONS_DEBUG
1670         Debug_Notification(sprintf(
1671                 "Kill_Notification(%s, '%s', %s, %d);\n",
1672                 Get_Notif_BroadcastName(broadcast),
1673                 client.netname,
1674                 (net_type ? Get_Notif_TypeName(net_type) : "0"),
1675                 net_name
1676         ));
1677         #endif
1678
1679         entity notif, net_notif;
1680         float killed_cpid = NO_CPID;
1681         
1682         switch(net_type)
1683         {
1684                 case 0:
1685                 {
1686                         killed_cpid = 0; // kill ALL centerprints
1687                         break;
1688                 }
1689                 
1690                 case MSG_CENTER:
1691                 {
1692                         if(net_name)
1693                         {
1694                                 entity notif = Get_Notif_Ent(net_type, net_name);
1695                                 if not(notif) { backtrace("Kill_Notification: Could not find notification entity!\n"); return; }
1696                                 
1697                                 if(notif.nent_cpid)
1698                                         killed_cpid = notif.nent_cpid;
1699                                 else
1700                                         killed_cpid = NO_CPID;
1701                         }
1702                         else
1703                         {
1704                                 killed_cpid = 0; // kill ALL centerprints
1705                         }
1706                         break;
1707                 }
1708
1709                 case MSG_CENTER_CPID:
1710                 {
1711                         killed_cpid = net_name;
1712                         break;
1713                 }
1714         }
1715
1716         if(killed_cpid != NO_CPID)
1717         {
1718                 net_notif = spawn();
1719                 net_notif.classname = "net_kill_notification";
1720                 net_notif.nent_broadcast = broadcast;
1721                 net_notif.nent_client = client;
1722                 net_notif.nent_net_type = MSG_CENTER_CPID;
1723                 net_notif.nent_net_name = killed_cpid;
1724                 Net_LinkEntity(net_notif, FALSE, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1725         }
1726
1727         for(notif = world; (notif = find(notif, classname, "net_notification"));)
1728         {
1729                 if(net_type)
1730                 {
1731                         if((killed_cpid != NO_CPID) && (notif.nent_net_type == MSG_CENTER))
1732                         {
1733                                 if(notif.owner.nent_cpid == killed_cpid)
1734                                 {
1735                                         notif.nent_net_name = -1;
1736                                         notif.nextthink = time;
1737                                 }
1738                                 else { continue; } // we ARE looking for a specific CPID, don't kill everything else too
1739                         }
1740                         else if(notif.nent_net_type == net_type)
1741                         {
1742                                 if(net_name)
1743                                 {
1744                                         if(notif.nent_net_name == net_name) { notif.nent_net_name = -1; notif.nextthink = time; }
1745                                         else { continue; } // we ARE looking for a certain net_name, don't kill everything else too
1746                                 }
1747                                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1748                         }
1749                         else { continue; } // we ARE looking for a certain net_type, don't kill everything else too
1750                 }
1751                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1752         }
1753 }
1754
1755 void Send_Notification(
1756         float broadcast, entity client,
1757         float net_type, float net_name,
1758         ...count)
1759 {
1760         // check supplied broadcast, target, type, and name for errors
1761         string checkargs = Notification_CheckArgs(broadcast, client, net_type, net_name);
1762         if(checkargs != "")
1763         {
1764                 #ifdef NOTIFICATIONS_DEBUG
1765                 Debug_Notification(sprintf(
1766                         "Send_Notification(%s, '%s', %s, %d, ...);\n",
1767                         Get_Notif_BroadcastName(broadcast),
1768                         client.classname,
1769                         Get_Notif_TypeName(net_type),
1770                         Get_Notif_Ent(net_type, net_name).nent_name
1771                 ));
1772                 #endif
1773                 backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs));
1774                 return;
1775         }
1776
1777         // retreive counts for the arguments of this notification
1778         entity notif = Get_Notif_Ent(net_type, net_name);
1779         if not(notif)
1780         {
1781                 #ifdef NOTIFICATIONS_DEBUG
1782                 Debug_Notification(sprintf(
1783                         "Send_Notification(%s, '%s', %s, %d, ...);\n",
1784                         Get_Notif_BroadcastName(broadcast),
1785                         client.classname,
1786                         Get_Notif_TypeName(net_type),
1787                         net_name
1788                 ));
1789                 #endif
1790                 backtrace("Send_Notification: Could not find notification entity!\n");
1791                 return;
1792         }
1793
1794         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1795         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1796         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1797         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1798         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1799         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1800         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1801         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1802
1803         #ifdef NOTIFICATIONS_DEBUG
1804         Debug_Notification(sprintf(
1805                 "Send_Notification(%s, %s, %s);\n",
1806                 sprintf(
1807                         "%s, '%s', %s, %s",
1808                         Get_Notif_BroadcastName(broadcast),
1809                         client.classname,
1810                         Get_Notif_TypeName(net_type),
1811                         notif.nent_name
1812                 ),
1813                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1814                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1815         ));
1816         #endif
1817
1818         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1819         {
1820                 backtrace(sprintf(
1821                         strcat(
1822                                 "Not enough arguments for Send_Notification(%s, ...)! ",
1823                                 "stringcount(%d) + floatcount(%d) > count(%d)\n", 
1824                                 "Check the definition and function call for accuracy...?\n"
1825                         ),
1826                         sprintf(
1827                                 "%s, '%s', %s, %s",
1828                                 Get_Notif_BroadcastName(broadcast),
1829                                 client.classname,
1830                                 Get_Notif_TypeName(net_type),
1831                                 notif.nent_name
1832                         ),
1833                         notif.nent_stringcount,
1834                         notif.nent_floatcount,
1835                         count
1836                 ));
1837                 return;
1838         }
1839         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1840         {
1841                 backtrace(sprintf(
1842                         strcat(
1843                                 "Too many arguments for Send_Notification(%s, ...)! ",
1844                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1845                                 "Check the definition and function call for accuracy...?\n"
1846                         ),
1847                         sprintf(
1848                                 "%s, '%s', %s, %s",
1849                                 Get_Notif_BroadcastName(broadcast),
1850                                 client.classname,
1851                                 Get_Notif_TypeName(net_type),
1852                                 notif.nent_name
1853                         ),
1854                         notif.nent_stringcount,
1855                         notif.nent_floatcount,
1856                         count
1857                 ));
1858                 return;
1859         }
1860
1861         if(
1862                 server_is_dedicated
1863                 &&
1864                 (
1865                         broadcast == NOTIF_ALL
1866                         ||
1867                         broadcast == NOTIF_ALL_EXCEPT
1868                 )
1869                 &&
1870                 !(
1871                         net_type == MSG_ANNCE
1872                         ||
1873                         net_type == MSG_CENTER
1874                 )
1875         )
1876         {
1877                 Local_Notification_WOVA(
1878                         net_type, net_name,
1879                         notif.nent_stringcount,
1880                         notif.nent_floatcount,
1881                         s1, s2, s3, s4,
1882                         f1, f2, f3, f4);
1883         }
1884
1885         if(net_type == MSG_CHOICE)
1886         {
1887                 // THIS GETS TRICKY... now we have to cycle through each possible player (checking broadcast)
1888                 // and then do an individual NOTIF_ONE_ONLY recursive call for each one depending on their option...
1889                 // It's slow, but it's better than the alternatives:
1890                 //   1. Constantly networking all info and letting client decide
1891                 //   2. Manually handling each separate call on per-usage basis (See old CTF usage of verbose)
1892                 entity found_choice; 
1893
1894                 #define RECURSE_FROM_CHOICE(ent,action) \
1895                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) \
1896                         { \
1897                                 switch(ent.msg_choice_choices[net_name]) \
1898                                 { \
1899                                         case 1: found_choice = notif.nent_optiona; break; \
1900                                         case 2: found_choice = notif.nent_optionb; break; \
1901                                         default: action; \
1902                                 } \
1903                         } \
1904                         else { found_choice = notif.nent_optiona; } \
1905                         Send_Notification_WOVA( \
1906                                 NOTIF_ONE_ONLY, \
1907                                 ent, \
1908                                 found_choice.nent_type, \
1909                                 found_choice.nent_id, \
1910                                 found_choice.nent_stringcount, \
1911                                 found_choice.nent_floatcount, \
1912                                 s1, s2, s3, s4, \
1913                                 f1, f2, f3, f4);
1914
1915                 switch(broadcast)
1916                 {
1917                         case NOTIF_ONE_ONLY: // we can potentially save processing power with this broadcast method
1918                         {
1919                                 if(IS_REAL_CLIENT(client))
1920                                         { RECURSE_FROM_CHOICE(client, return) }
1921                                 break;
1922                         }
1923                         default:
1924                         {
1925                                 entity to;
1926                                 FOR_EACH_REALCLIENT(to)
1927                                         { if(Notification_ShouldSend(broadcast, to, client))
1928                                                 { RECURSE_FROM_CHOICE(to, continue) } }
1929                                 break;
1930                         }
1931                 }
1932         }
1933         else
1934         {
1935                 entity net_notif = spawn();
1936                 net_notif.owner = notif;
1937                 net_notif.classname = "net_notification";
1938                 net_notif.nent_broadcast = broadcast;
1939                 net_notif.nent_client = client;
1940                 net_notif.nent_net_type = net_type;
1941                 net_notif.nent_net_name = net_name;
1942                 net_notif.nent_stringcount = notif.nent_stringcount;
1943                 net_notif.nent_floatcount = notif.nent_floatcount;
1944                 
1945                 float i;
1946                 for(i = 0; i < net_notif.nent_stringcount; ++i)
1947                         { net_notif.nent_strings[i] = strzone(...(i, string)); }
1948                 for(i = 0; i < net_notif.nent_floatcount; ++i)
1949                         { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
1950
1951                 net_notif.think = Net_Notification_Remove;
1952                 net_notif.nextthink =
1953                         ((time > autocvar_notification_lifetime_mapload)
1954                         ?
1955                                 (time + autocvar_notification_lifetime_runtime)
1956                                 :
1957                                 autocvar_notification_lifetime_mapload
1958                         ); 
1959
1960                 Net_LinkEntity(net_notif, FALSE, 0, Net_Write_Notification);
1961         }
1962 }
1963
1964 // WOVA = Without Variable Arguments 
1965 void Send_Notification_WOVA(
1966         float broadcast, entity client,
1967         float net_type, float net_name,
1968         float stringcount, float floatcount,
1969         string s1, string s2, string s3, string s4,
1970         float f1, float f2, float f3, float f4)
1971 {
1972         #ifdef NOTIFICATIONS_DEBUG
1973         entity notif = Get_Notif_Ent(net_type, net_name);
1974         Debug_Notification(sprintf(
1975                 "Send_Notification_WOVA(%s, %d, %d, %s, %s);\n",
1976                 sprintf(
1977                         "%s, '%s', %s, %s",
1978                         Get_Notif_BroadcastName(broadcast),
1979                         client.classname,
1980                         Get_Notif_TypeName(net_type),
1981                         notif.nent_name
1982                 ),
1983                 stringcount,
1984                 floatcount,
1985                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1986                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1987         ));
1988         #endif
1989         
1990         #define VARITEM(stringc,floatc,args) \
1991                 if((stringcount == stringc) && (floatcount == floatc)) \
1992                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
1993         EIGHT_VARS_TO_VARARGS_VARLIST
1994         #undef VARITEM
1995         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
1996 }
1997
1998 // WOCOVA = Without Counts Or Variable Arguments 
1999 void Send_Notification_WOCOVA(
2000         float broadcast, entity client,
2001         float net_type, float net_name,
2002         string s1, string s2, string s3, string s4,
2003         float f1, float f2, float f3, float f4)
2004 {
2005         entity notif = Get_Notif_Ent(net_type, net_name);
2006         
2007         #ifdef NOTIFICATIONS_DEBUG
2008         Debug_Notification(sprintf(
2009                 "Send_Notification_WOCOVA(%s, %s, %s);\n",
2010                 sprintf(
2011                         "%s, '%s', %s, %s",
2012                         Get_Notif_BroadcastName(broadcast),
2013                         client.classname,
2014                         Get_Notif_TypeName(net_type),
2015                         notif.nent_name
2016                 ),
2017                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2018                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2019         ));
2020         #endif
2021         
2022         #define VARITEM(stringc,floatc,args) \
2023                 if((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
2024                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2025         EIGHT_VARS_TO_VARARGS_VARLIST
2026         #undef VARITEM
2027         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2028 }
2029 #endif // ifdef SVQC