qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: March, 2013
   4 // ================================================
   5
   6 string Get_Notif_TypeName(float net_type)
   7 {
   8         switch(net_type)
   9         {
  10                 case MSG_ANNCE: return "MSG_ANNCE";
  11                 case MSG_INFO: return "MSG_INFO";
  12                 case MSG_CENTER: return "MSG_CENTER";
  13                 case MSG_CENTER_CPID: return "MSG_CENTER_CPID";
  14                 case MSG_MULTI: return "MSG_MULTI";
  15         }
  16         backtrace(sprintf("Get_Notif_TypeName(%d): Improper net type!\n", net_type));
  17         return "";
  18 }
  19
  20 entity Get_Notif_Ent(float net_type, float net_name)
  21 {
  22         switch(net_type)
  23         {
  24                 case MSG_ANNCE: return msg_annce_notifs[net_name - 1];
  25                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  26                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  27                 case MSG_MULTI: return msg_multi_notifs[net_name - 1];
  28         }
  29         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  30         return world;
  31 }
  32
  33 string Notification_CheckArgs_TypeName(float net_type, float net_name)
  34 {
  35         // check supplied type and name for errors
  36         string checkargs = "";
  37         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
  38                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
  39                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
  40         switch(net_type)
  41         {
  42                 CHECKARG_TYPENAME(ANNCE)
  43                 CHECKARG_TYPENAME(INFO)
  44                 CHECKARG_TYPENAME(CENTER)
  45                 CHECKARG_TYPENAME(MULTI)
  46                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
  47         }
  48         #undef CHECKARG_TYPENAME
  49         return checkargs;
  50 }
  51
  52 #ifdef SVQC
  53 string Notification_CheckArgs(
  54         float broadcast, entity client,
  55         float net_type, float net_name)
  56 {
  57         // check supplied broadcast, target, type, and name for errors
  58         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
  59         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
  60         switch(broadcast)
  61         {
  62                 case NOTIF_ONE:
  63                 case NOTIF_ONE_ONLY:
  64                 {
  65                         if(IS_NOT_A_CLIENT(client))
  66                                 { checkargs = sprintf("%sNo client provided!", checkargs); }
  67                         break;
  68                 }
  69
  70                 case NOTIF_ALL_EXCEPT:
  71                 {
  72                         if(IS_NOT_A_CLIENT(client))
  73                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
  74                         break;
  75                 }
  76
  77                 case NOTIF_ALL:
  78                 {
  79                         if(client)
  80                                 { checkargs = sprintf("%sEntity provided when world was required!", checkargs); }
  81                         break;
  82                 }
  83
  84                 case NOTIF_TEAM:
  85                 case NOTIF_TEAM_EXCEPT:
  86                 {
  87                         if not(teamplay) { checkargs = sprintf("%sTeamplay not active!", checkargs); }
  88                         else if(IS_NOT_A_CLIENT(client))
  89                         {
  90                                 if(broadcast == NOTIF_TEAM) { checkargs = sprintf("%sNo client provided!", checkargs); }
  91                                 else { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
  92                         }
  93                         break;
  94                 }
  95
  96                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
  97         }
  98         return checkargs;
  99 }
 100 #endif
 101
 102 // ===============================
 103 //  Initialization Core Functions
 104 // ===============================
 105
 106 // used by restartnotifs command to initialize notifications
 107 void Destroy_Notification_Entity(entity notif)
 108 {
 109         if(notif.nent_name != "") { strunzone(notif.nent_name); }
 110         if(notif.nent_snd != "") { strunzone(notif.nent_snd); }
 111         if(notif.nent_args != "") { strunzone(notif.nent_args); }
 112         if(notif.nent_hudargs != "") { strunzone(notif.nent_hudargs); }
 113         if(notif.nent_icon != "") { strunzone(notif.nent_icon); }
 114         if(notif.nent_durcnt != "") { strunzone(notif.nent_durcnt); }
 115         if(notif.nent_string != "") { strunzone(notif.nent_string); }
 116         remove(notif);
 117 }
 118
 119 void Destroy_All_Notifications(void)
 120 {
 121         entity notif;
 122         float i;
 123
 124         #define DESTROY_LOOP(type,count) \
 125                 for(i = 1; i <= count; ++i) \
 126                 { \
 127                         notif = Get_Notif_Ent(type, i); \
 128                         if not(notif) { backtrace("Destroy_All_Notifications(): Missing notification entity!\n"); return; } \
 129                         Destroy_Notification_Entity(notif); \
 130                 }
 131
 132         // kill all networked notifications and centerprints
 133         #ifdef SVQC
 134         Kill_Notification(NOTIF_ALL, world, 0, 0);
 135         #else
 136         reset_centerprint_messages();
 137         #endif
 138
 139         // kill all real notification entities
 140         DESTROY_LOOP(MSG_ANNCE, NOTIF_ANNCE_COUNT)
 141         DESTROY_LOOP(MSG_INFO, NOTIF_INFO_COUNT)
 142         DESTROY_LOOP(MSG_CENTER, NOTIF_CENTER_COUNT)
 143         DESTROY_LOOP(MSG_MULTI, NOTIF_MULTI_COUNT)
 144         #undef DESTROY_LOOP
 145 }
 146
 147 string Process_Notif_Line(
 148         float msg_is_info,
 149         float chat,
 150         string input,
 151         string notiftype,
 152         string notifname,
 153         string stringtype)
 154 {
 155         if(msg_is_info)
 156         {
 157                 #ifdef CSQC
 158                 if((chat && autocvar_notification_allow_chatboxprint)
 159                         || (autocvar_notification_allow_chatboxprint == 2))
 160                 {
 161                         // pass 1: add ETX char at beginning of line
 162                         input = strcat("\{3}", input);
 163
 164                         // pass 2: add ETX char at end of each new line (so that
 165                         // messages with multiple lines are put through chatbox too)
 166                         input = strreplace("\n", "\n\{3}", input);
 167
 168                         // pass 3: strip trailing ETX char
 169                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
 170                                 { input = substring(input, 0, (strlen(input) - 1)); }
 171                 }
 172                 #endif
 173                 if(substring(input, (strlen(input) - 1), 1) != "\n")
 174                 {
 175                         print(sprintf(
 176                                 strcat(
 177                                         "^1MISSING/BROKEN NEW LINE AT END OF NOTIFICATION: ",
 178                                         "^7net_type = %s, net_name = %s, string = %s.\n"
 179                                 ),
 180                                 notiftype,
 181                                 notifname,
 182                                 stringtype
 183                         ));
 184                         notif_error = TRUE;
 185                         return strcat(input, "\n");
 186                 }
 187         }
 188         return input;
 189 }
 190
 191 string Process_Notif_Args(
 192         float arg_type,
 193         string args,
 194         string notiftype,
 195         string notifname)
 196 {
 197         string selected, remaining = args;
 198         float sel_num = 0;
 199
 200         for(;(remaining != "");)
 201         {
 202                 selected = car(remaining); remaining = cdr(remaining);
 203
 204                 switch(arg_type)
 205                 {
 206                         case 1: // normal args
 207                         {
 208                                 if(sel_num == NOTIF_MAX_ARGS)
 209                                 {
 210                                         print(sprintf(
 211                                                 strcat(
 212                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 213                                                         "^7net_type = %s, net_name = %s, max args = %d.\n"
 214                                                 ),
 215                                                 notiftype,
 216                                                 notifname,
 217                                                 NOTIF_MAX_ARGS
 218                                         ));
 219                                         notif_error = TRUE;
 220                                         break;
 221                                 }
 222
 223                                 switch(strtolower(selected))
 224                                 {
 225                                         #define ARG_CASE(prog,selected,result) \
 226                                                 #if (prog != ARG_DC) \
 227                                                         case selected: { ++sel_num; break; } \
 228                                                 #endif
 229                                         NOTIF_ARGUMENT_LIST
 230                                         #undef ARG_CASE
 231                                         default:
 232                                         {
 233                                                 print(sprintf(
 234                                                         strcat(
 235                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 236                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'.\n"
 237                                                         ),
 238                                                         notiftype,
 239                                                         notifname,
 240                                                         selected
 241                                                 ));
 242                                                 notif_error = TRUE;
 243                                                 break;
 244                                         }
 245                                 }
 246                                 break;
 247                         }
 248                         case 2: // hudargs
 249                         {
 250                                 if(sel_num == NOTIF_MAX_HUDARGS)
 251                                 {
 252                                         print(sprintf(
 253                                                 strcat(
 254                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 255                                                         "^7net_type = %s, net_name = %s, max hudargs = %d.\n"
 256                                                 ),
 257                                                 notiftype,
 258                                                 notifname,
 259                                                 NOTIF_MAX_HUDARGS
 260                                         ));
 261                                         notif_error = TRUE;
 262                                         break;
 263                                 }
 264
 265                                 switch(strtolower(selected))
 266                                 {
 267                                         #define ARG_CASE(prog,selected,result) \
 268                                                 #if (prog == ARG_CS_SV_HA) \
 269                                                         case selected: { ++sel_num; break; } \
 270                                                 #endif
 271                                         NOTIF_ARGUMENT_LIST
 272                                         #undef ARG_CASE
 273                                         default:
 274                                         {
 275                                                 print(sprintf(
 276                                                         strcat(
 277                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 278                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'.\n"
 279                                                         ),
 280                                                         notiftype,
 281                                                         notifname,
 282                                                         selected
 283                                                 ));
 284                                                 notif_error = TRUE;
 285                                                 break;
 286                                         }
 287                                 }
 288                                 break;
 289                         }
 290                         case 3: // durcnt
 291                         {
 292                                 if(sel_num == NOTIF_MAX_DURCNT)
 293                                 {
 294                                         print(sprintf(
 295                                                 strcat(
 296                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 297                                                         "^7net_type = %s, net_name = %s, max durcnt = %d.\n"
 298                                                 ),
 299                                                 notiftype,
 300                                                 notifname,
 301                                                 NOTIF_MAX_DURCNT
 302                                         ));
 303                                         notif_error = TRUE;
 304                                         break;
 305                                 }
 306
 307                                 switch(strtolower(selected))
 308                                 {
 309                                         #define ARG_CASE(prog,selected,result) \
 310                                                 #if (prog == ARG_CS_SV_DC) || (prog == ARG_DC) \
 311                                                         case selected: { ++sel_num; break; } \
 312                                                 #endif
 313                                         NOTIF_ARGUMENT_LIST
 314                                         #undef ARG_CASE
 315                                         default:
 316                                         {
 317                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
 318                                                 else
 319                                                 {
 320                                                         print(sprintf(
 321                                                                 strcat(
 322                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 323                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'.\n"
 324                                                                 ),
 325                                                                 notiftype,
 326                                                                 notifname,
 327                                                                 selected
 328                                                         ));
 329                                                         notif_error = TRUE;
 330                                                 }
 331                                                 break;
 332                                         }
 333                                 }
 334                                 break;
 335                         }
 336                 }
 337         }
 338         return args;
 339 }
 340
 341 void Create_Notification_Entity(
 342         float var_default,
 343         float var_cvar,
 344         float typeid,
 345         float nameid,
 346         string namestring,
 347         float anncename,
 348         float infoname,
 349         float centername,
 350         float channel,
 351         string snd,
 352         float vol,
 353         float position,
 354         float strnum,
 355         float flnum,
 356         string args,
 357         string hudargs,
 358         string icon,
 359         float cpid,
 360         string durcnt,
 361         string normal,
 362         string gentle,
 363         float msg_is_info,
 364         float msg_is_multi)
 365 {
 366         // =====================
 367         //  Global Entity Setup
 368         // =====================
 369         entity notif = spawn();
 370         string typestring = "";
 371         switch(typeid)
 372         {
 373                 case MSG_ANNCE:
 374                 {
 375                         typestring = "MSG_ANNCE";
 376                         msg_annce_notifs[nameid - 1] = notif;
 377                         notif.classname = "msg_annce_notification";
 378                         break;
 379                 }
 380                 case MSG_INFO:
 381                 {
 382                         typestring = "MSG_INFO";
 383                         msg_info_notifs[nameid - 1] = notif;
 384                         notif.classname = "msg_info_notification";
 385                         break;
 386                 }
 387                 case MSG_CENTER:
 388                 {
 389                         typestring = "MSG_CENTER";
 390                         msg_center_notifs[nameid - 1] = notif;
 391                         notif.classname = "msg_center_notification";
 392                         break;
 393                 }
 394                 case MSG_MULTI:
 395                 {
 396                         typestring = "MSG_MULTI";
 397                         msg_multi_notifs[nameid - 1] = notif;
 398                         notif.classname = "MSG_MULTI_notification";
 399                         break;
 400                 }
 401
 402                 default:
 403                 {
 404                         error(sprintf(
 405                                 strcat(
 406                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
 407                                         "^7net_type = %d, net_name = %s.\n"
 408                                 ),
 409                                 typeid,
 410                                 namestring
 411                         ));
 412                         return; // It's not possible to recover from this one
 413                 }
 414         }
 415         notif.nent_default = var_default;
 416         notif.nent_name = strzone(namestring);
 417         notif.nent_id = nameid;
 418         notif.nent_enabled = (1 <= var_cvar);
 419
 420         // Other pre-notif-setup requisites
 421         notif_error = FALSE;
 422
 423         // ====================
 424         //  Notification Setup
 425         // ====================
 426         if(msg_is_multi)
 427         {
 428                 // Set MSG_MULTI string/float counts
 429                 if((anncename == NO_MSG) && (infoname == NO_MSG) && (centername == NO_MSG))
 430                 {
 431                         print(sprintf(
 432                                 strcat(
 433                                         "^1NOTIFICATION WITH NO SUBCALLS: ",
 434                                         "^7net_type = %s, net_name = %s.\n"
 435                                 ),
 436                                 typestring,
 437                                 namestring
 438                         ));
 439                         notif_error = TRUE;
 440                 }
 441                 else
 442                 {
 443                         // announcements don't actually need any arguments, so lets not even count them.
 444                         if(anncename != NO_MSG) { notif.nent_msgannce = msg_annce_notifs[anncename - 1]; }
 445
 446                         float infoname_stringcount = 0, infoname_floatcount = 0;
 447                         float centername_stringcount = 0, centername_floatcount = 0;
 448
 449                         if(infoname != NO_MSG)
 450                         {
 451                                 notif.nent_msginfo = msg_info_notifs[infoname - 1];
 452                                 infoname_stringcount = notif.nent_msginfo.nent_stringcount;
 453                                 infoname_floatcount = notif.nent_msginfo.nent_floatcount;
 454                         }
 455
 456                         if(centername != NO_MSG)
 457                         {
 458                                 notif.nent_msgcenter = msg_center_notifs[centername - 1];
 459                                 centername_stringcount = notif.nent_msgcenter.nent_stringcount;
 460                                 centername_floatcount = notif.nent_msgcenter.nent_floatcount;
 461                         }
 462
 463                         // set the requirements of THIS notification to the totals of its subcalls
 464                         notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
 465                         notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
 466                 }
 467         }
 468         else if(typeid == MSG_ANNCE)
 469         {
 470                 // Set MSG_ANNCE information and handle precaching
 471                 #ifdef CSQC
 472                 if not(GENTLE && (var_cvar == 1))
 473                 {
 474                         if(snd != "")
 475                         {
 476                                 if(notif.nent_enabled)
 477                                 {
 478                                         precache_sound(sprintf("announcer/%s/%s.wav", autocvar_cl_announcer, snd));
 479                                         notif.nent_channel = channel;
 480                                         notif.nent_snd = strzone(snd);
 481                                         notif.nent_vol = vol;
 482                                         notif.nent_position = position;
 483                                 }
 484                         }
 485                         else
 486                         {
 487                                 print(sprintf(
 488                                         strcat(
 489                                                 "^1NOTIFICATION WITH NO SOUND: ",
 490                                                 "^7net_type = %s, net_name = %s.\n"
 491                                         ),
 492                                         typestring,
 493                                         namestring
 494                                 ));
 495                                 notif_error = TRUE;
 496                         }
 497                 }
 498                 else { notif.nent_enabled = FALSE; }
 499                 #else
 500                 notif.nent_enabled = FALSE;
 501                 #endif
 502         }
 503         else
 504         {
 505                 // Set MSG_INFO and MSG_CENTER string/float counts
 506                 notif.nent_stringcount = strnum;
 507                 notif.nent_floatcount = flnum;
 508
 509                 // Only initialize arguments if we're either a client or on a dedicated server
 510                 #ifdef SVQC
 511                 float should_process_args = server_is_dedicated;
 512                 #else
 513                 float should_process_args = TRUE;
 514                 #endif
 515
 516                 if(should_process_args)
 517                 {
 518                         // ========================
 519                         //  Process Main Arguments
 520                         // ========================
 521                         if(strnum + flnum)
 522                         {
 523                                 if(args != "")
 524                                 {
 525                                         notif.nent_args = strzone(
 526                                                 Process_Notif_Args(1, args, typestring, namestring));
 527                                 }
 528                                 else if((hudargs == "") && (durcnt ==""))
 529                                 {
 530                                         print(sprintf(
 531                                                 strcat(
 532                                                         "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: ",
 533                                                         "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d\n"
 534                                                 ),
 535                                                 typestring,
 536                                                 namestring,
 537                                                 strnum,
 538                                                 flnum
 539                                         ));
 540                                         notif_error = TRUE;
 541                                 }
 542                         }
 543                         else if(args != "")
 544                         {
 545                                 notif.nent_args = strzone(
 546                                         Process_Notif_Args(1, args, typestring, namestring));
 547                         }
 548
 549
 550                         // =======================================
 551                         //  Process HUD and Centerprint Arguments
 552                         //    Only processed on CSQC, as these
 553                         //    args are only for HUD features.
 554                         // =======================================
 555                         #ifdef CSQC
 556                         if(hudargs != "")
 557                         {
 558                                 notif.nent_hudargs = strzone(
 559                                         Process_Notif_Args(2, hudargs, typestring, namestring));
 560
 561                                 if(icon != "") { notif.nent_icon = strzone(icon); }
 562                                 else
 563                                 {
 564                                         print(sprintf(
 565                                                 strcat(
 566                                                         "^1NOTIFICATION HAS HUDARGS BUT NO ICON: ",
 567                                                         "^7net_type = %s, net_name = %s.\n"
 568                                                 ),
 569                                                 typestring,
 570                                                 namestring
 571                                         ));
 572                                         notif_error = TRUE;
 573                                 }
 574                         }
 575                         else if(icon != "")
 576                         {
 577                                 print(sprintf(
 578                                         strcat(
 579                                                 "^1NOTIFICATION HAS ICON BUT NO HUDARGS: ",
 580                                                 "^7net_type = %s, net_name = %s.\n"
 581                                         ),
 582                                         typestring,
 583                                         namestring
 584                                 ));
 585                                 notif_error = TRUE;
 586                         }
 587
 588                         if(durcnt != "")
 589                         {
 590                                 notif.nent_durcnt = strzone(
 591                                         Process_Notif_Args(3, durcnt, typestring, namestring));
 592
 593                                 if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
 594                                 else
 595                                 {
 596                                         print(sprintf(
 597                                                 strcat(
 598                                                         "^1NOTIFICATION HAS DURCNT BUT NO CPID: ",
 599                                                         "^7net_type = %s, net_name = %s.\n"
 600                                                 ),
 601                                                 typestring,
 602                                                 namestring
 603                                         ));
 604                                         notif_error = TRUE;
 605                                 }
 606                         }
 607                         else if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
 608                         #endif
 609
 610
 611                         // ======================
 612                         //  Process Notif String
 613                         // ======================
 614                         #define SET_NOTIF_STRING(string,stringname) \
 615                                 notif.nent_string = strzone(CCR( \
 616                                         Process_Notif_Line( \
 617                                                 msg_is_info, \
 618                                                 (var_cvar > 1), \
 619                                                 string, \
 620                                                 typestring, \
 621                                                 namestring, \
 622                                                 stringname \
 623                                         )) \
 624                                 );
 625
 626                         if(GENTLE)
 627                         {
 628                                 if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE") }
 629                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL") }
 630                         }
 631                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL") }
 632
 633                         #undef SET_NOTIF_STRING
 634
 635                         // Check to make sure a string was chosen
 636                         if(notif.nent_string == "")
 637                         {
 638                                 print(sprintf(
 639                                         strcat(
 640                                                 "^1EMPTY NOTIFICATION: ",
 641                                                 "^7net_type = %s, net_name = %s.\n"
 642                                         ),
 643                                         typestring,
 644                                         namestring
 645                                 ));
 646                                 notif_error = TRUE;
 647                         }
 648                 }
 649         }
 650
 651         // now check to see if any errors happened
 652         if(notif_error)
 653         {
 654                 notif.nent_enabled = FALSE; // disable the notification so it can't cause trouble
 655                 notif_global_error = TRUE; // throw the red flag that an error happened on init
 656         }
 657 }
 658
 659
 660 // =========================================
 661 //  Cvar Handling With 'dumpnotifs' Command
 662 // =========================================
 663
 664 void Dump_Notifications(float fh, float alsoprint)
 665 {
 666         #define NOTIF_WRITE(a) { \
 667                 fputs(fh, a); \
 668                 if(alsoprint) { print(a); } }
 669         #define NOTIF_WRITE_ENTITY(name,default,description) { \
 670                 notif_msg = \
 671                         sprintf( \
 672                                 "seta notification_%s \"%d\" \"%s\"\n", \
 673                                 name, default, description \
 674                         ); \
 675                 NOTIF_WRITE(notif_msg) }
 676         #define NOTIF_WRITE_HARDCODED(cvar,default,description) { \
 677                 notif_msg = \
 678                         sprintf( \
 679                                 "seta notification_%s \"%s\" \"%s\"\n", \
 680                                 cvar, default, description \
 681                         ); \
 682                 NOTIF_WRITE(notif_msg) }
 683
 684         string notif_msg;
 685         float i;
 686         entity e;
 687
 688         // Note: This warning only applies to the notifications.cfg file that is output...
 689
 690         // You ARE supposed to manually edit this function to add i.e. hard coded
 691         // notification variables for mutators or game modes or such and then
 692         // regenerate the notifications.cfg file from the new code.
 693
 694         NOTIF_WRITE("// ********************************************** //\n");
 695         NOTIF_WRITE("// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n");
 696         NOTIF_WRITE("// **                                          ** //\n");
 697         NOTIF_WRITE("// **  This file is automatically generated    ** //\n");
 698         NOTIF_WRITE("// **  by code with the command 'dumpnotifs'.  ** //\n");
 699         NOTIF_WRITE("// **                                          ** //\n");
 700         NOTIF_WRITE("// **  If you add a new notification, please   ** //\n");
 701         NOTIF_WRITE("// **  regenerate this file with that command  ** //\n");
 702         NOTIF_WRITE("// **  making sure that the output matches     ** //\n");
 703         NOTIF_WRITE("// **  with the lists and defaults in code.    ** //\n");
 704         NOTIF_WRITE("// **                                          ** //\n");
 705         NOTIF_WRITE("// ********************************************** //\n");
 706
 707         // These notifications will also append their string as a comment...
 708         // This is not necessary, and does not matter if they vary between config versions,
 709         // it is just a semi-helpful tool for those who want to manually change their user settings.
 710
 711         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications (count = %d):\n", NOTIF_ANNCE_COUNT));
 712         for(i = 1; i <= NOTIF_ANNCE_COUNT; ++i)
 713         {
 714                 e = Get_Notif_Ent(MSG_ANNCE, i);
 715                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 716                 NOTIF_WRITE_ENTITY(e.nent_name, e.nent_default, "Notification control cvar: 0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled)");
 717         }
 718
 719         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
 720         for(i = 1; i <= NOTIF_INFO_COUNT; ++i)
 721         {
 722                 e = Get_Notif_Ent(MSG_INFO, i);
 723                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 724                 NOTIF_WRITE_ENTITY(e.nent_name, e.nent_default, "Notification control cvar: 0 = off, 1 = print to console, 2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)");
 725         }
 726
 727         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
 728         for(i = 1; i <= NOTIF_CENTER_COUNT; ++i)
 729         {
 730                 e = Get_Notif_Ent(MSG_CENTER, i);
 731                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 732                 NOTIF_WRITE_ENTITY(e.nent_name, e.nent_default, "Notification control cvar: 0 = off, 1 = centerprint");
 733         }
 734
 735         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications (count = %d):\n", NOTIF_MULTI_COUNT));
 736         for(i = 1; i <= NOTIF_MULTI_COUNT; ++i)
 737         {
 738                 e = Get_Notif_Ent(MSG_MULTI, i);
 739                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 740                 NOTIF_WRITE_ENTITY(e.nent_name, e.nent_default, "Notification control cvar: 0 = off, 1 = trigger subcalls");
 741         }
 742
 743         // edit these to match whichever cvars are used for specific notification options
 744         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
 745         NOTIF_WRITE_HARDCODED("allow_chatboxprint",              "1",    "Allow notifications to be printed to chat box by setting notification cvar to 2 (You can also set this cvar to 2 to force ALL notifications to be printed to the chatbox)");
 746         NOTIF_WRITE_HARDCODED("ctf_capture_verbose",             "0",    "Show extra information when someone captures a flag");
 747         NOTIF_WRITE_HARDCODED("ctf_pickup_enemy_verbose",        "0",    "Show extra information if an enemy picks up a flag");
 748         NOTIF_WRITE_HARDCODED("ctf_pickup_team_verbose",         "0",    "Show extra information if a team mate picks up a flag");
 749         NOTIF_WRITE_HARDCODED("errors_are_fatal",                "1",    "If a notification fails upon initialization, cause a Host_Error to stop the program");
 750         NOTIF_WRITE_HARDCODED("frag_verbose",                    "1",    "Show extra information when you frag someone (or when you are fragged");
 751         NOTIF_WRITE_HARDCODED("item_centerprinttime",            "1.5",  "How long to show item information centerprint messages (like 'You got the Electro' or such)");
 752         NOTIF_WRITE_HARDCODED("lifetime_mapload",                "10",   "Amount of time that notification entities last immediately at mapload (in seconds) to help prevent notifications from being lost on early init (like gamestart countdown)");
 753         NOTIF_WRITE_HARDCODED("lifetime_runtime",                "0.5",  "Amount of time that notification entities last on the server during runtime (In seconds)");
 754         NOTIF_WRITE_HARDCODED("server_allows_frag_verbose",      "1",    "Server side cvar for showing extra information in frag messages... 0 = no extra frag information, 1 = frag information only in warmup, 2 = frag information allowed all the time");
 755         NOTIF_WRITE_HARDCODED("server_allows_location",          "1",    "Server side cvar for allowing death messages to show location information too");
 756         NOTIF_WRITE_HARDCODED("show_location",                   "0",    "Append location information to MSG_INFO death/kill messages");
 757         NOTIF_WRITE_HARDCODED("show_location_string",            "",     "Replacement string piped into sprintf, so you can do different messages like this: ' at the %s' or ' (near %s)'");
 758         NOTIF_WRITE_HARDCODED("show_sprees",                     "1",    "Print information about sprees in death/kill messages");
 759         NOTIF_WRITE_HARDCODED("show_sprees_center",              "1",    "Show spree information in MSG_CENTER messages... 0 = off, 1 = target (but only for first victim) and attacker");
 760         NOTIF_WRITE_HARDCODED("show_sprees_center_specialonly",  "1",    "Don't show spree information in MSG_CENTER messages if it isn't an achievement");
 761         NOTIF_WRITE_HARDCODED("show_sprees_info",                "3",    "Show spree information in MSG_INFO messages... 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker");
 762         NOTIF_WRITE_HARDCODED("show_sprees_info_newline",        "1",    "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself");
 763         NOTIF_WRITE_HARDCODED("show_sprees_info_specialonly",    "1",    "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement");
 764
 765         NOTIF_WRITE(sprintf(
 766                 strcat(
 767                         "\n// Notification counts (total = %d): ",
 768                         "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d\n"
 769                 ),
 770                 (
 771                         NOTIF_ANNCE_COUNT +
 772                         NOTIF_INFO_COUNT +
 773                         NOTIF_CENTER_COUNT +
 774                         NOTIF_MULTI_COUNT
 775                 ),
 776                 NOTIF_ANNCE_COUNT,
 777                 NOTIF_INFO_COUNT,
 778                 NOTIF_CENTER_COUNT,
 779                 NOTIF_MULTI_COUNT
 780         ));
 781
 782         return;
 783         #undef NOTIF_WRITE_HARDCODED
 784         #undef NOTIF_WRITE_ENTITY
 785         #undef NOTIF_WRITE
 786 }
 787
 788 #ifdef SVQC
 789 void Notification_GetCvars()
 790 {
 791         GetCvars_handleFloat(get_cvars_s, get_cvars_f, FRAG_VERBOSE, "notification_frag_verbose");
 792 }
 793 #endif
 794
 795
 796 // ===============================
 797 //  Frontend Notification Pushing
 798 // ===============================
 799
 800 string Local_Notification_sprintf(
 801         string input, string args,
 802         string s1, string s2, string s3, string s4,
 803         float f1, float f2, float f3, float f4)
 804 {
 805         #ifdef NOTIFICATIONS_DEBUG
 806         dprint(sprintf(
 807                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
 808                 MakeConsoleSafe(input),
 809                 args,
 810                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
 811                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
 812         ));
 813         #endif
 814
 815         string selected;
 816         float sel_num;
 817         for(sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
 818
 819         string tmp_s;
 820
 821         for(sel_num = 0;(args != "");)
 822         {
 823                 selected = car(args); args = cdr(args);
 824                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
 825                 switch(strtolower(selected))
 826                 {
 827                         #define ARG_CASE(prog,selected,result) \
 828                                 #ifdef CSQC \
 829                                         #if (prog != ARG_SV) && (prog != ARG_DC) \
 830                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 831                                         #endif \
 832                                 #else \
 833                                         #if (prog != ARG_CS) && (prog != ARG_DC) \
 834                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 835                                         #endif \
 836                                 #endif
 837                         NOTIF_ARGUMENT_LIST
 838                         #undef ARG_CASE
 839                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
 840                 }
 841         }
 842         return sprintf(input, arg_slot[0], arg_slot[1], arg_slot[2], arg_slot[3], arg_slot[4], arg_slot[5], arg_slot[6]);
 843 }
 844
 845 #ifdef CSQC
 846 void Local_Notification_sound(
 847         float soundchannel, string soundfile,
 848         float soundvolume, float soundposition)
 849 {
 850         if((soundfile != prev_soundfile) || (time >= (prev_soundtime + autocvar_cl_announcer_antispam)))
 851         {
 852                 #ifdef NOTIFICATIONS_DEBUG
 853                 dprint(sprintf(
 854                         "Local_Notification_sound(world, %f, '%s', %f, %f);\n",
 855                         soundchannel,
 856                         sprintf(
 857                                 "announcer/%s/%s.wav",
 858                                 autocvar_cl_announcer,
 859                                 soundfile
 860                         ),
 861                         soundvolume,
 862                         soundposition
 863                 ));
 864                 #endif
 865
 866                 sound(
 867                         world,
 868                         soundchannel,
 869                         sprintf(
 870                                 "announcer/%s/%s.wav",
 871                                 autocvar_cl_announcer,
 872                                 soundfile
 873                         ),
 874                         soundvolume,
 875                         soundposition
 876                 );
 877
 878                 if(prev_soundfile) { strunzone(prev_soundfile); }
 879                 prev_soundfile = strzone(soundfile);
 880                 prev_soundtime = time;
 881         }
 882         else
 883         {
 884                 #ifdef NOTIFICATIONS_DEBUG
 885                 dprint(sprintf(
 886                         "Local_Notification_sound(world, %f, '%s', %f, %f) ^1BLOCKED BY ANTISPAM:^7 prevsnd: '%s', time/prevtime: %f, limit: %f\n",
 887                         soundchannel,
 888                         sprintf(
 889                                 "announcer/%s/%s.wav",
 890                                 autocvar_cl_announcer,
 891                                 soundfile
 892                         ),
 893                         soundvolume,
 894                         soundposition,
 895                         prev_soundfile,
 896                         (time - prev_soundtime),
 897                         autocvar_cl_announcer_antispam
 898                 ));
 899                 #endif
 900         }
 901 }
 902 void Local_Notification_HUD_Notify_Push(
 903         string icon, string hudargs,
 904         string s1, string s2, string s3, string s4)
 905 {
 906         string selected;
 907         float sel_num;
 908         arg_slot[0] = ""; arg_slot[1] = "";
 909
 910         for(sel_num = 0;(hudargs != "");)
 911         {
 912                 selected = car(hudargs); hudargs = cdr(hudargs);
 913                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
 914                 switch(strtolower(selected))
 915                 {
 916                         #define ARG_CASE(prog,selected,result) \
 917                                 #if (prog == ARG_CS_SV_HA) \
 918                                         case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 919                                 #endif
 920                         NOTIF_ARGUMENT_LIST
 921                         #undef ARG_CASE
 922                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
 923                 }
 924         }
 925         #ifdef NOTIFICATIONS_DEBUG
 926         dprint(sprintf(
 927                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s);\n",
 928                 icon,
 929                 hudargs,
 930                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
 931                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
 932         ));
 933         #endif
 934         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
 935 }
 936
 937 void Local_Notification_centerprint_generic(
 938         string input, string durcnt,
 939         float cpid, float f1, float f2)
 940 {
 941         string selected;
 942         float sel_num;
 943         arg_slot[0] = ""; arg_slot[1] = "";
 944
 945         for(sel_num = 0;(durcnt != "");)
 946         {
 947                 selected = car(durcnt); durcnt = cdr(durcnt);
 948                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic")
 949                 switch(strtolower(selected))
 950                 {
 951                         #define ARG_CASE(prog,selected,result) \
 952                                 #if (prog == ARG_CS_SV_DC) || (prog == ARG_DC) \
 953                                         case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 954                                 #endif
 955                         NOTIF_ARGUMENT_LIST
 956                         #undef ARG_CASE
 957                         default:
 958                         {
 959                                 if(ftos(stof(selected)) != "") { arg_slot[sel_num] = selected; ++sel_num; }
 960                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic") }
 961                                 break;
 962                         }
 963                 }
 964         }
 965         #ifdef NOTIFICATIONS_DEBUG
 966         dprint(sprintf(
 967                 "Local_Notification_centerprint_generic('%s^7', '%s', %d, %d, %d, %d);\n",
 968                 MakeConsoleSafe(input),
 969                 durcnt,
 970                 f1, f2,
 971                 stof(arg_slot[0]), stof(arg_slot[1])
 972         ));
 973         #endif
 974         centerprint_generic(cpid, input, stof(arg_slot[0]), stof(arg_slot[1]));
 975 }
 976 #endif
 977
 978 void Local_Notification(float net_type, float net_name, ...count)
 979 {
 980         // check supplied type and name for errors
 981         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
 982         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs)); return; }
 983
 984         entity notif = Get_Notif_Ent(net_type, net_name);
 985         if not(notif) { backtrace("Local_Notification: Could not find notification entity!\n"); return; }
 986         if not(notif.nent_enabled)
 987         {
 988                 #ifdef NOTIFICATIONS_DEBUG
 989                 dprint(sprintf(
 990                         "Local_Notification(%s, %s): Entity was disabled...\n",
 991                         Get_Notif_TypeName(net_type),
 992                         notif.nent_name
 993                 ));
 994                 #endif
 995                 return;
 996         }
 997
 998         if((notif.nent_stringcount + notif.nent_floatcount) > count)
 999         {
1000                 backtrace(sprintf(
1001                         strcat(
1002                                 "Not enough arguments for Local_Notification(%s, %s, ...)! ",
1003                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1004                                 "Check the definition and function call for accuracy...?\n"
1005                         ),
1006                         Get_Notif_TypeName(net_type), notif.nent_name,
1007                         notif.nent_stringcount, notif.nent_floatcount, count
1008                 ));
1009                 return;
1010         }
1011         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1012         {
1013                 backtrace(sprintf(
1014                         strcat(
1015                                 "Too many arguments for Local_Notification(%s, %s, ...)! ",
1016                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1017                                 "Check the definition and function call for accuracy...?\n"
1018                         ),
1019                         Get_Notif_TypeName(net_type), notif.nent_name,
1020                         notif.nent_stringcount, notif.nent_floatcount, count
1021                 ));
1022                 return;
1023         }
1024
1025         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1026         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1027         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1028         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1029         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1030         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1031         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1032         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1033
1034         #ifdef NOTIFICATIONS_DEBUG
1035         dprint(sprintf(
1036                 "Local_Notification(%s, %s, %s, %s);\n",
1037                 Get_Notif_TypeName(net_type),
1038                 notif.nent_name,
1039                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1040                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1041         ));
1042         #endif
1043
1044         switch(net_type)
1045         {
1046                 case MSG_ANNCE:
1047                 {
1048                         #ifdef CSQC
1049                         Local_Notification_sound(
1050                                 notif.nent_channel,
1051                                 notif.nent_snd,
1052                                 notif.nent_vol,
1053                                 notif.nent_position
1054                         );
1055                         #else
1056                         backtrace("MSG_ANNCE on server?... Please notify Samual immediately!\n");
1057                         #endif
1058                         break;
1059                 }
1060
1061                 case MSG_INFO:
1062                 {
1063                         print(
1064                                 Local_Notification_sprintf(
1065                                         notif.nent_string,
1066                                         notif.nent_args,
1067                                         s1, s2, s3, s4,
1068                                         f1, f2, f3, f4)
1069                         );
1070                         #ifdef CSQC
1071                         if(notif.nent_icon != "")
1072                         {
1073                                 Local_Notification_HUD_Notify_Push(
1074                                         notif.nent_icon,
1075                                         notif.nent_hudargs,
1076                                         s1, s2, s3, s4);
1077                         }
1078                         #endif
1079                         break;
1080                 }
1081
1082                 #ifdef CSQC
1083                 case MSG_CENTER:
1084                 {
1085                         Local_Notification_centerprint_generic(
1086                                 Local_Notification_sprintf(
1087                                         notif.nent_string,
1088                                         notif.nent_args,
1089                                         s1, s2, s3, s4,
1090                                         f1, f2, f3, f4),
1091                                 notif.nent_durcnt,
1092                                 notif.nent_cpid,
1093                                 f1, f2);
1094                         break;
1095                 }
1096                 #endif
1097
1098                 case MSG_MULTI:
1099                 {
1100                         if(notif.nent_msginfo)
1101                         if(notif.nent_msginfo.nent_enabled)
1102                         {
1103                                 Local_Notification_WOVA(
1104                                         MSG_INFO,
1105                                         notif.nent_msginfo.nent_id,
1106                                         notif.nent_msginfo.nent_stringcount,
1107                                         notif.nent_msginfo.nent_floatcount,
1108                                         s1, s2, s3, s4,
1109                                         f1, f2, f3, f4);
1110                         }
1111                         #ifdef CSQC
1112                         if(notif.nent_msgannce)
1113                         if(notif.nent_msgannce.nent_enabled)
1114                         {
1115                                 Local_Notification_WOVA(
1116                                         MSG_ANNCE,
1117                                         notif.nent_msgannce.nent_id,
1118                                         0, 0,
1119                                         "", "", "", "",
1120                                         0, 0, 0, 0);
1121                         }
1122                         if(notif.nent_msgcenter)
1123                         if(notif.nent_msgcenter.nent_enabled)
1124                         {
1125                                 Local_Notification_WOVA(
1126                                         MSG_CENTER,
1127                                         notif.nent_msgcenter.nent_id,
1128                                         notif.nent_msgcenter.nent_stringcount,
1129                                         notif.nent_msgcenter.nent_floatcount,
1130                                         s1, s2, s3, s4,
1131                                         f1, f2, f3, f4);
1132                         }
1133                         #endif
1134                         break;
1135                 }
1136         }
1137 }
1138
1139 // WOVA = Without Variable Arguments
1140 void Local_Notification_WOVA(
1141         float net_type, float net_name,
1142         float stringcount, float floatcount,
1143         string s1, string s2, string s3, string s4,
1144         float f1, float f2, float f3, float f4)
1145 {
1146         #define VARITEM(stringc,floatc,args) \
1147                 if((stringcount == stringc) && (floatcount == floatc)) \
1148                         { Local_Notification(net_type, net_name, args); return; }
1149         EIGHT_VARS_TO_VARARGS_VARLIST
1150         #undef VARITEM
1151         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1152 }
1153
1154
1155 // =========================
1156 //  Notification Networking
1157 // =========================
1158
1159 #ifdef CSQC
1160 void Read_Notification(float is_new)
1161 {
1162         float net_type = ReadByte();
1163         float net_name = ReadShort();
1164
1165         entity notif;
1166
1167         if(net_type == MSG_CENTER_CPID)
1168         {
1169                 #ifdef NOTIFICATIONS_DEBUG
1170                 dprint(sprintf(
1171                         "Read_Notification(%d) at %f: net_type = %s, net_name = %d\n",
1172                         is_new,
1173                         time,
1174                         Get_Notif_TypeName(net_type),
1175                         net_name
1176                 ));
1177                 #endif
1178
1179                 if(is_new)
1180                 {
1181                         if(net_name == 0) { reset_centerprint_messages(); }
1182                         else if(net_name != NO_CPID)
1183                         {
1184                                 // in this case, net_name IS the cpid we want to kill
1185                                 centerprint_generic(net_name, "", 0, 0);
1186                         }
1187                         else
1188                         {
1189                                 backtrace(sprintf(
1190                                         "Read_Notification(%d) at %f: ^1TRIED TO KILL NO_CPID CENTERPRINT!\n",
1191                                         is_new,
1192                                         time
1193                                 ));
1194                         }
1195                 }
1196         }
1197         else
1198         {
1199                 notif = Get_Notif_Ent(net_type, net_name);
1200                 if not(notif) { backtrace("Read_Notification: Could not find notification entity!\n"); return; }
1201
1202                 #ifdef NOTIFICATIONS_DEBUG
1203                 dprint(sprintf(
1204                         "Read_Notification(%d) at %f: net_type = %s, net_name = %s\n",
1205                         is_new,
1206                         time,
1207                         Get_Notif_TypeName(net_type),
1208                         notif.nent_name
1209                 ));
1210                 #endif
1211
1212                 string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
1213                 string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
1214                 string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
1215                 string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
1216                 float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : 0);
1217                 float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : 0);
1218                 float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : 0);
1219                 float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : 0);
1220
1221                 if(is_new)
1222                 {
1223                         Local_Notification_WOVA(
1224                                 net_type, net_name,
1225                                 notif.nent_stringcount,
1226                                 notif.nent_floatcount,
1227                                 s1, s2, s3, s4,
1228                                 f1, f2, f3, f4);
1229                 }
1230         }
1231 }
1232 #endif
1233
1234 #ifdef SVQC
1235 void Net_Notification_Remove()
1236 {
1237         if not(self) { backtrace(sprintf("Net_Notification_Remove() at %f: Missing self!?\n", time)); return; }
1238
1239         #ifdef NOTIFICATIONS_DEBUG
1240         dprint(sprintf(
1241                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1242                 time,
1243                 ((self.nent_net_name == -1) ? "Killed" : "Removed"),
1244                 Get_Notif_TypeName(self.nent_net_type),
1245                 self.owner.nent_name
1246         ));
1247         #endif
1248
1249         float i;
1250         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
1251         remove(self);
1252 }
1253
1254 float Net_Write_Notification(entity client, float sf)
1255 {
1256         float i, send = FALSE;
1257
1258         switch(self.nent_broadcast)
1259         {
1260                 case NOTIF_ONE: // send to one client and their spectator
1261                 {
1262                         if(
1263                                 (client == self.nent_client)
1264                                 ||
1265                                 (
1266                                         IS_SPEC(client)
1267                                         &&
1268                                         (client.enemy == self.nent_client)
1269                                 )
1270                         ) { send = TRUE; }
1271                         break;
1272                 }
1273                 case NOTIF_ONE_ONLY: // send ONLY to one client
1274                 {
1275                         if(client == self.nent_client) { send = TRUE; }
1276                         break;
1277                 }
1278                 case NOTIF_TEAM: // send only to X team and their spectators
1279                 {
1280                         if(
1281                                 (client.team == self.nent_client.team)
1282                                 ||
1283                                 (
1284                                         IS_SPEC(client)
1285                                         &&
1286                                         (client.enemy.team == self.nent_client.team)
1287                                 )
1288                         ) { send = TRUE; }
1289                         break;
1290                 }
1291                 case NOTIF_TEAM_EXCEPT: // send only to X team and their spectators, except for Y person and their spectators
1292                 {
1293                         if(
1294                                 (client != self.nent_client)
1295                                 &&
1296                                 (
1297                                         (client.team == self.nent_client.team)
1298                                         ||
1299                                         (
1300                                                 IS_SPEC(client)
1301                                                 &&
1302                                                 (
1303                                                         (client.enemy != self.nent_client)
1304                                                         &&
1305                                                         (client.enemy.team == self.nent_client.team)
1306                                                 )
1307                                         )
1308                                 )
1309                         ) { send = TRUE; }
1310                         break;
1311                 }
1312                 case NOTIF_ALL: // send to everyone
1313                 {
1314                         send = TRUE;
1315                         break;
1316                 }
1317                 case NOTIF_ALL_EXCEPT: // send to everyone except X person and their spectators
1318                 {
1319                         if(
1320                                 (client != self.nent_client)
1321                                 &&
1322                                 !(
1323                                         IS_SPEC(client)
1324                                         &&
1325                                         (client.enemy == self.nent_client)
1326                                 )
1327                         ) { send = TRUE; }
1328                         break;
1329                 }
1330                 default: { send = FALSE; break; }
1331         }
1332
1333         if(send)
1334         {
1335                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1336                 WriteByte(MSG_ENTITY, self.nent_net_type);
1337                 WriteShort(MSG_ENTITY, self.nent_net_name);
1338                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
1339                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
1340         }
1341
1342         return send;
1343 }
1344
1345 void Kill_Notification(
1346         float broadcast, entity client,
1347         float net_type, float net_name)
1348 {
1349         string checkargs = Notification_CheckArgs(broadcast, client, 1, 1);
1350         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Kill_Notification: %s\n", checkargs)); return; }
1351
1352         #ifdef NOTIFICATIONS_DEBUG
1353         dprint(sprintf(
1354                 "Kill_Notification(%d, '%s', %s, %d);\n",
1355                 broadcast,
1356                 client.netname,
1357                 (net_type ? Get_Notif_TypeName(net_type) : "0"),
1358                 net_name
1359         ));
1360         #endif
1361
1362         entity notif, net_notif;
1363         float killed_cpid = NO_CPID;
1364
1365         switch(net_type)
1366         {
1367                 case 0:
1368                 {
1369                         killed_cpid = 0; // kill ALL centerprints
1370                         break;
1371                 }
1372
1373                 case MSG_CENTER:
1374                 {
1375                         if(net_name)
1376                         {
1377                                 entity notif = Get_Notif_Ent(net_type, net_name);
1378                                 if not(notif) { backtrace("Kill_Notification: Could not find notification entity!\n"); return; }
1379
1380                                 if(notif.nent_cpid)
1381                                         killed_cpid = notif.nent_cpid;
1382                                 else
1383                                         killed_cpid = NO_CPID;
1384                         }
1385                         else
1386                         {
1387                                 killed_cpid = 0; // kill ALL centerprints
1388                         }
1389                         break;
1390                 }
1391
1392                 case MSG_CENTER_CPID:
1393                 {
1394                         killed_cpid = net_name;
1395                         break;
1396                 }
1397         }
1398
1399         if(killed_cpid != NO_CPID)
1400         {
1401                 net_notif = spawn();
1402                 net_notif.classname = "net_kill_notification";
1403                 net_notif.nent_broadcast = broadcast;
1404                 net_notif.nent_client = client;
1405                 net_notif.nent_net_type = MSG_CENTER_CPID;
1406                 net_notif.nent_net_name = killed_cpid;
1407                 Net_LinkEntity(net_notif, FALSE, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1408         }
1409
1410         for(notif = world; (notif = find(notif, classname, "net_notification"));)
1411         {
1412                 if(net_type)
1413                 {
1414                         if(killed_cpid != NO_CPID)
1415                         {
1416                                 if(notif.owner.nent_cpid == killed_cpid)
1417                                 {
1418                                         notif.nent_net_name = -1;
1419                                         notif.nextthink = time;
1420                                 }
1421                                 else { continue; } // we ARE looking for a specific CPID, don't kill everything else too
1422                         }
1423                         else if(notif.nent_net_type == net_type)
1424                         {
1425                                 if(net_name)
1426                                 {
1427                                         if(notif.nent_net_name == net_name) { notif.nent_net_name = -1; notif.nextthink = time; }
1428                                         else { continue; } // we ARE looking for a certain net_name, don't kill everything else too
1429                                 }
1430                                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1431                         }
1432                         else { continue; } // we ARE looking for a certain net_type, don't kill everything else too
1433                 }
1434                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1435         }
1436 }
1437
1438 void Send_Notification(
1439         float broadcast, entity client,
1440         float net_type, float net_name,
1441         ...count)
1442 {
1443         // check supplied broadcast, target, type, and name for errors
1444         string checkargs = Notification_CheckArgs(broadcast, client, net_type, net_name);
1445         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs)); return; }
1446
1447         // retreive counts for the arguments of this notification
1448         entity notif = Get_Notif_Ent(net_type, net_name);
1449         if not(notif) { backtrace("Send_Notification: Could not find notification entity!\n"); return; }
1450
1451         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1452         {
1453                 backtrace(sprintf(
1454                         strcat(
1455                                 "Not enough arguments for Send_Notification(%d, %s, %s, ...)! ",
1456                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1457                                 "Check the definition and function call for accuracy...?\n"
1458                         ),
1459                         broadcast, Get_Notif_TypeName(net_type), notif.nent_name,
1460                         notif.nent_stringcount, notif.nent_floatcount, count
1461                 ));
1462                 return;
1463         }
1464         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1465         {
1466                 backtrace(sprintf(
1467                         strcat(
1468                                 "Too many arguments for Send_Notification(%d, %s, %s, ...)! ",
1469                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1470                                 "Check the definition and function call for accuracy...?\n"
1471                         ),
1472                         broadcast, Get_Notif_TypeName(net_type), notif.nent_name,
1473                         notif.nent_stringcount, notif.nent_floatcount, count
1474                 ));
1475                 return;
1476         }
1477
1478         #ifdef NOTIFICATIONS_DEBUG
1479         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1480         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1481         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1482         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1483         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1484         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1485         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1486         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1487         dprint(sprintf(
1488                 "Send_Notification(%d, %s, %s, %s, %s);\n",
1489                 broadcast,
1490                 Get_Notif_TypeName(net_type),
1491                 notif.nent_name,
1492                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1493                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1494         ));
1495         #endif
1496
1497         entity net_notif = spawn();
1498         net_notif.owner = notif;
1499         net_notif.classname = "net_notification";
1500         net_notif.nent_broadcast = broadcast;
1501         net_notif.nent_client = client;
1502         net_notif.nent_net_type = net_type;
1503         net_notif.nent_net_name = net_name;
1504         net_notif.nent_stringcount = notif.nent_stringcount;
1505         net_notif.nent_floatcount = notif.nent_floatcount;
1506
1507         float i;
1508         for(i = 0; i < net_notif.nent_stringcount; ++i) { net_notif.nent_strings[i] = strzone(...(i, string)); }
1509         for(i = 0; i < net_notif.nent_floatcount; ++i) { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
1510
1511         net_notif.think = Net_Notification_Remove;
1512         net_notif.nextthink =
1513                 ((time > autocvar_notification_lifetime_mapload)
1514                 ?
1515                         (time + autocvar_notification_lifetime_runtime)
1516                         :
1517                         autocvar_notification_lifetime_mapload
1518                 );
1519
1520         Net_LinkEntity(net_notif, FALSE, 0, Net_Write_Notification);
1521
1522         if(server_is_dedicated && (broadcast == NOTIF_ALL || broadcast == NOTIF_ALL_EXCEPT) && (net_type != MSG_ANNCE) && (net_type != MSG_CENTER))
1523         {
1524                 Local_Notification_WOVA(
1525                         net_type, net_name,
1526                         notif.nent_stringcount,
1527                         notif.nent_floatcount,
1528                         IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3),
1529                         IFFL(0), IFFL(1), IFFL(2), IFFL(3));
1530         }
1531 }
1532
1533 // WOVA = Without Variable Arguments
1534 void Send_Notification_WOVA(
1535         float broadcast, entity client,
1536         float net_type, float net_name,
1537         string s1, string s2, string s3, string s4,
1538         float f1, float f2, float f3, float f4)
1539 {
1540         entity notif = Get_Notif_Ent(net_type, net_name);
1541
1542         #ifdef NOTIFICATIONS_DEBUG
1543         dprint(sprintf(
1544                 "Send_Notification_WOVA(%d, %s, %s, %s, %s);\n",
1545                 broadcast,
1546                 Get_Notif_TypeName(net_type),
1547                 notif.nent_name,
1548                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1549                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1550         ));
1551         #endif
1552
1553         #define VARITEM(stringc,floatc,args) \
1554                 if((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
1555                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
1556         EIGHT_VARS_TO_VARARGS_VARLIST
1557         #undef VARITEM
1558         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
1559 }
1560 #endif // ifdef SVQC