qcsrc/common/notifications.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "constants.qh"
   7     #include "teams.qh"
   8     #include "counting.qh"
   9     #include "../server/autocvars.qh"
  10     #include "../server/constants.qh"
  11     #include "../server/defs.qh"
  12     #include "notifications.qh"
  13     #include "../server/mutators/mutators_include.qh"
  14 #endif
  15
  16 // ================================================
  17 //  Unified notification system, written by Samual
  18 //  Last updated: August, 2013
  19 // ================================================
  20
  21 string Get_Notif_TypeName(int net_type)
  22 {
  23         switch(net_type)
  24         {
  25                 case MSG_ANNCE: return "MSG_ANNCE";
  26                 case MSG_INFO: return "MSG_INFO";
  27                 case MSG_CENTER: return "MSG_CENTER";
  28                 case MSG_CENTER_CPID: return "MSG_CENTER_CPID";
  29                 case MSG_MULTI: return "MSG_MULTI";
  30                 case MSG_CHOICE: return "MSG_CHOICE";
  31         }
  32         backtrace(sprintf("Get_Notif_TypeName(%d): Improper net type!\n", net_type));
  33         return "";
  34 }
  35
  36 entity Get_Notif_Ent(int net_type, int net_name)
  37 {
  38         switch(net_type)
  39         {
  40                 case MSG_ANNCE: return msg_annce_notifs[net_name - 1];
  41                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  42                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  43                 case MSG_MULTI: return msg_multi_notifs[net_name - 1];
  44                 case MSG_CHOICE: return msg_choice_notifs[net_name - 1];
  45         }
  46         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  47         return world;
  48 }
  49
  50 #ifdef SVQC
  51 #ifdef NOTIFICATIONS_DEBUG
  52 string Get_Notif_BroadcastName(float broadcast)
  53 {
  54         switch(broadcast)
  55         {
  56                 case NOTIF_ONE: return "NOTIF_ONE";
  57                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
  58                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
  59                 case NOTIF_ALL: return "NOTIF_ALL";
  60                 case NOTIF_TEAM: return "NOTIF_TEAM";
  61                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
  62         }
  63         backtrace(sprintf("Get_Notif_BroadcastName(%d): Improper broadcast!\n", broadcast));
  64         return "";
  65 }
  66 #endif
  67 #endif
  68
  69 string Notification_CheckArgs_TypeName(float net_type, float net_name)
  70 {
  71         // check supplied type and name for errors
  72         string checkargs = "";
  73         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
  74                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
  75                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
  76         switch(net_type)
  77         {
  78                 CHECKARG_TYPENAME(ANNCE)
  79                 CHECKARG_TYPENAME(INFO)
  80                 CHECKARG_TYPENAME(CENTER)
  81                 CHECKARG_TYPENAME(MULTI)
  82                 CHECKARG_TYPENAME(CHOICE)
  83                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
  84         }
  85         #undef CHECKARG_TYPENAME
  86         return checkargs;
  87 }
  88
  89 #ifdef SVQC
  90 string Notification_CheckArgs(
  91         float broadcast, entity client,
  92         float net_type, float net_name)
  93 {
  94         // check supplied broadcast, target, type, and name for errors
  95         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
  96         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
  97         switch(broadcast)
  98         {
  99                 case NOTIF_ONE:
 100                 case NOTIF_ONE_ONLY:
 101                 {
 102                         if(IS_NOT_A_CLIENT(client))
 103                                 { checkargs = sprintf("%sNo client provided!", checkargs); }
 104                         break;
 105                 }
 106
 107                 case NOTIF_ALL_EXCEPT:
 108                 {
 109                         if(IS_NOT_A_CLIENT(client))
 110                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 111                         break;
 112                 }
 113
 114                 case NOTIF_ALL:
 115                 {
 116                         if(client)
 117                                 { checkargs = sprintf("%sEntity provided when world was required!", checkargs); }
 118                         break;
 119                 }
 120
 121                 case NOTIF_TEAM:
 122                 {
 123                         if (!teamplay)
 124                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 125                         //else if (!client.team) { checkargs = sprintf("%sNo team provided!", checkargs); }
 126                         break;
 127                 }
 128
 129                 case NOTIF_TEAM_EXCEPT:
 130                 {
 131                         if (!teamplay)
 132                                 { checkargs = sprintf("%sTeamplay not active!", checkargs); }
 133                         else if(IS_NOT_A_CLIENT(client))
 134                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
 135                         break;
 136                 }
 137
 138                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
 139         }
 140         return checkargs;
 141 }
 142
 143 float Notification_ShouldSend(float broadcast, entity to_client, entity other_client)
 144 {
 145         switch(broadcast)
 146         {
 147                 case NOTIF_ONE: // send to one client and their spectator
 148                 {
 149                         if(
 150                                 (to_client == other_client)
 151                                 ||
 152                                 (
 153                                         IS_SPEC(to_client)
 154                                         &&
 155                                         (to_client.enemy == other_client)
 156                                 )
 157                         ) { return true; }
 158                         break;
 159                 }
 160                 case NOTIF_ONE_ONLY: // send ONLY to one client
 161                 {
 162                         if(to_client == other_client) { return true; }
 163                         break;
 164                 }
 165                 case NOTIF_TEAM: // send only to X team and their spectators
 166                 {
 167                         if(
 168                                 (to_client.team == other_client.team)
 169                                 ||
 170                                 (
 171                                         IS_SPEC(to_client)
 172                                         &&
 173                                         (to_client.enemy.team == other_client.team)
 174                                 )
 175                         ) { return true; }
 176                         break;
 177                 }
 178                 case NOTIF_TEAM_EXCEPT: // send only to X team and their spectators, except for Y person and their spectators
 179                 {
 180                         if(
 181                                 (to_client != other_client)
 182                                 &&
 183                                 (
 184                                         (to_client.team == other_client.team)
 185                                         ||
 186                                         (
 187                                                 IS_SPEC(to_client)
 188                                                 &&
 189                                                 (
 190                                                         (to_client.enemy != other_client)
 191                                                         &&
 192                                                         (to_client.enemy.team == other_client.team)
 193                                                 )
 194                                         )
 195                                 )
 196                         ) { return true; }
 197                         break;
 198                 }
 199                 case NOTIF_ALL: // send to everyone
 200                 {
 201                         return true;
 202                 }
 203                 case NOTIF_ALL_EXCEPT: // send to everyone except X person and their spectators
 204                 {
 205                         if(
 206                                 (to_client != other_client)
 207                                 &&
 208                                 !(
 209                                         IS_SPEC(to_client)
 210                                         &&
 211                                         (to_client.enemy == other_client)
 212                                 )
 213                         ) { return true; }
 214                         break;
 215                 }
 216         }
 217         return false;
 218 }
 219
 220 #endif
 221
 222 // ===============================
 223 //  Initialization Core Functions
 224 // ===============================
 225
 226 // used by restartnotifs command to initialize notifications
 227 void Destroy_Notification_Entity(entity notif)
 228 {
 229         if(notif.nent_name != "") { strunzone(notif.nent_name); }
 230         if(notif.nent_snd != "") { strunzone(notif.nent_snd); }
 231         if(notif.nent_args != "") { strunzone(notif.nent_args); }
 232         if(notif.nent_hudargs != "") { strunzone(notif.nent_hudargs); }
 233         if(notif.nent_icon != "") { strunzone(notif.nent_icon); }
 234         if(notif.nent_durcnt != "") { strunzone(notif.nent_durcnt); }
 235         if(notif.nent_string != "") { strunzone(notif.nent_string); }
 236         remove(notif);
 237 }
 238
 239 void Destroy_All_Notifications(void)
 240 {
 241         entity notif;
 242         int i;
 243
 244         #define DESTROY_LOOP(type,count) do { \
 245                 for(i = 1; i <= count; ++i) \
 246                 { \
 247                         notif = Get_Notif_Ent(type, i); \
 248                         if (!notif) { backtrace("Destroy_All_Notifications(): Missing notification entity!\n"); return; } \
 249                         Destroy_Notification_Entity(notif); \
 250                 } \
 251         } while(0)
 252
 253         // kill all networked notifications and centerprints
 254         #ifdef SVQC
 255         Kill_Notification(NOTIF_ALL, world, 0, 0);
 256         #else
 257         reset_centerprint_messages();
 258         #endif
 259
 260         // kill all real notification entities
 261         DESTROY_LOOP(MSG_ANNCE, NOTIF_ANNCE_COUNT);
 262         DESTROY_LOOP(MSG_INFO, NOTIF_INFO_COUNT);
 263         DESTROY_LOOP(MSG_CENTER, NOTIF_CENTER_COUNT);
 264         DESTROY_LOOP(MSG_MULTI, NOTIF_MULTI_COUNT);
 265         DESTROY_LOOP(MSG_CHOICE, NOTIF_CHOICE_COUNT);
 266         #undef DESTROY_LOOP
 267 }
 268
 269 string Process_Notif_Line(
 270         int typeId,
 271         bool chat,
 272         string input,
 273         string notiftype,
 274         string notifname,
 275         string stringtype)
 276 {
 277         #ifdef CSQC
 278         if(typeId == MSG_INFO)
 279         {
 280                 if((chat && autocvar_notification_allow_chatboxprint)
 281                         || (autocvar_notification_allow_chatboxprint == 2))
 282                 {
 283                         // pass 1: add ETX char at beginning of line
 284                         input = strcat("\{3}", input);
 285
 286                         // pass 2: add ETX char at end of each new line (so that
 287                         // messages with multiple lines are put through chatbox too)
 288                         input = strreplace("\n", "\n\{3}", input);
 289
 290                         // pass 3: strip trailing ETX char
 291                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
 292                                 { input = substring(input, 0, (strlen(input) - 1)); }
 293                 }
 294         }
 295         #endif
 296
 297         // done to both MSG_INFO and MSG_CENTER
 298         if(substring(input, (strlen(input) - 1), 1) == "\n")
 299         {
 300                 printf(
 301                         strcat(
 302                                 "^1TRAILING NEW LINE AT END OF NOTIFICATION: ",
 303                                 "^7net_type = %s, net_name = %s, string = %s.\n"
 304                         ),
 305                         notiftype,
 306                         notifname,
 307                         stringtype
 308                 );
 309                 notif_error = true;
 310                 input = substring(input, 1, (strlen(input) - 1));
 311         }
 312
 313         return input;
 314 }
 315
 316 string Process_Notif_Args(
 317         float arg_type,
 318         string args,
 319         string notiftype,
 320         string notifname)
 321 {
 322         string selected, remaining = args;
 323         float sel_num = 0;
 324
 325         for (;(remaining != "");)
 326         {
 327                 selected = car(remaining); remaining = cdr(remaining);
 328
 329                 switch(arg_type)
 330                 {
 331                         case 1: // normal args
 332                         {
 333                                 if(sel_num == NOTIF_MAX_ARGS)
 334                                 {
 335                                         printf(
 336                                                 strcat(
 337                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 338                                                         "^7net_type = %s, net_name = %s, max args = %d.\n"
 339                                                 ),
 340                                                 notiftype,
 341                                                 notifname,
 342                                                 NOTIF_MAX_ARGS
 343                                         );
 344                                         notif_error = true;
 345                                         break;
 346                                 }
 347
 348                                 switch(strtolower(selected))
 349                                 {
 350                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { ++sel_num; break; }
 351                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { ++sel_num; break; }
 352                                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { ++sel_num; break; }
 353                                         #define ARG_CASE_ARG_CS(selected,result)       case selected: { ++sel_num; break; }
 354                                         #define ARG_CASE_ARG_SV(selected,result)       case selected: { ++sel_num; break; }
 355                                         #define ARG_CASE_ARG_DC(selected,result)
 356                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 357                                         NOTIF_ARGUMENT_LIST
 358                                         #undef ARG_CASE
 359                                         #undef ARG_CASE_ARG_DC
 360                                         #undef ARG_CASE_ARG_SV
 361                                         #undef ARG_CASE_ARG_CS
 362                                         #undef ARG_CASE_ARG_CS_SV
 363                                         #undef ARG_CASE_ARG_CS_SV_DC
 364                                         #undef ARG_CASE_ARG_CS_SV_HA
 365                                         default:
 366                                         {
 367                                                 printf(
 368                                                         strcat(
 369                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 370                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'.\n"
 371                                                         ),
 372                                                         notiftype,
 373                                                         notifname,
 374                                                         selected
 375                                                 );
 376                                                 notif_error = true;
 377                                                 break;
 378                                         }
 379                                 }
 380                                 break;
 381                         }
 382                         case 2: // hudargs
 383                         {
 384                                 if(sel_num == NOTIF_MAX_HUDARGS)
 385                                 {
 386                                         printf(
 387                                                 strcat(
 388                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 389                                                         "^7net_type = %s, net_name = %s, max hudargs = %d.\n"
 390                                                 ),
 391                                                 notiftype,
 392                                                 notifname,
 393                                                 NOTIF_MAX_HUDARGS
 394                                         );
 395                                         notif_error = true;
 396                                         break;
 397                                 }
 398
 399                                 switch(strtolower(selected))
 400                                 {
 401                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { ++sel_num; break; }
 402                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
 403                                         #define ARG_CASE_ARG_CS_SV(selected,result)
 404                                         #define ARG_CASE_ARG_CS(selected,result)
 405                                         #define ARG_CASE_ARG_SV(selected,result)
 406                                         #define ARG_CASE_ARG_DC(selected,result)
 407                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 408                                         NOTIF_ARGUMENT_LIST
 409                                         #undef ARG_CASE
 410                                         #undef ARG_CASE_ARG_DC
 411                                         #undef ARG_CASE_ARG_SV
 412                                         #undef ARG_CASE_ARG_CS
 413                                         #undef ARG_CASE_ARG_CS_SV
 414                                         #undef ARG_CASE_ARG_CS_SV_DC
 415                                         #undef ARG_CASE_ARG_CS_SV_HA
 416                                         default:
 417                                         {
 418                                                 printf(
 419                                                         strcat(
 420                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 421                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'.\n"
 422                                                         ),
 423                                                         notiftype,
 424                                                         notifname,
 425                                                         selected
 426                                                 );
 427                                                 notif_error = true;
 428                                                 break;
 429                                         }
 430                                 }
 431                                 break;
 432                         }
 433                         case 3: // durcnt
 434                         {
 435                                 if(sel_num == NOTIF_MAX_DURCNT)
 436                                 {
 437                                         printf(
 438                                                 strcat(
 439                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 440                                                         "^7net_type = %s, net_name = %s, max durcnt = %d.\n"
 441                                                 ),
 442                                                 notiftype,
 443                                                 notifname,
 444                                                 NOTIF_MAX_DURCNT
 445                                         );
 446                                         notif_error = true;
 447                                         break;
 448                                 }
 449
 450                                 switch(strtolower(selected))
 451                                 {
 452                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
 453                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { ++sel_num; break; }
 454                                         #define ARG_CASE_ARG_CS_SV(selected,result)
 455                                         #define ARG_CASE_ARG_CS(selected,result)
 456                                         #define ARG_CASE_ARG_SV(selected,result)
 457                                         #define ARG_CASE_ARG_DC(selected,result)       case selected: { ++sel_num; break; }
 458                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 459                                         NOTIF_ARGUMENT_LIST
 460                                         #undef ARG_CASE
 461                                         #undef ARG_CASE_ARG_DC
 462                                         #undef ARG_CASE_ARG_SV
 463                                         #undef ARG_CASE_ARG_CS
 464                                         #undef ARG_CASE_ARG_CS_SV
 465                                         #undef ARG_CASE_ARG_CS_SV_DC
 466                                         #undef ARG_CASE_ARG_CS_SV_HA
 467                                         default:
 468                                         {
 469                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
 470                                                 else
 471                                                 {
 472                                                         printf(
 473                                                                 strcat(
 474                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 475                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'.\n"
 476                                                                 ),
 477                                                                 notiftype,
 478                                                                 notifname,
 479                                                                 selected
 480                                                         );
 481                                                         notif_error = true;
 482                                                 }
 483                                                 break;
 484                                         }
 485                                 }
 486                                 break;
 487                         }
 488                 }
 489         }
 490         return args;
 491 }
 492
 493 void Create_Notification_Entity(
 494         float var_default,
 495         float var_cvar,
 496         int typeId,
 497         int nameid,
 498         string namestring,
 499         int strnum,
 500         int flnum,
 501         /* MSG_ANNCE */
 502         float channel,
 503         string snd,
 504         float vol,
 505         float position,
 506         /* MSG_INFO & MSG_CENTER */
 507         string args,
 508         string hudargs,
 509         string icon,
 510         float cpid,
 511         string durcnt,
 512         string normal,
 513         string gentle,
 514         /* MSG_MULTI */
 515         int anncename,
 516         int infoname,
 517         int centername,
 518         /* MSG_CHOICE */
 519         float challow_def,
 520         float challow_var,
 521         int chtype,
 522         int optiona,
 523         int optionb)
 524 {
 525         // =====================
 526         //  Global Entity Setup
 527         // =====================
 528         entity notif = spawn();
 529         switch(typeId)
 530         {
 531                 case MSG_ANNCE:
 532                 {
 533                         msg_annce_notifs[nameid - 1] = notif;
 534                         notif.classname = "msg_annce_notification";
 535                         break;
 536                 }
 537                 case MSG_INFO:
 538                 {
 539                         msg_info_notifs[nameid - 1] = notif;
 540                         notif.classname = "msg_info_notification";
 541                         break;
 542                 }
 543                 case MSG_CENTER:
 544                 {
 545                         msg_center_notifs[nameid - 1] = notif;
 546                         notif.classname = "msg_center_notification";
 547                         break;
 548                 }
 549                 case MSG_MULTI:
 550                 {
 551                         msg_multi_notifs[nameid - 1] = notif;
 552                         notif.classname = "msg_multi_notification";
 553                         break;
 554                 }
 555                 case MSG_CHOICE:
 556                 {
 557                         msg_choice_notifs[nameid - 1] = notif;
 558                         notif.classname = "msg_choice_notification";
 559                         break;
 560                 }
 561
 562                 default:
 563                 {
 564                         error(sprintf(
 565                                 strcat(
 566                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
 567                                         "^7net_type = %d, net_name = %s.\n"
 568                                 ),
 569                                 typeId,
 570                                 namestring
 571                         ));
 572                         return; // It's not possible to recover from this one
 573                 }
 574         }
 575         notif.nent_default = var_default;
 576         notif.nent_enabled = (1 <= var_cvar);
 577         notif.nent_type = typeId;
 578         notif.nent_id = nameid;
 579         notif.nent_name = strzone(namestring);
 580
 581         string typestring = Get_Notif_TypeName(typeId);
 582
 583         // Other pre-notif-setup requisites
 584         notif_error = false;
 585
 586         // ====================
 587         //  Notification Setup
 588         // ====================
 589         switch(typeId)
 590         {
 591                 case MSG_ANNCE:
 592                 {
 593                         // Set MSG_ANNCE information and handle precaching
 594                         #ifdef CSQC
 595                         if (!(GENTLE && (var_cvar == 1)))
 596                         {
 597                                 if(snd != "")
 598                                 {
 599                                         if(notif.nent_enabled)
 600                                         {
 601                                                 precache_sound(sprintf("announcer/%s/%s.wav", autocvar_cl_announcer, snd));
 602                                                 notif.nent_channel = channel;
 603                                                 notif.nent_snd = strzone(snd);
 604                                                 notif.nent_vol = vol;
 605                                                 notif.nent_position = position;
 606                                         }
 607                                 }
 608                                 else
 609                                 {
 610                                         printf(
 611                                                 strcat(
 612                                                         "^1NOTIFICATION WITH NO SOUND: ",
 613                                                         "^7net_type = %s, net_name = %s.\n"
 614                                                 ),
 615                                                 typestring,
 616                                                 namestring
 617                                         );
 618                                         notif_error = true;
 619                                 }
 620                         }
 621                         else { notif.nent_enabled = false; }
 622                         #else
 623                         notif.nent_enabled = false;
 624                         #endif
 625
 626                         break;
 627                 }
 628
 629                 case MSG_INFO:
 630                 case MSG_CENTER:
 631                 {
 632                         // Set MSG_INFO and MSG_CENTER string/float counts
 633                         notif.nent_stringcount = strnum;
 634                         notif.nent_floatcount = flnum;
 635
 636                         // Only initialize arguments if we're either a client or on a dedicated server
 637                         #ifdef SVQC
 638                         float should_process_args = server_is_dedicated;
 639                         #else
 640                         float should_process_args = true;
 641                         #endif
 642
 643                         if(should_process_args)
 644                         {
 645                                 // ========================
 646                                 //  Process Main Arguments
 647                                 // ========================
 648                                 if(strnum + flnum)
 649                                 {
 650                                         if(args != "")
 651                                         {
 652                                                 notif.nent_args = strzone(
 653                                                         Process_Notif_Args(1, args, typestring, namestring));
 654                                         }
 655                                         else if((hudargs == "") && (durcnt ==""))
 656                                         {
 657                                                 printf(
 658                                                         strcat(
 659                                                                 "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: ",
 660                                                                 "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d\n"
 661                                                         ),
 662                                                         typestring,
 663                                                         namestring,
 664                                                         strnum,
 665                                                         flnum
 666                                                 );
 667                                                 notif_error = true;
 668                                         }
 669                                 }
 670                                 else if(args != "")
 671                                 {
 672                                         notif.nent_args = strzone(
 673                                                 Process_Notif_Args(1, args, typestring, namestring));
 674                                 }
 675
 676
 677                                 // =======================================
 678                                 //  Process HUD and Centerprint Arguments
 679                                 //    Only processed on CSQC, as these
 680                                 //    args are only for HUD features.
 681                                 // =======================================
 682                                 #ifdef CSQC
 683                                 if(hudargs != "")
 684                                 {
 685                                         notif.nent_hudargs = strzone(
 686                                                 Process_Notif_Args(2, hudargs, typestring, namestring));
 687
 688                                         if(icon != "") { notif.nent_icon = strzone(icon); }
 689                                         else
 690                                         {
 691                                                 printf(
 692                                                         strcat(
 693                                                                 "^1NOTIFICATION HAS HUDARGS BUT NO ICON: ",
 694                                                                 "^7net_type = %s, net_name = %s.\n"
 695                                                         ),
 696                                                         typestring,
 697                                                         namestring
 698                                                 );
 699                                                 notif_error = true;
 700                                         }
 701                                 }
 702                                 else if(icon != "")
 703                                 {
 704                                         printf(
 705                                                 strcat(
 706                                                         "^1NOTIFICATION HAS ICON BUT NO HUDARGS: ",
 707                                                         "^7net_type = %s, net_name = %s.\n"
 708                                                 ),
 709                                                 typestring,
 710                                                 namestring
 711                                         );
 712                                         notif_error = true;
 713                                 }
 714
 715                                 if(durcnt != "")
 716                                 {
 717                                         notif.nent_durcnt = strzone(
 718                                                 Process_Notif_Args(3, durcnt, typestring, namestring));
 719
 720                                         if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
 721                                         else
 722                                         {
 723                                                 printf(
 724                                                         strcat(
 725                                                                 "^1NOTIFICATION HAS DURCNT BUT NO CPID: ",
 726                                                                 "^7net_type = %s, net_name = %s.\n"
 727                                                         ),
 728                                                         typestring,
 729                                                         namestring
 730                                                 );
 731                                                 notif_error = true;
 732                                         }
 733                                 }
 734                                 else if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
 735                                 #endif
 736
 737
 738                                 // ======================
 739                                 //  Process Notif String
 740                                 // ======================
 741                                 #define SET_NOTIF_STRING(string,stringname) do { \
 742                                         notif.nent_string = strzone(CCR( \
 743                                                 Process_Notif_Line( \
 744                                                         typeId, \
 745                                                         (var_cvar > 1), \
 746                                                         string, \
 747                                                         typestring, \
 748                                                         namestring, \
 749                                                         stringname \
 750                                                 )) \
 751                                         ); \
 752                                 } while(0)
 753
 754                                 if(GENTLE)
 755                                 {
 756                                         if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE"); }
 757                                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
 758                                 }
 759                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
 760                                 #undef SET_NOTIF_STRING
 761
 762                                 // Check to make sure a string was chosen
 763                                 if(notif.nent_string == "")
 764                                 {
 765                                         printf(
 766                                                 strcat(
 767                                                         "^1EMPTY NOTIFICATION: ",
 768                                                         "^7net_type = %s, net_name = %s.\n"
 769                                                 ),
 770                                                 typestring,
 771                                                 namestring
 772                                         );
 773                                         notif_error = true;
 774                                 }
 775                         }
 776
 777                         break;
 778                 }
 779
 780                 case MSG_MULTI:
 781                 {
 782                         // Set MSG_MULTI string/float counts
 783                         if((anncename == NO_MSG) && (infoname == NO_MSG) && (centername == NO_MSG))
 784                         {
 785                                 printf(
 786                                         strcat(
 787                                                 "^1NOTIFICATION WITH NO SUBCALLS: ",
 788                                                 "^7net_type = %s, net_name = %s.\n"
 789                                         ),
 790                                         typestring,
 791                                         namestring
 792                                 );
 793                                 notif_error = true;
 794                         }
 795                         else
 796                         {
 797                                 // announcements don't actually need any arguments, so lets not even count them.
 798                                 if(anncename != NO_MSG) { notif.nent_msgannce = msg_annce_notifs[anncename - 1]; }
 799
 800                                 float infoname_stringcount = 0, infoname_floatcount = 0;
 801                                 float centername_stringcount = 0, centername_floatcount = 0;
 802
 803                                 if(infoname != NO_MSG)
 804                                 {
 805                                         notif.nent_msginfo = msg_info_notifs[infoname - 1];
 806                                         infoname_stringcount = notif.nent_msginfo.nent_stringcount;
 807                                         infoname_floatcount = notif.nent_msginfo.nent_floatcount;
 808                                 }
 809
 810                                 if(centername != NO_MSG)
 811                                 {
 812                                         notif.nent_msgcenter = msg_center_notifs[centername - 1];
 813                                         centername_stringcount = notif.nent_msgcenter.nent_stringcount;
 814                                         centername_floatcount = notif.nent_msgcenter.nent_floatcount;
 815                                 }
 816
 817                                 // set the requirements of THIS notification to the totals of its subcalls
 818                                 notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
 819                                 notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
 820                         }
 821
 822                         break;
 823                 }
 824
 825                 case MSG_CHOICE:
 826                 {
 827                         if((chtype == NO_MSG) || (optiona == NO_MSG) || (optionb == NO_MSG))
 828                         {
 829                                 printf(
 830                                         strcat(
 831                                                 "^1NOTIFICATION IS MISSING CHOICE PARAMS: ",
 832                                                 "^7net_type = %s, net_name = %s.\n"
 833                                         ),
 834                                         typestring,
 835                                         namestring
 836                                 );
 837                                 notif_error = true;
 838                         }
 839                         else
 840                         {
 841                                 switch(chtype)
 842                                 {
 843                                         case MSG_ANNCE:
 844                                         {
 845                                                 notif.nent_optiona = msg_annce_notifs[optiona - 1];
 846                                                 notif.nent_optionb = msg_annce_notifs[optionb - 1];
 847                                                 break;
 848                                         }
 849                                         case MSG_INFO:
 850                                         {
 851                                                 notif.nent_optiona = msg_info_notifs[optiona - 1];
 852                                                 notif.nent_optionb = msg_info_notifs[optionb - 1];
 853                                                 break;
 854                                         }
 855                                         case MSG_CENTER:
 856                                         {
 857                                                 notif.nent_optiona = msg_center_notifs[optiona - 1];
 858                                                 notif.nent_optionb = msg_center_notifs[optionb - 1];
 859                                                 break;
 860                                         }
 861                                         case MSG_MULTI:
 862                                         {
 863                                                 notif.nent_optiona = msg_multi_notifs[optiona - 1];
 864                                                 notif.nent_optionb = msg_multi_notifs[optionb - 1];
 865                                                 break;
 866                                         }
 867                                         case MSG_CHOICE: // should we REALLY allow nested options?...
 868                                         {
 869                                                 notif.nent_optiona = msg_choice_notifs[optiona - 1];
 870                                                 notif.nent_optionb = msg_choice_notifs[optionb - 1];
 871                                                 break;
 872                                         }
 873
 874                                         default:
 875                                         {
 876                                                 printf(
 877                                                         strcat(
 878                                                                 "^1NOTIFICATION WITH IMPROPER TYPE: ",
 879                                                                 "^7net_type = %d, net_name = %s.\n"
 880                                                         ),
 881                                                         typeId,
 882                                                         namestring
 883                                                 );
 884                                                 notif_error = true;
 885                                                 break;
 886                                         }
 887                                 }
 888                                 notif.nent_challow_def = challow_def; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 889                                 notif.nent_challow_var = challow_var; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 890                                 notif.nent_stringcount = max(notif.nent_optiona.nent_stringcount, notif.nent_optionb.nent_stringcount);
 891                                 notif.nent_floatcount = max(notif.nent_optiona.nent_floatcount, notif.nent_optionb.nent_floatcount);
 892
 893                                 /*#ifdef NOTIFICATIONS_DEBUG
 894                                 Debug_Notification(sprintf(
 895                                         "Create_Notification_Entity(...): MSG_CHOICE: %s\n%s\n%s\n",
 896                                         notif.nent_name,
 897                                         sprintf(
 898                                                 "^ optiona: %s %s : %d %d",
 899                                                 Get_Notif_TypeName(notif.nent_optiona.nent_type),
 900                                                 notif.nent_optiona.nent_name,
 901                                                 notif.nent_optiona.nent_stringcount,
 902                                                 notif.nent_optiona.nent_floatcount
 903                                         ),
 904                                         sprintf(
 905                                                 "^ optionb: %s %s : %d %d",
 906                                                 Get_Notif_TypeName(notif.nent_optionb.nent_type),
 907                                                 notif.nent_optionb.nent_name,
 908                                                 notif.nent_optionb.nent_stringcount,
 909                                                 notif.nent_optionb.nent_floatcount
 910                                         )
 911                                 ));
 912                                 #endif*/
 913                         }
 914                         break;
 915                 }
 916
 917                 default:
 918                 {
 919                         printf(
 920                                 strcat(
 921                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
 922                                         "^7net_type = %d, net_name = %s.\n"
 923                                 ),
 924                                 typeId,
 925                                 namestring
 926                         );
 927                         notif_error = true;
 928                         break;
 929                 }
 930         }
 931
 932         // now check to see if any errors happened
 933         if(notif_error)
 934         {
 935                 notif.nent_enabled = false; // disable the notification so it can't cause trouble
 936                 notif_global_error = true; // throw the red flag that an error happened on init
 937         }
 938 }
 939
 940
 941 // ===============
 942 //  Cvar Handling
 943 // ===============
 944
 945 // used by MSG_CHOICE to build list of choices
 946 #ifdef SVQC
 947 void Notification_GetCvars(void)
 948 {
 949         float i;
 950         for(i = 0; i <= NOTIF_CHOICE_COUNT; ++i)
 951         {
 952                 GetCvars_handleFloat(
 953                         get_cvars_s,
 954                         get_cvars_f,
 955                         msg_choice_choices[i],
 956                         sprintf("notification_%s", msg_choice_notifs[i].nent_name)
 957                 );
 958         }
 959 }
 960 #endif
 961
 962 // used to output notifications.cfg file
 963 void Dump_Notifications(float fh, float alsoprint)
 964 {
 965         #define NOTIF_WRITE(a) { \
 966                 fputs(fh, a); \
 967                 if(alsoprint) { print(a); } }
 968         #define NOTIF_WRITE_ENTITY(description) { \
 969                 notif_msg = \
 970                         sprintf( \
 971                                 "seta notification_%s \"%d\" \"%s\"\n", \
 972                                 e.nent_name, e.nent_default, description \
 973                         ); \
 974                 NOTIF_WRITE(notif_msg) }
 975         #define NOTIF_WRITE_ENTITY_CHOICE(descriptiona,descriptionb) { \
 976                 notif_msg = \
 977                         sprintf( \
 978                                 "seta notification_%s \"%d\" \"%s\"\n" \
 979                                 "seta notification_%s_ALLOWED \"%d\" \"%s\"\n", \
 980                                 e.nent_name, e.nent_default, descriptiona, \
 981                                 e.nent_name, e.nent_challow_def, descriptionb \
 982                         ); \
 983                 NOTIF_WRITE(notif_msg) }
 984         #define NOTIF_WRITE_HARDCODED(cvar,default,description) { \
 985                 notif_msg = \
 986                         sprintf( \
 987                                 "seta notification_%s \"%s\" \"%s\"\n", \
 988                                 cvar, default, description \
 989                         ); \
 990                 NOTIF_WRITE(notif_msg) }
 991
 992         string notif_msg;
 993         int i;
 994         entity e;
 995
 996         // Note: This warning only applies to the notifications.cfg file that is output...
 997
 998         // You ARE supposed to manually edit this function to add i.e. hard coded
 999         // notification variables for mutators or game modes or such and then
1000         // regenerate the notifications.cfg file from the new code.
1001
1002         NOTIF_WRITE("// ********************************************** //\n");
1003         NOTIF_WRITE("// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n");
1004         NOTIF_WRITE("// **                                          ** //\n");
1005         NOTIF_WRITE("// **  This file is automatically generated    ** //\n");
1006         NOTIF_WRITE("// **  by code with the command 'dumpnotifs'.  ** //\n");
1007         NOTIF_WRITE("// **                                          ** //\n");
1008         NOTIF_WRITE("// **  If you add a new notification, please   ** //\n");
1009         NOTIF_WRITE("// **  regenerate this file with that command  ** //\n");
1010         NOTIF_WRITE("// **  making sure that the output matches     ** //\n");
1011         NOTIF_WRITE("// **  with the lists and defaults in code.    ** //\n");
1012         NOTIF_WRITE("// **                                          ** //\n");
1013         NOTIF_WRITE("// ********************************************** //\n");
1014
1015         // These notifications will also append their string as a comment...
1016         // This is not necessary, and does not matter if they vary between config versions,
1017         // it is just a semi-helpful tool for those who want to manually change their user settings.
1018
1019         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications (count = %d):\n", NOTIF_ANNCE_COUNT));
1020         for(i = 1; i <= NOTIF_ANNCE_COUNT; ++i)
1021         {
1022                 e = Get_Notif_Ent(MSG_ANNCE, i);
1023                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1024
1025                 NOTIF_WRITE_ENTITY(
1026                         "0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled"
1027                 );
1028         }
1029
1030         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
1031         for(i = 1; i <= NOTIF_INFO_COUNT; ++i)
1032         {
1033                 e = Get_Notif_Ent(MSG_INFO, i);
1034                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1035
1036                 NOTIF_WRITE_ENTITY(
1037                         "0 = off, 1 = print to console, "
1038                         "2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)"
1039                 );
1040         }
1041
1042         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
1043         for(i = 1; i <= NOTIF_CENTER_COUNT; ++i)
1044         {
1045                 e = Get_Notif_Ent(MSG_CENTER, i);
1046                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1047
1048                 NOTIF_WRITE_ENTITY(
1049                         "0 = off, 1 = centerprint"
1050                 );
1051         }
1052
1053         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications (count = %d):\n", NOTIF_MULTI_COUNT));
1054         for(i = 1; i <= NOTIF_MULTI_COUNT; ++i)
1055         {
1056                 e = Get_Notif_Ent(MSG_MULTI, i);
1057                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1058
1059                 NOTIF_WRITE_ENTITY(
1060                         "Enable this multiple notification"
1061                 );
1062         }
1063
1064         NOTIF_WRITE(sprintf("\n// MSG_CHOICE notifications (count = %d):\n", NOTIF_CHOICE_COUNT));
1065         for(i = 1; i <= NOTIF_CHOICE_COUNT; ++i)
1066         {
1067                 e = Get_Notif_Ent(MSG_CHOICE, i);
1068                 if (!e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
1069
1070                 NOTIF_WRITE_ENTITY_CHOICE(
1071                         "Choice for this notification 0 = off, 1 = default message, 2 = verbose message",
1072                         "Allow choice for this notification 0 = off, 1 = only in warmup mode, 2 = always"
1073                 );
1074         }
1075
1076         // edit these to match whichever cvars are used for specific notification options
1077         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
1078
1079         NOTIF_WRITE_HARDCODED(
1080                 "allow_chatboxprint", "1",
1081                 "Allow INFO notifications to be printed to chat box"
1082                 "0 = do not allow, "
1083                 "1 = allow only if allowed by individual notification_INFO* cvars, "
1084                 "2 = force all INFO notifications to be printed to the chatbox"
1085         );
1086
1087         NOTIF_WRITE_HARDCODED(
1088                 "debug", "0",
1089                 "Print extra debug information on all notification function calls "
1090                 "(Requires -DNOTIFICATIONS_DEBUG flag to be enabled on QCSRC compilation)... "
1091                 "0 = disabled, 1 = dprint, 2 = print"
1092         );
1093
1094         NOTIF_WRITE_HARDCODED(
1095                 "errors_are_fatal", "1",
1096                 "If a notification fails upon initialization, cause a Host_Error to stop the program"
1097         );
1098
1099         NOTIF_WRITE_HARDCODED(
1100                 "item_centerprinttime", "1.5",
1101                 "How long to show item information centerprint messages (like 'You got the Electro' or such)"
1102         );
1103
1104         NOTIF_WRITE_HARDCODED(
1105                 "lifetime_mapload", "10",
1106                 "Amount of time that notification entities last immediately at mapload (in seconds) "
1107                 "to help prevent notifications from being lost on early init (like gamestart countdown)"
1108         );
1109
1110         NOTIF_WRITE_HARDCODED(
1111                 "lifetime_runtime", "0.5",
1112                 "Amount of time that notification entities last on the server during runtime (In seconds)"
1113         );
1114
1115         NOTIF_WRITE_HARDCODED(
1116                 "server_allows_location", "1",
1117                 "Server side cvar for allowing death messages to show location information too"
1118         );
1119
1120         NOTIF_WRITE_HARDCODED(
1121                 "show_location", "0",
1122                 "Append location information to MSG_INFO death/kill messages"
1123         );
1124
1125         NOTIF_WRITE_HARDCODED(
1126                 "show_location_string", "",
1127                 "Replacement string piped into sprintf, "
1128                 "so you can do different messages like this: ' at the %s' or ' (near %s)'"
1129         );
1130
1131         NOTIF_WRITE_HARDCODED(
1132                 "show_sprees", "1",
1133                 "Print information about sprees in death/kill messages"
1134         );
1135
1136         NOTIF_WRITE_HARDCODED(
1137                 "show_sprees_center", "1",
1138                 "Show spree information in MSG_CENTER messages... "
1139                 "0 = off, 1 = target (but only for first victim) and attacker"
1140         );
1141
1142         NOTIF_WRITE_HARDCODED(
1143                 "show_sprees_center_specialonly", "1",
1144                 "Don't show spree information in MSG_CENTER messages if it isn't an achievement"
1145         );
1146
1147         NOTIF_WRITE_HARDCODED(
1148                 "show_sprees_info", "3",
1149                 "Show spree information in MSG_INFO messages... "
1150                 "0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker"
1151         );
1152
1153         NOTIF_WRITE_HARDCODED(
1154                 "show_sprees_info_newline", "1",
1155                 "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself"
1156         );
1157
1158         NOTIF_WRITE_HARDCODED(
1159                 "show_sprees_info_specialonly", "1",
1160                 "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement"
1161         );
1162
1163         NOTIF_WRITE(sprintf(
1164                 strcat(
1165                         "\n// Notification counts (total = %d): ",
1166                         "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
1167                 ),
1168                 (
1169                         NOTIF_ANNCE_COUNT +
1170                         NOTIF_INFO_COUNT +
1171                         NOTIF_CENTER_COUNT +
1172                         NOTIF_MULTI_COUNT +
1173                         NOTIF_CHOICE_COUNT
1174                 ),
1175                 NOTIF_ANNCE_COUNT,
1176                 NOTIF_INFO_COUNT,
1177                 NOTIF_CENTER_COUNT,
1178                 NOTIF_MULTI_COUNT,
1179                 NOTIF_CHOICE_COUNT
1180         ));
1181
1182         return;
1183         #undef NOTIF_WRITE_HARDCODED
1184         #undef NOTIF_WRITE_ENTITY
1185         #undef NOTIF_WRITE
1186 }
1187
1188
1189 // ===============================
1190 //  Frontend Notification Pushing
1191 // ===============================
1192
1193 #ifdef NOTIFICATIONS_DEBUG
1194 void Debug_Notification(string input)
1195 {
1196         switch(autocvar_notification_debug)
1197         {
1198                 case 1: { dprint(input); break; }
1199                 case 2: { print(input); break; }
1200         }
1201 }
1202 #endif
1203
1204 string Local_Notification_sprintf(
1205         string input, string args,
1206         string s1, string s2, string s3, string s4,
1207         int f1, float f2, float f3, float f4)
1208 {
1209         #ifdef NOTIFICATIONS_DEBUG
1210         Debug_Notification(sprintf(
1211                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
1212                 MakeConsoleSafe(input),
1213                 args,
1214                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1215                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1216         ));
1217         #endif
1218
1219         string selected;
1220         int sel_num;
1221         for(sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
1222
1223         string tmp_s;
1224
1225         for(sel_num = 0;(args != "");)
1226         {
1227                 selected = car(args); args = cdr(args);
1228                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf");
1229                 switch(strtolower(selected))
1230                 {
1231                         #ifdef CSQC
1232                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1233                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1234                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1235                         #define ARG_CASE_ARG_CS(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1236                         #define ARG_CASE_ARG_SV(selected,result)
1237                         #define ARG_CASE_ARG_DC(selected,result)
1238                         #else
1239                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1240                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1241                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1242                         #define ARG_CASE_ARG_CS(selected,result)
1243                         #define ARG_CASE_ARG_SV(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1244                         #define ARG_CASE_ARG_DC(selected,result)
1245                         #endif
1246                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1247                         NOTIF_ARGUMENT_LIST
1248                         #undef ARG_CASE
1249                         #undef ARG_CASE_ARG_DC
1250                         #undef ARG_CASE_ARG_SV
1251                         #undef ARG_CASE_ARG_CS
1252                         #undef ARG_CASE_ARG_CS_SV
1253                         #undef ARG_CASE_ARG_CS_SV_DC
1254                         #undef ARG_CASE_ARG_CS_SV_HA
1255                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1256                 }
1257         }
1258         return sprintf(
1259                 strcat(input, "\n"),
1260                 arg_slot[0],
1261                 arg_slot[1],
1262                 arg_slot[2],
1263                 arg_slot[3],
1264                 arg_slot[4],
1265                 arg_slot[5],
1266                 arg_slot[6]
1267         );
1268 }
1269
1270 #ifdef CSQC
1271 void Local_Notification_sound(
1272         float soundchannel, string soundfile,
1273         float soundvolume, float soundposition)
1274 {
1275         if((soundfile != prev_soundfile) || (time >= (prev_soundtime + autocvar_cl_announcer_antispam)))
1276         {
1277                 #ifdef NOTIFICATIONS_DEBUG
1278                 Debug_Notification(sprintf(
1279                         "Local_Notification_sound(world, %f, '%s', %f, %f);\n",
1280                         soundchannel,
1281                         sprintf(
1282                                 "announcer/%s/%s.wav",
1283                                 autocvar_cl_announcer,
1284                                 soundfile
1285                         ),
1286                         soundvolume,
1287                         soundposition
1288                 ));
1289                 #endif
1290
1291                 sound(
1292                         world,
1293                         soundchannel,
1294                         sprintf(
1295                                 "announcer/%s/%s.wav",
1296                                 autocvar_cl_announcer,
1297                                 soundfile
1298                         ),
1299                         soundvolume,
1300                         soundposition
1301                 );
1302
1303                 if(prev_soundfile) { strunzone(prev_soundfile); }
1304                 prev_soundfile = strzone(soundfile);
1305                 prev_soundtime = time;
1306         }
1307         else
1308         {
1309                 #ifdef NOTIFICATIONS_DEBUG
1310                 Debug_Notification(sprintf(
1311                         strcat(
1312                                 "Local_Notification_sound(world, %f, '%s', %f, %f) ",
1313                                 "^1BLOCKED BY ANTISPAM:^7 prevsnd: '%s', timediff: %f, limit: %f\n"
1314                          ),
1315                         soundchannel,
1316                         sprintf(
1317                                 "announcer/%s/%s.wav",
1318                                 autocvar_cl_announcer,
1319                                 soundfile
1320                         ),
1321                         soundvolume,
1322                         soundposition,
1323                         prev_soundfile,
1324                         (time - prev_soundtime),
1325                         autocvar_cl_announcer_antispam
1326                 ));
1327                 #endif
1328         }
1329 }
1330
1331 void Local_Notification_HUD_Notify_Push(
1332         string icon, string hudargs,
1333         string s1, string s2, string s3, string s4,
1334         float f1, float f2, float f3, float f4)
1335 {
1336         string selected;
1337         arg_slot[0] = ""; arg_slot[1] = "";
1338
1339         int sel_num;
1340         for(sel_num = 0;(hudargs != "");)
1341         {
1342                 selected = car(hudargs); hudargs = cdr(hudargs);
1343                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push");
1344                 switch(strtolower(selected))
1345                 {
1346                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1347                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
1348                         #define ARG_CASE_ARG_CS_SV(selected,result)
1349                         #define ARG_CASE_ARG_CS(selected,result)
1350                         #define ARG_CASE_ARG_SV(selected,result)
1351                         #define ARG_CASE_ARG_DC(selected,result)
1352                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1353                         NOTIF_ARGUMENT_LIST
1354                         #undef ARG_CASE
1355                         #undef ARG_CASE_ARG_DC
1356                         #undef ARG_CASE_ARG_SV
1357                         #undef ARG_CASE_ARG_CS
1358                         #undef ARG_CASE_ARG_CS_SV
1359                         #undef ARG_CASE_ARG_CS_SV_DC
1360                         #undef ARG_CASE_ARG_CS_SV_HA
1361                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1362                 }
1363         }
1364         #ifdef NOTIFICATIONS_DEBUG
1365         Debug_Notification(sprintf(
1366                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s, %s);\n",
1367                 icon,
1368                 hudargs,
1369                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1370                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4),
1371                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
1372         ));
1373         #endif
1374         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
1375 }
1376
1377 void Local_Notification_centerprint_generic(
1378         string input, string durcnt,
1379         int cpid, float f1, float f2)
1380 {
1381         arg_slot[0] = ""; arg_slot[1] = "";
1382
1383         for(int sel_num = 0;(durcnt != "");)
1384         {
1385                 string selected = car(durcnt); durcnt = cdr(durcnt);
1386                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic");
1387                 switch(strtolower(selected))
1388                 {
1389                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
1390                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1391                         #define ARG_CASE_ARG_CS_SV(selected,result)
1392                         #define ARG_CASE_ARG_CS(selected,result)
1393                         #define ARG_CASE_ARG_SV(selected,result)
1394                         #define ARG_CASE_ARG_DC(selected,result)       case selected: { arg_slot[sel_num] = result; ++sel_num; break; }
1395                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
1396                         NOTIF_ARGUMENT_LIST
1397                         #undef ARG_CASE
1398                         #undef ARG_CASE_ARG_DC
1399                         #undef ARG_CASE_ARG_SV
1400                         #undef ARG_CASE_ARG_CS
1401                         #undef ARG_CASE_ARG_CS_SV
1402                         #undef ARG_CASE_ARG_CS_SV_DC
1403                         #undef ARG_CASE_ARG_CS_SV_HA
1404                         default:
1405                         {
1406                                 if(ftos(stof(selected)) != "") { arg_slot[sel_num] = selected; ++sel_num; }
1407                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic") }
1408                                 break;
1409                         }
1410                 }
1411         }
1412         #ifdef NOTIFICATIONS_DEBUG
1413         Debug_Notification(sprintf(
1414                 "Local_Notification_centerprint_generic('%s^7', '%s', %d, %d, %d, %d);\n",
1415                 MakeConsoleSafe(input),
1416                 durcnt,
1417                 f1, f2,
1418                 stof(arg_slot[0]),
1419                 stof(arg_slot[1])
1420         ));
1421         #endif
1422         centerprint_generic(cpid, input, stof(arg_slot[0]), stof(arg_slot[1]));
1423 }
1424 #endif
1425
1426 void Local_Notification(int net_type, int net_name, ...count)
1427 {
1428         // check if this should be aborted
1429         if(net_name == NOTIF_ABORT)
1430         {
1431                 #ifdef NOTIFICATIONS_DEBUG
1432                 Debug_Notification(sprintf(
1433                         "Local_Notification(%s, %s, ...);\n",
1434                         Get_Notif_TypeName(net_type),
1435                         "NOTIF_ABORT"
1436                 ));
1437                 #endif
1438                 return;
1439         }
1440
1441         // check supplied type and name for errors
1442         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
1443         if(checkargs != "")
1444         {
1445                 #ifdef NOTIFICATIONS_DEBUG
1446                 Debug_Notification(sprintf(
1447                         "Local_Notification(%s, %d, ...);\n",
1448                         Get_Notif_TypeName(net_type),
1449                         Get_Notif_Ent(net_type, net_name).nent_name
1450                 ));
1451                 #endif
1452                 backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs));
1453                 return;
1454         }
1455
1456         // retreive entity of this notification
1457         entity notif = Get_Notif_Ent(net_type, net_name);
1458         if (!notif)
1459         {
1460                 #ifdef NOTIFICATIONS_DEBUG
1461                 Debug_Notification(sprintf(
1462                         "Local_Notification(%s, %d, ...);\n",
1463                         Get_Notif_TypeName(net_type),
1464                         net_name
1465                 ));
1466                 #endif
1467                 backtrace("Local_Notification: Could not find notification entity!\n");
1468                 return;
1469         }
1470
1471         // check if the notification is enabled
1472         if (!notif.nent_enabled)
1473         {
1474                 #ifdef NOTIFICATIONS_DEBUG
1475                 Debug_Notification(sprintf(
1476                         "Local_Notification(%s, %s, ...): Entity was disabled...\n",
1477                         Get_Notif_TypeName(net_type),
1478                         notif.nent_name
1479                 ));
1480                 #endif
1481                 return;
1482         }
1483
1484         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1485         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1486         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1487         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1488         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1489         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1490         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1491         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1492
1493         #ifdef NOTIFICATIONS_DEBUG
1494         Debug_Notification(sprintf(
1495                 "Local_Notification(%s, %s, %s, %s);\n",
1496                 Get_Notif_TypeName(net_type),
1497                 notif.nent_name,
1498                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1499                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1500         ));
1501         #endif
1502
1503         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1504         {
1505                 backtrace(sprintf(
1506                         strcat(
1507                                 "Not enough arguments for Local_Notification(%s, %s, ...)! ",
1508                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1509                                 "Check the definition and function call for accuracy...?\n"
1510                         ),
1511                         Get_Notif_TypeName(net_type),
1512                         notif.nent_name,
1513                         notif.nent_stringcount,
1514                         notif.nent_floatcount,
1515                         count
1516                 ));
1517                 return;
1518         }
1519         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1520         {
1521                 backtrace(sprintf(
1522                         strcat(
1523                                 "Too many arguments for Local_Notification(%s, %s, ...)! ",
1524                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1525                                 "Check the definition and function call for accuracy...?\n"
1526                         ),
1527                         Get_Notif_TypeName(net_type),
1528                         notif.nent_name,
1529                         notif.nent_stringcount,
1530                         notif.nent_floatcount,
1531                         count
1532                 ));
1533                 return;
1534         }
1535
1536         switch(net_type)
1537         {
1538                 case MSG_ANNCE:
1539                 {
1540                         #ifdef CSQC
1541                         Local_Notification_sound(
1542                                 notif.nent_channel,
1543                                 notif.nent_snd,
1544                                 notif.nent_vol,
1545                                 notif.nent_position
1546                         );
1547                         #else
1548                         backtrace("MSG_ANNCE on server?... Please notify Samual immediately!\n");
1549                         #endif
1550                         break;
1551                 }
1552
1553                 case MSG_INFO:
1554                 {
1555                         print(
1556                                 Local_Notification_sprintf(
1557                                         notif.nent_string,
1558                                         notif.nent_args,
1559                                         s1, s2, s3, s4,
1560                                         f1, f2, f3, f4)
1561                         );
1562                         #ifdef CSQC
1563                         if(notif.nent_icon != "")
1564                         {
1565                                 Local_Notification_HUD_Notify_Push(
1566                                         notif.nent_icon,
1567                                         notif.nent_hudargs,
1568                                         s1, s2, s3, s4,
1569                                         f1, f2, f3, f4);
1570                         }
1571                         #endif
1572                         break;
1573                 }
1574
1575                 #ifdef CSQC
1576                 case MSG_CENTER:
1577                 {
1578                         Local_Notification_centerprint_generic(
1579                                 Local_Notification_sprintf(
1580                                         notif.nent_string,
1581                                         notif.nent_args,
1582                                         s1, s2, s3, s4,
1583                                         f1, f2, f3, f4),
1584                                 notif.nent_durcnt,
1585                                 notif.nent_cpid,
1586                                 f1, f2);
1587                         break;
1588                 }
1589                 #endif
1590
1591                 case MSG_MULTI:
1592                 {
1593                         if(notif.nent_msginfo)
1594                         if(notif.nent_msginfo.nent_enabled)
1595                         {
1596                                 Local_Notification_WOVA(
1597                                         MSG_INFO,
1598                                         notif.nent_msginfo.nent_id,
1599                                         notif.nent_msginfo.nent_stringcount,
1600                                         notif.nent_msginfo.nent_floatcount,
1601                                         s1, s2, s3, s4,
1602                                         f1, f2, f3, f4);
1603                         }
1604                         #ifdef CSQC
1605                         if(notif.nent_msgannce)
1606                         if(notif.nent_msgannce.nent_enabled)
1607                         {
1608                                 Local_Notification_WOVA(
1609                                         MSG_ANNCE,
1610                                         notif.nent_msgannce.nent_id,
1611                                         0, 0,
1612                                         "", "", "", "",
1613                                         0, 0, 0, 0);
1614                         }
1615                         if(notif.nent_msgcenter)
1616                         if(notif.nent_msgcenter.nent_enabled)
1617                         {
1618                                 Local_Notification_WOVA(
1619                                         MSG_CENTER,
1620                                         notif.nent_msgcenter.nent_id,
1621                                         notif.nent_msgcenter.nent_stringcount,
1622                                         notif.nent_msgcenter.nent_floatcount,
1623                                         s1, s2, s3, s4,
1624                                         f1, f2, f3, f4);
1625                         }
1626                         #endif
1627                         break;
1628                 }
1629
1630                 case MSG_CHOICE:
1631                 {
1632                         entity found_choice;
1633
1634                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2)))
1635                         {
1636                                 switch(cvar_string(sprintf("notification_%s", notif.nent_name)))
1637                                 {
1638                                         case 1: found_choice = notif.nent_optiona; break;
1639                                         case 2: found_choice = notif.nent_optionb; break;
1640                                         default: return; // not enabled anyway
1641                                 }
1642                         }
1643                         else { found_choice = notif.nent_optiona; }
1644
1645                         Local_Notification_WOVA(
1646                                 found_choice.nent_type,
1647                                 found_choice.nent_id,
1648                                 found_choice.nent_stringcount,
1649                                 found_choice.nent_floatcount,
1650                                 s1, s2, s3, s4,
1651                                 f1, f2, f3, f4);
1652                 }
1653         }
1654 }
1655
1656 // WOVA = Without Variable Arguments
1657 void Local_Notification_WOVA(
1658         int net_type, float net_name,
1659         float stringcount, float floatcount,
1660         string s1, string s2, string s3, string s4,
1661         float f1, float f2, float f3, float f4)
1662 {
1663         #define VARITEM(stringc,floatc,args) \
1664                 if((stringcount == stringc) && (floatcount == floatc)) \
1665                         { Local_Notification(net_type, net_name, args); return; }
1666         EIGHT_VARS_TO_VARARGS_VARLIST
1667         #undef VARITEM
1668         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1669 }
1670
1671
1672 // =========================
1673 //  Notification Networking
1674 // =========================
1675
1676 #ifdef CSQC
1677 void Read_Notification(float is_new)
1678 {
1679         int net_type = ReadByte();
1680         int net_name = ReadShort();
1681
1682         entity notif;
1683
1684         if(net_type == MSG_CENTER_CPID)
1685         {
1686                 #ifdef NOTIFICATIONS_DEBUG
1687                 Debug_Notification(sprintf(
1688                         "Read_Notification(%d) at %f: net_type = %s, net_name = %d\n",
1689                         is_new,
1690                         time,
1691                         Get_Notif_TypeName(net_type),
1692                         net_name
1693                 ));
1694                 #endif
1695
1696                 if(is_new)
1697                 {
1698                         if(net_name == 0) { reset_centerprint_messages(); }
1699                         else if(net_name != NO_CPID)
1700                         {
1701                                 // in this case, net_name IS the cpid we want to kill
1702                                 centerprint_generic(net_name, "", 0, 0);
1703                         }
1704                         else
1705                         {
1706                                 backtrace(sprintf(
1707                                         "Read_Notification(%d) at %f: ^1TRIED TO KILL NO_CPID CENTERPRINT!\n",
1708                                         is_new,
1709                                         time
1710                                 ));
1711                         }
1712                 }
1713         }
1714         else
1715         {
1716                 notif = Get_Notif_Ent(net_type, net_name);
1717                 if (!notif) { backtrace("Read_Notification: Could not find notification entity!\n"); return; }
1718
1719                 #ifdef NOTIFICATIONS_DEBUG
1720                 Debug_Notification(sprintf(
1721                         "Read_Notification(%d) at %f: net_type = %s, net_name = %s\n",
1722                         is_new,
1723                         time,
1724                         Get_Notif_TypeName(net_type),
1725                         notif.nent_name
1726                 ));
1727                 #endif
1728
1729                 string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
1730                 string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
1731                 string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
1732                 string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
1733                 float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : 0);
1734                 float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : 0);
1735                 float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : 0);
1736                 float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : 0);
1737
1738                 if(is_new)
1739                 {
1740                         Local_Notification_WOVA(
1741                                 net_type, net_name,
1742                                 notif.nent_stringcount,
1743                                 notif.nent_floatcount,
1744                                 s1, s2, s3, s4,
1745                                 f1, f2, f3, f4);
1746                 }
1747         }
1748 }
1749 #endif
1750
1751 #ifdef SVQC
1752 void Net_Notification_Remove()
1753 {
1754         if (!self) { backtrace(sprintf("Net_Notification_Remove() at %f: Missing self!?\n", time)); return; }
1755
1756         #ifdef NOTIFICATIONS_DEBUG
1757         Debug_Notification(sprintf(
1758                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1759                 time,
1760                 ((self.nent_net_name == -1) ? "Killed" : "Removed"),
1761                 Get_Notif_TypeName(self.nent_net_type),
1762                 self.owner.nent_name
1763         ));
1764         #endif
1765
1766         float i;
1767         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
1768         remove(self);
1769 }
1770
1771 float Net_Write_Notification(entity client, float sf)
1772 {
1773         if(Notification_ShouldSend(self.nent_broadcast, client, self.nent_client))
1774         {
1775                 float i;
1776                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1777                 WriteByte(MSG_ENTITY, self.nent_net_type);
1778                 WriteShort(MSG_ENTITY, self.nent_net_name);
1779                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
1780                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
1781                 return true;
1782         }
1783         else { return false; }
1784 }
1785
1786 void Kill_Notification(
1787         float broadcast, entity client,
1788         float net_type, float net_name)
1789 {
1790         #ifdef NOTIFICATIONS_DEBUG
1791         Debug_Notification(sprintf(
1792                 "Kill_Notification(%s, '%s', %s, %d);\n",
1793                 Get_Notif_BroadcastName(broadcast),
1794                 client.netname,
1795                 (net_type ? Get_Notif_TypeName(net_type) : "0"),
1796                 net_name
1797         ));
1798         #endif
1799
1800         string checkargs = Notification_CheckArgs(broadcast, client, 1, 1);
1801         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Kill_Notification: %s\n", checkargs)); return; }
1802
1803         entity notif, net_notif;
1804         float killed_cpid = NO_CPID;
1805
1806         switch(net_type)
1807         {
1808                 case 0:
1809                 {
1810                         killed_cpid = 0; // kill ALL centerprints
1811                         break;
1812                 }
1813
1814                 case MSG_CENTER:
1815                 {
1816                         if(net_name)
1817                         {
1818                                 entity notif = Get_Notif_Ent(net_type, net_name);
1819                                 if (!notif) { backtrace("Kill_Notification: Could not find notification entity!\n"); return; }
1820
1821                                 if(notif.nent_cpid)
1822                                         killed_cpid = notif.nent_cpid;
1823                                 else
1824                                         killed_cpid = NO_CPID;
1825                         }
1826                         else
1827                         {
1828                                 killed_cpid = 0; // kill ALL centerprints
1829                         }
1830                         break;
1831                 }
1832
1833                 case MSG_CENTER_CPID:
1834                 {
1835                         killed_cpid = net_name;
1836                         break;
1837                 }
1838         }
1839
1840         if(killed_cpid != NO_CPID)
1841         {
1842                 net_notif = spawn();
1843                 net_notif.classname = "net_kill_notification";
1844                 net_notif.nent_broadcast = broadcast;
1845                 net_notif.nent_client = client;
1846                 net_notif.nent_net_type = MSG_CENTER_CPID;
1847                 net_notif.nent_net_name = killed_cpid;
1848                 Net_LinkEntity(net_notif, false, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1849         }
1850
1851         for(notif = world; (notif = find(notif, classname, "net_notification"));)
1852         {
1853                 if(net_type)
1854                 {
1855                         if((killed_cpid != NO_CPID) && (notif.nent_net_type == MSG_CENTER))
1856                         {
1857                                 if(notif.owner.nent_cpid == killed_cpid)
1858                                 {
1859                                         notif.nent_net_name = -1;
1860                                         notif.nextthink = time;
1861                                 }
1862                                 else { continue; } // we ARE looking for a specific CPID, don't kill everything else too
1863                         }
1864                         else if(notif.nent_net_type == net_type)
1865                         {
1866                                 if(net_name)
1867                                 {
1868                                         if(notif.nent_net_name == net_name) { notif.nent_net_name = -1; notif.nextthink = time; }
1869                                         else { continue; } // we ARE looking for a certain net_name, don't kill everything else too
1870                                 }
1871                                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1872                         }
1873                         else { continue; } // we ARE looking for a certain net_type, don't kill everything else too
1874                 }
1875                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1876         }
1877 }
1878
1879 void Send_Notification(
1880         float broadcast, entity client,
1881         float net_type, float net_name,
1882         ...count)
1883 {
1884         // check if this should be aborted
1885         if(net_name == NOTIF_ABORT)
1886         {
1887                 #ifdef NOTIFICATIONS_DEBUG
1888                 Debug_Notification(sprintf(
1889                         "Send_Notification(%s, '%s', %s, %s, ...);\n",
1890                         Get_Notif_BroadcastName(broadcast),
1891                         client.classname,
1892                         Get_Notif_TypeName(net_type),
1893                         "NOTIF_ABORT"
1894                 ));
1895                 #endif
1896                 return;
1897         }
1898
1899         // check supplied broadcast, target, type, and name for errors
1900         string checkargs = Notification_CheckArgs(broadcast, client, net_type, net_name);
1901         if(checkargs != "")
1902         {
1903                 #ifdef NOTIFICATIONS_DEBUG
1904                 Debug_Notification(sprintf(
1905                         "Send_Notification(%s, '%s', %s, %s, ...);\n",
1906                         Get_Notif_BroadcastName(broadcast),
1907                         client.classname,
1908                         Get_Notif_TypeName(net_type),
1909                         Get_Notif_Ent(net_type, net_name).nent_name
1910                 ));
1911                 #endif
1912                 backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs));
1913                 return;
1914         }
1915
1916         // retreive entity of this notification
1917         entity notif = Get_Notif_Ent(net_type, net_name);
1918         if (!notif)
1919         {
1920                 #ifdef NOTIFICATIONS_DEBUG
1921                 Debug_Notification(sprintf(
1922                         "Send_Notification(%s, '%s', %s, %d, ...);\n",
1923                         Get_Notif_BroadcastName(broadcast),
1924                         client.classname,
1925                         Get_Notif_TypeName(net_type),
1926                         net_name
1927                 ));
1928                 #endif
1929                 backtrace("Send_Notification: Could not find notification entity!\n");
1930                 return;
1931         }
1932
1933         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1934         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1935         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1936         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1937         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1938         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1939         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1940         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1941
1942         #ifdef NOTIFICATIONS_DEBUG
1943         Debug_Notification(sprintf(
1944                 "Send_Notification(%s, %s, %s);\n",
1945                 sprintf(
1946                         "%s, '%s', %s, %s",
1947                         Get_Notif_BroadcastName(broadcast),
1948                         client.classname,
1949                         Get_Notif_TypeName(net_type),
1950                         notif.nent_name
1951                 ),
1952                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1953                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1954         ));
1955         #endif
1956
1957         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1958         {
1959                 backtrace(sprintf(
1960                         strcat(
1961                                 "Not enough arguments for Send_Notification(%s, ...)! ",
1962                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1963                                 "Check the definition and function call for accuracy...?\n"
1964                         ),
1965                         sprintf(
1966                                 #ifdef NOTIFICATIONS_DEBUG
1967                                 "%s, '%s', %s, %s",
1968                                 Get_Notif_BroadcastName(broadcast),
1969                                 #else
1970                                 "%d, '%s', %s, %s",
1971                                 broadcast,
1972                                 #endif
1973                                 client.classname,
1974                                 Get_Notif_TypeName(net_type),
1975                                 notif.nent_name
1976                         ),
1977                         notif.nent_stringcount,
1978                         notif.nent_floatcount,
1979                         count
1980                 ));
1981                 return;
1982         }
1983         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1984         {
1985                 backtrace(sprintf(
1986                         strcat(
1987                                 "Too many arguments for Send_Notification(%s, ...)! ",
1988                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1989                                 "Check the definition and function call for accuracy...?\n"
1990                         ),
1991                         sprintf(
1992                                 #ifdef NOTIFICATIONS_DEBUG
1993                                 "%s, '%s', %s, %s",
1994                                 Get_Notif_BroadcastName(broadcast),
1995                                 #else
1996                                 "%d, '%s', %s, %s",
1997                                 broadcast,
1998                                 #endif
1999                                 client.classname,
2000                                 Get_Notif_TypeName(net_type),
2001                                 notif.nent_name
2002                         ),
2003                         notif.nent_stringcount,
2004                         notif.nent_floatcount,
2005                         count
2006                 ));
2007                 return;
2008         }
2009
2010         if(
2011                 server_is_dedicated
2012                 &&
2013                 (
2014                         broadcast == NOTIF_ALL
2015                         ||
2016                         broadcast == NOTIF_ALL_EXCEPT
2017                 )
2018                 &&
2019                 !(
2020                         net_type == MSG_ANNCE
2021                         ||
2022                         net_type == MSG_CENTER
2023                 )
2024         )
2025         {
2026                 Local_Notification_WOVA(
2027                         net_type, net_name,
2028                         notif.nent_stringcount,
2029                         notif.nent_floatcount,
2030                         s1, s2, s3, s4,
2031                         f1, f2, f3, f4);
2032         }
2033
2034         if(net_type == MSG_CHOICE)
2035         {
2036                 // THIS GETS TRICKY... now we have to cycle through each possible player (checking broadcast)
2037                 // and then do an individual NOTIF_ONE_ONLY recursive call for each one depending on their option...
2038                 // It's slow, but it's better than the alternatives:
2039                 //   1. Constantly networking all info and letting client decide
2040                 //   2. Manually handling each separate call on per-usage basis (See old CTF usage of verbose)
2041                 entity found_choice;
2042
2043                 #define RECURSE_FROM_CHOICE(ent,action) do { \
2044                         if(notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) \
2045                         { \
2046                                 switch(ent.msg_choice_choices[net_name - 1]) \
2047                                 { \
2048                                         case 1: found_choice = notif.nent_optiona; break; \
2049                                         case 2: found_choice = notif.nent_optionb; break; \
2050                                         default: action; \
2051                                 } \
2052                         } \
2053                         else { found_choice = notif.nent_optiona; } \
2054                         Send_Notification_WOVA( \
2055                                 NOTIF_ONE_ONLY, \
2056                                 ent, \
2057                                 found_choice.nent_type, \
2058                                 found_choice.nent_id, \
2059                                 found_choice.nent_stringcount, \
2060                                 found_choice.nent_floatcount, \
2061                                 s1, s2, s3, s4, \
2062                                 f1, f2, f3, f4); \
2063                 } while(0)
2064
2065                 switch(broadcast)
2066                 {
2067                         case NOTIF_ONE_ONLY: // we can potentially save processing power with this broadcast method
2068                         {
2069                                 if(IS_REAL_CLIENT(client))
2070                                 {
2071                                         RECURSE_FROM_CHOICE(client, return);
2072                                 }
2073                                 break;
2074                         }
2075                         default:
2076                         {
2077                                 entity to;
2078                                 FOR_EACH_REALCLIENT(to)
2079                                 {
2080                                         if(Notification_ShouldSend(broadcast, to, client))
2081                                         {
2082                                                 RECURSE_FROM_CHOICE(to, continue);
2083                                         }
2084                                 }
2085                                 break;
2086                         }
2087                 }
2088         }
2089         else
2090         {
2091                 entity net_notif = spawn();
2092                 net_notif.owner = notif;
2093                 net_notif.classname = "net_notification";
2094                 net_notif.nent_broadcast = broadcast;
2095                 net_notif.nent_client = client;
2096                 net_notif.nent_net_type = net_type;
2097                 net_notif.nent_net_name = net_name;
2098                 net_notif.nent_stringcount = notif.nent_stringcount;
2099                 net_notif.nent_floatcount = notif.nent_floatcount;
2100
2101                 float i;
2102                 for(i = 0; i < net_notif.nent_stringcount; ++i)
2103                         { net_notif.nent_strings[i] = strzone(...(i, string)); }
2104                 for(i = 0; i < net_notif.nent_floatcount; ++i)
2105                         { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
2106
2107                 net_notif.think = Net_Notification_Remove;
2108                 net_notif.nextthink =
2109                         ((time > autocvar_notification_lifetime_mapload)
2110                         ?
2111                                 (time + autocvar_notification_lifetime_runtime)
2112                                 :
2113                                 autocvar_notification_lifetime_mapload
2114                         );
2115
2116                 Net_LinkEntity(net_notif, false, 0, Net_Write_Notification);
2117         }
2118 }
2119
2120 // WOVA = Without Variable Arguments
2121 void Send_Notification_WOVA(
2122         float broadcast, entity client,
2123         float net_type, float net_name,
2124         float stringcount, float floatcount,
2125         string s1, string s2, string s3, string s4,
2126         float f1, float f2, float f3, float f4)
2127 {
2128         #ifdef NOTIFICATIONS_DEBUG
2129         entity notif = Get_Notif_Ent(net_type, net_name);
2130         Debug_Notification(sprintf(
2131                 "Send_Notification_WOVA(%s, %d, %d, %s, %s);\n",
2132                 sprintf(
2133                         "%s, '%s', %s, %s",
2134                         Get_Notif_BroadcastName(broadcast),
2135                         client.classname,
2136                         Get_Notif_TypeName(net_type),
2137                         notif.nent_name
2138                 ),
2139                 stringcount,
2140                 floatcount,
2141                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2142                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2143         ));
2144         #endif
2145
2146         #define VARITEM(stringc,floatc,args) \
2147                 if((stringcount == stringc) && (floatcount == floatc)) \
2148                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2149         EIGHT_VARS_TO_VARARGS_VARLIST
2150         #undef VARITEM
2151         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2152 }
2153
2154 // WOCOVA = Without Counts Or Variable Arguments
2155 void Send_Notification_WOCOVA(
2156         float broadcast, entity client,
2157         float net_type, float net_name,
2158         string s1, string s2, string s3, string s4,
2159         float f1, float f2, float f3, float f4)
2160 {
2161         entity notif = Get_Notif_Ent(net_type, net_name);
2162
2163         #ifdef NOTIFICATIONS_DEBUG
2164         Debug_Notification(sprintf(
2165                 "Send_Notification_WOCOVA(%s, %s, %s);\n",
2166                 sprintf(
2167                         "%s, '%s', %s, %s",
2168                         Get_Notif_BroadcastName(broadcast),
2169                         client.classname,
2170                         Get_Notif_TypeName(net_type),
2171                         notif.nent_name
2172                 ),
2173                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
2174                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
2175         ));
2176         #endif
2177
2178         #define VARITEM(stringc,floatc,args) \
2179                 if((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
2180                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
2181         EIGHT_VARS_TO_VARARGS_VARLIST
2182         #undef VARITEM
2183         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
2184 }
2185 #endif // ifdef SVQC