qcsrc/common/notifications.qc

   1 // ================================================
   2 //  Unified notification system, written by Samual
   3 //  Last updated: March, 2013
   4 // ================================================
   5
   6 string Get_Notif_TypeName(float net_type)
   7 {
   8         switch(net_type)
   9         {
  10                 case MSG_ANNCE: return "MSG_ANNCE";
  11                 case MSG_INFO: return "MSG_INFO";
  12                 case MSG_CENTER: return "MSG_CENTER";
  13                 case MSG_CENTER_CPID: return "MSG_CENTER_CPID";
  14                 case MSG_MULTI: return "MSG_MULTI";
  15         }
  16         backtrace(sprintf("Get_Notif_TypeName(%d): Improper net type!\n", net_type));
  17         return "";
  18 }
  19
  20 entity Get_Notif_Ent(float net_type, float net_name)
  21 {
  22         switch(net_type)
  23         {
  24                 case MSG_ANNCE: return msg_annce_notifs[net_name - 1];
  25                 case MSG_INFO: return msg_info_notifs[net_name - 1];
  26                 case MSG_CENTER: return msg_center_notifs[net_name - 1];
  27                 case MSG_MULTI: return msg_multi_notifs[net_name - 1];
  28         }
  29         backtrace(sprintf("Get_Notif_Ent(%d, %d): Improper net type!\n", net_type, net_name));
  30         return world;
  31 }
  32
  33 string Notification_CheckArgs_TypeName(float net_type, float net_name)
  34 {
  35         // check supplied type and name for errors
  36         string checkargs = "";
  37         #define CHECKARG_TYPENAME(type) case MSG_##type##: \
  38                 { if(!net_name || (net_name > NOTIF_##type##_COUNT)) \
  39                 { checkargs = sprintf("Improper name: %d!", net_name); } break; }
  40         switch(net_type)
  41         {
  42                 CHECKARG_TYPENAME(ANNCE)
  43                 CHECKARG_TYPENAME(INFO)
  44                 CHECKARG_TYPENAME(CENTER)
  45                 CHECKARG_TYPENAME(MULTI)
  46                 default: { checkargs = sprintf("Improper type: %d!", checkargs, net_type); break; }
  47         }
  48         #undef CHECKARG_TYPENAME
  49         return checkargs;
  50 }
  51
  52 #ifdef SVQC
  53 string Notification_CheckArgs(
  54         float broadcast, entity client,
  55         float net_type, float net_name)
  56 {
  57         // check supplied broadcast, target, type, and name for errors
  58         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
  59         if(checkargs != "") { checkargs = strcat(checkargs, " "); }
  60         switch(broadcast)
  61         {
  62                 case NOTIF_ONE:
  63                 case NOTIF_ONE_ONLY:
  64                 {
  65                         if(IS_NOT_A_CLIENT(client))
  66                                 { checkargs = sprintf("%sNo client provided!", checkargs); }
  67                         break;
  68                 }
  69
  70                 case NOTIF_ALL_EXCEPT:
  71                 {
  72                         if(IS_NOT_A_CLIENT(client))
  73                                 { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
  74                         break;
  75                 }
  76
  77                 case NOTIF_ALL:
  78                 {
  79                         if(client)
  80                                 { checkargs = sprintf("%sEntity provided when world was required!", checkargs); }
  81                         break;
  82                 }
  83
  84                 case NOTIF_TEAM:
  85                 case NOTIF_TEAM_EXCEPT:
  86                 {
  87                         if not(teamplay) { checkargs = sprintf("%sTeamplay not active!", checkargs); }
  88                         else if(IS_NOT_A_CLIENT(client))
  89                         {
  90                                 if(broadcast == NOTIF_TEAM) { checkargs = sprintf("%sNo client provided!", checkargs); }
  91                                 else { checkargs = sprintf("%sException can't be a non-client!", checkargs); }
  92                         }
  93                         break;
  94                 }
  95
  96                 default: { checkargs = sprintf("%sImproper broadcast: %d!", checkargs, broadcast); break; }
  97         }
  98         return checkargs;
  99 }
 100 #endif
 101
 102 // ===============================
 103 //  Initialization Core Functions
 104 // ===============================
 105
 106 // used by restartnotifs command to initialize notifications
 107 void Destroy_Notification_Entity(entity notif)
 108 {
 109         if(notif.nent_name != "") { strunzone(notif.nent_name); }
 110         if(notif.nent_snd != "") { strunzone(notif.nent_snd); }
 111         if(notif.nent_args != "") { strunzone(notif.nent_args); }
 112         if(notif.nent_hudargs != "") { strunzone(notif.nent_hudargs); }
 113         if(notif.nent_icon != "") { strunzone(notif.nent_icon); }
 114         if(notif.nent_durcnt != "") { strunzone(notif.nent_durcnt); }
 115         if(notif.nent_string != "") { strunzone(notif.nent_string); }
 116         remove(notif);
 117 }
 118
 119 void Destroy_All_Notifications(void)
 120 {
 121         entity notif;
 122         float i;
 123
 124         #define DESTROY_LOOP(type,count) \
 125                 for(i = 1; i <= count; ++i) \
 126                 { \
 127                         notif = Get_Notif_Ent(type, i); \
 128                         if not(notif) { backtrace("Destroy_All_Notifications(): Missing notification entity!\n"); return; } \
 129                         Destroy_Notification_Entity(notif); \
 130                 }
 131
 132         // kill all networked notifications and centerprints
 133         #ifdef SVQC
 134         Kill_Notification(NOTIF_ALL, world, 0, 0);
 135         #else
 136         reset_centerprint_messages();
 137         #endif
 138
 139         // kill all real notification entities
 140         DESTROY_LOOP(MSG_ANNCE, NOTIF_ANNCE_COUNT)
 141         DESTROY_LOOP(MSG_INFO, NOTIF_INFO_COUNT)
 142         DESTROY_LOOP(MSG_CENTER, NOTIF_CENTER_COUNT)
 143         DESTROY_LOOP(MSG_MULTI, NOTIF_MULTI_COUNT)
 144         #undef DESTROY_LOOP
 145 }
 146
 147 string Process_Notif_Line(
 148         float msg_is_info,
 149         float chat,
 150         string input,
 151         string notiftype,
 152         string notifname,
 153         string stringtype)
 154 {
 155         if(msg_is_info)
 156         {
 157                 #ifdef CSQC
 158                 if((chat && autocvar_notification_allow_chatboxprint)
 159                         || (autocvar_notification_allow_chatboxprint == 2))
 160                 {
 161                         // pass 1: add ETX char at beginning of line
 162                         input = strcat("\{3}", input);
 163
 164                         // pass 2: add ETX char at end of each new line (so that
 165                         // messages with multiple lines are put through chatbox too)
 166                         input = strreplace("\n", "\n\{3}", input);
 167
 168                         // pass 3: strip trailing ETX char
 169                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
 170                                 { input = substring(input, 0, (strlen(input) - 1)); }
 171                 }
 172                 #endif
 173                 if(substring(input, (strlen(input) - 1), 1) != "\n")
 174                 {
 175                         print(sprintf(
 176                                 strcat(
 177                                         "^1MISSING/BROKEN NEW LINE AT END OF NOTIFICATION: ",
 178                                         "^7net_type = %s, net_name = %s, string = %s.\n"
 179                                 ),
 180                                 notiftype,
 181                                 notifname,
 182                                 stringtype
 183                         ));
 184                         notif_error = TRUE;
 185                         return strcat(input, "\n");
 186                 }
 187         }
 188         return input;
 189 }
 190
 191 string Process_Notif_Args(
 192         float arg_type,
 193         string args,
 194         string notiftype,
 195         string notifname)
 196 {
 197         string selected, remaining = args;
 198         float sel_num = 0;
 199
 200         for(;(remaining != "");)
 201         {
 202                 selected = car(remaining); remaining = cdr(remaining);
 203
 204                 switch(arg_type)
 205                 {
 206                         case 1: // normal args
 207                         {
 208                                 if(sel_num == NOTIF_MAX_ARGS)
 209                                 {
 210                                         print(sprintf(
 211                                                 strcat(
 212                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 213                                                         "^7net_type = %s, net_name = %s, max args = %d.\n"
 214                                                 ),
 215                                                 notiftype,
 216                                                 notifname,
 217                                                 NOTIF_MAX_ARGS
 218                                         ));
 219                                         notif_error = TRUE;
 220                                         break;
 221                                 }
 222
 223                                 switch(strtolower(selected))
 224                                 {
 225                                         #define ARG_CASE(prog,selected,result) \
 226                                                 #if (prog != ARG_DC) \
 227                                                         case selected: { ++sel_num; break; } \
 228                                                 #endif
 229                                         NOTIF_ARGUMENT_LIST
 230                                         #undef ARG_CASE
 231                                         default:
 232                                         {
 233                                                 print(sprintf(
 234                                                         strcat(
 235                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 236                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'.\n"
 237                                                         ),
 238                                                         notiftype,
 239                                                         notifname,
 240                                                         selected
 241                                                 ));
 242                                                 notif_error = TRUE;
 243                                                 break;
 244                                         }
 245                                 }
 246                                 break;
 247                         }
 248                         case 2: // hudargs
 249                         {
 250                                 if(sel_num == NOTIF_MAX_HUDARGS)
 251                                 {
 252                                         print(sprintf(
 253                                                 strcat(
 254                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 255                                                         "^7net_type = %s, net_name = %s, max hudargs = %d.\n"
 256                                                 ),
 257                                                 notiftype,
 258                                                 notifname,
 259                                                 NOTIF_MAX_HUDARGS
 260                                         ));
 261                                         notif_error = TRUE;
 262                                         break;
 263                                 }
 264
 265                                 switch(strtolower(selected))
 266                                 {
 267                                         #define ARG_CASE(prog,selected,result) \
 268                                                 #if (prog == ARG_CS_SV_HA) \
 269                                                         case selected: { ++sel_num; break; } \
 270                                                 #endif
 271                                         NOTIF_ARGUMENT_LIST
 272                                         #undef ARG_CASE
 273                                         default:
 274                                         {
 275                                                 print(sprintf(
 276                                                         strcat(
 277                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 278                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'.\n"
 279                                                         ),
 280                                                         notiftype,
 281                                                         notifname,
 282                                                         selected
 283                                                 ));
 284                                                 notif_error = TRUE;
 285                                                 break;
 286                                         }
 287                                 }
 288                                 break;
 289                         }
 290                         case 3: // durcnt
 291                         {
 292                                 if(sel_num == NOTIF_MAX_DURCNT)
 293                                 {
 294                                         print(sprintf(
 295                                                 strcat(
 296                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: ",
 297                                                         "^7net_type = %s, net_name = %s, max durcnt = %d.\n"
 298                                                 ),
 299                                                 notiftype,
 300                                                 notifname,
 301                                                 NOTIF_MAX_DURCNT
 302                                         ));
 303                                         notif_error = TRUE;
 304                                         break;
 305                                 }
 306
 307                                 switch(strtolower(selected))
 308                                 {
 309                                         #define ARG_CASE(prog,selected,result) \
 310                                                 #if (prog == ARG_CS_SV_DC) || (prog == ARG_DC) \
 311                                                         case selected: { ++sel_num; break; } \
 312                                                 #endif
 313                                         NOTIF_ARGUMENT_LIST
 314                                         #undef ARG_CASE
 315                                         default:
 316                                         {
 317                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
 318                                                 else
 319                                                 {
 320                                                         print(sprintf(
 321                                                                 strcat(
 322                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: ",
 323                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'.\n"
 324                                                                 ),
 325                                                                 notiftype,
 326                                                                 notifname,
 327                                                                 selected
 328                                                         ));
 329                                                         notif_error = TRUE;
 330                                                 }
 331                                                 break;
 332                                         }
 333                                 }
 334                                 break;
 335                         }
 336                 }
 337         }
 338         return args;
 339 }
 340
 341 void Create_Notification_Entity(
 342         float var_default,
 343         float var_cvar,
 344         float typeid,
 345         float nameid,
 346         string namestring,
 347         float anncename,
 348         float infoname,
 349         float centername,
 350         float channel,
 351         string snd,
 352         float vol,
 353         float position,
 354         float strnum,
 355         float flnum,
 356         string args,
 357         string hudargs,
 358         string icon,
 359         float cpid,
 360         string durcnt,
 361         string normal,
 362         string gentle,
 363         float msg_is_info,
 364         float msg_is_multi)
 365 {
 366         // =====================
 367         //  Global Entity Setup
 368         // =====================
 369         entity notif = spawn();
 370         string typestring = "";
 371         switch(typeid)
 372         {
 373                 case MSG_ANNCE:
 374                 {
 375                         typestring = "MSG_ANNCE";
 376                         msg_annce_notifs[nameid - 1] = notif;
 377                         notif.classname = "msg_annce_notification";
 378                         break;
 379                 }
 380                 case MSG_INFO:
 381                 {
 382                         typestring = "MSG_INFO";
 383                         msg_info_notifs[nameid - 1] = notif;
 384                         notif.classname = "msg_info_notification";
 385                         break;
 386                 }
 387                 case MSG_CENTER:
 388                 {
 389                         typestring = "MSG_CENTER";
 390                         msg_center_notifs[nameid - 1] = notif;
 391                         notif.classname = "msg_center_notification";
 392                         break;
 393                 }
 394                 case MSG_MULTI:
 395                 {
 396                         typestring = "MSG_MULTI";
 397                         msg_multi_notifs[nameid - 1] = notif;
 398                         notif.classname = "MSG_MULTI_notification";
 399                         break;
 400                 }
 401
 402                 default:
 403                 {
 404                         error(sprintf(
 405                                 strcat(
 406                                         "^1NOTIFICATION WITH IMPROPER TYPE: ",
 407                                         "^7net_type = %d, net_name = %s.\n"
 408                                 ),
 409                                 typeid,
 410                                 namestring
 411                         ));
 412                         return; // It's not possible to recover from this one
 413                 }
 414         }
 415         notif.nent_default = var_default;
 416         notif.nent_name = strzone(namestring);
 417         notif.nent_id = nameid;
 418         notif.nent_enabled = (1 <= var_cvar);
 419
 420         // Other pre-notif-setup requisites
 421         notif_error = FALSE;
 422
 423         // ====================
 424         //  Notification Setup
 425         // ====================
 426         if(msg_is_multi)
 427         {
 428                 // Set MSG_MULTI string/float counts
 429                 if((anncename == NO_MSG) && (infoname == NO_MSG) && (centername == NO_MSG))
 430                 {
 431                         print(sprintf(
 432                                 strcat(
 433                                         "^1NOTIFICATION WITH NO SUBCALLS: ",
 434                                         "^7net_type = %s, net_name = %s.\n"
 435                                 ),
 436                                 typestring,
 437                                 namestring
 438                         ));
 439                         notif_error = TRUE;
 440                 }
 441                 else
 442                 {
 443                         // announcements don't actually need any arguments, so lets not even count them.
 444                         if(anncename != NO_MSG) { notif.nent_msgannce = msg_annce_notifs[anncename - 1]; }
 445
 446                         float infoname_stringcount = 0, infoname_floatcount = 0;
 447                         float centername_stringcount = 0, centername_floatcount = 0;
 448
 449                         if(infoname != NO_MSG)
 450                         {
 451                                 notif.nent_msginfo = msg_info_notifs[infoname - 1];
 452                                 infoname_stringcount = notif.nent_msginfo.nent_stringcount;
 453                                 infoname_floatcount = notif.nent_msginfo.nent_floatcount;
 454                         }
 455
 456                         if(centername != NO_MSG)
 457                         {
 458                                 notif.nent_msgcenter = msg_center_notifs[centername - 1];
 459                                 centername_stringcount = notif.nent_msgcenter.nent_stringcount;
 460                                 centername_floatcount = notif.nent_msgcenter.nent_floatcount;
 461                         }
 462
 463                         // set the requirements of THIS notification to the totals of its subcalls
 464                         notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
 465                         notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
 466                 }
 467         }
 468         else if(typeid == MSG_ANNCE)
 469         {
 470                 // Set MSG_ANNCE information and handle precaching
 471                 #ifdef CSQC
 472                 if(snd != "")
 473                 {
 474                         precache_sound(sprintf("announcer/%s/%s", autocvar_cl_announcer, snd));
 475                         notif.nent_channel = channel;
 476                         notif.nent_snd = strzone(snd);
 477                         notif.nent_vol = vol;
 478                         notif.nent_position = position;
 479                 }
 480                 else
 481                 {
 482                         print(sprintf(
 483                                 strcat(
 484                                         "^1NOTIFICATION WITH NO SOUND: ",
 485                                         "^7net_type = %s, net_name = %s.\n"
 486                                 ),
 487                                 typestring,
 488                                 namestring
 489                         ));
 490                         notif_error = TRUE;
 491                 }
 492                 #else
 493                 notif.nent_enabled = FALSE;
 494                 #endif
 495         }
 496         else
 497         {
 498                 // Set MSG_INFO and MSG_CENTER string/float counts
 499                 notif.nent_stringcount = strnum;
 500                 notif.nent_floatcount = flnum;
 501
 502                 // Only initialize arguments if we're either a client or on a dedicated server
 503                 #ifdef SVQC
 504                 float should_process_args = server_is_dedicated;
 505                 #else
 506                 float should_process_args = TRUE;
 507                 #endif
 508
 509                 if(should_process_args)
 510                 {
 511                         // ========================
 512                         //  Process Main Arguments
 513                         // ========================
 514                         if(strnum + flnum)
 515                         {
 516                                 if(args != "")
 517                                 {
 518                                         notif.nent_args = strzone(
 519                                                 Process_Notif_Args(1, args, typestring, namestring));
 520                                 }
 521                                 else if((hudargs == "") && (durcnt ==""))
 522                                 {
 523                                         print(sprintf(
 524                                                 strcat(
 525                                                         "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: ",
 526                                                         "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d\n"
 527                                                 ),
 528                                                 typestring,
 529                                                 namestring,
 530                                                 strnum,
 531                                                 flnum
 532                                         ));
 533                                         notif_error = TRUE;
 534                                 }
 535                         }
 536                         else if(args != "")
 537                         {
 538                                 notif.nent_args = strzone(
 539                                         Process_Notif_Args(1, args, typestring, namestring));
 540                         }
 541
 542
 543                         // =======================================
 544                         //  Process HUD and Centerprint Arguments
 545                         //    Only processed on CSQC, as these
 546                         //    args are only for HUD features.
 547                         // =======================================
 548                         #ifdef CSQC
 549                         if(hudargs != "")
 550                         {
 551                                 notif.nent_hudargs = strzone(
 552                                         Process_Notif_Args(2, hudargs, typestring, namestring));
 553
 554                                 if(icon != "") { notif.nent_icon = strzone(icon); }
 555                                 else
 556                                 {
 557                                         print(sprintf(
 558                                                 strcat(
 559                                                         "^1NOTIFICATION HAS HUDARGS BUT NO ICON: ",
 560                                                         "^7net_type = %s, net_name = %s.\n"
 561                                                 ),
 562                                                 typestring,
 563                                                 namestring
 564                                         ));
 565                                         notif_error = TRUE;
 566                                 }
 567                         }
 568                         else if(icon != "")
 569                         {
 570                                 print(sprintf(
 571                                         strcat(
 572                                                 "^1NOTIFICATION HAS ICON BUT NO HUDARGS: ",
 573                                                 "^7net_type = %s, net_name = %s.\n"
 574                                         ),
 575                                         typestring,
 576                                         namestring
 577                                 ));
 578                                 notif_error = TRUE;
 579                         }
 580
 581                         if(durcnt != "")
 582                         {
 583                                 notif.nent_durcnt = strzone(
 584                                         Process_Notif_Args(3, durcnt, typestring, namestring));
 585
 586                                 if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
 587                                 else
 588                                 {
 589                                         print(sprintf(
 590                                                 strcat(
 591                                                         "^1NOTIFICATION HAS DURCNT BUT NO CPID: ",
 592                                                         "^7net_type = %s, net_name = %s.\n"
 593                                                 ),
 594                                                 typestring,
 595                                                 namestring
 596                                         ));
 597                                         notif_error = TRUE;
 598                                 }
 599                         }
 600                         else if(cpid != NO_MSG) { notif.nent_cpid = cpid; }
 601                         #endif
 602
 603
 604                         // ======================
 605                         //  Process Notif String
 606                         // ======================
 607                         #define SET_NOTIF_STRING(string,stringname) \
 608                                 notif.nent_string = strzone(CCR( \
 609                                         Process_Notif_Line( \
 610                                                 msg_is_info, \
 611                                                 (var_cvar > 1), \
 612                                                 string, \
 613                                                 typestring, \
 614                                                 namestring, \
 615                                                 stringname \
 616                                         )) \
 617                                 );
 618
 619                         if(GENTLE)
 620                         {
 621                                 if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE") }
 622                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL") }
 623                         }
 624                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL") }
 625
 626                         #undef SET_NOTIF_STRING
 627
 628                         // Check to make sure a string was chosen
 629                         if(notif.nent_string == "")
 630                         {
 631                                 print(sprintf(
 632                                         strcat(
 633                                                 "^1EMPTY NOTIFICATION: ",
 634                                                 "^7net_type = %s, net_name = %s.\n"
 635                                         ),
 636                                         typestring,
 637                                         namestring
 638                                 ));
 639                                 notif_error = TRUE;
 640                         }
 641                 }
 642         }
 643
 644         // now check to see if any errors happened
 645         if(notif_error)
 646         {
 647                 notif.nent_enabled = FALSE; // disable the notification so it can't cause trouble
 648                 notif_global_error = TRUE; // throw the red flag that an error happened on init
 649         }
 650 }
 651
 652
 653 // =========================================
 654 //  Cvar Handling With 'dumpnotifs' Command
 655 // =========================================
 656
 657 void Dump_Notifications(float fh, float alsoprint)
 658 {
 659         #define NOTIF_WRITE(a) { \
 660                 fputs(fh, a); \
 661                 if(alsoprint) { print(a); } }
 662         #define NOTIF_WRITE_ENTITY(name,default,description) { \
 663                 notif_msg = \
 664                         sprintf( \
 665                                 "seta notification_%s \"%d\" \"%s\"\n", \
 666                                 name, default, description \
 667                         ); \
 668                 NOTIF_WRITE(notif_msg) }
 669         #define NOTIF_WRITE_HARDCODED(cvar,default,description) { \
 670                 notif_msg = \
 671                         sprintf( \
 672                                 "seta notification_%s \"%s\" \"%s\"\n", \
 673                                 cvar, default, description \
 674                         ); \
 675                 NOTIF_WRITE(notif_msg) }
 676
 677         string notif_msg;
 678         float i;
 679         entity e;
 680
 681         // Note: This warning only applies to the notifications.cfg file that is output...
 682
 683         // You ARE supposed to manually edit this function to add i.e. hard coded
 684         // notification variables for mutators or game modes or such and then
 685         // regenerate the notifications.cfg file from the new code.
 686
 687         NOTIF_WRITE("// ********************************************** //\n");
 688         NOTIF_WRITE("// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n");
 689         NOTIF_WRITE("// **                                          ** //\n");
 690         NOTIF_WRITE("// **  This file is automatically generated    ** //\n");
 691         NOTIF_WRITE("// **  by code with the command 'dumpnotifs'.  ** //\n");
 692         NOTIF_WRITE("// **                                          ** //\n");
 693         NOTIF_WRITE("// **  If you add a new notification, please   ** //\n");
 694         NOTIF_WRITE("// **  regenerate this file with that command  ** //\n");
 695         NOTIF_WRITE("// **  making sure that the output matches     ** //\n");
 696         NOTIF_WRITE("// **  with the lists and defaults in code.    ** //\n");
 697         NOTIF_WRITE("// **                                          ** //\n");
 698         NOTIF_WRITE("// ********************************************** //\n");
 699
 700         // These notifications will also append their string as a comment...
 701         // This is not necessary, and does not matter if they vary between config versions,
 702         // it is just a semi-helpful tool for those who want to manually change their user settings.
 703
 704         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications (count = %d):\n", NOTIF_ANNCE_COUNT));
 705         for(i = 1; i <= NOTIF_ANNCE_COUNT; ++i)
 706         {
 707                 e = Get_Notif_Ent(MSG_ANNCE, i);
 708                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 709                 NOTIF_WRITE_ENTITY(e.nent_name, e.nent_default, "Notification control cvar: 0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled)");
 710         }
 711
 712         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
 713         for(i = 1; i <= NOTIF_INFO_COUNT; ++i)
 714         {
 715                 e = Get_Notif_Ent(MSG_INFO, i);
 716                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 717                 NOTIF_WRITE_ENTITY(e.nent_name, e.nent_default, "Notification control cvar: 0 = off, 1 = print to console, 2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)");
 718         }
 719
 720         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
 721         for(i = 1; i <= NOTIF_CENTER_COUNT; ++i)
 722         {
 723                 e = Get_Notif_Ent(MSG_CENTER, i);
 724                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 725                 NOTIF_WRITE_ENTITY(e.nent_name, e.nent_default, "Notification control cvar: 0 = off, 1 = centerprint");
 726         }
 727
 728         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications (count = %d):\n", NOTIF_MULTI_COUNT));
 729         for(i = 1; i <= NOTIF_MULTI_COUNT; ++i)
 730         {
 731                 e = Get_Notif_Ent(MSG_MULTI, i);
 732                 if not(e) { backtrace("Dump_Notifications(): Missing notification entity!\n"); return; }
 733                 NOTIF_WRITE_ENTITY(e.nent_name, e.nent_default, "Notification control cvar: 0 = off, 1 = trigger subcalls");
 734         }
 735
 736         // edit these to match whichever cvars are used for specific notification options
 737         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
 738         NOTIF_WRITE_HARDCODED("allow_chatboxprint",              "1",    "Allow notifications to be printed to chat box by setting notification cvar to 2 (You can also set this cvar to 2 to force ALL notifications to be printed to the chatbox)");
 739         NOTIF_WRITE_HARDCODED("ctf_capture_verbose",             "0",    "Show extra information when someone captures a flag");
 740         NOTIF_WRITE_HARDCODED("ctf_pickup_enemy_verbose",        "0",    "Show extra information if an enemy picks up a flag");
 741         NOTIF_WRITE_HARDCODED("ctf_pickup_team_verbose",         "0",    "Show extra information if a team mate picks up a flag");
 742         NOTIF_WRITE_HARDCODED("errors_are_fatal",                "1",    "If a notification fails upon initialization, cause a Host_Error to stop the program");
 743         NOTIF_WRITE_HARDCODED("frag_verbose",                    "1",    "Show extra information when you frag someone (or when you are fragged");
 744         NOTIF_WRITE_HARDCODED("item_centerprinttime",            "1.5",  "How long to show item information centerprint messages (like 'You got the Electro' or such)");
 745         NOTIF_WRITE_HARDCODED("lifetime_mapload",                "10",   "Amount of time that notification entities last immediately at mapload (in seconds) to help prevent notifications from being lost on early init (like gamestart countdown)");
 746         NOTIF_WRITE_HARDCODED("lifetime_runtime",                "0.5",  "Amount of time that notification entities last on the server during runtime (In seconds)");
 747         NOTIF_WRITE_HARDCODED("server_allows_frag_verbose",      "1",    "Server side cvar for showing extra information in frag messages... 0 = no extra frag information, 1 = frag information only in warmup, 2 = frag information allowed all the time");
 748         NOTIF_WRITE_HARDCODED("server_allows_location",          "1",    "Server side cvar for allowing death messages to show location information too");
 749         NOTIF_WRITE_HARDCODED("show_location",                   "0",    "Append location information to MSG_INFO death/kill messages");
 750         NOTIF_WRITE_HARDCODED("show_location_string",            "",     "Replacement string piped into sprintf, so you can do different messages like this: ' at the %s' or ' (near %s)'");
 751         NOTIF_WRITE_HARDCODED("show_sprees",                     "1",    "Print information about sprees in death/kill messages");
 752         NOTIF_WRITE_HARDCODED("show_sprees_center",              "1",    "Show spree information in MSG_CENTER messages... 0 = off, 1 = target (but only for first victim) and attacker");
 753         NOTIF_WRITE_HARDCODED("show_sprees_center_specialonly",  "1",    "Don't show spree information in MSG_CENTER messages if it isn't an achievement");
 754         NOTIF_WRITE_HARDCODED("show_sprees_info",                "3",    "Show spree information in MSG_INFO messages... 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker");
 755         NOTIF_WRITE_HARDCODED("show_sprees_info_newline",        "1",    "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself");
 756         NOTIF_WRITE_HARDCODED("show_sprees_info_specialonly",    "1",    "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement");
 757
 758         NOTIF_WRITE(sprintf(
 759                 strcat(
 760                         "\n// Notification counts (total = %d): ",
 761                         "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d\n"
 762                 ),
 763                 (
 764                         NOTIF_ANNCE_COUNT +
 765                         NOTIF_INFO_COUNT +
 766                         NOTIF_CENTER_COUNT +
 767                         NOTIF_MULTI_COUNT
 768                 ),
 769                 NOTIF_ANNCE_COUNT,
 770                 NOTIF_INFO_COUNT,
 771                 NOTIF_CENTER_COUNT,
 772                 NOTIF_MULTI_COUNT
 773         ));
 774
 775         return;
 776         #undef NOTIF_WRITE_HARDCODED
 777         #undef NOTIF_WRITE_ENTITY
 778         #undef NOTIF_WRITE
 779 }
 780
 781 #ifdef SVQC
 782 void Notification_GetCvars()
 783 {
 784         GetCvars_handleFloat(get_cvars_s, get_cvars_f, FRAG_VERBOSE, "notification_frag_verbose");
 785 }
 786 #endif
 787
 788
 789 // ===============================
 790 //  Frontend Notification Pushing
 791 // ===============================
 792
 793 string Local_Notification_sprintf(
 794         string input, string args,
 795         string s1, string s2, string s3, string s4,
 796         float f1, float f2, float f3, float f4)
 797 {
 798         #ifdef NOTIFICATIONS_DEBUG
 799         dprint(sprintf(
 800                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
 801                 MakeConsoleSafe(input),
 802                 args,
 803                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
 804                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
 805         ));
 806         #endif
 807
 808         string selected;
 809         float sel_num;
 810         for(sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
 811
 812         string tmp_s;
 813
 814         for(sel_num = 0;(args != "");)
 815         {
 816                 selected = car(args); args = cdr(args);
 817                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
 818                 switch(strtolower(selected))
 819                 {
 820                         #define ARG_CASE(prog,selected,result) \
 821                                 #ifdef CSQC \
 822                                         #if (prog != ARG_SV) && (prog != ARG_DC) \
 823                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 824                                         #endif \
 825                                 #else \
 826                                         #if (prog != ARG_CS) && (prog != ARG_DC) \
 827                                                 case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 828                                         #endif \
 829                                 #endif
 830                         NOTIF_ARGUMENT_LIST
 831                         #undef ARG_CASE
 832                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
 833                 }
 834         }
 835         return sprintf(input, arg_slot[0], arg_slot[1], arg_slot[2], arg_slot[3], arg_slot[4], arg_slot[5], arg_slot[6]);
 836 }
 837
 838 #ifdef CSQC
 839 void Local_Notification_HUD_Notify_Push(
 840         string icon, string hudargs,
 841         string s1, string s2, string s3, string s4)
 842 {
 843         string selected;
 844         float sel_num;
 845         arg_slot[0] = ""; arg_slot[1] = "";
 846
 847         for(sel_num = 0;(hudargs != "");)
 848         {
 849                 selected = car(hudargs); hudargs = cdr(hudargs);
 850                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
 851                 switch(strtolower(selected))
 852                 {
 853                         #define ARG_CASE(prog,selected,result) \
 854                                 #if (prog == ARG_CS_SV_HA) \
 855                                         case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 856                                 #endif
 857                         NOTIF_ARGUMENT_LIST
 858                         #undef ARG_CASE
 859                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
 860                 }
 861         }
 862         #ifdef NOTIFICATIONS_DEBUG
 863         dprint(sprintf(
 864                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s);\n",
 865                 icon,
 866                 hudargs,
 867                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
 868                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
 869         ));
 870         #endif
 871         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
 872 }
 873
 874 void Local_Notification_centerprint_generic(
 875         string input, string durcnt,
 876         float cpid, float f1, float f2)
 877 {
 878         string selected;
 879         float sel_num;
 880         arg_slot[0] = ""; arg_slot[1] = "";
 881
 882         for(sel_num = 0;(durcnt != "");)
 883         {
 884                 selected = car(durcnt); durcnt = cdr(durcnt);
 885                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic")
 886                 switch(strtolower(selected))
 887                 {
 888                         #define ARG_CASE(prog,selected,result) \
 889                                 #if (prog == ARG_CS_SV_DC) || (prog == ARG_DC) \
 890                                         case selected: { arg_slot[sel_num] = result; ++sel_num; break; } \
 891                                 #endif
 892                         NOTIF_ARGUMENT_LIST
 893                         #undef ARG_CASE
 894                         default:
 895                         {
 896                                 if(ftos(stof(selected)) != "") { arg_slot[sel_num] = selected; ++sel_num; }
 897                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_generic") }
 898                                 break;
 899                         }
 900                 }
 901         }
 902         #ifdef NOTIFICATIONS_DEBUG
 903         dprint(sprintf(
 904                 "Local_Notification_centerprint_generic('%s^7', '%s', %d, %d, %d, %d);\n",
 905                 MakeConsoleSafe(input),
 906                 durcnt,
 907                 f1, f2,
 908                 stof(arg_slot[0]), stof(arg_slot[1])
 909         ));
 910         #endif
 911         centerprint_generic(cpid, input, stof(arg_slot[0]), stof(arg_slot[1]));
 912 }
 913 string previous_announcement;
 914 #endif
 915
 916 void Local_Notification(float net_type, float net_name, ...count)
 917 {
 918         // check supplied type and name for errors
 919         string checkargs = Notification_CheckArgs_TypeName(net_type, net_name);
 920         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Local_Notification: %s\n", checkargs)); return; }
 921
 922         entity notif = Get_Notif_Ent(net_type, net_name);
 923         if not(notif) { backtrace("Local_Notification: Could not find notification entity!\n"); return; }
 924         if not(notif.nent_enabled)
 925         {
 926                 #ifdef NOTIFICATIONS_DEBUG
 927                 dprint(sprintf(
 928                         "Local_Notification(%s, %s): Entity was disabled...\n",
 929                         Get_Notif_TypeName(net_type),
 930                         notif.nent_name
 931                 ));
 932                 #endif
 933                 return;
 934         }
 935
 936         if((notif.nent_stringcount + notif.nent_floatcount) > count)
 937         {
 938                 backtrace(sprintf(
 939                         strcat(
 940                                 "Not enough arguments for Local_Notification(%s, %s, ...)! ",
 941                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
 942                                 "Check the definition and function call for accuracy...?\n"
 943                         ),
 944                         Get_Notif_TypeName(net_type), notif.nent_name,
 945                         notif.nent_stringcount, notif.nent_floatcount, count
 946                 ));
 947                 return;
 948         }
 949         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
 950         {
 951                 backtrace(sprintf(
 952                         strcat(
 953                                 "Too many arguments for Local_Notification(%s, %s, ...)! ",
 954                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
 955                                 "Check the definition and function call for accuracy...?\n"
 956                         ),
 957                         Get_Notif_TypeName(net_type), notif.nent_name,
 958                         notif.nent_stringcount, notif.nent_floatcount, count
 959                 ));
 960                 return;
 961         }
 962
 963         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
 964         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
 965         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
 966         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
 967         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
 968         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
 969         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
 970         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
 971
 972         #ifdef NOTIFICATIONS_DEBUG
 973         dprint(sprintf(
 974                 "Local_Notification(%s, %s, %s, %s);\n",
 975                 Get_Notif_TypeName(net_type),
 976                 notif.nent_name,
 977                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
 978                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
 979         ));
 980         #endif
 981
 982         switch(net_type)
 983         {
 984                 case MSG_ANNCE:
 985                 {
 986                         #ifdef CSQC
 987                         if((notif.nent_snd != previous_announcement) || (time >= (previous_announcement_time + autocvar_cl_announcer_antispam)))
 988                         {
 989                                 sound(
 990                                         world,
 991                                         notif.nent_channel,
 992                                         sprintf(
 993                                                 "announcer/%s/%s",
 994                                                 autocvar_cl_announcer,
 995                                                 notif.nent_snd
 996                                         ),
 997                                         notif.nent_vol,
 998                                         notif.nent_position
 999                                 );
1000
1001                                 if(previous_announcement) { strunzone(previous_announcement); }
1002                                 previous_announcement = strzone(notif.nent_snd);
1003                                 previous_announcement_time = time;
1004                         }
1005                         #else
1006                         print("MSG_ANNCE on server?...\n");
1007                         #endif
1008                         break;
1009                 }
1010
1011                 case MSG_INFO:
1012                 {
1013                         print(
1014                                 Local_Notification_sprintf(
1015                                         notif.nent_string,
1016                                         notif.nent_args,
1017                                         s1, s2, s3, s4,
1018                                         f1, f2, f3, f4)
1019                         );
1020                         #ifdef CSQC
1021                         if(notif.nent_icon != "")
1022                         {
1023                                 Local_Notification_HUD_Notify_Push(
1024                                         notif.nent_icon,
1025                                         notif.nent_hudargs,
1026                                         s1, s2, s3, s4);
1027                         }
1028                         #endif
1029                         break;
1030                 }
1031
1032                 #ifdef CSQC
1033                 case MSG_CENTER:
1034                 {
1035                         Local_Notification_centerprint_generic(
1036                                 Local_Notification_sprintf(
1037                                         notif.nent_string,
1038                                         notif.nent_args,
1039                                         s1, s2, s3, s4,
1040                                         f1, f2, f3, f4),
1041                                 notif.nent_durcnt,
1042                                 notif.nent_cpid,
1043                                 f1, f2);
1044                         break;
1045                 }
1046                 #endif
1047
1048                 case MSG_MULTI:
1049                 {
1050                         if(notif.nent_msginfo)
1051                         if(notif.nent_msginfo.nent_enabled)
1052                         {
1053                                 Local_Notification_WOVA(
1054                                         MSG_INFO,
1055                                         notif.nent_msginfo.nent_id,
1056                                         notif.nent_msginfo.nent_stringcount,
1057                                         notif.nent_msginfo.nent_floatcount,
1058                                         s1, s2, s3, s4,
1059                                         f1, f2, f3, f4);
1060                         }
1061                         #ifdef CSQC
1062                         if(notif.nent_msgcenter)
1063                         if(notif.nent_msgcenter.nent_enabled)
1064                         {
1065                                 Local_Notification_WOVA(
1066                                         MSG_CENTER,
1067                                         notif.nent_msgcenter.nent_id,
1068                                         notif.nent_msgcenter.nent_stringcount,
1069                                         notif.nent_msgcenter.nent_floatcount,
1070                                         s1, s2, s3, s4,
1071                                         f1, f2, f3, f4);
1072                         }
1073                         #endif
1074                         break;
1075                 }
1076         }
1077 }
1078
1079 // WOVA = Without Variable Arguments
1080 void Local_Notification_WOVA(
1081         float net_type, float net_name,
1082         float stringcount, float floatcount,
1083         string s1, string s2, string s3, string s4,
1084         float f1, float f2, float f3, float f4)
1085 {
1086         #define VARITEM(stringc,floatc,args) \
1087                 if((stringcount == stringc) && (floatcount == floatc)) \
1088                         { Local_Notification(net_type, net_name, args); return; }
1089         EIGHT_VARS_TO_VARARGS_VARLIST
1090         #undef VARITEM
1091         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1092 }
1093
1094
1095 // =========================
1096 //  Notification Networking
1097 // =========================
1098
1099 #ifdef CSQC
1100 void Read_Notification(float is_new)
1101 {
1102         float net_type = ReadByte();
1103         float net_name = ReadShort();
1104
1105         entity notif;
1106
1107         if(net_type == MSG_CENTER_CPID)
1108         {
1109                 #ifdef NOTIFICATIONS_DEBUG
1110                 dprint(sprintf(
1111                         "Read_Notification(%d) at %f: net_type = %s, net_name = %d\n",
1112                         is_new,
1113                         time,
1114                         Get_Notif_TypeName(net_type),
1115                         net_name
1116                 ));
1117                 #endif
1118
1119                 if(is_new)
1120                 {
1121                         if(net_name == 0) { reset_centerprint_messages(); }
1122                         else if(net_name != NO_CPID)
1123                         {
1124                                 // in this case, net_name IS the cpid we want to kill
1125                                 centerprint_generic(net_name, "", 0, 0);
1126                         }
1127                         else
1128                         {
1129                                 backtrace(sprintf(
1130                                         "Read_Notification(%d) at %f: ^1TRIED TO KILL NO_CPID CENTERPRINT!\n",
1131                                         is_new,
1132                                         time
1133                                 ));
1134                         }
1135                 }
1136         }
1137         else
1138         {
1139                 notif = Get_Notif_Ent(net_type, net_name);
1140                 if not(notif) { backtrace("Read_Notification: Could not find notification entity!\n"); return; }
1141
1142                 #ifdef NOTIFICATIONS_DEBUG
1143                 dprint(sprintf(
1144                         "Read_Notification(%d) at %f: net_type = %s, net_name = %s\n",
1145                         is_new,
1146                         time,
1147                         Get_Notif_TypeName(net_type),
1148                         notif.nent_name
1149                 ));
1150                 #endif
1151
1152                 string s1 = ((0 < notif.nent_stringcount) ? ReadString() : "");
1153                 string s2 = ((1 < notif.nent_stringcount) ? ReadString() : "");
1154                 string s3 = ((2 < notif.nent_stringcount) ? ReadString() : "");
1155                 string s4 = ((3 < notif.nent_stringcount) ? ReadString() : "");
1156                 float f1 = ((0 < notif.nent_floatcount) ? ReadLong() : 0);
1157                 float f2 = ((1 < notif.nent_floatcount) ? ReadLong() : 0);
1158                 float f3 = ((2 < notif.nent_floatcount) ? ReadLong() : 0);
1159                 float f4 = ((3 < notif.nent_floatcount) ? ReadLong() : 0);
1160
1161                 if(is_new)
1162                 {
1163                         Local_Notification_WOVA(
1164                                 net_type, net_name,
1165                                 notif.nent_stringcount,
1166                                 notif.nent_floatcount,
1167                                 s1, s2, s3, s4,
1168                                 f1, f2, f3, f4);
1169                 }
1170         }
1171 }
1172 #endif
1173
1174 #ifdef SVQC
1175 void Net_Notification_Remove()
1176 {
1177         if not(self) { backtrace(sprintf("Net_Notification_Remove() at %f: Missing self!?\n", time)); return; }
1178
1179         #ifdef NOTIFICATIONS_DEBUG
1180         dprint(sprintf(
1181                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1182                 time,
1183                 ((self.nent_net_name == -1) ? "Killed" : "Removed"),
1184                 Get_Notif_TypeName(self.nent_net_type),
1185                 self.owner.nent_name
1186         ));
1187         #endif
1188
1189         float i;
1190         for(i = 0; i < 4; ++i) { if(self.nent_strings[i]) { strunzone(self.nent_strings[i]); } }
1191         remove(self);
1192 }
1193
1194 float Net_Write_Notification(entity client, float sf)
1195 {
1196         float i, send = FALSE;
1197
1198         switch(self.nent_broadcast)
1199         {
1200                 case NOTIF_ONE: // send to one client and their spectator
1201                 {
1202                         if(
1203                                 (client == self.nent_client)
1204                                 ||
1205                                 (
1206                                         IS_SPEC(client)
1207                                         &&
1208                                         (client.enemy == self.nent_client)
1209                                 )
1210                         ) { send = TRUE; }
1211                         break;
1212                 }
1213                 case NOTIF_ONE_ONLY: // send ONLY to one client
1214                 {
1215                         if(client == self.nent_client) { send = TRUE; }
1216                         break;
1217                 }
1218                 case NOTIF_TEAM: // send only to X team and their spectators
1219                 {
1220                         if(
1221                                 (client.team == self.nent_client.team)
1222                                 ||
1223                                 (
1224                                         IS_SPEC(client)
1225                                         &&
1226                                         (client.enemy.team == self.nent_client.team)
1227                                 )
1228                         ) { send = TRUE; }
1229                         break;
1230                 }
1231                 case NOTIF_TEAM_EXCEPT: // send only to X team and their spectators, except for Y person and their spectators
1232                 {
1233                         if(
1234                                 (client != self.nent_client)
1235                                 &&
1236                                 (
1237                                         (client.team == self.nent_client.team)
1238                                         ||
1239                                         (
1240                                                 IS_SPEC(client)
1241                                                 &&
1242                                                 (
1243                                                         (client.enemy != self.nent_client)
1244                                                         &&
1245                                                         (client.enemy.team == self.nent_client.team)
1246                                                 )
1247                                         )
1248                                 )
1249                         ) { send = TRUE; }
1250                         break;
1251                 }
1252                 case NOTIF_ALL: // send to everyone
1253                 {
1254                         send = TRUE;
1255                         break;
1256                 }
1257                 case NOTIF_ALL_EXCEPT: // send to everyone except X person and their spectators
1258                 {
1259                         if(
1260                                 (client != self.nent_client)
1261                                 &&
1262                                 !(
1263                                         IS_SPEC(client)
1264                                         &&
1265                                         (client.enemy == self.nent_client)
1266                                 )
1267                         ) { send = TRUE; }
1268                         break;
1269                 }
1270                 default: { send = FALSE; break; }
1271         }
1272
1273         if(send)
1274         {
1275                 WriteByte(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1276                 WriteByte(MSG_ENTITY, self.nent_net_type);
1277                 WriteShort(MSG_ENTITY, self.nent_net_name);
1278                 for(i = 0; i < self.nent_stringcount; ++i) { WriteString(MSG_ENTITY, self.nent_strings[i]); }
1279                 for(i = 0; i < self.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, self.nent_floats[i]); }
1280         }
1281
1282         return send;
1283 }
1284
1285 void Kill_Notification(
1286         float broadcast, entity client,
1287         float net_type, float net_name)
1288 {
1289         string checkargs = Notification_CheckArgs(broadcast, client, 1, 1);
1290         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Kill_Notification: %s\n", checkargs)); return; }
1291
1292         #ifdef NOTIFICATIONS_DEBUG
1293         dprint(sprintf(
1294                 "Kill_Notification(%d, '%s', %s, %d);\n",
1295                 broadcast,
1296                 client.netname,
1297                 Get_Notif_TypeName(net_type),
1298                 net_name
1299         ));
1300         #endif
1301
1302         entity notif, net_notif;
1303         float killed_cpid = NO_CPID;
1304
1305         switch(net_type)
1306         {
1307                 case 0:
1308                 {
1309                         killed_cpid = 0; // kill ALL centerprints
1310                         break;
1311                 }
1312
1313                 case MSG_CENTER:
1314                 {
1315                         if(net_name)
1316                         {
1317                                 entity notif = Get_Notif_Ent(net_type, net_name);
1318                                 if not(notif) { backtrace("Kill_Notification: Could not find notification entity!\n"); return; }
1319
1320                                 if(notif.nent_cpid)
1321                                         killed_cpid = notif.nent_cpid;
1322                                 else
1323                                         killed_cpid = NO_CPID;
1324                         }
1325                         else
1326                         {
1327                                 killed_cpid = 0; // kill ALL centerprints
1328                         }
1329                         break;
1330                 }
1331
1332                 case MSG_CENTER_CPID:
1333                 {
1334                         killed_cpid = net_name;
1335                         break;
1336                 }
1337         }
1338
1339         if(killed_cpid != NO_CPID)
1340         {
1341                 net_notif = spawn();
1342                 net_notif.classname = "net_kill_notification";
1343                 net_notif.nent_broadcast = broadcast;
1344                 net_notif.nent_client = client;
1345                 net_notif.nent_net_type = MSG_CENTER_CPID;
1346                 net_notif.nent_net_name = killed_cpid;
1347                 Net_LinkEntity(net_notif, FALSE, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1348         }
1349
1350         for(notif = world; (notif = find(notif, classname, "net_notification"));)
1351         {
1352                 if(net_type)
1353                 {
1354                         if(killed_cpid != NO_CPID)
1355                         {
1356                                 if(notif.owner.nent_cpid == killed_cpid)
1357                                 {
1358                                         notif.nent_net_name = -1;
1359                                         notif.nextthink = time;
1360                                 }
1361                                 else { continue; } // we ARE looking for a specific CPID, don't kill everything else too
1362                         }
1363                         else if(notif.nent_net_type == net_type)
1364                         {
1365                                 if(net_name)
1366                                 {
1367                                         if(notif.nent_net_name == net_name) { notif.nent_net_name = -1; notif.nextthink = time; }
1368                                         else { continue; } // we ARE looking for a certain net_name, don't kill everything else too
1369                                 }
1370                                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1371                         }
1372                         else { continue; } // we ARE looking for a certain net_type, don't kill everything else too
1373                 }
1374                 else { notif.nent_net_name = -1; notif.nextthink = time; }
1375         }
1376 }
1377
1378 void Send_Notification(
1379         float broadcast, entity client,
1380         float net_type, float net_name,
1381         ...count)
1382 {
1383         // check supplied broadcast, target, type, and name for errors
1384         string checkargs = Notification_CheckArgs(broadcast, client, net_type, net_name);
1385         if(checkargs != "") { backtrace(sprintf("Incorrect usage of Send_Notification: %s\n", checkargs)); return; }
1386
1387         // retreive counts for the arguments of this notification
1388         entity notif = Get_Notif_Ent(net_type, net_name);
1389         if not(notif) { backtrace("Send_Notification: Could not find notification entity!\n"); return; }
1390
1391         if((notif.nent_stringcount + notif.nent_floatcount) > count)
1392         {
1393                 backtrace(sprintf(
1394                         strcat(
1395                                 "Not enough arguments for Send_Notification(%d, %s, %s, ...)! ",
1396                                 "stringcount(%d) + floatcount(%d) > count(%d)\n",
1397                                 "Check the definition and function call for accuracy...?\n"
1398                         ),
1399                         broadcast, Get_Notif_TypeName(net_type), notif.nent_name,
1400                         notif.nent_stringcount, notif.nent_floatcount, count
1401                 ));
1402                 return;
1403         }
1404         else if((notif.nent_stringcount + notif.nent_floatcount) < count)
1405         {
1406                 backtrace(sprintf(
1407                         strcat(
1408                                 "Too many arguments for Send_Notification(%d, %s, %s, ...)! ",
1409                                 "stringcount(%d) + floatcount(%d) < count(%d)\n",
1410                                 "Check the definition and function call for accuracy...?\n"
1411                         ),
1412                         broadcast, Get_Notif_TypeName(net_type), notif.nent_name,
1413                         notif.nent_stringcount, notif.nent_floatcount, count
1414                 ));
1415                 return;
1416         }
1417
1418         #ifdef NOTIFICATIONS_DEBUG
1419         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1420         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1421         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1422         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1423         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1424         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1425         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1426         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1427         dprint(sprintf(
1428                 "Send_Notification(%d, %s, %s, %s, %s);\n",
1429                 broadcast,
1430                 Get_Notif_TypeName(net_type),
1431                 notif.nent_name,
1432                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1433                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1434         ));
1435         #endif
1436
1437         entity net_notif = spawn();
1438         net_notif.owner = notif;
1439         net_notif.classname = "net_notification";
1440         net_notif.nent_broadcast = broadcast;
1441         net_notif.nent_client = client;
1442         net_notif.nent_net_type = net_type;
1443         net_notif.nent_net_name = net_name;
1444         net_notif.nent_stringcount = notif.nent_stringcount;
1445         net_notif.nent_floatcount = notif.nent_floatcount;
1446
1447         float i;
1448         for(i = 0; i < net_notif.nent_stringcount; ++i) { net_notif.nent_strings[i] = strzone(...(i, string)); }
1449         for(i = 0; i < net_notif.nent_floatcount; ++i) { net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float); }
1450
1451         net_notif.think = Net_Notification_Remove;
1452         net_notif.nextthink =
1453                 ((time > autocvar_notification_lifetime_mapload)
1454                 ?
1455                         (time + autocvar_notification_lifetime_runtime)
1456                         :
1457                         autocvar_notification_lifetime_mapload
1458                 );
1459
1460         Net_LinkEntity(net_notif, FALSE, 0, Net_Write_Notification);
1461
1462         if(server_is_dedicated && (broadcast == NOTIF_ALL || broadcast == NOTIF_ALL_EXCEPT) && (net_type != MSG_ANNCE) && (net_type != MSG_CENTER))
1463         {
1464                 Local_Notification_WOVA(
1465                         net_type, net_name,
1466                         notif.nent_stringcount,
1467                         notif.nent_floatcount,
1468                         IFSTR(0), IFSTR(1), IFSTR(2), IFSTR(3),
1469                         IFFL(0), IFFL(1), IFFL(2), IFFL(3));
1470         }
1471 }
1472
1473 // WOVA = Without Variable Arguments
1474 void Send_Notification_WOVA(
1475         float broadcast, entity client,
1476         float net_type, float net_name,
1477         string s1, string s2, string s3, string s4,
1478         float f1, float f2, float f3, float f4)
1479 {
1480         entity notif = Get_Notif_Ent(net_type, net_name);
1481
1482         #ifdef NOTIFICATIONS_DEBUG
1483         dprint(sprintf(
1484                 "Send_Notification_WOVA(%d, %s, %s, %s, %s);\n",
1485                 broadcast,
1486                 Get_Notif_TypeName(net_type),
1487                 notif.nent_name,
1488                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1489                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1490         ));
1491         #endif
1492
1493         #define VARITEM(stringc,floatc,args) \
1494                 if((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
1495                         { Send_Notification(broadcast, client, net_type, net_name, args); return; }
1496         EIGHT_VARS_TO_VARARGS_VARLIST
1497         #undef VARITEM
1498         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
1499 }
1500 #endif // ifdef SVQC