qcsrc/common/notifications.qh

   1 #ifndef NOTIFICATIONS_H
   2 #define NOTIFICATIONS_H
   3
   4 #include <common/command/all.qh>
   5
   6 #include "constants.qh"
   7 #include "teams.qh"
   8 #include "util.qh"
   9
  10 // ================================================
  11 //  Unified notification system, written by Samual
  12 //  Last updated: March, 2013
  13 // ================================================
  14
  15 // main types/groups of notifications
  16 const int MSG_ANNCE = 1; // "Global" AND "personal" announcer messages
  17 const int MSG_INFO = 2; // "Global" information messages
  18 const int MSG_CENTER = 3; // "Personal" centerprint messages
  19 const int MSG_CENTER_CPID = 4; // Kill centerprint message
  20 const int MSG_MULTI = 5; // Subcall MSG_INFO and/or MSG_CENTER notifications
  21 const int MSG_CHOICE = 6; // Choose which subcall wrapper to activate
  22
  23 // negative confirmations
  24 const int NO_MSG = -12345;  // allows various things to know when no information is added
  25 const int NOTIF_ABORT = -1234;   // allows Send_Notification to safely abort sending
  26
  27 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  28     VARITEM(1, 0, s1) \
  29     VARITEM(2, 0, XPD(s1, s2)) \
  30     VARITEM(3, 0, XPD(s1, s2, s3)) \
  31     VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  32     VARITEM(0, 1, f1) \
  33     VARITEM(1, 1, XPD(s1, f1)) \
  34     VARITEM(2, 1, XPD(s1, s2, f1)) \
  35     VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  36     VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  37     VARITEM(0, 2, XPD(f1, f2)) \
  38     VARITEM(1, 2, XPD(s1, f1, f2)) \
  39     VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
  40     VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
  41     VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
  42     VARITEM(0, 3, XPD(f1, f2, f3)) \
  43     VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
  44     VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
  45     VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
  46     VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
  47     VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
  48     VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
  49     VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
  50     VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
  51     VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
  52
  53 void Destroy_All_Notifications();
  54 void Create_Notification_Entity(
  55     float var_default,
  56     float var_cvar,
  57     float typeId,
  58     float nameid,
  59     string namestring,
  60     int strnum,
  61     int flnum,
  62     /* MSG_ANNCE */
  63     float channel,
  64     string snd,
  65     float vol,
  66     float position,
  67     /* MSG_INFO & MSG_CENTER */
  68     string args,
  69     string hudargs,
  70     string icon,
  71     float cpid,
  72     string durcnt,
  73     string normal,
  74     string gentle,
  75     /* MSG_MULTI */
  76     float anncename,
  77     float infoname,
  78     float centername,
  79     /* MSG_CHOICE */
  80     float challow_def,
  81     float challow_var,
  82     float chtype,
  83     float optiona,
  84     float optionb);
  85
  86 void Dump_Notifications(float fh, float alsoprint);
  87
  88
  89 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into notifications_dump.txt")
  90 {
  91         switch(request)
  92         {
  93                 case CMD_REQUEST_COMMAND:
  94                 {
  95                         #ifndef MENUQC
  96                         float fh, alsoprint = false;
  97                         string filename = argv(1);
  98
  99                         if(filename == "")
 100                         {
 101                                 filename = "notifications_dump.cfg";
 102                                 alsoprint = false;
 103                         }
 104                         else if(filename == "-")
 105                         {
 106                                 filename = "notifications_dump.cfg";
 107                                 alsoprint = true;
 108                         }
 109                         fh = fopen(filename, FILE_WRITE);
 110
 111                         if(fh >= 0)
 112                         {
 113                                 Dump_Notifications(fh, alsoprint);
 114                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 115                                 fclose(fh);
 116                         }
 117                         else
 118                         {
 119                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!\n", filename);
 120                         }
 121                         #else
 122                         LOG_INFO(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 123                         #endif
 124                         return;
 125                 }
 126
 127                 default:
 128                 case CMD_REQUEST_USAGE:
 129                 {
 130                         LOG_INFO(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 131                         LOG_INFO("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 132                         LOG_INFO("  if supplied with '-' output to console as well as default,\n");
 133                         LOG_INFO("  if left blank, it will only write to default.\n");
 134                         return;
 135                 }
 136         }
 137 }
 138
 139 #ifdef NOTIFICATIONS_DEBUG
 140 void Debug_Notification(string input);
 141 #endif
 142
 143 void Local_Notification(int net_type, int net_name, ...count);
 144 void Local_Notification_WOVA(
 145     float net_type, float net_name,
 146     float stringcount, float floatcount,
 147     string s1, string s2, string s3, string s4,
 148     float f1, float f2, float f3, float f4);
 149
 150 #ifdef CSQC // CLIENT ONLY
 151 string prev_soundfile;
 152 float prev_soundtime;
 153 #endif
 154
 155 #ifdef SVQC // SERVER ONLY
 156 const float NOTIF_ONE = 1;
 157 const float NOTIF_ONE_ONLY = 2;
 158 const float NOTIF_TEAM = 3;
 159 const float NOTIF_TEAM_EXCEPT = 4;
 160 const float NOTIF_ALL = 5;
 161 const float NOTIF_ALL_EXCEPT = 6;
 162
 163 void Kill_Notification(
 164     float broadcast, entity client,
 165     float net_type, float net_name);
 166 void Send_Notification(
 167     float broadcast, entity client,
 168     float net_type, float net_name,
 169     ...count);
 170 void Send_Notification_WOVA(
 171     float broadcast, entity client,
 172     float net_type, float net_name,
 173     float stringcount, float floatcount,
 174     string s1, string s2, string s3, string s4,
 175     float f1, float f2, float f3, float f4);
 176 void Send_Notification_WOCOVA(
 177     float broadcast, entity client,
 178     float net_type, float net_name,
 179     string s1, string s2, string s3, string s4,
 180     float f1, float f2, float f3, float f4);
 181 #endif
 182
 183 // ===========================
 184 //  Special CVAR Declarations
 185 // ===========================
 186
 187 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 188 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 189
 190 #define NOTIF_ADD_AUTOCVAR(name,default) float autocvar_notification_##name = default;
 191
 192 float autocvar_notification_show_location = false;
 193 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 194 float autocvar_notification_show_sprees = true;
 195 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 196 float autocvar_notification_show_sprees_info_newline = true;
 197 float autocvar_notification_show_sprees_info_specialonly = true;
 198 float autocvar_notification_errors_are_fatal = true;
 199 float autocvar_notification_lifetime_runtime = 0.5;
 200 float autocvar_notification_lifetime_mapload = 10;
 201 float autocvar_notification_debug = false;
 202
 203 #ifdef SVQC
 204 .float FRAG_VERBOSE;
 205 void Notification_GetCvars();
 206 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 207 #else
 208 float autocvar_notification_item_centerprinttime = 1.5;
 209
 210 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 211 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 212 float autocvar_notification_allow_chatboxprint = 0;
 213
 214 float autocvar_notification_show_sprees_center = true;
 215 float autocvar_notification_show_sprees_center_specialonly = true;
 216 #endif
 217
 218
 219 // ============================
 220 //  Notification Argument List
 221 // ============================
 222 /*
 223  These arguments get replaced with the Local_Notification_sprintf
 224  and other such functions found in notifications.qc to supply data
 225  from networked notifications to their usage in sprintf... It
 226  allows for more dynamic data to be inferred by the local
 227  notification parser, so that the server does not have to network
 228  anything too crazy on a per-client/per-situation basis.
 229
 230  Pay attention to the CSQC/SVQC relations, some of these are redefined
 231  in slightly different ways for different programs, this is because the
 232  server does a more conservative approach to the notifs than the client.
 233
 234  All arguments are swapped into strings, so be sure that your
 235  sprintf usage matches with proper %s placement.
 236
 237  Argument descriptions:
 238     s1-s4: string arguments to be literally swapped into sprintf
 239     s2loc: s2 string of locations of deaths or other events
 240     s3loc: s3 string of locations of deaths or other events
 241     f1-f4: float arguments expanded into strings to be swapped into sprintf
 242     f1p2dec: f1 float to string with 2 decimal places
 243     f2p2dec: f2 float to string with 2 decimal places
 244     f2primsec: f2 float primary or secondary selection for weapons
 245     f3primsec: f3 float primary or secondary selection for weapons
 246     f1secs: count_seconds of f1
 247     f1points: point or points depending on f1
 248     f1ord: count_ordinal of f1
 249     f1time: process_time of f1
 250     f1race_time: mmssss of f1
 251     f2race_time: mmssss of f2
 252     race_col: color of race time/position (i.e. good or bad)
 253     race_diff: show time difference between f2 and f3
 254     missing_teams: show which teams still need players
 255     pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 256     frag_ping: show the ping of a player
 257     frag_stats: show health/armor/ping of a player
 258     frag_pos: show score status and position in the match of a player
 259     spree_cen: centerprint notif for kill spree/how many kills they have
 260     spree_inf: info notif for kill spree/how many kills they have
 261     spree_end: placed at the end of murder messages to show ending of sprees
 262     spree_lost: placed at the end of suicide messages to show losing of sprees
 263     item_wepname: return full name of a weapon from weaponid
 264     item_wepammo: ammo display for weapon from string
 265     item_centime: amount of time to display weapon message in centerprint
 266     item_buffname: return full name of a buff from buffid
 267     death_team: show the full name of the team a player is switching from
 268     minigame1_name: return human readable name of a minigame from its id(s1)
 269     minigame1_d: return descriptor name of a minigame from its id(s1)
 270 */
 271
 272 const float NOTIF_MAX_ARGS = 7;
 273 const float NOTIF_MAX_HUDARGS = 2;
 274 const float NOTIF_MAX_DURCNT = 2;
 275
 276 string arg_slot[NOTIF_MAX_ARGS];
 277
 278 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 279 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 280 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 281 const float ARG_CS = 4; // unique result to CSQC
 282 const float ARG_SV = 5; // unique result to SVQC
 283 const float ARG_DC = 6; // unique result to durcnt/centerprint
 284
 285 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 286 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 287
 288 string BUFF_NAME(int i);
 289
 290 #define NOTIF_ARGUMENT_LIST \
 291     ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 292     ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 293     ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 294     ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 295     ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 296     ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 297     ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 298     ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 299     ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 300     ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 301     ARG_CASE(ARG_CS_SV,     "f1p2dec",       ftos_decimals(f1/100, 2)) \
 302     ARG_CASE(ARG_CS_SV,     "f2p2dec",       ftos_decimals(f2/100, 2)) \
 303     ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 304     ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 305     ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 306     ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 307     ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 308     ARG_CASE(ARG_CS,        "f1time",        process_time(2, f1)) \
 309     ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssss(f1)) \
 310     ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssss(f2)) \
 311     ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssss(f3)) \
 312     ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 313     ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssss(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssss(f3 - f2)))) \
 314     ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 315     ARG_CASE(ARG_CS,        "pass_key",      ((((tmp_s = getcommandkey("pass", "+use")) != "pass") && !(strstrofs(tmp_s, "not bound", 0) >= 0)) ? sprintf(CCR(_(" ^F1(Press %s)")), tmp_s) : "")) \
 316     ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 317     ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 318     /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 319     ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 320     ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 321     ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 322     ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 323     ARG_CASE(ARG_CS_SV,     "item_wepname",  Weapons_from(f1).m_name) \
 324     ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 325     ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 326     ARG_CASE(ARG_CS_SV,     "item_wepammo",  (s1 != "" ? sprintf(_(" with %s"), s1) : "")) \
 327     ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 328     ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 329     ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 330     ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(world,netname,s1).descriptor.message) \
 331     ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(world,netname,s1).descriptor.netname)
 332
 333 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN { \
 334     if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 335 } MACRO_END
 336 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 337
 338 #define KILL_SPREE_LIST \
 339     SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 340     SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 341     SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 342     SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 343     SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 344     SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 345     SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 346
 347 #ifdef CSQC
 348 string notif_arg_frag_ping(float newline, float fping)
 349 {
 350     if(fping == NO_MSG)
 351         return sprintf(CCR(_("%s(^F1Bot^BG)")), (newline ? "\n" : " "));
 352     else
 353         return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), (newline ? "\n" : " "), fping);
 354 }
 355
 356 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 357 {
 358     if (!(fhealth < 1))
 359         return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, notif_arg_frag_ping(false, fping));
 360     else
 361         return sprintf(CCR(_("\n(^F4Dead^BG)%s")), notif_arg_frag_ping(false, fping));
 362 }
 363
 364 string notif_arg_missing_teams(float f1)
 365 {
 366     return sprintf("%s%s%s%s",
 367         ((f1 & 1) ?
 368             sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_1), ((f1 & (2 + 4 + 8)) ? ", " : ""))
 369             :
 370             ""
 371         ),
 372         ((f1 & 2) ?
 373             sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_2), ((f1 & (4 + 8)) ? ", " : ""))
 374             :
 375             ""
 376         ),
 377         ((f1 & 4) ?
 378             sprintf("%s%s", Team_ColoredFullName(NUM_TEAM_3), ((f1 & 8) ? ", " : ""))
 379             :
 380             ""
 381         ),
 382         ((f1 & 8) ?
 383             Team_ColoredFullName(NUM_TEAM_4)
 384             :
 385             ""
 386         )
 387     );
 388 }
 389
 390 string notif_arg_spree_cen(float spree)
 391 {
 392     // 0 = off, 1 = target (but only for first victim) and attacker
 393     if(autocvar_notification_show_sprees_center)
 394     {
 395         if(spree > 1)
 396         {
 397             #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 398                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 399
 400             switch(spree)
 401             {
 402                 KILL_SPREE_LIST
 403                 default:
 404                 {
 405                     if (!autocvar_notification_show_sprees_center_specialonly)
 406                     {
 407                         return
 408                             sprintf(
 409                                 normal_or_gentle(
 410                                     _("%d frag spree! "),
 411                                     _("%d score spree! ")
 412                                 ),
 413                                 spree);
 414                     }
 415                     else { return ""; } // don't show spree information if it isn't an achievement
 416                 }
 417             }
 418
 419             #undef SPREE_ITEM
 420         }
 421         else if(spree == -1) // first blood
 422         {
 423             return normal_or_gentle(_("First blood! "), _("First score! "));
 424         }
 425         else if(spree == -2) // first victim
 426         {
 427             return normal_or_gentle(_("First victim! "), _("First casualty! "));
 428         }
 429     }
 430     return "";
 431 }
 432 #endif
 433
 434 string notif_arg_spree_inf(float type, string input, string player, float spree)
 435 {
 436     switch(type)
 437     {
 438         case 1: // attacker kill spree
 439         {
 440             // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 441             // this conditional (& 2) is true for 2 and 3
 442             if(autocvar_notification_show_sprees_info & 2)
 443             {
 444                 #ifdef CSQC
 445                 string spree_newline =
 446                     ( autocvar_notification_show_sprees_info_newline ?
 447                         ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 448                 #else
 449                 string spree_newline =
 450                     (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 451                 #endif
 452
 453                 if(spree > 1)
 454                 {
 455                     #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 456                         case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 457
 458                     switch(spree)
 459                     {
 460                         KILL_SPREE_LIST
 461                         default:
 462                         {
 463                             if (!autocvar_notification_show_sprees_info_specialonly)
 464                             {
 465                                 return
 466                                     sprintf(
 467                                         CCR(normal_or_gentle(
 468                                             _("%s^K1 has %d frags in a row! %s^BG"),
 469                                             _("%s^K1 made %d scores in a row! %s^BG")
 470                                         )),
 471                                         player,
 472                                         spree,
 473                                         spree_newline
 474                                     );
 475                             }
 476                             else { return ""; } // don't show spree information if it isn't an achievement
 477                         }
 478                     }
 479
 480                     #undef SPREE_ITEM
 481                 }
 482                 else if(spree == -1) // firstblood
 483                 {
 484                     return
 485                         sprintf(
 486                             CCR(normal_or_gentle(
 487                                 _("%s^K1 drew first blood! %s^BG"),
 488                                 _("%s^K1 got the first score! %s^BG")
 489                             )),
 490                             player,
 491                             spree_newline
 492                         );
 493                 }
 494             }
 495             break;
 496         }
 497
 498         case -1: // kill spree ended
 499         {
 500             if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 501             {
 502                 return
 503                     sprintf(normal_or_gentle(
 504                         _(", ending their %d frag spree"),
 505                         _(", ending their %d score spree")
 506                         ),
 507                         spree
 508                     );
 509             }
 510             break;
 511         }
 512
 513         case -2: // kill spree lost
 514         {
 515             if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 516             {
 517                 return
 518                     sprintf(normal_or_gentle(
 519                         _(", losing their %d frag spree"),
 520                         _(", losing their %d score spree")
 521                         ),
 522                         spree
 523                     );
 524             }
 525             break;
 526         }
 527     }
 528     return "";
 529 }
 530
 531
 532 // ====================================
 533 //  Initialization/Create Declarations
 534 // ====================================
 535
 536 enum {
 537     NO_CPID
 538 ,   CPID_ASSAULT_ROLE
 539 ,   CPID_ROUND
 540 ,   CPID_CAMPCHECK
 541 ,   CPID_CTF_CAPSHIELD
 542 ,   CPID_CTF_LOWPRIO
 543 ,   CPID_CTF_PASS
 544 ,   CPID_STALEMATE
 545 ,   CPID_NADES
 546 ,   CPID_IDLING
 547 ,   CPID_ITEM
 548 ,   CPID_PREVENT_JOIN
 549 ,   CPID_KEEPAWAY
 550 ,   CPID_KEEPAWAY_WARN
 551 ,   CPID_KEYHUNT
 552 ,   CPID_KEYHUNT_OTHER
 553 ,   CPID_LMS
 554 ,   CPID_MISSING_TEAMS
 555 ,   CPID_MISSING_PLAYERS
 556 ,   CPID_INSTAGIB_FINDAMMO
 557 ,   CPID_MOTD
 558 ,   CPID_NIX
 559 ,   CPID_ONSLAUGHT
 560 ,   CPID_ONS_CAPSHIELD
 561 ,   CPID_OVERTIME
 562 ,   CPID_POWERUP
 563 ,   CPID_RACE_FINISHLAP
 564 ,   CPID_TEAMCHANGE
 565 ,   CPID_TIMEOUT
 566 ,   CPID_VEHICLES
 567 ,   CPID_VEHICLES_OTHER
 568 // always last
 569 ,   NOTIF_CPID_COUNT
 570 };
 571 // notification counts
 572 const float NOTIF_FIRST = 1;
 573 float NOTIF_ANNCE_COUNT;
 574 float NOTIF_INFO_COUNT;
 575 float NOTIF_CENTER_COUNT;
 576 float NOTIF_MULTI_COUNT;
 577 float NOTIF_CHOICE_COUNT;
 578
 579 // notification limits -- INCREASE AS NECESSARY
 580 const float NOTIF_ANNCE_MAX   = 400;
 581 const float NOTIF_INFO_MAX    = 450;
 582 const float NOTIF_CENTER_MAX  = 350;
 583 const float NOTIF_MULTI_MAX   = 300;
 584 const float NOTIF_CHOICE_MAX  = 50;
 585
 586 // notification entities
 587 entity msg_annce_notifs[NOTIF_ANNCE_MAX];
 588 entity msg_info_notifs[NOTIF_INFO_MAX];
 589 entity msg_center_notifs[NOTIF_CENTER_MAX];
 590 entity msg_multi_notifs[NOTIF_MULTI_MAX];
 591 entity msg_choice_notifs[NOTIF_CHOICE_MAX];
 592
 593 // common notification entity values
 594 .float nent_default;
 595 .float nent_enabled;
 596 .float nent_type;
 597 .float nent_id;
 598 .string nent_name;
 599 .int nent_stringcount;
 600 .int nent_floatcount;
 601
 602 // MSG_ANNCE entity values
 603 .float nent_channel;
 604 .string nent_snd;
 605 .float nent_vol;
 606 .float nent_position;
 607
 608 // MSG_INFO and MSG_CENTER entity values
 609 .string nent_args; // used by both
 610 .string nent_hudargs; // used by info
 611 .string nent_icon; // used by info
 612 .float nent_cpid; // used by center
 613 .string nent_durcnt; // used by center
 614 .string nent_string; // used by both
 615
 616 // MSG_MULTI entity values
 617 .entity nent_msgannce;
 618 .entity nent_msginfo;
 619 .entity nent_msgcenter;
 620
 621 // MSG_CHOICE entity values
 622 .float nent_challow_def;
 623 .float nent_challow_var;
 624 .entity nent_optiona;
 625 .entity nent_optionb;
 626
 627 // networked notification entity values
 628 .float nent_broadcast;
 629 .entity nent_client;
 630 .float nent_net_type;
 631 .float nent_net_name;
 632 .string nent_strings[4];
 633 .float nent_floats[4];
 634
 635 // other notification properties
 636 .float msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 637
 638 // initialization error detection
 639 float notif_error;
 640 float notif_global_error;
 641
 642 #define MSG_ANNCE_NOTIF(default,name,channel,sound,volume,position) \
 643     NOTIF_ADD_AUTOCVAR(name, default) \
 644     float name; \
 645     void RegisterNotification_##name() \
 646     { \
 647         SET_FIELD_COUNT(name, NOTIF_FIRST, NOTIF_ANNCE_COUNT) \
 648         CHECK_MAX_COUNT(name, NOTIF_ANNCE_MAX, NOTIF_ANNCE_COUNT, "MSG_ANNCE") \
 649         Create_Notification_Entity( \
 650             /* COMMON ======================== */ \
 651             default,            /* var_default */ \
 652             ACVNN(name),        /* var_cvar    */ \
 653             MSG_ANNCE,          /* typeId      */ \
 654             name,               /* nameid      */ \
 655             strtoupper(#name),  /* namestring  */ \
 656             NO_MSG,             /* strnum      */ \
 657             NO_MSG,             /* flnum       */ \
 658             /* ANNCE ============= */ \
 659             channel,   /* channel  */ \
 660             sound,     /* snd      */ \
 661             volume,    /* vol      */ \
 662             position,  /* position */ \
 663             /* INFO & CENTER == */ \
 664             "",      /* args    */ \
 665             "",      /* hudargs */ \
 666             "",      /* icon    */ \
 667             NO_MSG,  /* cpid    */ \
 668             "",      /* durcnt  */ \
 669             "",      /* normal  */ \
 670             "",      /* gentle  */ \
 671             /* MULTI ============= */ \
 672             NO_MSG,  /* anncename  */ \
 673             NO_MSG,  /* infoname   */ \
 674             NO_MSG,  /* centername */ \
 675             /* MSG_CHOICE ========== */ \
 676             NO_MSG,   /* challow_def */ \
 677             NO_MSG,   /* challow_var */ \
 678             NO_MSG,   /* chtype      */ \
 679             NO_MSG,   /* optiona     */ \
 680             NO_MSG);  /* optionb     */ \
 681     } \
 682     ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 683
 684 #define MSG_INFO_NOTIF(default,name,strnum,flnum,args,hudargs,icon,normal,gentle) \
 685     NOTIF_ADD_AUTOCVAR(name, default) \
 686     int name; \
 687     void RegisterNotification_##name() \
 688     { \
 689         SET_FIELD_COUNT(name, NOTIF_FIRST, NOTIF_INFO_COUNT) \
 690         CHECK_MAX_COUNT(name, NOTIF_INFO_MAX, NOTIF_INFO_COUNT, "MSG_INFO") \
 691         Create_Notification_Entity( \
 692             /* COMMON ======================== */ \
 693             default,            /* var_default */ \
 694             ACVNN(name),        /* var_cvar    */ \
 695             MSG_INFO,           /* typeId      */ \
 696             name,               /* nameid      */ \
 697             strtoupper(#name),  /* namestring  */ \
 698             strnum,             /* strnum      */ \
 699             flnum,              /* flnum       */ \
 700             /* ANNCE =========== */ \
 701             NO_MSG,  /* channel  */ \
 702             "",      /* snd      */ \
 703             NO_MSG,  /* vol      */ \
 704             NO_MSG,  /* position */ \
 705             /* INFO & CENTER === */ \
 706             args,     /* args    */ \
 707             hudargs,  /* hudargs */ \
 708             icon,     /* icon    */ \
 709             NO_MSG,   /* cpid    */ \
 710             "",       /* durcnt  */ \
 711             normal,   /* normal  */ \
 712             gentle,   /* gentle  */ \
 713             /* MULTI ============= */ \
 714             NO_MSG,  /* anncename  */ \
 715             NO_MSG,  /* infoname   */ \
 716             NO_MSG,  /* centername */ \
 717             /* CHOICE ============== */ \
 718             NO_MSG,   /* challow_def */ \
 719             NO_MSG,   /* challow_var */ \
 720             NO_MSG,   /* chtype      */ \
 721             NO_MSG,   /* optiona     */ \
 722             NO_MSG);  /* optionb     */ \
 723     } \
 724     ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 725
 726 .string nent_iconargs;
 727 #define MULTIICON_INFO(default,name,strnum,flnum,args,hudargs,iconargs,icon,normal,gentle) \
 728     NOTIF_ADD_AUTOCVAR(name, default) \
 729     int name; \
 730     void RegisterNotification_##name() \
 731     { \
 732         SET_FIELD_COUNT(name, NOTIF_FIRST, NOTIF_INFO_COUNT) \
 733         CHECK_MAX_COUNT(name, NOTIF_INFO_MAX, NOTIF_INFO_COUNT, "MSG_INFO") \
 734         Create_Notification_Entity( \
 735             /* COMMON ======================== */ \
 736             default,            /* var_default */ \
 737             ACVNN(name),        /* var_cvar    */ \
 738             MSG_INFO,           /* typeid      */ \
 739             name,               /* nameid      */ \
 740             strtoupper(#name),  /* namestring  */ \
 741             strnum,             /* strnum      */ \
 742             flnum,              /* flnum       */ \
 743             /* ANNCE =========== */ \
 744             NO_MSG,  /* channel  */ \
 745             "",      /* snd      */ \
 746             NO_MSG,  /* vol      */ \
 747             NO_MSG,  /* position */ \
 748             /* INFO & CENTER === */ \
 749             args,     /* args    */ \
 750             hudargs,  /* hudargs */ \
 751             icon,     /* icon    */ \
 752             NO_MSG,   /* cpid    */ \
 753             "",       /* durcnt  */ \
 754             normal,   /* normal  */ \
 755             gentle,   /* gentle  */ \
 756             /* MULTI ============= */ \
 757             NO_MSG,  /* anncename  */ \
 758             NO_MSG,  /* infoname   */ \
 759             NO_MSG,  /* centername */ \
 760             /* CHOICE ============== */ \
 761             NO_MSG,   /* challow_def */ \
 762             NO_MSG,   /* challow_var */ \
 763             NO_MSG,   /* chtype      */ \
 764             NO_MSG,   /* optiona     */ \
 765             NO_MSG);  /* optionb     */ \
 766         msg_info_notifs[name - 1].nent_iconargs = iconargs; \
 767     } \
 768     ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 769
 770 #define MSG_CENTER_NOTIF(default,name,strnum,flnum,args,cpid,durcnt,normal,gentle) \
 771     NOTIF_ADD_AUTOCVAR(name, default) \
 772     float name; \
 773     void RegisterNotification_##name() \
 774     { \
 775         SET_FIELD_COUNT(name, NOTIF_FIRST, NOTIF_CENTER_COUNT) \
 776         CHECK_MAX_COUNT(name, NOTIF_CENTER_MAX, NOTIF_CENTER_COUNT, "MSG_CENTER") \
 777         Create_Notification_Entity( \
 778             /* COMMON ======================== */ \
 779             default,            /* var_default */ \
 780             ACVNN(name),        /* var_cvar    */ \
 781             MSG_CENTER,         /* typeId      */ \
 782             name,               /* nameid      */ \
 783             strtoupper(#name),  /* namestring  */ \
 784             strnum,             /* strnum      */ \
 785             flnum,              /* flnum       */ \
 786             /* ANNCE =========== */ \
 787             NO_MSG,  /* channel  */ \
 788             "",      /* snd      */ \
 789             NO_MSG,  /* vol      */ \
 790             NO_MSG,  /* position */ \
 791             /* INFO & CENTER == */ \
 792             args,    /* args    */ \
 793             "",      /* hudargs */ \
 794             "",      /* icon    */ \
 795             cpid,    /* cpid    */ \
 796             durcnt,  /* durcnt  */ \
 797             normal,  /* normal  */ \
 798             gentle,  /* gentle  */ \
 799             /* MULTI ============= */ \
 800             NO_MSG,  /* anncename  */ \
 801             NO_MSG,  /* infoname   */ \
 802             NO_MSG,  /* centername */ \
 803             /* CHOICE ============== */ \
 804             NO_MSG,   /* challow_def */ \
 805             NO_MSG,   /* challow_var */ \
 806             NO_MSG,   /* chtype      */ \
 807             NO_MSG,   /* optiona     */ \
 808             NO_MSG);  /* optionb     */ \
 809     } \
 810     ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 811
 812 #define MSG_MULTI_NOTIF(default,name,anncename,infoname,centername) \
 813     NOTIF_ADD_AUTOCVAR(name, default) \
 814     int name; \
 815     void RegisterNotification_##name() \
 816     { \
 817         SET_FIELD_COUNT(name, NOTIF_FIRST, NOTIF_MULTI_COUNT) \
 818         CHECK_MAX_COUNT(name, NOTIF_MULTI_MAX, NOTIF_MULTI_COUNT, "MSG_MULTI") \
 819         Create_Notification_Entity( \
 820             /* COMMON ======================== */ \
 821             default,            /* var_default */ \
 822             ACVNN(name),        /* var_cvar    */ \
 823             MSG_MULTI,          /* typeId      */ \
 824             name,               /* nameid      */ \
 825             strtoupper(#name),  /* namestring  */ \
 826             NO_MSG,             /* strnum      */ \
 827             NO_MSG,             /* flnum       */ \
 828             /* ANNCE =========== */ \
 829             NO_MSG,  /* channel  */ \
 830             "",      /* snd      */ \
 831             NO_MSG,  /* vol      */ \
 832             NO_MSG,  /* position */ \
 833             /* INFO & CENTER == */ \
 834             "",      /* args    */ \
 835             "",      /* hudargs */ \
 836             "",      /* icon    */ \
 837             NO_MSG,  /* cpid    */ \
 838             "",      /* durcnt  */ \
 839             "",      /* normal  */ \
 840             "",      /* gentle  */ \
 841             /* MULTI ================= */ \
 842             anncename,   /* anncename  */ \
 843             infoname,    /* infoname   */ \
 844             centername,  /* centername */ \
 845             /* CHOICE ============== */ \
 846             NO_MSG,   /* challow_def */ \
 847             NO_MSG,   /* challow_var */ \
 848             NO_MSG,   /* chtype      */ \
 849             NO_MSG,   /* optiona     */ \
 850             NO_MSG);  /* optionb     */ \
 851     } \
 852     ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 853
 854 #define ACVNN(name) autocvar_notification_##name
 855
 856 #define MSG_CHOICE_NOTIF(default,challow,name,chtype,optiona,optionb) \
 857     NOTIF_ADD_AUTOCVAR(name, default) \
 858     NOTIF_ADD_AUTOCVAR(name##_ALLOWED, challow) \
 859     float name; \
 860     void RegisterNotification_##name() \
 861     { \
 862         SET_FIELD_COUNT(name, NOTIF_FIRST, NOTIF_CHOICE_COUNT) \
 863         CHECK_MAX_COUNT(name, NOTIF_CHOICE_MAX, NOTIF_CHOICE_COUNT, "MSG_CHOICE") \
 864         Create_Notification_Entity( \
 865             /* COMMON ======================== */ \
 866             default,            /* var_default */ \
 867             ACVNN(name),        /* var_cvar    */ \
 868             MSG_CHOICE,         /* typeId      */ \
 869             name,               /* nameid      */ \
 870             strtoupper(#name),  /* namestring  */ \
 871             NO_MSG,             /* strnum      */ \
 872             NO_MSG,             /* flnum       */ \
 873             /* ANNCE =========== */ \
 874             NO_MSG,  /* channel  */ \
 875             "",      /* snd      */ \
 876             NO_MSG,  /* vol      */ \
 877             NO_MSG,  /* position */ \
 878             /* INFO & CENTER == */ \
 879             "",      /* args    */ \
 880             "",      /* hudargs */ \
 881             "",      /* icon    */ \
 882             NO_MSG,  /* cpid    */ \
 883             "",      /* durcnt  */ \
 884             "",      /* normal  */ \
 885             "",      /* gentle  */ \
 886             /* MULTI ============= */ \
 887             NO_MSG,  /* anncename  */ \
 888             NO_MSG,  /* infoname   */ \
 889             NO_MSG,  /* centername */ \
 890             /* CHOICE ============================================= */ \
 891             challow,                                 /* challow_def */ \
 892             autocvar_notification_##name##_ALLOWED,  /* challow_var */ \
 893             chtype,                                  /* chtype      */ \
 894             optiona,                                 /* optiona     */ \
 895             optionb);                                /* optionb     */ \
 896     } \
 897     ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotification_##name)
 898
 899 void RegisterNotifications_First()
 900 {
 901     notif_global_error = false;
 902 }
 903
 904 void RegisterNotifications_Done()
 905 {
 906     if(notif_global_error)
 907     {
 908         // shit happened... stop the loading of the program now if this is unacceptable
 909         if(autocvar_notification_errors_are_fatal)
 910             LOG_FATAL("Notification initialization failed! Read above and fix the errors!\n");
 911         else
 912             LOG_SEVERE("Notification initialization failed! Read above and fix the errors!\n");
 913     }
 914 }
 915
 916 // NOW we actually activate the declarations
 917 ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotifications_First)
 918 #include "notifications.inc"
 919 ACCUMULATE_FUNCTION(RegisterNotifications, RegisterNotifications_Done)
 920
 921 STATIC_INIT(RegisterNotifications) { CALL_ACCUMULATED_FUNCTION(RegisterNotifications); }
 922
 923 #endif