qcsrc/common/notifications/all.qc

   1 #include "all.qh"
   2 #if defined(CSQC)
   3         #include <client/announcer.qh>
   4 #elif defined(MENUQC)
   5 #elif defined(SVQC)
   6         #include <common/constants.qh>
   7         #include <common/net_linked.qh>
   8         #include <common/teams.qh>
   9         #include <server/autocvars.qh>
  10         #include <server/constants.qh>
  11         #include <server/defs.qh>
  12         #include <server/mutators/_mod.qh>
  13 #endif
  14
  15 // ================================================
  16 //  Unified notification system, written by Samual
  17 //  Last updated: August, 2013
  18 // ================================================
  19
  20 #ifdef SVQC
  21 string Notification_CheckArgs(
  22         NOTIF broadcast, entity client)
  23 {
  24         // check supplied broadcast and target for errors
  25         switch (broadcast)
  26         {
  27                 case NOTIF_ONE:
  28                 case NOTIF_ONE_ONLY:
  29                 {
  30                         if (IS_NOT_A_CLIENT(client)) {
  31                                 return "No client provided!";
  32                         }
  33                         break;
  34                 }
  35
  36                 case NOTIF_ALL_EXCEPT:
  37                 {
  38                         if (IS_NOT_A_CLIENT(client)) {
  39                                 return "Exception can't be a non-client!";
  40                         }
  41                         break;
  42                 }
  43
  44                 case NOTIF_ALL:
  45                 {
  46                         if (client) {
  47                                 return "Entity provided when NULL was required!";
  48                         }
  49                         break;
  50                 }
  51
  52                 case NOTIF_TEAM:
  53                 {
  54                         if (!teamplay) {
  55                                 return "Teamplay not active!";
  56                         } else if (!client.team) {
  57                                 // checkargs = sprintf("%sNo team provided!", checkargs);
  58                         }
  59                         break;
  60                 }
  61
  62                 case NOTIF_TEAM_EXCEPT:
  63                 {
  64                         if (!teamplay) {
  65                                 return "Teamplay not active!";
  66                         } else if (IS_NOT_A_CLIENT(client)) {
  67                                 return "Exception can't be a non-client!";
  68                         }
  69                         break;
  70                 }
  71
  72                 default:
  73                 {
  74                         return sprintf("Improper broadcast: %d!", broadcast);
  75                 }
  76         }
  77         return "";
  78 }
  79
  80 bool Notification_ShouldSend(NOTIF broadcast, entity to_client, entity other_client)
  81 {
  82         switch (broadcast)
  83         {
  84                 case NOTIF_ONE:
  85                         return (
  86                                 (to_client == other_client)
  87                                 ||
  88                                 (IS_SPEC(to_client) && (to_client.enemy == other_client))
  89                         );
  90                 case NOTIF_ONE_ONLY:
  91                         return (to_client == other_client);
  92                 case NOTIF_TEAM:
  93                         return (
  94                                 (to_client.team == other_client.team)
  95                                 ||
  96                                 (
  97                                         IS_SPEC(to_client)
  98                                         &&
  99                                         (to_client.enemy.team == other_client.team)
 100                                 )
 101                         );
 102                 case NOTIF_TEAM_EXCEPT:
 103                         return (
 104                                 (to_client != other_client)
 105                                 &&
 106                                 (
 107                                         (to_client.team == other_client.team)
 108                                         ||
 109                                         (
 110                                                 IS_SPEC(to_client)
 111                                                 &&
 112                                                 (
 113                                                         (to_client.enemy != other_client)
 114                                                         &&
 115                                                         (to_client.enemy.team == other_client.team)
 116                                                 )
 117                                         )
 118                                 )
 119                         );
 120                 case NOTIF_ALL:
 121                         return true;
 122                 case NOTIF_ALL_EXCEPT:
 123                         return (
 124                                 (to_client != other_client)
 125                                 &&
 126                                 !(
 127                                         IS_SPEC(to_client)
 128                                         &&
 129                                         (to_client.enemy == other_client)
 130                                 )
 131                         );
 132                 default:
 133                         return false;
 134         }
 135 }
 136
 137 #endif
 138
 139 // ===============================
 140 //  Initialization Core Functions
 141 // ===============================
 142
 143 // used by restartnotifs command to initialize notifications
 144 void Destroy_Notification_Entity(entity notif)
 145 {
 146         if (notif.nent_name != "") strunzone(notif.nent_name);
 147         if (notif.nent_snd != "") strunzone(notif.nent_snd);
 148         if (notif.nent_args != "") strunzone(notif.nent_args);
 149         if (notif.nent_hudargs != "") strunzone(notif.nent_hudargs);
 150         if (notif.nent_icon != "") strunzone(notif.nent_icon);
 151         if (notif.nent_durcnt != "") strunzone(notif.nent_durcnt);
 152         if (notif.nent_string != "") strunzone(notif.nent_string);
 153         delete(notif);
 154 }
 155
 156 void Destroy_All_Notifications()
 157 {
 158         // kill all networked notifications and centerprints
 159         #ifdef SVQC
 160         Kill_Notification(NOTIF_ALL, NULL, MSG_Null, CPID_Null);
 161         #else
 162         centerprint_KillAll();
 163         #endif
 164
 165         // kill all real notification entities
 166         FOREACH(Notifications, true, { Destroy_Notification_Entity(it); });
 167 }
 168
 169 string Process_Notif_Line(
 170         MSG typeId,
 171         bool chat,
 172         string input,
 173         string notiftype,
 174         string notifname,
 175         string stringtype)
 176 {
 177         #ifdef CSQC
 178         if(typeId == MSG_INFO)
 179         {
 180                 if((chat && autocvar_notification_allow_chatboxprint)
 181                         || (autocvar_notification_allow_chatboxprint == 2))
 182                 {
 183                         // pass 1: add ETX char at beginning of line
 184                         input = strcat("\{3}", input);
 185
 186                         // pass 2: add ETX char at end of each new line (so that
 187                         // messages with multiple lines are put through chatbox too)
 188                         input = strreplace("\n", "\n\{3}", input);
 189
 190                         // pass 3: strip trailing ETX char
 191                         if(substring(input, (strlen(input) - 1), 1) == "\{3}")
 192                                 { input = substring(input, 0, (strlen(input) - 1)); }
 193                 }
 194         }
 195         #endif
 196
 197         // done to both MSG_INFO and MSG_CENTER
 198         if(substring(input, (strlen(input) - 1), 1) == "\n")
 199         {
 200                 LOG_INFOF(
 201                         (
 202                                 "^1TRAILING NEW LINE AT END OF NOTIFICATION: "
 203                                 "^7net_type = %s, net_name = %s, string = %s."
 204                         ),
 205                         notiftype,
 206                         notifname,
 207                         stringtype
 208                 );
 209                 notif_error = true;
 210                 input = substring(input, 1, (strlen(input) - 1));
 211         }
 212
 213         return input;
 214 }
 215
 216 string Process_Notif_Args(
 217         float arg_type,
 218         string args,
 219         string notiftype,
 220         string notifname)
 221 {
 222         string selected, remaining = args;
 223         float sel_num = 0;
 224
 225         for (;(remaining != "");)
 226         {
 227                 selected = car(remaining); remaining = cdr(remaining);
 228
 229                 switch(arg_type)
 230                 {
 231                         case 1: // normal args
 232                         {
 233                                 if(sel_num == NOTIF_MAX_ARGS)
 234                                 {
 235                                         LOG_INFOF(
 236                                                 (
 237                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: "
 238                                                         "^7net_type = %s, net_name = %s, max args = %d."
 239                                                 ),
 240                                                 notiftype,
 241                                                 notifname,
 242                                                 NOTIF_MAX_ARGS
 243                                         );
 244                                         notif_error = true;
 245                                         break;
 246                                 }
 247
 248                                 switch(strtolower(selected))
 249                                 {
 250                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: ++sel_num; break;
 251                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: ++sel_num; break;
 252                                         #define ARG_CASE_ARG_CS_SV(selected,result)    case selected: ++sel_num; break;
 253                                         #define ARG_CASE_ARG_CS(selected,result)       case selected: ++sel_num; break;
 254                                         #define ARG_CASE_ARG_SV(selected,result)       case selected: ++sel_num; break;
 255                                         #define ARG_CASE_ARG_DC(selected,result)
 256                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 257                                         NOTIF_ARGUMENT_LIST
 258                                         #undef ARG_CASE
 259                                         #undef ARG_CASE_ARG_DC
 260                                         #undef ARG_CASE_ARG_SV
 261                                         #undef ARG_CASE_ARG_CS
 262                                         #undef ARG_CASE_ARG_CS_SV
 263                                         #undef ARG_CASE_ARG_CS_SV_DC
 264                                         #undef ARG_CASE_ARG_CS_SV_HA
 265                                         default:
 266                                         {
 267                                                 LOG_INFOF(
 268                                                         (
 269                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: "
 270                                                                 "^7net_type = %s, net_name = %s, args arg = '%s'."
 271                                                         ),
 272                                                         notiftype,
 273                                                         notifname,
 274                                                         selected
 275                                                 );
 276                                                 notif_error = true;
 277                                                 break;
 278                                         }
 279                                 }
 280                                 break;
 281                         }
 282                         case 2: // hudargs
 283                         {
 284                                 if(sel_num == NOTIF_MAX_HUDARGS)
 285                                 {
 286                                         LOG_INFOF(
 287                                                 (
 288                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: "
 289                                                         "^7net_type = %s, net_name = %s, max hudargs = %d."
 290                                                 ),
 291                                                 notiftype,
 292                                                 notifname,
 293                                                 NOTIF_MAX_HUDARGS
 294                                         );
 295                                         notif_error = true;
 296                                         break;
 297                                 }
 298
 299                                 switch(strtolower(selected))
 300                                 {
 301                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result) case selected: ++sel_num; break;
 302                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result)
 303                                         #define ARG_CASE_ARG_CS_SV(selected,result)
 304                                         #define ARG_CASE_ARG_CS(selected,result)
 305                                         #define ARG_CASE_ARG_SV(selected,result)
 306                                         #define ARG_CASE_ARG_DC(selected,result)
 307                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 308                                         NOTIF_ARGUMENT_LIST
 309                                         #undef ARG_CASE
 310                                         #undef ARG_CASE_ARG_DC
 311                                         #undef ARG_CASE_ARG_SV
 312                                         #undef ARG_CASE_ARG_CS
 313                                         #undef ARG_CASE_ARG_CS_SV
 314                                         #undef ARG_CASE_ARG_CS_SV_DC
 315                                         #undef ARG_CASE_ARG_CS_SV_HA
 316                                         default:
 317                                         {
 318                                                 LOG_INFOF(
 319                                                         (
 320                                                                 "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: "
 321                                                                 "^7net_type = %s, net_name = %s, hudargs arg = '%s'."
 322                                                         ),
 323                                                         notiftype,
 324                                                         notifname,
 325                                                         selected
 326                                                 );
 327                                                 notif_error = true;
 328                                                 break;
 329                                         }
 330                                 }
 331                                 break;
 332                         }
 333                         case 3: // durcnt
 334                         {
 335                                 if(sel_num == NOTIF_MAX_DURCNT)
 336                                 {
 337                                         LOG_INFOF(
 338                                                 (
 339                                                         "^1NOTIFICATION HAS TOO MANY ARGUMENTS: "
 340                                                         "^7net_type = %s, net_name = %s, max durcnt = %d."
 341                                                 ),
 342                                                 notiftype,
 343                                                 notifname,
 344                                                 NOTIF_MAX_DURCNT
 345                                         );
 346                                         notif_error = true;
 347                                         break;
 348                                 }
 349
 350                                 switch(strtolower(selected))
 351                                 {
 352                                         #define ARG_CASE_ARG_CS_SV_HA(selected,result)
 353                                         #define ARG_CASE_ARG_CS_SV_DC(selected,result) case selected: ++sel_num; break;
 354                                         #define ARG_CASE_ARG_CS_SV(selected,result)
 355                                         #define ARG_CASE_ARG_CS(selected,result)
 356                                         #define ARG_CASE_ARG_SV(selected,result)
 357                                         #define ARG_CASE_ARG_DC(selected,result)       case selected: ++sel_num; break;
 358                                         #define ARG_CASE(prog,selected,result)         ARG_CASE_##prog(selected,result)
 359                                         NOTIF_ARGUMENT_LIST
 360                                         #undef ARG_CASE
 361                                         #undef ARG_CASE_ARG_DC
 362                                         #undef ARG_CASE_ARG_SV
 363                                         #undef ARG_CASE_ARG_CS
 364                                         #undef ARG_CASE_ARG_CS_SV
 365                                         #undef ARG_CASE_ARG_CS_SV_DC
 366                                         #undef ARG_CASE_ARG_CS_SV_HA
 367                                         default:
 368                                         {
 369                                                 if(ftos(stof(selected)) != "") { ++sel_num; }
 370                                                 else
 371                                                 {
 372                                                         LOG_INFOF(
 373                                                                 (
 374                                                                         "^1NOTIFICATION WITH UNKNOWN TOKEN IN ARGUMENT STRING: "
 375                                                                         "^7net_type = %s, net_name = %s, durcnt arg = '%s'."
 376                                                                 ),
 377                                                                 notiftype,
 378                                                                 notifname,
 379                                                                 selected
 380                                                         );
 381                                                         notif_error = true;
 382                                                 }
 383                                                 break;
 384                                         }
 385                                 }
 386                                 break;
 387                         }
 388                 }
 389         }
 390         return args;
 391 }
 392
 393 void Create_Notification_Entity(entity notif,
 394         float var_default,
 395         float var_cvar,
 396         MSG typeId,
 397         string namestring,
 398         int teamnum)
 399 {
 400         // =====================
 401         //  Global Entity Setup
 402         // =====================
 403         notif.nent_default = var_default;
 404         notif.nent_enabled = (var_cvar >= 1);
 405         notif.nent_type = typeId;
 406         notif.nent_name = strzone(namestring);
 407         notif.nent_teamnum = teamnum;
 408
 409         // Other pre-notif-setup requisites
 410         notif_error = false;
 411
 412         switch (typeId)
 413         {
 414                 case MSG_ANNCE:
 415                 case MSG_INFO:
 416                 case MSG_CENTER:
 417                 case MSG_MULTI:
 418                 case MSG_CHOICE:
 419                         break;
 420                 default:
 421                         LOG_INFOF(
 422                                 (
 423                                         "^1NOTIFICATION WITH IMPROPER TYPE: "
 424                                         "^7net_type = %d, net_name = %s."
 425                                 ),
 426                                 typeId,
 427                                 namestring
 428                         );
 429                         notif_error = true;
 430                         break;
 431         }
 432
 433         // now check to see if any errors happened
 434         if (notif_error)
 435         {
 436                 notif.nent_enabled = false; // disable the notification so it can't cause trouble
 437                 notif_global_error = true; // throw the red flag that an error happened on init
 438         }
 439 }
 440
 441 #define AnnouncerFilename(snd) sprintf("announcer/%s/%s.wav", AnnouncerOption(), snd)
 442
 443 void Create_Notification_Entity_Annce(entity notif,
 444                                                                                 float var_cvar,
 445                                                                                 string namestring,
 446                                                                                 /* MSG_ANNCE */
 447                                                                                 float channel,
 448                                                                                 string snd,
 449                                                                                 float vol,
 450                                                                                 float position)
 451                 {
 452                         // Set MSG_ANNCE information and handle precaching
 453                         #ifdef CSQC
 454                         MSG typeId = MSG_ANNCE;
 455                         if (!(GENTLE && (var_cvar == 1)))
 456                         {
 457                                 if(snd != "")
 458                                 {
 459                                         if(notif.nent_enabled)
 460                                         {
 461                                                 precache_sound(AnnouncerFilename(snd));
 462                                                 notif.nent_channel = channel;
 463                                                 notif.nent_snd = strzone(snd);
 464                                                 notif.nent_vol = vol;
 465                                                 notif.nent_position = position;
 466                                         }
 467                                 }
 468                                 else
 469                                 {
 470                                         string typestring = Get_Notif_TypeName(typeId);
 471                                         LOG_INFOF(
 472                                                 (
 473                                                         "^1NOTIFICATION WITH NO SOUND: "
 474                                                         "^7net_type = %s, net_name = %s."
 475                                                 ),
 476                                                 typestring,
 477                                                 namestring
 478                                         );
 479                                         notif_error = true;
 480                                 }
 481                         }
 482                         else { notif.nent_enabled = false; }
 483                         #else
 484                         notif.nent_enabled = false;
 485                         #endif
 486
 487                 }
 488
 489 void Create_Notification_Entity_InfoCenter(entity notif,
 490                                                                                         float var_cvar,
 491                                                                                         string namestring,
 492                                                                                         int strnum,
 493                                                                                         int flnum,
 494                                                                                         /* MSG_INFO & MSG_CENTER */
 495                                                                                         string args,
 496                                                                                         string hudargs,
 497                                                                                         string icon,
 498                                                                                         CPID cpid,
 499                                                                                         string durcnt,
 500                                                                                         string normal,
 501                                                                                         string gentle)
 502                 {
 503                         MSG typeId = notif.nent_type;
 504                         // Set MSG_INFO and MSG_CENTER string/float counts
 505                         notif.nent_stringcount = strnum;
 506                         notif.nent_floatcount = flnum;
 507
 508                         // Only initialize arguments if we're either a client or on a dedicated server
 509                         #ifdef SVQC
 510                         float should_process_args = server_is_dedicated;
 511                         #else
 512                         float should_process_args = true;
 513                         #endif
 514                         string typestring = Get_Notif_TypeName(typeId);
 515                         if(should_process_args)
 516                         {
 517                                 // ========================
 518                                 //  Process Main Arguments
 519                                 // ========================
 520                                 if(strnum + flnum)
 521                                 {
 522                                         if(args != "")
 523                                         {
 524                                                 notif.nent_args = strzone(
 525                                                         Process_Notif_Args(1, args, typestring, namestring));
 526                                         }
 527                                         else if((hudargs == "") && (durcnt ==""))
 528                                         {
 529                                                 LOG_INFOF(
 530                                                         (
 531                                                                 "^1NOTIFICATION HAS ARG COUNTS BUT NO ARGS OR HUDARGS OR DURCNT: "
 532                                                                 "^7net_type = %s, net_name = %s, strnum = %d, flnum = %d"
 533                                                         ),
 534                                                         typestring,
 535                                                         namestring,
 536                                                         strnum,
 537                                                         flnum
 538                                                 );
 539                                                 notif_error = true;
 540                                         }
 541                                 }
 542                                 else if(args != "")
 543                                 {
 544                                         notif.nent_args = strzone(
 545                                                 Process_Notif_Args(1, args, typestring, namestring));
 546                                 }
 547
 548
 549                                 // =======================================
 550                                 //  Process HUD and Centerprint Arguments
 551                                 //    Only processed on CSQC, as these
 552                                 //    args are only for HUD features.
 553                                 // =======================================
 554                                 #ifdef CSQC
 555                                 if(hudargs != "")
 556                                 {
 557                                         notif.nent_hudargs = strzone(
 558                                                 Process_Notif_Args(2, hudargs, typestring, namestring));
 559
 560                                         if(icon != "") { notif.nent_icon = strzone(icon); }
 561                                         else
 562                                         {
 563                                                 LOG_INFOF(
 564                                                         (
 565                                                                 "^1NOTIFICATION HAS HUDARGS BUT NO ICON: "
 566                                                                 "^7net_type = %s, net_name = %s."
 567                                                         ),
 568                                                         typestring,
 569                                                         namestring
 570                                                 );
 571                                                 notif_error = true;
 572                                         }
 573                                 }
 574                                 else if(icon != "")
 575                                 {
 576                                         LOG_WARNF(
 577                                                 (
 578                                                         "^1NOTIFICATION HAS ICON BUT NO HUDARGS: "
 579                                                         "^7net_type = %s, net_name = %s.\n"
 580                                                 ),
 581                                                 typestring,
 582                                                 namestring
 583                                         );
 584                                         notif_error = true;
 585                                 }
 586
 587                                 if (durcnt != "")
 588                                 {
 589                                         notif.nent_durcnt = strzone(Process_Notif_Args(3, durcnt, typestring, namestring));
 590
 591                                         if (cpid == CPID_Null && durcnt != "0 0")
 592                                         {
 593                                                 LOG_WARNF(
 594                                                         (
 595                                                                 "Notification has durcnt but no cpid: "
 596                                                                 "net_type = %s, net_name = %s."
 597                                                         ),
 598                                                         typestring,
 599                                                         namestring
 600                                                 );
 601                                                 notif_error = true;
 602                                         }
 603                                 }
 604                                 notif.nent_cpid = cpid;
 605                                 #endif
 606
 607
 608                                 // ======================
 609                                 //  Process Notif String
 610                                 // ======================
 611                                 #define SET_NOTIF_STRING(string,stringname) MACRO_BEGIN \
 612                                         notif.nent_string = strzone(CCR( \
 613                                                 Process_Notif_Line( \
 614                                                         typeId, \
 615                                                         (var_cvar > 1), \
 616                                                         string, \
 617                                                         typestring, \
 618                                                         namestring, \
 619                                                         stringname \
 620                                                 )) \
 621                                         ); \
 622                                 MACRO_END
 623
 624                                 if(GENTLE)
 625                                 {
 626                                         if(gentle != "") { SET_NOTIF_STRING(gentle, "GENTLE"); }
 627                                         else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
 628                                 }
 629                                 else if(normal != "") { SET_NOTIF_STRING(normal, "NORMAL"); }
 630                                 #undef SET_NOTIF_STRING
 631
 632                                 // Check to make sure a string was chosen
 633                                 if(notif.nent_string == "")
 634                                 {
 635                                         LOG_INFOF(
 636                                                 (
 637                                                         "^1EMPTY NOTIFICATION: "
 638                                                         "^7net_type = %s, net_name = %s."
 639                                                 ),
 640                                                 typestring,
 641                                                 namestring
 642                                         );
 643                                         notif_error = true;
 644                                 }
 645                         }
 646                 }
 647
 648 void Create_Notification_Entity_Multi(entity notif,
 649                                                                                 float var_cvar,
 650                                                                                 string namestring,
 651                                                                                 /* MSG_MULTI */
 652                                                                                 Notification anncename,
 653                                                                                 Notification infoname,
 654                                                                                 Notification centername)
 655                 {
 656                         MSG typeId = MSG_MULTI;
 657                         // Set MSG_MULTI string/float counts
 658                         if (!anncename && !infoname && !centername)
 659                         {
 660                                 string typestring = Get_Notif_TypeName(typeId);
 661                                 LOG_INFOF(
 662                                         (
 663                                                 "^1NOTIFICATION WITH NO SUBCALLS: "
 664                                                 "^7net_type = %s, net_name = %s."
 665                                         ),
 666                                         typestring,
 667                                         namestring
 668                                 );
 669                                 notif_error = true;
 670                         }
 671                         else
 672                         {
 673                                 // announcements don't actually need any arguments, so lets not even count them.
 674                                 if (anncename) { notif.nent_msgannce = anncename; }
 675
 676                                 float infoname_stringcount = 0, infoname_floatcount = 0;
 677                                 float centername_stringcount = 0, centername_floatcount = 0;
 678
 679                                 if (infoname)
 680                                 {
 681                                         notif.nent_msginfo = infoname;
 682                                         infoname_stringcount = notif.nent_msginfo.nent_stringcount;
 683                                         infoname_floatcount = notif.nent_msginfo.nent_floatcount;
 684                                 }
 685
 686                                 if (centername)
 687                                 {
 688                                         notif.nent_msgcenter = centername;
 689                                         centername_stringcount = notif.nent_msgcenter.nent_stringcount;
 690                                         centername_floatcount = notif.nent_msgcenter.nent_floatcount;
 691                                 }
 692
 693                                 // set the requirements of THIS notification to the totals of its subcalls
 694                                 notif.nent_stringcount = max(infoname_stringcount, centername_stringcount);
 695                                 notif.nent_floatcount = max(infoname_floatcount, centername_floatcount);
 696                         }
 697                 }
 698
 699 void Create_Notification_Entity_Choice(entity notif,
 700                                                                                 float var_cvar,
 701                                                                                 string namestring,
 702                                                                                 /* MSG_CHOICE */
 703                                                                                 float challow_def,
 704                                                                                 float challow_var,
 705                                                                                 MSG chtype,
 706                                                                                 Notification optiona,
 707                                                                                 Notification optionb)
 708                 {
 709                         MSG typeId = MSG_CHOICE;
 710                         if (chtype == MSG_Null || !optiona || !optionb)
 711                         {
 712                                 string typestring = Get_Notif_TypeName(typeId);
 713                                 LOG_INFOF(
 714                                         (
 715                                                 "^1NOTIFICATION IS MISSING CHOICE PARAMS: "
 716                                                 "^7net_type = %s, net_name = %s."
 717                                         ),
 718                                         typestring,
 719                                         namestring
 720                                 );
 721                                 notif_error = true;
 722                         }
 723                         else
 724                         {
 725                                 notif.nent_optiona = optiona;
 726                                 notif.nent_optionb = optionb;
 727                                 notif.nent_challow_def = challow_def; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 728                                 notif.nent_challow_var = challow_var; // 0: never allowed, 1: allowed in warmup, 2: always allowed
 729                                 notif.nent_stringcount = max(notif.nent_optiona.nent_stringcount, notif.nent_optionb.nent_stringcount);
 730                                 notif.nent_floatcount = max(notif.nent_optiona.nent_floatcount, notif.nent_optionb.nent_floatcount);
 731
 732                                 /*#ifdef NOTIFICATIONS_DEBUG
 733                                 Debug_Notification(sprintf(
 734                                         "Create_Notification_Entity(...): MSG_CHOICE: %s\n%s\n%s\n",
 735                                         notif.nent_name,
 736                                         sprintf(
 737                                                 "^ optiona: %s %s : %d %d",
 738                                                 Get_Notif_TypeName(notif.nent_optiona.nent_type),
 739                                                 notif.nent_optiona.nent_name,
 740                                                 notif.nent_optiona.nent_stringcount,
 741                                                 notif.nent_optiona.nent_floatcount
 742                                         ),
 743                                         sprintf(
 744                                                 "^ optionb: %s %s : %d %d",
 745                                                 Get_Notif_TypeName(notif.nent_optionb.nent_type),
 746                                                 notif.nent_optionb.nent_name,
 747                                                 notif.nent_optionb.nent_stringcount,
 748                                                 notif.nent_optionb.nent_floatcount
 749                                         )
 750                                 ));
 751                                 #endif*/
 752                         }
 753                 }
 754
 755
 756 // ===============
 757 //  Cvar Handling
 758 // ===============
 759
 760 // used by MSG_CHOICE to build list of choices
 761 #ifdef SVQC
 762 void Notification_GetCvars(entity this)
 763 {
 764         FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 765                 GetCvars_handleFloat(
 766                         this,
 767                         CS(this),
 768                         get_cvars_s,
 769                         get_cvars_f,
 770                         msg_choice_choices[it.nent_choice_idx],
 771                         sprintf("notification_%s", Get_Notif_CvarName(it))
 772                 );
 773         });
 774 }
 775 #endif
 776
 777 /** used to output notifications.cfg file */
 778 void Dump_Notifications(int fh, bool alsoprint)
 779 {
 780         #define NOTIF_WRITE(str) write_String_To_File(fh, str, alsoprint)
 781
 782         #define NOTIF_WRITE_ENTITY(e, description) \
 783                 NOTIF_WRITE(sprintf( \
 784                         "seta notification_%s \"%d\" \"%s\"\n", \
 785                         Get_Notif_CvarName(e), e.nent_default, description \
 786                 ))
 787
 788         #define NOTIF_WRITE_ENTITY_CHOICE(e, descriptiona, descriptionb) \
 789                 NOTIF_WRITE(sprintf( \
 790                         "seta notification_%s \"%d\" \"%s\"\n" \
 791                         "seta notification_%s_ALLOWED \"%d\" \"%s\"\n", \
 792                         Get_Notif_CvarName(e), e.nent_default, descriptiona, \
 793                         Get_Notif_CvarName(e), e.nent_challow_def, descriptionb \
 794                 ))
 795
 796         #define NOTIF_WRITE_HARDCODED(cvar, default, description) \
 797                 NOTIF_WRITE("seta notification_" cvar " \"" default "\" \"" description "\"\n")
 798
 799         // Note: This warning only applies to the notifications.cfg file that is output...
 800         // You ARE supposed to manually edit this function to add i.e. hard coded
 801         // notification variables for mutators or game modes or such and then
 802         // regenerate the notifications.cfg file from the new code.
 803
 804         NOTIF_WRITE(
 805                 "// ********************************************** //\n"
 806                 "// ** WARNING - DO NOT MANUALLY EDIT THIS FILE ** //\n"
 807                 "// **                                          ** //\n"
 808                 "// **  This file is automatically generated    ** //\n"
 809                 "// **  by code with the command 'dumpnotifs'.  ** //\n"
 810                 "// **                                          ** //\n"
 811                 "// **  If you add a new notification, please   ** //\n"
 812                 "// **  regenerate this file with that command  ** //\n"
 813                 "// **  making sure that the output matches     ** //\n"
 814                 "// **  with the lists and defaults in code.    ** //\n"
 815                 "// **                                          ** //\n"
 816                 "// ********************************************** //\n");
 817
 818         // These notifications will also append their string as a comment...
 819         // This is not necessary, and does not matter if they vary between config versions,
 820         // it is just a semi-helpful tool for those who want to manually change their user settings.
 821
 822         int NOTIF_ANNCE_COUNT = 0;
 823         int NOTIF_INFO_COUNT = 0;
 824         int NOTIF_CENTER_COUNT = 0;
 825         int NOTIF_MULTI_COUNT = 0;
 826         int NOTIF_CHOICE_COUNT = 0;
 827         FOREACH(Notifications, true, {
 828                 switch (it.nent_type)
 829                 {
 830                         case MSG_ANNCE: ++NOTIF_ANNCE_COUNT; break;
 831                         case MSG_INFO: ++NOTIF_INFO_COUNT; break;
 832                         case MSG_CENTER: ++NOTIF_CENTER_COUNT; break;
 833                         case MSG_MULTI: ++NOTIF_MULTI_COUNT; break;
 834                         case MSG_CHOICE: ++NOTIF_CHOICE_COUNT; break;
 835                 }
 836         });
 837
 838         NOTIF_WRITE(sprintf("\n// MSG_ANNCE notifications (count = %d):\n", NOTIF_ANNCE_COUNT));
 839         FOREACH(Notifications, it.nent_type == MSG_ANNCE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 840                 NOTIF_WRITE_ENTITY(it,
 841                         "0 = disabled, 1 = enabled if gentle mode is off, 2 = always enabled"
 842                 );
 843         });
 844
 845         NOTIF_WRITE(sprintf("\n// MSG_INFO notifications (count = %d):\n", NOTIF_INFO_COUNT));
 846         FOREACH(Notifications, it.nent_type == MSG_INFO && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 847                 NOTIF_WRITE_ENTITY(it,
 848                         "0 = off, 1 = print to console, "
 849                         "2 = print to console and chatbox (if notification_allow_chatboxprint is enabled)"
 850                 );
 851         });
 852
 853         NOTIF_WRITE(sprintf("\n// MSG_CENTER notifications (count = %d):\n", NOTIF_CENTER_COUNT));
 854         FOREACH(Notifications, it.nent_type == MSG_CENTER && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 855                 NOTIF_WRITE_ENTITY(it,
 856                         "0 = off, 1 = centerprint"
 857                 );
 858         });
 859
 860         NOTIF_WRITE(sprintf("\n// MSG_MULTI notifications (count = %d):\n", NOTIF_MULTI_COUNT));
 861         FOREACH(Notifications, it.nent_type == MSG_MULTI && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 862                 NOTIF_WRITE_ENTITY(it,
 863                         "Enable this multiple notification"
 864                 );
 865         });
 866
 867         NOTIF_WRITE(sprintf("\n// MSG_CHOICE notifications (count = %d):\n", NOTIF_CHOICE_COUNT));
 868         FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 869                 NOTIF_WRITE_ENTITY_CHOICE(it,
 870                         "Choice for this notification 0 = off, 1 = default message, 2 = verbose message",
 871                         "Allow choice for this notification 0 = off, 1 = only in warmup mode, 2 = always"
 872                 );
 873         });
 874
 875         // edit these to match whichever cvars are used for specific notification options
 876         NOTIF_WRITE("\n// HARD CODED notification variables:\n");
 877
 878         NOTIF_WRITE_HARDCODED(
 879                 "allow_chatboxprint", "1",
 880                 "Allow INFO notifications to be printed to chat box "
 881                 "0 = do not allow, "
 882                 "1 = allow only if allowed by individual notification_INFO* cvars, "
 883                 "2 = force all INFO notifications to be printed to the chatbox"
 884         );
 885
 886         NOTIF_WRITE_HARDCODED(
 887                 "debug", "0",
 888                 "Print extra debug information on all notification function calls "
 889                 "(Requires -DNOTIFICATIONS_DEBUG flag to be enabled on QCSRC compilation)... "
 890                 "0 = disabled, 1 = dprint, 2 = print"
 891         );
 892
 893         NOTIF_WRITE_HARDCODED(
 894                 "errors_are_fatal", "1",
 895                 "If a notification fails upon initialization, cause a Host_Error to stop the program"
 896         );
 897
 898         NOTIF_WRITE_HARDCODED(
 899                 "item_centerprinttime", "1.5",
 900                 "How long to show item information centerprint messages (like 'You got the Electro' or such)"
 901         );
 902
 903         NOTIF_WRITE_HARDCODED(
 904                 "lifetime_mapload", "10",
 905                 "Amount of time that notification entities last immediately at mapload (in seconds) "
 906                 "to help prevent notifications from being lost on early init (like gamestart countdown)"
 907         );
 908
 909         NOTIF_WRITE_HARDCODED(
 910                 "lifetime_runtime", "0.5",
 911                 "Amount of time that notification entities last on the server during runtime (In seconds)"
 912         );
 913
 914         NOTIF_WRITE_HARDCODED(
 915                 "server_allows_location", "1",
 916                 "Server side cvar for allowing death messages to show location information too"
 917         );
 918
 919         NOTIF_WRITE_HARDCODED(
 920                 "show_location", "0",
 921                 "Append location information to MSG_INFO death/kill messages"
 922         );
 923
 924         NOTIF_WRITE_HARDCODED(
 925                 "show_location_string", "",
 926                 "Replacement string piped into sprintf, "
 927                 "so you can do different messages like this: ' at the %s' or ' (near %s)'"
 928         );
 929
 930         NOTIF_WRITE_HARDCODED(
 931                 "show_sprees", "1",
 932                 "Print information about sprees in death/kill messages"
 933         );
 934
 935         NOTIF_WRITE_HARDCODED(
 936                 "show_sprees_center", "1",
 937                 "Show spree information in MSG_CENTER messages... "
 938                 "0 = off, 1 = target (but only for first victim) and attacker"
 939         );
 940
 941         NOTIF_WRITE_HARDCODED(
 942                 "show_sprees_center_specialonly", "1",
 943                 "Don't show spree information in MSG_CENTER messages if it isn't an achievement"
 944         );
 945
 946         NOTIF_WRITE_HARDCODED(
 947                 "show_sprees_info", "3",
 948                 "Show spree information in MSG_INFO messages... "
 949                 "0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker"
 950         );
 951
 952         NOTIF_WRITE_HARDCODED(
 953                 "show_sprees_info_newline", "1",
 954                 "Show attacker spree information for MSG_INFO messages on a separate line than the death notification itself"
 955         );
 956
 957         NOTIF_WRITE_HARDCODED(
 958                 "show_sprees_info_specialonly", "1",
 959                 "Don't show attacker spree information in MSG_INFO messages if it isn't an achievement"
 960         );
 961
 962         NOTIF_WRITE(sprintf(
 963                 (
 964                         "\n// Notification counts (total = %d): "
 965                         "MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
 966                 ),
 967                 (
 968                         NOTIF_ANNCE_COUNT +
 969                         NOTIF_INFO_COUNT +
 970                         NOTIF_CENTER_COUNT +
 971                         NOTIF_MULTI_COUNT +
 972                         NOTIF_CHOICE_COUNT
 973                 ),
 974                 NOTIF_ANNCE_COUNT,
 975                 NOTIF_INFO_COUNT,
 976                 NOTIF_CENTER_COUNT,
 977                 NOTIF_MULTI_COUNT,
 978                 NOTIF_CHOICE_COUNT
 979         ));
 980         #undef NOTIF_WRITE_HARDCODED
 981         #undef NOTIF_WRITE_ENTITY
 982         #undef NOTIF_WRITE
 983 }
 984
 985
 986 // ===============================
 987 //  Frontend Notification Pushing
 988 // ===============================
 989
 990 string Local_Notification_sprintf(
 991         string input, string args,
 992         string s1, string s2, string s3, string s4,
 993         int f1, float f2, float f3, float f4)
 994 {
 995         #ifdef NOTIFICATIONS_DEBUG
 996         Debug_Notification(sprintf(
 997                 "Local_Notification_sprintf('%s^7', '%s', %s, %s);\n",
 998                 MakeConsoleSafe(input),
 999                 args,
1000                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1001                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1002         ));
1003         #endif
1004
1005         for (int sel_num = 0; sel_num < NOTIF_MAX_ARGS; ++sel_num) { arg_slot[sel_num] = ""; }
1006
1007         for (int sel_num = 0; (args != ""); )
1008         {
1009                 string selected = car(args); args = cdr(args);
1010                 NOTIF_HIT_MAX(NOTIF_MAX_ARGS, "Local_Notification_sprintf");
1011                 string tmp_s; // used by NOTIF_ARGUMENT_LIST
1012                 switch (strtolower(selected))
1013                 {
1014                         #define ARG_CASE_ARG_CS_SV_HA(selected, result) case selected: arg_slot[sel_num++] = result; break;
1015                         #define ARG_CASE_ARG_CS_SV_DC(selected, result) case selected: arg_slot[sel_num++] = result; break;
1016                         #define ARG_CASE_ARG_CS_SV(selected, result)    case selected: arg_slot[sel_num++] = result; break;
1017 #ifdef CSQC
1018                         #define ARG_CASE_ARG_CS(selected, result)       case selected: arg_slot[sel_num++] = result; break;
1019                         #define ARG_CASE_ARG_SV(selected, result)
1020 #else
1021                         #define ARG_CASE_ARG_CS(selected, result)
1022                         #define ARG_CASE_ARG_SV(selected, result)       case selected: arg_slot[sel_num++] = result; break;
1023 #endif
1024                         #define ARG_CASE_ARG_DC(selected, result)
1025                         #define ARG_CASE(prog, selected, result)        ARG_CASE_##prog(selected, result)
1026                         NOTIF_ARGUMENT_LIST
1027                         #undef ARG_CASE
1028                         #undef ARG_CASE_ARG_DC
1029                         #undef ARG_CASE_ARG_SV
1030                         #undef ARG_CASE_ARG_CS
1031                         #undef ARG_CASE_ARG_CS_SV
1032                         #undef ARG_CASE_ARG_CS_SV_DC
1033                         #undef ARG_CASE_ARG_CS_SV_HA
1034                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_ARGS, "Local_Notification_sprintf")
1035                 }
1036         }
1037         return sprintf(
1038                 strcat(input, "\n"),
1039                 arg_slot[0],
1040                 arg_slot[1],
1041                 arg_slot[2],
1042                 arg_slot[3],
1043                 arg_slot[4],
1044                 arg_slot[5],
1045                 arg_slot[6]
1046         );
1047 }
1048
1049 #ifdef CSQC
1050 void Local_Notification_sound(int soundchannel, string soundfile, float soundvolume, float soundposition)
1051 {
1052         if ((soundfile != prev_soundfile) || (time >= (prev_soundtime + autocvar_cl_announcer_antispam)))
1053         {
1054                 #ifdef NOTIFICATIONS_DEBUG
1055                 Debug_Notification(sprintf(
1056                         "Local_Notification_sound(%f, '%s', %f, %f);\n",
1057                         soundchannel,
1058                         AnnouncerFilename(soundfile),
1059                         soundvolume,
1060                         soundposition
1061                 ));
1062                 #endif
1063
1064                 _sound(NULL, soundchannel, AnnouncerFilename(soundfile), soundvolume, soundposition);
1065
1066                 strcpy(prev_soundfile, soundfile);
1067                 prev_soundtime = time;
1068         }
1069         else
1070         {
1071                 #ifdef NOTIFICATIONS_DEBUG
1072                 Debug_Notification(sprintf(
1073                         (
1074                                 "Local_Notification_sound(%f, '%s', %f, %f) "
1075                                 "^1BLOCKED BY ANTISPAM:^7 prevsnd: '%s', timediff: %f, limit: %f\n"
1076                         ),
1077                         soundchannel,
1078                         AnnouncerFilename(soundfile),
1079                         soundvolume,
1080                         soundposition,
1081                         prev_soundfile,
1082                         (time - prev_soundtime),
1083                         autocvar_cl_announcer_antispam
1084                 ));
1085                 #endif
1086         }
1087 }
1088
1089 void Local_Notification_HUD_Notify_Push(
1090         string icon, string hudargs,
1091         string s1, string s2, string s3, string s4,
1092         float f1, float f2, float f3, float f4)
1093 {
1094         arg_slot[0] = ""; arg_slot[1] = "";
1095
1096         for (int sel_num = 0; (hudargs != ""); )
1097         {
1098                 string selected = car(hudargs); hudargs = cdr(hudargs);
1099                 NOTIF_HIT_MAX(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push");
1100                 switch (strtolower(selected))
1101                 {
1102                         #define ARG_CASE_ARG_CS_SV_HA(selected, result) case selected: arg_slot[sel_num++] = result; break;
1103                         #define ARG_CASE_ARG_CS_SV_DC(selected, result)
1104                         #define ARG_CASE_ARG_CS_SV(selected, result)
1105                         #define ARG_CASE_ARG_CS(selected, result)
1106                         #define ARG_CASE_ARG_SV(selected, result)
1107                         #define ARG_CASE_ARG_DC(selected, result)
1108                         #define ARG_CASE(prog, selected, result)        ARG_CASE_##prog(selected, result)
1109                         NOTIF_ARGUMENT_LIST
1110                         #undef ARG_CASE
1111                         #undef ARG_CASE_ARG_DC
1112                         #undef ARG_CASE_ARG_SV
1113                         #undef ARG_CASE_ARG_CS
1114                         #undef ARG_CASE_ARG_CS_SV
1115                         #undef ARG_CASE_ARG_CS_SV_DC
1116                         #undef ARG_CASE_ARG_CS_SV_HA
1117                         default: NOTIF_HIT_UNKNOWN(NOTIF_MAX_HUDARGS, "Local_Notification_HUD_Notify_Push")
1118                 }
1119         }
1120         #ifdef NOTIFICATIONS_DEBUG
1121         Debug_Notification(sprintf(
1122                 "Local_Notification_HUD_Notify_Push('%s^7', '%s', %s, %s, %s);\n",
1123                 icon,
1124                 hudargs,
1125                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1126                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4),
1127                 MakeConsoleSafe(sprintf("'%s^7', '%s^7'", stof(arg_slot[0]), stof(arg_slot[1])))
1128         ));
1129         #endif
1130         HUD_Notify_Push(icon, arg_slot[0], arg_slot[1]);
1131 }
1132
1133 void Local_Notification_centerprint_Add(
1134         string input, string durcnt,
1135         CPID cpid, float f1, float f2)
1136 {
1137         arg_slot[0] = ""; arg_slot[1] = "";
1138
1139         for (int sel_num = 0; (durcnt != ""); )
1140         {
1141                 string selected = car(durcnt); durcnt = cdr(durcnt);
1142                 NOTIF_HIT_MAX(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_Add");
1143                 switch (strtolower(selected))
1144                 {
1145                         #define ARG_CASE_ARG_CS_SV_HA(selected, result)
1146                         #define ARG_CASE_ARG_CS_SV_DC(selected, result) case selected: arg_slot[sel_num++] = result; break;
1147                         #define ARG_CASE_ARG_CS_SV(selected, result)
1148                         #define ARG_CASE_ARG_CS(selected, result)
1149                         #define ARG_CASE_ARG_SV(selected, result)
1150                         #define ARG_CASE_ARG_DC(selected, result)       case selected: arg_slot[sel_num++] = result; break;
1151                         #define ARG_CASE(prog, selected, result)        ARG_CASE_##prog(selected,result)
1152                         NOTIF_ARGUMENT_LIST
1153                         #undef ARG_CASE
1154                         #undef ARG_CASE_ARG_DC
1155                         #undef ARG_CASE_ARG_SV
1156                         #undef ARG_CASE_ARG_CS
1157                         #undef ARG_CASE_ARG_CS_SV
1158                         #undef ARG_CASE_ARG_CS_SV_DC
1159                         #undef ARG_CASE_ARG_CS_SV_HA
1160                         default:
1161                         {
1162                                 if (/* wtf */ ftos(stof(selected)) != "") { arg_slot[sel_num++] = selected; }
1163                                 else { NOTIF_HIT_UNKNOWN(NOTIF_MAX_DURCNT, "Local_Notification_centerprint_Add") }
1164                                 break;
1165                         }
1166                 }
1167         }
1168         #ifdef NOTIFICATIONS_DEBUG
1169         Debug_Notification(sprintf(
1170                 "Local_Notification_centerprint_Add('%s^7', '%s', %d, %d, %d, %d);\n",
1171                 MakeConsoleSafe(input),
1172                 durcnt,
1173                 f1, f2,
1174                 stof(arg_slot[0]),
1175                 stof(arg_slot[1])
1176         ));
1177         #endif
1178         centerprint_Add(ORDINAL(cpid), input, stof(arg_slot[0]), stof(arg_slot[1]));
1179 }
1180 #endif
1181
1182 void Local_Notification(MSG net_type, Notification net_name, ...count)
1183 {
1184         // retreive entity of this notification
1185         entity notif = net_name;
1186         if (!notif)
1187         {
1188                 #ifdef NOTIFICATIONS_DEBUG
1189                 Debug_Notification(sprintf(
1190                         "Local_Notification(%s, NULL, ...);\n",
1191                         Get_Notif_TypeName(net_type)
1192                 ));
1193                 #endif
1194                 LOG_WARNF("Incorrect usage of Local_Notification: %s", "Null notification");
1195                 return;
1196         }
1197
1198         // check if the notification is enabled
1199         if (!notif.nent_enabled)
1200         {
1201                 #ifdef NOTIFICATIONS_DEBUG
1202                 Debug_Notification(sprintf(
1203                         "Local_Notification(%s, %s, ...): Entity was disabled...\n",
1204                         Get_Notif_TypeName(net_type),
1205                         notif.nent_name
1206                 ));
1207                 #endif
1208                 return;
1209         }
1210
1211         string s1 = CCR((notif.nent_stringcount > 0) ? ...(0, string) : "");
1212         string s2 = CCR((notif.nent_stringcount > 1) ? ...(1, string) : "");
1213         string s3 = CCR((notif.nent_stringcount > 2) ? ...(2, string) : "");
1214         string s4 = CCR((notif.nent_stringcount > 3) ? ...(3, string) : "");
1215         float f1 =  ((notif.nent_floatcount  > 0) ? ...((notif.nent_stringcount + 0), float) : 0);
1216         float f2 =  ((notif.nent_floatcount  > 1) ? ...((notif.nent_stringcount + 1), float) : 0);
1217         float f3 =  ((notif.nent_floatcount  > 2) ? ...((notif.nent_stringcount + 2), float) : 0);
1218         float f4 =  ((notif.nent_floatcount  > 3) ? ...((notif.nent_stringcount + 3), float) : 0);
1219
1220         #ifdef NOTIFICATIONS_DEBUG
1221         Debug_Notification(sprintf(
1222                 "Local_Notification(%s, %s, %s, %s);\n",
1223                 Get_Notif_TypeName(net_type),
1224                 notif.nent_name,
1225                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1226                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1227         ));
1228         #endif
1229
1230         if ((notif.nent_stringcount + notif.nent_floatcount) != count)
1231         {
1232                 backtrace(sprintf(
1233                         (
1234                                 "Arguments mismatch for Local_Notification(%s, %s, ...)! "
1235                                 "stringcount(%d) + floatcount(%d) != count(%d)\n"
1236                                 "Check the definition and function call for accuracy...?\n"
1237                         ),
1238                         Get_Notif_TypeName(net_type),
1239                         notif.nent_name,
1240                         notif.nent_stringcount,
1241                         notif.nent_floatcount,
1242                         count
1243                 ));
1244                 return;
1245         }
1246
1247         switch (net_type)
1248         {
1249                 case MSG_ANNCE:
1250                 {
1251                         #ifdef CSQC
1252                         Local_Notification_sound(notif.nent_channel, notif.nent_snd, notif.nent_vol, notif.nent_position);
1253                         #else
1254                         backtrace("MSG_ANNCE on server?... Please notify Samual immediately!\n");
1255                         #endif
1256                         break;
1257                 }
1258
1259                 case MSG_INFO:
1260                 {
1261                         print(
1262                                 Local_Notification_sprintf(
1263                                         notif.nent_string,
1264                                         notif.nent_args,
1265                                         s1, s2, s3, s4,
1266                                         f1, f2, f3, f4)
1267                         );
1268                         #ifdef CSQC
1269                         if (notif.nent_icon != "")
1270                         {
1271                                 if (notif.nent_iconargs != "")
1272                                 {
1273                                         string s = Local_Notification_sprintf(
1274                                                 notif.nent_icon,notif.nent_iconargs,
1275                                                 s1, s2, s3, s4, f1, f2, f3, f4);
1276                                         // remove the trailing newline
1277                                         notif.nent_icon = strzone(substring(s, 0, -1));
1278                                 }
1279                                 Local_Notification_HUD_Notify_Push(
1280                                         notif.nent_icon,
1281                                         notif.nent_hudargs,
1282                                         s1, s2, s3, s4,
1283                                         f1, f2, f3, f4);
1284                         }
1285                         #endif
1286                         break;
1287                 }
1288
1289                 #ifdef CSQC
1290                 case MSG_CENTER:
1291                 {
1292                         Local_Notification_centerprint_Add(
1293                                 Local_Notification_sprintf(
1294                                         notif.nent_string,
1295                                         notif.nent_args,
1296                                         s1, s2, s3, s4,
1297                                         f1, f2, f3, f4),
1298                                 notif.nent_durcnt,
1299                                 notif.nent_cpid,
1300                                 f1, f2);
1301                         break;
1302                 }
1303                 #endif
1304
1305                 case MSG_MULTI:
1306                 {
1307                         if (notif.nent_msginfo && notif.nent_msginfo.nent_enabled)
1308                         {
1309                                 Local_Notification_WOVA(
1310                                         MSG_INFO,
1311                                         notif.nent_msginfo,
1312                                         notif.nent_msginfo.nent_stringcount,
1313                                         notif.nent_msginfo.nent_floatcount,
1314                                         s1, s2, s3, s4,
1315                                         f1, f2, f3, f4);
1316                         }
1317                         #ifdef CSQC
1318                         if (notif.nent_msgannce && notif.nent_msgannce.nent_enabled)
1319                         {
1320                                 Local_Notification_WOVA(
1321                                         MSG_ANNCE,
1322                                         notif.nent_msgannce,
1323                                         0, 0,
1324                                         "", "", "", "",
1325                                         0, 0, 0, 0);
1326                         }
1327                         if (notif.nent_msgcenter && notif.nent_msgcenter.nent_enabled)
1328                         {
1329                                 Local_Notification_WOVA(
1330                                         MSG_CENTER,
1331                                         notif.nent_msgcenter,
1332                                         notif.nent_msgcenter.nent_stringcount,
1333                                         notif.nent_msgcenter.nent_floatcount,
1334                                         s1, s2, s3, s4,
1335                                         f1, f2, f3, f4);
1336                         }
1337                         #endif
1338                         break;
1339                 }
1340
1341                 case MSG_CHOICE:
1342                 {
1343                         entity found_choice = notif.nent_optiona;
1344                         if (notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) {
1345                                 switch (cvar(sprintf("notification_%s", Get_Notif_CvarName(notif))))
1346                                 {
1347                                         case 1: break;
1348                                         case 2: found_choice = notif.nent_optionb; break;
1349                                         default: return; // not enabled anyway
1350                                 }
1351                         }
1352
1353                         Local_Notification_WOVA(
1354                                 found_choice.nent_type,
1355                                 found_choice,
1356                                 found_choice.nent_stringcount,
1357                                 found_choice.nent_floatcount,
1358                                 s1, s2, s3, s4,
1359                                 f1, f2, f3, f4);
1360                 }
1361         }
1362 }
1363
1364 // WOVA = Without Variable Arguments
1365 void Local_Notification_WOVA(
1366         MSG net_type, Notification net_name,
1367         float stringcount, float floatcount,
1368         string s1, string s2, string s3, string s4,
1369         float f1, float f2, float f3, float f4)
1370 {
1371         #define VARITEM(stringc, floatc, args) \
1372                 if ((stringcount == stringc) && (floatcount == floatc)) \
1373                 { Local_Notification(net_type, net_name, args); return; }
1374         EIGHT_VARS_TO_VARARGS_VARLIST
1375         #undef VARITEM
1376         Local_Notification(net_type, net_name); // some notifications don't have any arguments at all
1377 }
1378
1379
1380 // =========================
1381 //  Notification Networking
1382 // =========================
1383
1384 /** networked as a linked entity to give newly connecting clients some notification context */
1385 REGISTER_NET_LINKED(ENT_CLIENT_NOTIFICATION)
1386
1387 #ifdef CSQC
1388 NET_HANDLE(ENT_CLIENT_NOTIFICATION, bool is_new)
1389 {
1390         make_pure(this);
1391         MSG net_type = ENUMCAST(MSG, ReadByte());
1392         int net_name = ReadShort();
1393     return = true;
1394
1395         if (net_type == MSG_CENTER_KILL)
1396     {
1397         if (!is_new) return;
1398         // killing
1399         #ifdef NOTIFICATIONS_DEBUG
1400         Debug_Notification(sprintf(
1401             "Read_Notification(%d) at %f: net_type = %s, cpid = %d\n",
1402             is_new,
1403             time,
1404             Get_Notif_TypeName(net_type),
1405             net_name
1406         ));
1407         #endif
1408         int _net_name = net_name;
1409         CPID net_name = ENUMCAST(CPID, _net_name);
1410         if (net_name == CPID_Null) {
1411             centerprint_KillAll();
1412         } else {
1413             centerprint_Kill(ORDINAL(net_name));// kill group
1414         }
1415         return;
1416     }
1417
1418         Notification notif = Get_Notif_Ent(net_type, net_name);
1419
1420         #ifdef NOTIFICATIONS_DEBUG
1421         Debug_Notification(sprintf(
1422                 "Read_Notification(%d) at %f: net_type = %s, net_name = %s (%d)\n",
1423                 is_new,
1424                 time,
1425                 Get_Notif_TypeName(net_type),
1426                 notif.registered_id,
1427                 net_name
1428         ));
1429         #endif
1430
1431     if (!notif) {
1432         backtrace("Read_Notification: Could not find notification entity!\n");
1433         return false;
1434     }
1435
1436     string s1 = ((notif.nent_stringcount > 0) ? ReadString() : "");
1437     string s2 = ((notif.nent_stringcount > 1) ? ReadString() : "");
1438     string s3 = ((notif.nent_stringcount > 2) ? ReadString() : "");
1439     string s4 = ((notif.nent_stringcount > 3) ? ReadString() : "");
1440     float f1 = ((notif.nent_floatcount > 0) ? ReadLong() : 0);
1441     float f2 = ((notif.nent_floatcount > 1) ? ReadLong() : 0);
1442     float f3 = ((notif.nent_floatcount > 2) ? ReadLong() : 0);
1443     float f4 = ((notif.nent_floatcount > 3) ? ReadLong() : 0);
1444
1445     if (!is_new) return;
1446     Local_Notification_WOVA(
1447         net_type, notif,
1448         notif.nent_stringcount,
1449         notif.nent_floatcount,
1450         s1, s2, s3, s4,
1451         f1, f2, f3, f4);
1452 }
1453 #endif
1454
1455 #ifdef SVQC
1456 void Net_Notification_Remove(entity this)
1457 {
1458         #ifdef NOTIFICATIONS_DEBUG
1459         Debug_Notification(sprintf(
1460                 "Net_Notification_Remove() at %f: %s '%s - %s' notification\n",
1461                 time,
1462                 ((this.nent_net_name == -1) ? "Killed" : "Removed"),
1463                 Get_Notif_TypeName(this.nent_net_type),
1464                 this.owner.nent_name
1465         ));
1466         #endif
1467         for (int i = 0; i < this.nent_stringcount; ++i) { strfree(this.nent_strings[i]); }
1468         delete(this);
1469 }
1470
1471 bool Net_Write_Notification(entity this, entity client, int sf)
1472 {
1473         if (!Notification_ShouldSend(this.nent_broadcast, client, this.nent_client)) return false;
1474         WriteHeader(MSG_ENTITY, ENT_CLIENT_NOTIFICATION);
1475         WriteByte(MSG_ENTITY, ORDINAL(this.nent_net_type));
1476         WriteShort(MSG_ENTITY, this.nent_net_name);
1477         for (int i = 0; i < this.nent_stringcount; ++i) { WriteString(MSG_ENTITY, this.nent_strings[i]); }
1478         for (int i = 0; i < this.nent_floatcount; ++i) { WriteLong(MSG_ENTITY, this.nent_floats[i]); }
1479         return true;
1480 }
1481
1482 void Kill_Notification(
1483         NOTIF broadcast, entity client,
1484         /** message group, MSG_Null for all */
1485         MSG net_type,
1486         /** cpid group, CPID_Null for all */
1487         CPID net_cpid)
1488 {
1489         #ifdef NOTIFICATIONS_DEBUG
1490         Debug_Notification(sprintf(
1491                 "Kill_Notification(%s, '%s', %s, %d);\n",
1492                 Get_Notif_BroadcastName(broadcast),
1493                 client.netname,
1494                 (net_type ? Get_Notif_TypeName(net_type) : "0"),
1495                 net_cpid
1496         ));
1497         #endif
1498
1499         string checkargs = Notification_CheckArgs(broadcast, client);
1500         if (checkargs != "") { LOG_WARNF("Incorrect usage of Kill_Notification: %s", checkargs); return; }
1501
1502         entity net_notif = new_pure(net_kill_notification);
1503         net_notif.nent_broadcast = broadcast;
1504         net_notif.nent_client = client;
1505         net_notif.nent_net_type = MSG_CENTER_KILL;
1506         net_notif.nent_net_name = ORDINAL(net_cpid);
1507         Net_LinkEntity(net_notif, false, autocvar_notification_lifetime_runtime, Net_Write_Notification);
1508
1509         IL_EACH(g_notifications,
1510                 (it.owner.nent_type == net_type || net_type == MSG_Null) && (it.owner.nent_cpid == net_cpid || net_cpid == CPID_Null),
1511                 {
1512                         it.nent_net_name = -1;
1513                         it.nextthink = time;
1514                 }
1515         );
1516 }
1517
1518 void Send_Notification(
1519         NOTIF broadcast, entity client,
1520         MSG net_type, Notification net_name,
1521         ...count)
1522 {
1523     if (broadcast != NOTIF_ALL && broadcast != NOTIF_ALL_EXCEPT && !IS_REAL_CLIENT(client)) return;
1524         entity notif = net_name;
1525         string parms = sprintf("%s, '%s', %s, %s",
1526                 Get_Notif_BroadcastName(broadcast),
1527                 client.classname,
1528                 Get_Notif_TypeName(net_type),
1529                 net_name.registered_id
1530         );
1531         #ifdef NOTIFICATIONS_DEBUG
1532         Debug_Notification(sprintf("Send_Notification(%s, ...%d);\n", parms, count));
1533         #endif
1534
1535         if (!notif)
1536         {
1537                 LOG_WARN("Send_Notification: Could not find notification entity!");
1538                 return;
1539         }
1540
1541         // check supplied broadcast, target, type, and name for errors
1542         string checkargs = Notification_CheckArgs(broadcast, client);
1543     if (!net_name) { checkargs = sprintf("No notification provided! %s", checkargs); }
1544         if (checkargs != "")
1545         {
1546                 LOG_WARNF("Incorrect usage of Send_Notification: %s", checkargs);
1547                 return;
1548         }
1549
1550         string s1 = ((0 < notif.nent_stringcount) ? ...(0, string) : "");
1551         string s2 = ((1 < notif.nent_stringcount) ? ...(1, string) : "");
1552         string s3 = ((2 < notif.nent_stringcount) ? ...(2, string) : "");
1553         string s4 = ((3 < notif.nent_stringcount) ? ...(3, string) : "");
1554         float f1 = ((0 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 0), float) : 0);
1555         float f2 = ((1 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 1), float) : 0);
1556         float f3 = ((2 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 2), float) : 0);
1557         float f4 = ((3 < notif.nent_floatcount) ? ...((notif.nent_stringcount + 3), float) : 0);
1558
1559         #ifdef NOTIFICATIONS_DEBUG
1560         Debug_Notification(sprintf(
1561                 "Send_Notification(%s, %s, %s);\n",
1562                 parms,
1563                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1564                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1565         ));
1566         #endif
1567
1568         if ((notif.nent_stringcount + notif.nent_floatcount) != count)
1569         {
1570                 LOG_WARNF(
1571                         "Argument mismatch for Send_Notification(%s, ...)! "
1572                         "stringcount(%d) + floatcount(%d) != count(%d)\n"
1573                         "Check the definition and function call for accuracy...?\n",
1574                         parms,
1575                         notif.nent_stringcount,
1576                         notif.nent_floatcount,
1577                         count
1578                 );
1579                 return;
1580         }
1581
1582         if (server_is_dedicated
1583                 && (broadcast == NOTIF_ALL || broadcast == NOTIF_ALL_EXCEPT)
1584                 && !(net_type == MSG_ANNCE || net_type == MSG_CENTER)
1585         )
1586         {
1587                 Local_Notification_WOVA(
1588                         net_type, net_name,
1589                         notif.nent_stringcount,
1590                         notif.nent_floatcount,
1591                         s1, s2, s3, s4,
1592                         f1, f2, f3, f4);
1593         }
1594
1595         if (net_type == MSG_CHOICE)
1596         {
1597                 // THIS GETS TRICKY... now we have to cycle through each possible player (checking broadcast)
1598                 // and then do an individual NOTIF_ONE_ONLY recursive call for each one depending on their option...
1599                 // It's slow, but it's better than the alternatives:
1600                 //   1. Constantly networking all info and letting client decide
1601                 //   2. Manually handling each separate call on per-usage basis (See old CTF usage of verbose)
1602                 entity found_choice;
1603
1604                 #define RECURSE_FROM_CHOICE(ent,action) MACRO_BEGIN \
1605                         if (notif.nent_challow_var && (warmup_stage || (notif.nent_challow_var == 2))) { \
1606                                 switch (CS(ent).msg_choice_choices[net_name.nent_choice_idx]) \
1607                                 { \
1608                                         case 1: found_choice = notif.nent_optiona; break; \
1609                                         case 2: found_choice = notif.nent_optionb; break; \
1610                                         default: action; \
1611                                 } \
1612                         } else { \
1613                                 found_choice = notif.nent_optiona; \
1614                         } \
1615                         Send_Notification_WOVA( \
1616                                 NOTIF_ONE_ONLY, \
1617                                 ent, \
1618                                 found_choice.nent_type, \
1619                                 found_choice, \
1620                                 found_choice.nent_stringcount, \
1621                                 found_choice.nent_floatcount, \
1622                                 s1, s2, s3, s4, \
1623                                 f1, f2, f3, f4); \
1624                 MACRO_END
1625
1626                 switch (broadcast)
1627                 {
1628                         case NOTIF_ONE_ONLY: // we can potentially save processing power with this broadcast method
1629                         {
1630                                 if (IS_REAL_CLIENT(client)) {
1631                                         RECURSE_FROM_CHOICE(client, return);
1632                                 }
1633                                 break;
1634                         }
1635                         default:
1636                         {
1637                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && Notification_ShouldSend(broadcast, it, client), {
1638                                         RECURSE_FROM_CHOICE(it, continue);
1639                                 });
1640                                 break;
1641                         }
1642                 }
1643         }
1644         else
1645         {
1646                 entity net_notif = new_pure(net_notification);
1647                 IL_PUSH(g_notifications, net_notif);
1648                 net_notif.owner = notif;
1649                 net_notif.nent_broadcast = broadcast;
1650                 net_notif.nent_client = client;
1651                 net_notif.nent_net_type = net_type;
1652                 net_notif.nent_net_name = notif.m_id;
1653                 net_notif.nent_stringcount = notif.nent_stringcount;
1654                 net_notif.nent_floatcount = notif.nent_floatcount;
1655
1656                 for (int i = 0; i < net_notif.nent_stringcount; ++i) {
1657                         net_notif.nent_strings[i] = strzone(...(i, string));
1658                 }
1659                 for (int i = 0; i < net_notif.nent_floatcount; ++i) {
1660                         net_notif.nent_floats[i] = ...((net_notif.nent_stringcount + i), float);
1661                 }
1662
1663                 setthink(net_notif, Net_Notification_Remove);
1664                 net_notif.nextthink = (time > autocvar_notification_lifetime_mapload)
1665                         ? (time + autocvar_notification_lifetime_runtime)
1666                         : autocvar_notification_lifetime_mapload;
1667
1668                 Net_LinkEntity(net_notif, false, 0, Net_Write_Notification);
1669         }
1670 }
1671
1672 // WOVA = Without Variable Arguments
1673 void Send_Notification_WOVA(
1674         NOTIF broadcast, entity client,
1675         MSG net_type, Notification net_name,
1676         float stringcount, float floatcount,
1677         string s1, string s2, string s3, string s4,
1678         float f1, float f2, float f3, float f4)
1679 {
1680         #ifdef NOTIFICATIONS_DEBUG
1681         entity notif = net_name;
1682         Debug_Notification(sprintf(
1683                 "Send_Notification_WOVA(%s, %d, %d, %s, %s);\n",
1684                 sprintf(
1685                         "%s, '%s', %s, %s",
1686                         Get_Notif_BroadcastName(broadcast),
1687                         client.classname,
1688                         Get_Notif_TypeName(net_type),
1689                         notif.nent_name
1690                 ),
1691                 stringcount,
1692                 floatcount,
1693                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1694                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1695         ));
1696         #endif
1697
1698         #define VARITEM(stringc, floatc, args) \
1699                 if ((stringcount == stringc) && (floatcount == floatc)) \
1700                 { Send_Notification(broadcast, client, net_type, net_name, args); return; }
1701         EIGHT_VARS_TO_VARARGS_VARLIST
1702         #undef VARITEM
1703         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
1704 }
1705
1706 // WOCOVA = Without Counts Or Variable Arguments
1707 void Send_Notification_WOCOVA(
1708         NOTIF broadcast, entity client,
1709         MSG net_type, Notification net_name,
1710         string s1, string s2, string s3, string s4,
1711         float f1, float f2, float f3, float f4)
1712 {
1713         entity notif = net_name;
1714
1715         #ifdef NOTIFICATIONS_DEBUG
1716         Debug_Notification(sprintf(
1717                 "Send_Notification_WOCOVA(%s, %s, %s);\n",
1718                 sprintf(
1719                         "%s, '%s', %s, %s",
1720                         Get_Notif_BroadcastName(broadcast),
1721                         client.classname,
1722                         Get_Notif_TypeName(net_type),
1723                         notif.nent_name
1724                 ),
1725                 MakeConsoleSafe(sprintf("'%s^7', '%s^7', '%s^7', '%s^7'", s1, s2, s3, s4)),
1726                 sprintf("%d, %d, %d, %d", f1, f2, f3, f4)
1727         ));
1728         #endif
1729
1730         #define VARITEM(stringc, floatc, args) \
1731                 if ((notif.nent_stringcount == stringc) && (notif.nent_floatcount == floatc)) \
1732                 { Send_Notification(broadcast, client, net_type, net_name, args); return; }
1733         EIGHT_VARS_TO_VARARGS_VARLIST
1734         #undef VARITEM
1735         Send_Notification(broadcast, client, net_type, net_name); // some notifications don't have any arguments at all
1736 }
1737 #endif // ifdef SVQC